// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

import {IAdminable} from "../interfaces/IAdminable.sol";

/// @title Adminable
abstract contract Adminable is IAdminable {
    /// @inheritdoc IAdminable
    address public admin;

    /// @notice Reverts if called by any account other than the admin.
    modifier onlyAdmin() {
        _checkAdmin();
        _;
    }

    /// @param _initialAdmin The address of the initial admin.
    constructor(address _initialAdmin) {
        if (_initialAdmin == address(0)) {
            revert AdminableUnauthorizedAccount(address(0), address(0));
        }
        _transferAdmin(address(0), _initialAdmin);
    }

    /// @inheritdoc IAdminable
    function transferAdmin(address _newAdmin) external onlyAdmin {
        _transferAdmin(msg.sender, _newAdmin);
    }

    /// @inheritdoc IAdminable
    function renounceAdmin() external onlyAdmin {
        _transferAdmin(msg.sender, address(0));
    }

    /// @notice Checks if msg.sender is the admin, reverts otherwise.
    /// @dev This is an internal function used by the onlyAdmin modifier.
    function _checkAdmin() internal view {
        if (admin != msg.sender) {
            revert AdminableUnauthorizedAccount(admin, msg.sender);
        }
    }

    /// @notice Internal function to handle admin transfer logic.
    /// @param _oldAdmin The address of the current admin.
    /// @param _newAdmin The address of the new admin.
    function _transferAdmin(address _oldAdmin, address _newAdmin) internal {
        admin = _newAdmin;
        emit TransferAdmin(_oldAdmin, _newAdmin);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (token/ERC20/ERC20.sol)

pragma solidity ^0.8.20;

import {IERC20} from "./IERC20.sol";
import {IERC20Metadata} from "./extensions/IERC20Metadata.sol";
import {Context} from "../../utils/Context.sol";
import {IERC20Errors} from "../../interfaces/draft-IERC6093.sol";

/**
 * @dev Implementation of the {IERC20} interface.
 *
 * This implementation is agnostic to the way tokens are created. This means
 * that a supply mechanism has to be added in a derived contract using {_mint}.
 *
 * TIP: For a detailed writeup see our guide
 * https://forum.openzeppelin.com/t/how-to-implement-erc20-supply-mechanisms/226[How
 * to implement supply mechanisms].
 *
 * The default value of {decimals} is 18. To change this, you should override
 * this function so it returns a different value.
 *
 * We have followed general OpenZeppelin Contracts guidelines: functions revert
 * instead returning `false` on failure. This behavior is nonetheless
 * conventional and does not conflict with the expectations of ERC-20
 * applications.
 */
abstract contract ERC20 is Context, IERC20, IERC20Metadata, IERC20Errors {
    mapping(address account => uint256) private _balances;

    mapping(address account => mapping(address spender => uint256)) private _allowances;

    uint256 private _totalSupply;

    string private _name;
    string private _symbol;

    /**
     * @dev Sets the values for {name} and {symbol}.
     *
     * All two of these values are immutable: they can only be set once during
     * construction.
     */
    constructor(string memory name_, string memory symbol_) {
        _name = name_;
        _symbol = symbol_;
    }

    /**
     * @dev Returns the name of the token.
     */
    function name() public view virtual returns (string memory) {
        return _name;
    }

    /**
     * @dev Returns the symbol of the token, usually a shorter version of the
     * name.
     */
    function symbol() public view virtual returns (string memory) {
        return _symbol;
    }

    /**
     * @dev Returns the number of decimals used to get its user representation.
     * For example, if `decimals` equals `2`, a balance of `505` tokens should
     * be displayed to a user as `5.05` (`505 / 10 ** 2`).
     *
     * Tokens usually opt for a value of 18, imitating the relationship between
     * Ether and Wei. This is the default value returned by this function, unless
     * it's overridden.
     *
     * NOTE: This information is only used for _display_ purposes: it in
     * no way affects any of the arithmetic of the contract, including
     * {IERC20-balanceOf} and {IERC20-transfer}.
     */
    function decimals() public view virtual returns (uint8) {
        return 18;
    }

    /**
     * @dev See {IERC20-totalSupply}.
     */
    function totalSupply() public view virtual returns (uint256) {
        return _totalSupply;
    }

    /**
     * @dev See {IERC20-balanceOf}.
     */
    function balanceOf(address account) public view virtual returns (uint256) {
        return _balances[account];
    }

    /**
     * @dev See {IERC20-transfer}.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     * - the caller must have a balance of at least `value`.
     */
    function transfer(address to, uint256 value) public virtual returns (bool) {
        address owner = _msgSender();
        _transfer(owner, to, value);
        return true;
    }

    /**
     * @dev See {IERC20-allowance}.
     */
    function allowance(address owner, address spender) public view virtual returns (uint256) {
        return _allowances[owner][spender];
    }

    /**
     * @dev See {IERC20-approve}.
     *
     * NOTE: If `value` is the maximum `uint256`, the allowance is not updated on
     * `transferFrom`. This is semantically equivalent to an infinite approval.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function approve(address spender, uint256 value) public virtual returns (bool) {
        address owner = _msgSender();
        _approve(owner, spender, value);
        return true;
    }

    /**
     * @dev See {IERC20-transferFrom}.
     *
     * Skips emitting an {Approval} event indicating an allowance update. This is not
     * required by the ERC. See {xref-ERC20-_approve-address-address-uint256-bool-}[_approve].
     *
     * NOTE: Does not update the allowance if the current allowance
     * is the maximum `uint256`.
     *
     * Requirements:
     *
     * - `from` and `to` cannot be the zero address.
     * - `from` must have a balance of at least `value`.
     * - the caller must have allowance for ``from``'s tokens of at least
     * `value`.
     */
    function transferFrom(address from, address to, uint256 value) public virtual returns (bool) {
        address spender = _msgSender();
        _spendAllowance(from, spender, value);
        _transfer(from, to, value);
        return true;
    }

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to`.
     *
     * This internal function is equivalent to {transfer}, and can be used to
     * e.g. implement automatic token fees, slashing mechanisms, etc.
     *
     * Emits a {Transfer} event.
     *
     * NOTE: This function is not virtual, {_update} should be overridden instead.
     */
    function _transfer(address from, address to, uint256 value) internal {
        if (from == address(0)) {
            revert ERC20InvalidSender(address(0));
        }
        if (to == address(0)) {
            revert ERC20InvalidReceiver(address(0));
        }
        _update(from, to, value);
    }

    /**
     * @dev Transfers a `value` amount of tokens from `from` to `to`, or alternatively mints (or burns) if `from`
     * (or `to`) is the zero address. All customizations to transfers, mints, and burns should be done by overriding
     * this function.
     *
     * Emits a {Transfer} event.
     */
    function _update(address from, address to, uint256 value) internal virtual {
        if (from == address(0)) {
            // Overflow check required: The rest of the code assumes that totalSupply never overflows
            _totalSupply += value;
        } else {
            uint256 fromBalance = _balances[from];
            if (fromBalance < value) {
                revert ERC20InsufficientBalance(from, fromBalance, value);
            }
            unchecked {
                // Overflow not possible: value <= fromBalance <= totalSupply.
                _balances[from] = fromBalance - value;
            }
        }

        if (to == address(0)) {
            unchecked {
                // Overflow not possible: value <= totalSupply or value <= fromBalance <= totalSupply.
                _totalSupply -= value;
            }
        } else {
            unchecked {
                // Overflow not possible: balance + value is at most totalSupply, which we know fits into a uint256.
                _balances[to] += value;
            }
        }

        emit Transfer(from, to, value);
    }

    /**
     * @dev Creates a `value` amount of tokens and assigns them to `account`, by transferring it from address(0).
     * Relies on the `_update` mechanism
     *
     * Emits a {Transfer} event with `from` set to the zero address.
     *
     * NOTE: This function is not virtual, {_update} should be overridden instead.
     */
    function _mint(address account, uint256 value) internal {
        if (account == address(0)) {
            revert ERC20InvalidReceiver(address(0));
        }
        _update(address(0), account, value);
    }

    /**
     * @dev Destroys a `value` amount of tokens from `account`, lowering the total supply.
     * Relies on the `_update` mechanism.
     *
     * Emits a {Transfer} event with `to` set to the zero address.
     *
     * NOTE: This function is not virtual, {_update} should be overridden instead
     */
    function _burn(address account, uint256 value) internal {
        if (account == address(0)) {
            revert ERC20InvalidSender(address(0));
        }
        _update(account, address(0), value);
    }

    /**
     * @dev Sets `value` as the allowance of `spender` over the `owner` s tokens.
     *
     * This internal function is equivalent to `approve`, and can be used to
     * e.g. set automatic allowances for certain subsystems, etc.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `owner` cannot be the zero address.
     * - `spender` cannot be the zero address.
     *
     * Overrides to this logic should be done to the variant with an additional `bool emitEvent` argument.
     */
    function _approve(address owner, address spender, uint256 value) internal {
        _approve(owner, spender, value, true);
    }

    /**
     * @dev Variant of {_approve} with an optional flag to enable or disable the {Approval} event.
     *
     * By default (when calling {_approve}) the flag is set to true. On the other hand, approval changes made by
     * `_spendAllowance` during the `transferFrom` operation set the flag to false. This saves gas by not emitting any
     * `Approval` event during `transferFrom` operations.
     *
     * Anyone who wishes to continue emitting `Approval` events on the`transferFrom` operation can force the flag to
     * true using the following override:
     *
     * ```solidity
     * function _approve(address owner, address spender, uint256 value, bool) internal virtual override {
     *     super._approve(owner, spender, value, true);
     * }
     * ```
     *
     * Requirements are the same as {_approve}.
     */
    function _approve(address owner, address spender, uint256 value, bool emitEvent) internal virtual {
        if (owner == address(0)) {
            revert ERC20InvalidApprover(address(0));
        }
        if (spender == address(0)) {
            revert ERC20InvalidSpender(address(0));
        }
        _allowances[owner][spender] = value;
        if (emitEvent) {
            emit Approval(owner, spender, value);
        }
    }

    /**
     * @dev Updates `owner` s allowance for `spender` based on spent `value`.
     *
     * Does not update the allowance value in case of infinite allowance.
     * Revert if not enough allowance is available.
     *
     * Does not emit an {Approval} event.
     */
    function _spendAllowance(address owner, address spender, uint256 value) internal virtual {
        uint256 currentAllowance = allowance(owner, spender);
        if (currentAllowance != type(uint256).max) {
            if (currentAllowance < value) {
                revert ERC20InsufficientAllowance(spender, currentAllowance, value);
            }
            unchecked {
                _approve(owner, spender, currentAllowance - value, false);
            }
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/extensions/ERC20Burnable.sol)

pragma solidity ^0.8.20;

import {ERC20} from "../ERC20.sol";
import {Context} from "../../../utils/Context.sol";

/**
 * @dev Extension of {ERC20} that allows token holders to destroy both their own
 * tokens and those that they have an allowance for, in a way that can be
 * recognized off-chain (via event analysis).
 */
abstract contract ERC20Burnable is Context, ERC20 {
    /**
     * @dev Destroys a `value` amount of tokens from the caller.
     *
     * See {ERC20-_burn}.
     */
    function burn(uint256 value) public virtual {
        _burn(_msgSender(), value);
    }

    /**
     * @dev Destroys a `value` amount of tokens from `account`, deducting from
     * the caller's allowance.
     *
     * See {ERC20-_burn} and {ERC20-allowance}.
     *
     * Requirements:
     *
     * - the caller must have allowance for ``accounts``'s tokens of at least
     * `value`.
     */
    function burnFrom(address account, uint256 value) public virtual {
        _spendAllowance(account, _msgSender(), value);
        _burn(account, value);
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

import {IERC7572} from "../interfaces/IERC7572.sol";

/**
 * @title ERC7572
 * @author fxhash
 * @notice Abstract implementation of EIP-7572 for contract-level metadata
 * @dev Provides contractURI() function and ContractURIUpdated event
 */
abstract contract ERC7572 is IERC7572 {
    /// @notice URI for contract metadata
    string public contractURI;

    /**
     * @notice Internal function to set the contract URI
     * @param _newURI The new URI to set
     */
    function _setContractURI(string memory _newURI) internal virtual {
        contractURI = _newURI;
        emit ContractURIUpdated();
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (utils/structs/EnumerableSet.sol)
// This file was procedurally generated from scripts/generate/templates/EnumerableSet.js.

pragma solidity ^0.8.20;

/**
 * @dev Library for managing
 * https://en.wikipedia.org/wiki/Set_(abstract_data_type)[sets] of primitive
 * types.
 *
 * Sets have the following properties:
 *
 * - Elements are added, removed, and checked for existence in constant time
 * (O(1)).
 * - Elements are enumerated in O(n). No guarantees are made on the ordering.
 *
 * ```solidity
 * contract Example {
 *     // Add the library methods
 *     using EnumerableSet for EnumerableSet.AddressSet;
 *
 *     // Declare a set state variable
 *     EnumerableSet.AddressSet private mySet;
 * }
 * ```
 *
 * As of v3.3.0, sets of type `bytes32` (`Bytes32Set`), `address` (`AddressSet`)
 * and `uint256` (`UintSet`) are supported.
 *
 * [WARNING]
 * ====
 * Trying to delete such a structure from storage will likely result in data corruption, rendering the structure
 * unusable.
 * See https://github.com/ethereum/solidity/pull/11843[ethereum/solidity#11843] for more info.
 *
 * In order to clean an EnumerableSet, you can either remove all elements one by one or create a fresh instance using an
 * array of EnumerableSet.
 * ====
 */
library EnumerableSet {
    // To implement this library for multiple types with as little code
    // repetition as possible, we write it in terms of a generic Set type with
    // bytes32 values.
    // The Set implementation uses private functions, and user-facing
    // implementations (such as AddressSet) are just wrappers around the
    // underlying Set.
    // This means that we can only create new EnumerableSets for types that fit
    // in bytes32.

    struct Set {
        // Storage of set values
        bytes32[] _values;
        // Position is the index of the value in the `values` array plus 1.
        // Position 0 is used to mean a value is not in the set.
        mapping(bytes32 value => uint256) _positions;
    }

    /**
     * @dev Add a value to a set. O(1).
     *
     * Returns true if the value was added to the set, that is if it was not
     * already present.
     */
    function _add(Set storage set, bytes32 value) private returns (bool) {
        if (!_contains(set, value)) {
            set._values.push(value);
            // The value is stored at length-1, but we add 1 to all indexes
            // and use 0 as a sentinel value
            set._positions[value] = set._values.length;
            return true;
        } else {
            return false;
        }
    }

    /**
     * @dev Removes a value from a set. O(1).
     *
     * Returns true if the value was removed from the set, that is if it was
     * present.
     */
    function _remove(Set storage set, bytes32 value) private returns (bool) {
        // We cache the value's position to prevent multiple reads from the same storage slot
        uint256 position = set._positions[value];

        if (position != 0) {
            // Equivalent to contains(set, value)
            // To delete an element from the _values array in O(1), we swap the element to delete with the last one in
            // the array, and then remove the last element (sometimes called as 'swap and pop').
            // This modifies the order of the array, as noted in {at}.

            uint256 valueIndex = position - 1;
            uint256 lastIndex = set._values.length - 1;

            if (valueIndex != lastIndex) {
                bytes32 lastValue = set._values[lastIndex];

                // Move the lastValue to the index where the value to delete is
                set._values[valueIndex] = lastValue;
                // Update the tracked position of the lastValue (that was just moved)
                set._positions[lastValue] = position;
            }

            // Delete the slot where the moved value was stored
            set._values.pop();

            // Delete the tracked position for the deleted slot
            delete set._positions[value];

            return true;
        } else {
            return false;
        }
    }

    /**
     * @dev Returns true if the value is in the set. O(1).
     */
    function _contains(Set storage set, bytes32 value) private view returns (bool) {
        return set._positions[value] != 0;
    }

    /**
     * @dev Returns the number of values on the set. O(1).
     */
    function _length(Set storage set) private view returns (uint256) {
        return set._values.length;
    }

    /**
     * @dev Returns the value stored at position `index` in the set. O(1).
     *
     * Note that there are no guarantees on the ordering of values inside the
     * array, and it may change when more values are added or removed.
     *
     * Requirements:
     *
     * - `index` must be strictly less than {length}.
     */
    function _at(Set storage set, uint256 index) private view returns (bytes32) {
        return set._values[index];
    }

    /**
     * @dev Return the entire set in an array
     *
     * WARNING: This operation will copy the entire storage to memory, which can be quite expensive. This is designed
     * to mostly be used by view accessors that are queried without any gas fees. Developers should keep in mind that
     * this function has an unbounded cost, and using it as part of a state-changing function may render the function
     * uncallable if the set grows to a point where copying to memory consumes too much gas to fit in a block.
     */
    function _values(Set storage set) private view returns (bytes32[] memory) {
        return set._values;
    }

    // Bytes32Set

    struct Bytes32Set {
        Set _inner;
    }

    /**
     * @dev Add a value to a set. O(1).
     *
     * Returns true if the value was added to the set, that is if it was not
     * already present.
     */
    function add(Bytes32Set storage set, bytes32 value) internal returns (bool) {
        return _add(set._inner, value);
    }

    /**
     * @dev Removes a value from a set. O(1).
     *
     * Returns true if the value was removed from the set, that is if it was
     * present.
     */
    function remove(Bytes32Set storage set, bytes32 value) internal returns (bool) {
        return _remove(set._inner, value);
    }

    /**
     * @dev Returns true if the value is in the set. O(1).
     */
    function contains(Bytes32Set storage set, bytes32 value) internal view returns (bool) {
        return _contains(set._inner, value);
    }

    /**
     * @dev Returns the number of values in the set. O(1).
     */
    function length(Bytes32Set storage set) internal view returns (uint256) {
        return _length(set._inner);
    }

    /**
     * @dev Returns the value stored at position `index` in the set. O(1).
     *
     * Note that there are no guarantees on the ordering of values inside the
     * array, and it may change when more values are added or removed.
     *
     * Requirements:
     *
     * - `index` must be strictly less than {length}.
     */
    function at(Bytes32Set storage set, uint256 index) internal view returns (bytes32) {
        return _at(set._inner, index);
    }

    /**
     * @dev Return the entire set in an array
     *
     * WARNING: This operation will copy the entire storage to memory, which can be quite expensive. This is designed
     * to mostly be used by view accessors that are queried without any gas fees. Developers should keep in mind that
     * this function has an unbounded cost, and using it as part of a state-changing function may render the function
     * uncallable if the set grows to a point where copying to memory consumes too much gas to fit in a block.
     */
    function values(Bytes32Set storage set) internal view returns (bytes32[] memory) {
        bytes32[] memory store = _values(set._inner);
        bytes32[] memory result;

        assembly ("memory-safe") {
            result := store
        }

        return result;
    }

    // AddressSet

    struct AddressSet {
        Set _inner;
    }

    /**
     * @dev Add a value to a set. O(1).
     *
     * Returns true if the value was added to the set, that is if it was not
     * already present.
     */
    function add(AddressSet storage set, address value) internal returns (bool) {
        return _add(set._inner, bytes32(uint256(uint160(value))));
    }

    /**
     * @dev Removes a value from a set. O(1).
     *
     * Returns true if the value was removed from the set, that is if it was
     * present.
     */
    function remove(AddressSet storage set, address value) internal returns (bool) {
        return _remove(set._inner, bytes32(uint256(uint160(value))));
    }

    /**
     * @dev Returns true if the value is in the set. O(1).
     */
    function contains(AddressSet storage set, address value) internal view returns (bool) {
        return _contains(set._inner, bytes32(uint256(uint160(value))));
    }

    /**
     * @dev Returns the number of values in the set. O(1).
     */
    function length(AddressSet storage set) internal view returns (uint256) {
        return _length(set._inner);
    }

    /**
     * @dev Returns the value stored at position `index` in the set. O(1).
     *
     * Note that there are no guarantees on the ordering of values inside the
     * array, and it may change when more values are added or removed.
     *
     * Requirements:
     *
     * - `index` must be strictly less than {length}.
     */
    function at(AddressSet storage set, uint256 index) internal view returns (address) {
        return address(uint160(uint256(_at(set._inner, index))));
    }

    /**
     * @dev Return the entire set in an array
     *
     * WARNING: This operation will copy the entire storage to memory, which can be quite expensive. This is designed
     * to mostly be used by view accessors that are queried without any gas fees. Developers should keep in mind that
     * this function has an unbounded cost, and using it as part of a state-changing function may render the function
     * uncallable if the set grows to a point where copying to memory consumes too much gas to fit in a block.
     */
    function values(AddressSet storage set) internal view returns (address[] memory) {
        bytes32[] memory store = _values(set._inner);
        address[] memory result;

        assembly ("memory-safe") {
            result := store
        }

        return result;
    }

    // UintSet

    struct UintSet {
        Set _inner;
    }

    /**
     * @dev Add a value to a set. O(1).
     *
     * Returns true if the value was added to the set, that is if it was not
     * already present.
     */
    function add(UintSet storage set, uint256 value) internal returns (bool) {
        return _add(set._inner, bytes32(value));
    }

    /**
     * @dev Removes a value from a set. O(1).
     *
     * Returns true if the value was removed from the set, that is if it was
     * present.
     */
    function remove(UintSet storage set, uint256 value) internal returns (bool) {
        return _remove(set._inner, bytes32(value));
    }

    /**
     * @dev Returns true if the value is in the set. O(1).
     */
    function contains(UintSet storage set, uint256 value) internal view returns (bool) {
        return _contains(set._inner, bytes32(value));
    }

    /**
     * @dev Returns the number of values in the set. O(1).
     */
    function length(UintSet storage set) internal view returns (uint256) {
        return _length(set._inner);
    }

    /**
     * @dev Returns the value stored at position `index` in the set. O(1).
     *
     * Note that there are no guarantees on the ordering of values inside the
     * array, and it may change when more values are added or removed.
     *
     * Requirements:
     *
     * - `index` must be strictly less than {length}.
     */
    function at(UintSet storage set, uint256 index) internal view returns (uint256) {
        return uint256(_at(set._inner, index));
    }

    /**
     * @dev Return the entire set in an array
     *
     * WARNING: This operation will copy the entire storage to memory, which can be quite expensive. This is designed
     * to mostly be used by view accessors that are queried without any gas fees. Developers should keep in mind that
     * this function has an unbounded cost, and using it as part of a state-changing function may render the function
     * uncallable if the set grows to a point where copying to memory consumes too much gas to fit in a block.
     */
    function values(UintSet storage set) internal view returns (uint256[] memory) {
        bytes32[] memory store = _values(set._inner);
        uint256[] memory result;

        assembly ("memory-safe") {
            result := store
        }

        return result;
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

import {Adminable} from "./utils/Adminable.sol";
import {EnumerableSet} from "@openzeppelin/contracts/utils/structs/EnumerableSet.sol";
import {ERC20} from "@openzeppelin/contracts/token/ERC20/ERC20.sol";
import {ERC20Burnable} from "@openzeppelin/contracts/token/ERC20/extensions/ERC20Burnable.sol";
import {ERC7572} from "./utils/ERC7572.sol";
import {Ownable} from "@openzeppelin/contracts/access/Ownable.sol";

import {IERC165} from "@openzeppelin/contracts/utils/introspection/IERC165.sol";
import {IERC7572} from "./interfaces/IERC7572.sol";
import {IGraduatedToken} from "./interfaces/IGraduatedToken.sol";

/**
 * @title GraduatedToken
 * @author fxhash
 * @notice Custom ERC20 token with a tax rate that is applied on all UniswapV2 DEX trades
 * @dev Features:
 * - Tax applied on DEX trades
 * - Fees split between creator and FX receiver according to configurable ratios
 * - Basis points precision (1% = 100bps) for fee calculations
 */
contract GraduatedToken is IGraduatedToken, ERC7572, Adminable, ERC20Burnable, Ownable {
    using EnumerableSet for EnumerableSet.AddressSet;

    /// @notice Basis points in percentage (100%)
    uint256 public constant BASIS_POINTS = 10_000;
    /// @notice Initial supply of graduated tokens
    uint256 public constant INITIAL_SUPPLY = 1_000_000 * 1e18;
    /// @notice Initial tax rate (1%)
    uint256 public constant INITIAL_TAX_RATE = 100;
    /// @notice Initial fx fee split (10%)
    uint256 private constant INITIAL_FX_SPLIT = 1000;
    /// @notice Initial creator fee split (90%)
    uint256 private constant INITIAL_CREATOR_SPLIT = 9000;

    /// @notice Percentage of tax applied on all trades
    uint256 public taxRate;
    /// @notice Creator fee receiver address
    address public creatorFeeReceiver;
    /// @notice FX fee receiver address
    address public fxFeeReceiver;
    /// @notice Percentage of tax allocated to fx
    uint256 public fxFeeSplit;
    /// @notice Percentage of tax allocated to creator
    uint256 public creatorFeeSplit;
    /// @notice Address of the TokenLaunchpad contract
    address public immutable tokenLaunchpad;

    /// @notice Set of pairs that are subject to the tax
    EnumerableSet.AddressSet internal pairs;

    /**
     * @notice Initializes the token contracts
     * @param _name The name of the token
     * @param _symbol The symbol of the token
     * @param _tokenLaunchpad The address of the TokenLaunchpad contract
     * @param _creatorFeeReceiver The address of the creator fee receiver
     * @param _fxFeeReceiver The address of the fx fee receiver
     * @param _initialOwner The address of the initial contract owner
     * @param _initialSupply The initial supply of the token
     * @param _initialAdmin The address of the initial admin
     * @param _contractURI The URI for contract metadata
     */
    constructor(
        string memory _name,
        string memory _symbol,
        address _tokenLaunchpad,
        address _creatorFeeReceiver,
        address _fxFeeReceiver,
        address _initialOwner,
        uint256 _initialSupply,
        address _initialAdmin,
        string memory _contractURI
    ) ERC20(_name, _symbol) Ownable(_initialOwner) Adminable(_initialAdmin) {
        tokenLaunchpad = _tokenLaunchpad;
        _mint(_tokenLaunchpad, _initialSupply);
        _setTaxRate(INITIAL_TAX_RATE);

        _setCreatorFeeReceiver(_creatorFeeReceiver);
        _setFxFeeReceiver(_fxFeeReceiver);
        _updateFeeSplit(INITIAL_FX_SPLIT, INITIAL_CREATOR_SPLIT);
        _setContractURI(_contractURI);
    }

    /*//////////////////////////////////////////////////////////////////////////
                                LAUNCHPAD FUNCTIONS
    //////////////////////////////////////////////////////////////////////////*/

    /**
     * @notice Modifier to restrict function access to TokenLaunchpad only
     */
    modifier onlyLaunchpad() {
        _checkLaunchpad();
        _;
    }

    /**
     * @notice Adds a pair to the tax list during the graduation process
     * @dev Only callable by the tokenLaunchpad contract
     * @param _pair The address of the Uniswap V2 pair to add to taxed pairs
     */
    function addTaxedPair(address _pair) external onlyLaunchpad {
        _addPair(_pair);
    }

    /*//////////////////////////////////////////////////////////////////////////
                                OWNER FUNCTIONS
    //////////////////////////////////////////////////////////////////////////*/

    /**
     * @notice Adds a pair to the set of pairs that are subject to the tax
     * @param _pair The address of the pair
     */
    function addPair(address _pair) external onlyOwner {
        _addPair(_pair);
    }

    /**
     * @notice Removes a pair from the set of pairs that are subject to the tax
     * @param _pair The address of the pair
     */
    function removePair(address _pair) external onlyOwner {
        _removePair(_pair);
    }

    /**
     * @notice Sets the contract URI for the token
     * @param _newURI The new URI
     */
    function setContractURI(string memory _newURI) external onlyOwner {
        _setContractURI(_newURI);
    }

    /**
     * @notice Sets the tax rate percentage
     * @param _taxRate The new tax rate
     */
    function setTaxRate(uint256 _taxRate) external onlyOwner {
        _setTaxRate(_taxRate);
    }

    /**
     * @notice Sets the creator fee receiver address
     * @dev Only callable by the owner
     * @dev Reverts if the address is zero
     * @dev Emits a FeeReceiversUpdated event
     * @param _creator The new creator fee receiver address
     */
    function setCreatorFeeReceiver(address _creator) external onlyOwner {
        _setCreatorFeeReceiver(_creator);
    }

    /**
     * @notice Sets the fx fee receiver address
     * @dev Only callable by the admin
     * @dev Reverts if the address is zero
     * @dev Emits a FeeReceiversUpdated event
     * @param _fx The new fx fee receiver address
     */
    function setFxFeeReceiver(address _fx) external onlyAdmin {
        _setFxFeeReceiver(_fx);
    }

    /**
     * @notice Sets the fee split between fx and creator
     * @param _fx The fx fee percentage (in basis points)
     * @param _creator The creator fee percentage (in basis points)
     * @dev Sum must equal BASIS_POINTS (10_000)
     * @dev Emits FeeSplitUpdated on change
     */
    function setFeeSplit(uint256 _fx, uint256 _creator) external onlyAdmin {
        _updateFeeSplit(_fx, _creator);
    }

    /*//////////////////////////////////////////////////////////////////////////
                                VIEW FUNCTIONS
    //////////////////////////////////////////////////////////////////////////*/

    /**
     * @notice Checks if an account is in the set of pairs
     * @param _account The address of the account
     * @return True if the account is in the set, false otherwise
     */
    function isPair(address _account) external view returns (bool) {
        return pairs.contains(_account);
    }

    /**
     * @notice Returns true if this contract implements the interface defined by interfaceId
     * @dev See IERC165
     * @param interfaceId The interface identifier, as specified in ERC-165
     * @return true if the contract implements interfaceId
     */
    function supportsInterface(bytes4 interfaceId) external view virtual returns (bool) {
        return
            interfaceId == type(IERC165).interfaceId ||
            interfaceId == type(IERC7572).interfaceId ||
            interfaceId == type(IGraduatedToken).interfaceId;
    }

    /*//////////////////////////////////////////////////////////////////////////
                                INTERNAL FUNCTIONS
    //////////////////////////////////////////////////////////////////////////*/

    /**
     * @notice Internal function to add a pair to the taxed pairs set
     * @param _pair The address of the pair to add
     */
    function _addPair(address _pair) internal {
        if (_pair == address(0)) {
            revert GraduatedToken__ZeroAddress();
        }
        if (!pairs.add(_pair)) {
            revert GraduatedToken__InvalidPair();
        }
        emit PairAdded(_pair);
    }

    /**
     * @notice Internal function to remove a pair from the taxed pairs set
     * @param _pair The address of the pair to remove
     */
    function _removePair(address _pair) internal {
        if (!pairs.remove(_pair)) {
            revert GraduatedToken__InvalidPair();
        }
        emit PairRemoved(_pair);
    }

    function _setTaxRate(uint256 _taxRate) internal {
        if (_taxRate > BASIS_POINTS) {
            revert GraduatedToken__InvalidTaxRate();
        }
        taxRate = _taxRate;
        emit TaxRateUpdated(_taxRate);
    }

    /**
     * @notice Sets the creator fee receiver address
     * @dev Reverts if the address is zero
     * @dev Updates state and emits event
     * @param _creator The new creator fee receiver address
     */
    function _setCreatorFeeReceiver(address _creator) internal {
        if (_creator == address(0)) {
            revert GraduatedToken__ZeroAddress();
        }
        creatorFeeReceiver = _creator;
        emit FeeReceiversUpdated(creatorFeeReceiver, fxFeeReceiver);
    }

    /**
     * @notice Sets the fx fee receiver address
     * @dev Reverts if the address is zero
     * @dev Updates state and emits event
     * @param _fx The new fx fee receiver address
     */
    function _setFxFeeReceiver(address _fx) internal {
        if (_fx == address(0)) {
            revert GraduatedToken__ZeroAddress();
        }
        fxFeeReceiver = _fx;
        emit FeeReceiversUpdated(creatorFeeReceiver, fxFeeReceiver);
    }

    /**
     * @notice Updates the fee split between fx and creator
     * @param _fx The fx fee percentage (in basis points)
     * @param _creator The creator fee percentage (in basis points)
     * @dev Sum must equal BASIS_POINTS (10_000)
     * @dev Emits FeeSplitUpdated on change
     */
    function _updateFeeSplit(uint256 _fx, uint256 _creator) internal {
        if (_fx + _creator != BASIS_POINTS) {
            revert GraduatedToken__InvalidFeeSplit();
        }
        fxFeeSplit = _fx;
        creatorFeeSplit = _creator;
        emit FeeSplitUpdated(_fx, _creator);
    }

    /**
     * @notice Handles token transfers with tax application and fee splitting
     * @dev Splits taxes between creator and FX receiver using current ratios
     * @dev FX amount = (taxAmount * fxFeeNumerator) / BASIS_POINTS
     * @dev Creator amount = taxAmount - FX amount
     */
    function _update(address _from, address _to, uint256 _amount) internal virtual override {
        // Ignore taxes for mints and burns
        if (_from == address(0) || _to == address(0)) {
            super._update(_from, _to, _amount);
            return;
        }

        // Calculate tax and transfer amounts
        uint256 taxAmount = _calculateTax(_from, _to, _amount);
        uint256 transferAmount = _amount - taxAmount;

        if (taxAmount > 0) {
            // Split tax amount between fx and creator
            uint256 fxAmount = (taxAmount * fxFeeSplit) / BASIS_POINTS;
            uint256 creatorAmount = taxAmount - fxAmount;

            // Transfer calculated amounts for only DEX trades
            super._update(_from, fxFeeReceiver, fxAmount);
            super._update(_from, creatorFeeReceiver, creatorAmount);
            super._update(_from, _to, transferAmount);
        } else {
            // Ignore taxes for non-DEX trades
            super._update(_from, _to, _amount);
        }
    }

    function _calculateTax(
        address _from,
        address _to,
        uint256 _amount
    ) internal view returns (uint256 taxAmount) {
        // Check if transfer is DEX trade
        if (pairs.contains(_from) || pairs.contains(_to)) {
            taxAmount = (_amount * taxRate) / BASIS_POINTS;
        }
    }

    /*
     * @notice Checks if caller is TokenLaunchpad
     * @dev Reverts if not
     */
    function _checkLaunchpad() internal view {
        if (msg.sender != tokenLaunchpad) {
            revert GraduatedToken__Unauthorized();
        }
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

import {IAdminableEventsAndErrors} from "./events-and-errors/IAdminableEventsAndErrors.sol";

/// @title IAdminable
/// @notice Interface for contracts that can be administered by an admin.
interface IAdminable is IAdminableEventsAndErrors {
    /// @notice Returns the address of the current admin.
    /// @return The address of the current admin.
    function admin() external view returns (address);

    /// @notice Allows the current admin to renounce their role.
    /// @dev Emits a {TransferAdmin} event with newAdmin set to address(0).
    function renounceAdmin() external;

    /// @notice Transfers the admin to a new address.
    /// @dev Emits a {TransferAdmin} event.
    /// @param newAdmin The address of the new admin.
    function transferAdmin(address newAdmin) external;
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

/// @title IAdminableEventsAndErrors
/// @notice Events and errors for contracts that can be administered by an admin.
interface IAdminableEventsAndErrors {
    /// @notice Thrown when a caller is not the admin.
    /// @param admin The address of the admin.
    /// @param caller The address of the caller.
    error AdminableUnauthorizedAccount(address admin, address caller);

    /// @notice Emitted when the admin is transferred.
    /// @param oldAdmin The address of the previous admin.
    /// @param newAdmin The address of the new admin.
    event TransferAdmin(address indexed oldAdmin, address indexed newAdmin);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (utils/introspection/IERC165.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC-165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[ERC].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[ERC section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC-20 standard as defined in the ERC.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (token/ERC20/extensions/IERC20Metadata.sol)

pragma solidity ^0.8.20;

import {IERC20} from "../IERC20.sol";

/**
 * @dev Interface for the optional metadata functions from the ERC-20 standard.
 */
interface IERC20Metadata is IERC20 {
    /**
     * @dev Returns the name of the token.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the symbol of the token.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the decimals places of the token.
     */
    function decimals() external view returns (uint8);
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

/**
 * @title IERC7572
 * @notice Interface for EIP-7572: Contract-level metadata via contractURI()
 * @dev This interface standardizes contract-level metadata for better discoverability
 */
interface IERC7572 {
    /**
     * @notice Returns the URI for contract-level metadata
     * @dev The returned URI should point to a JSON document with the following schema:
     * {
     *   "name": "Contract Name",
     *   "symbol": "SYMBOL",
     *   "description": "Contract description",
     *   "image": "https://example.com/image.png"
     * }
     * @return The URI for contract metadata
     */
    function contractURI() external view returns (string memory);

    /**
     * @notice Emitted when the contract URI is updated
     * @dev This event notifies offchain indexers that contract metadata has changed
     */
    event ContractURIUpdated();
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

import {IERC7572} from "./IERC7572.sol";
import {IGraduatedTokenEventsAndErrors} from "./events-and-errors/IGraduatedTokenEventsAndErrors.sol";

/**
 * @title IGraduatedToken
 * @dev Interface for the GraduatedToken contract
 */
interface IGraduatedToken is IERC7572, IGraduatedTokenEventsAndErrors {
    /**
     * @notice Adds a DEX pair address
     * @dev Only callable by the owner
     * @param pair The DEX pair address to add
     */
    function addPair(address pair) external;

    /**
     * @notice Adds a pair to the tax list during the graduation process
     * @dev Only callable by the tokenLaunchpad contract
     * @param pair The address of the Uniswap V2 pair to add to taxed pairs
     */
    function addTaxedPair(address pair) external;

    /**
     * @notice Sets the creator fee receiver address
     * @dev Only callable by the owner
     * @dev Reverts if the address is zero
     * @dev Emits a FeeReceiversUpdated event
     * @param creator The new creator fee receiver address
     */
    function setCreatorFeeReceiver(address creator) external;

    /**
     * @notice Sets the fee split between creator and fx
     * @dev Only callable by the owner
     * @dev The sum of creator and fx must equal BASIS_POINTS
     * @dev Emits a FeeSplitUpdated event
     * @param creator The creator fee numerator
     * @param fx The fx fee numerator
     */
    function setFeeSplit(uint256 creator, uint256 fx) external;

    /**
     * @notice Sets the fx fee receiver address
     * @dev Only callable by the admin
     * @dev Reverts if the address is zero
     * @dev Emits a FeeReceiversUpdated event
     * @param fx The new fx fee receiver address
     */
    function setFxFeeReceiver(address fx) external;

    /**
     * @notice Removes a DEX pair address
     * @dev Only callable by the owner
     * @param pair The DEX pair address to remove
     */
    function removePair(address pair) external;

    /**
     * @notice Returns the basis points constant (10000)
     * @return The basis points value
     */
    function BASIS_POINTS() external view returns (uint256);

    /**
     * @notice Returns the current creator fee receiver address
     * @return The creator fee receiver address
     */
    function creatorFeeReceiver() external view returns (address);

    /**
     * @notice Returns the current creator fee numerator
     * @return The creator fee numerator
     */
    function creatorFeeSplit() external view returns (uint256);

    /**
     * @notice Returns the current fx fee receiver address
     * @return The fx fee receiver address
     */
    function fxFeeReceiver() external view returns (address);

    /**
     * @notice Returns the current fx fee numerator
     * @return The fx fee numerator
     */
    function fxFeeSplit() external view returns (uint256);

    /**
     * @notice Checks if an address is a DEX pair
     * @param pair The address to check
     * @return True if the address is a DEX pair, false otherwise
     */
    function isPair(address pair) external view returns (bool);

    /**
     * @notice Returns the current tax rate in basis points
     * @return The tax rate
     */
    function taxRate() external view returns (uint256);

    function INITIAL_SUPPLY() external view returns (uint256);

    function INITIAL_TAX_RATE() external view returns (uint256);
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

interface IGraduatedTokenEventsAndErrors {
    /*//////////////////////////////////////////////////////////////////////////
                                    ERRORS
    //////////////////////////////////////////////////////////////////////////*/

    error GraduatedToken__InvalidPair();
    error GraduatedToken__InvalidTaxRate();
    error GraduatedToken__ZeroAddress();
    error GraduatedToken__InvalidFeeSplit();
    error GraduatedToken__Unauthorized();

    /*//////////////////////////////////////////////////////////////////////////
                                    EVENTS
    //////////////////////////////////////////////////////////////////////////*/

    event PairAdded(address indexed token);
    event PairRemoved(address indexed token);
    event TaxRateUpdated(uint256 rate);
    event FeeSplitUpdated(uint256 fx, uint256 creator);
    event FeeReceiversUpdated(address indexed creator, address indexed fx);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable.sol)

pragma solidity ^0.8.20;

import {Context} from "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is set to the address provided by the deployer. This can
 * later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    /**
     * @dev The caller account is not authorized to perform an operation.
     */
    error OwnableUnauthorizedAccount(address account);

    /**
     * @dev The owner is not a valid owner account. (eg. `address(0)`)
     */
    error OwnableInvalidOwner(address owner);

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the address provided by the deployer as the initial owner.
     */
    constructor(address initialOwner) {
        if (initialOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(initialOwner);
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        if (owner() != _msgSender()) {
            revert OwnableUnauthorizedAccount(_msgSender());
        }
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        if (newOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (interfaces/draft-IERC6093.sol)
pragma solidity ^0.8.20;

/**
 * @dev Standard ERC-20 Errors
 * Interface of the https://eips.ethereum.org/EIPS/eip-6093[ERC-6093] custom errors for ERC-20 tokens.
 */
interface IERC20Errors {
    /**
     * @dev Indicates an error related to the current `balance` of a `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     * @param balance Current balance for the interacting account.
     * @param needed Minimum amount required to perform a transfer.
     */
    error ERC20InsufficientBalance(address sender, uint256 balance, uint256 needed);

    /**
     * @dev Indicates a failure with the token `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     */
    error ERC20InvalidSender(address sender);

    /**
     * @dev Indicates a failure with the token `receiver`. Used in transfers.
     * @param receiver Address to which tokens are being transferred.
     */
    error ERC20InvalidReceiver(address receiver);

    /**
     * @dev Indicates a failure with the `spender`’s `allowance`. Used in transfers.
     * @param spender Address that may be allowed to operate on tokens without being their owner.
     * @param allowance Amount of tokens a `spender` is allowed to operate with.
     * @param needed Minimum amount required to perform a transfer.
     */
    error ERC20InsufficientAllowance(address spender, uint256 allowance, uint256 needed);

    /**
     * @dev Indicates a failure with the `approver` of a token to be approved. Used in approvals.
     * @param approver Address initiating an approval operation.
     */
    error ERC20InvalidApprover(address approver);

    /**
     * @dev Indicates a failure with the `spender` to be approved. Used in approvals.
     * @param spender Address that may be allowed to operate on tokens without being their owner.
     */
    error ERC20InvalidSpender(address spender);
}

/**
 * @dev Standard ERC-721 Errors
 * Interface of the https://eips.ethereum.org/EIPS/eip-6093[ERC-6093] custom errors for ERC-721 tokens.
 */
interface IERC721Errors {
    /**
     * @dev Indicates that an address can't be an owner. For example, `address(0)` is a forbidden owner in ERC-20.
     * Used in balance queries.
     * @param owner Address of the current owner of a token.
     */
    error ERC721InvalidOwner(address owner);

    /**
     * @dev Indicates a `tokenId` whose `owner` is the zero address.
     * @param tokenId Identifier number of a token.
     */
    error ERC721NonexistentToken(uint256 tokenId);

    /**
     * @dev Indicates an error related to the ownership over a particular token. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     * @param tokenId Identifier number of a token.
     * @param owner Address of the current owner of a token.
     */
    error ERC721IncorrectOwner(address sender, uint256 tokenId, address owner);

    /**
     * @dev Indicates a failure with the token `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     */
    error ERC721InvalidSender(address sender);

    /**
     * @dev Indicates a failure with the token `receiver`. Used in transfers.
     * @param receiver Address to which tokens are being transferred.
     */
    error ERC721InvalidReceiver(address receiver);

    /**
     * @dev Indicates a failure with the `operator`’s approval. Used in transfers.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     * @param tokenId Identifier number of a token.
     */
    error ERC721InsufficientApproval(address operator, uint256 tokenId);

    /**
     * @dev Indicates a failure with the `approver` of a token to be approved. Used in approvals.
     * @param approver Address initiating an approval operation.
     */
    error ERC721InvalidApprover(address approver);

    /**
     * @dev Indicates a failure with the `operator` to be approved. Used in approvals.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     */
    error ERC721InvalidOperator(address operator);
}

/**
 * @dev Standard ERC-1155 Errors
 * Interface of the https://eips.ethereum.org/EIPS/eip-6093[ERC-6093] custom errors for ERC-1155 tokens.
 */
interface IERC1155Errors {
    /**
     * @dev Indicates an error related to the current `balance` of a `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     * @param balance Current balance for the interacting account.
     * @param needed Minimum amount required to perform a transfer.
     * @param tokenId Identifier number of a token.
     */
    error ERC1155InsufficientBalance(address sender, uint256 balance, uint256 needed, uint256 tokenId);

    /**
     * @dev Indicates a failure with the token `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     */
    error ERC1155InvalidSender(address sender);

    /**
     * @dev Indicates a failure with the token `receiver`. Used in transfers.
     * @param receiver Address to which tokens are being transferred.
     */
    error ERC1155InvalidReceiver(address receiver);

    /**
     * @dev Indicates a failure with the `operator`’s approval. Used in transfers.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     * @param owner Address of the current owner of a token.
     */
    error ERC1155MissingApprovalForAll(address operator, address owner);

    /**
     * @dev Indicates a failure with the `approver` of a token to be approved. Used in approvals.
     * @param approver Address initiating an approval operation.
     */
    error ERC1155InvalidApprover(address approver);

    /**
     * @dev Indicates a failure with the `operator` to be approved. Used in approvals.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     */
    error ERC1155InvalidOperator(address operator);

    /**
     * @dev Indicates an array length mismatch between ids and values in a safeBatchTransferFrom operation.
     * Used in batch transfers.
     * @param idsLength Length of the array of token identifiers
     * @param valuesLength Length of the array of token amounts
     */
    error ERC1155InvalidArrayLength(uint256 idsLength, uint256 valuesLength);
}

{
  "compilationTarget": {
    "src/GraduatedToken.sol": "GraduatedToken"
  },
  "evmVersion": "cancun",
  "libraries": {
    "src/libraries/ProjectTokenLib.sol:ProjectTokenLib": "0x19b2a21cb0a1938388050bb196c5dbc0e8bc110c",
    "src/libraries/TokenLaunchPadLib.sol:TokenLaunchPadLib": "0x961b7b0bcbe7af3182cdfde92537b5dd37ee9463"
  },
  "metadata": {
    "bytecodeHash": "none"
  },
  "optimizer": {
    "enabled": true,
    "runs": 200
  },
  "remappings": [
    ":@openzeppelin/contracts-upgradeable/=lib/openzeppelin-contracts-upgradeable/contracts/",
    ":@openzeppelin/contracts/=lib/openzeppelin-contracts/contracts/",
    ":ds-test/=lib/solmate/lib/ds-test/src/",
    ":erc4626-tests/=lib/openzeppelin-contracts/lib/erc4626-tests/",
    ":forge-std/=lib/forge-std/src/",
    ":halmos-cheatcodes/=lib/openzeppelin-contracts/lib/halmos-cheatcodes/src/",
    ":openzeppelin-contracts/=lib/openzeppelin-contracts/",
    ":solday/=lib/src/",
    ":solidity-lib/=lib/solidity-lib/contracts/",
    ":solmate/=lib/solmate/src/",
    ":v2-core/=lib/v2-core/contracts/",
    ":v2-periphery/=lib/v2-periphery/contracts/"
  ]
}