// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (access/AccessControl.sol)

pragma solidity ^0.8.0;

import "./IAccessControl.sol";
import "../utils/Context.sol";
import "../utils/Strings.sol";
import "../utils/introspection/ERC165.sol";

/**
 * @dev Contract module that allows children to implement role-based access
 * control mechanisms. This is a lightweight version that doesn't allow enumerating role
 * members except through off-chain means by accessing the contract event logs. Some
 * applications may benefit from on-chain enumerability, for those cases see
 * {AccessControlEnumerable}.
 *
 * Roles are referred to by their `bytes32` identifier. These should be exposed
 * in the external API and be unique. The best way to achieve this is by
 * using `public constant` hash digests:
 *
 * ```solidity
 * bytes32 public constant MY_ROLE = keccak256("MY_ROLE");
 * ```
 *
 * Roles can be used to represent a set of permissions. To restrict access to a
 * function call, use {hasRole}:
 *
 * ```solidity
 * function foo() public {
 *     require(hasRole(MY_ROLE, msg.sender));
 *     ...
 * }
 * ```
 *
 * Roles can be granted and revoked dynamically via the {grantRole} and
 * {revokeRole} functions. Each role has an associated admin role, and only
 * accounts that have a role's admin role can call {grantRole} and {revokeRole}.
 *
 * By default, the admin role for all roles is `DEFAULT_ADMIN_ROLE`, which means
 * that only accounts with this role will be able to grant or revoke other
 * roles. More complex role relationships can be created by using
 * {_setRoleAdmin}.
 *
 * WARNING: The `DEFAULT_ADMIN_ROLE` is also its own admin: it has permission to
 * grant and revoke this role. Extra precautions should be taken to secure
 * accounts that have been granted it. We recommend using {AccessControlDefaultAdminRules}
 * to enforce additional security measures for this role.
 */
abstract contract AccessControl is Context, IAccessControl, ERC165 {
    struct RoleData {
        mapping(address => bool) members;
        bytes32 adminRole;
    }

    mapping(bytes32 => RoleData) private _roles;

    bytes32 public constant DEFAULT_ADMIN_ROLE = 0x00;

    /**
     * @dev Modifier that checks that an account has a specific role. Reverts
     * with a standardized message including the required role.
     *
     * The format of the revert reason is given by the following regular expression:
     *
     *  /^AccessControl: account (0x[0-9a-f]{40}) is missing role (0x[0-9a-f]{64})$/
     *
     * _Available since v4.1._
     */
    modifier onlyRole(bytes32 role) {
        _checkRole(role);
        _;
    }

    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
        return interfaceId == type(IAccessControl).interfaceId || super.supportsInterface(interfaceId);
    }

    /**
     * @dev Returns `true` if `account` has been granted `role`.
     */
    function hasRole(bytes32 role, address account) public view virtual override returns (bool) {
        return _roles[role].members[account];
    }

    /**
     * @dev Revert with a standard message if `_msgSender()` is missing `role`.
     * Overriding this function changes the behavior of the {onlyRole} modifier.
     *
     * Format of the revert message is described in {_checkRole}.
     *
     * _Available since v4.6._
     */
    function _checkRole(bytes32 role) internal view virtual {
        _checkRole(role, _msgSender());
    }

    /**
     * @dev Revert with a standard message if `account` is missing `role`.
     *
     * The format of the revert reason is given by the following regular expression:
     *
     *  /^AccessControl: account (0x[0-9a-f]{40}) is missing role (0x[0-9a-f]{64})$/
     */
    function _checkRole(bytes32 role, address account) internal view virtual {
        if (!hasRole(role, account)) {
            revert(
                string(
                    abi.encodePacked(
                        "AccessControl: account ",
                        Strings.toHexString(account),
                        " is missing role ",
                        Strings.toHexString(uint256(role), 32)
                    )
                )
            );
        }
    }

    /**
     * @dev Returns the admin role that controls `role`. See {grantRole} and
     * {revokeRole}.
     *
     * To change a role's admin, use {_setRoleAdmin}.
     */
    function getRoleAdmin(bytes32 role) public view virtual override returns (bytes32) {
        return _roles[role].adminRole;
    }

    /**
     * @dev Grants `role` to `account`.
     *
     * If `account` had not been already granted `role`, emits a {RoleGranted}
     * event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     *
     * May emit a {RoleGranted} event.
     */
    function grantRole(bytes32 role, address account) public virtual override onlyRole(getRoleAdmin(role)) {
        _grantRole(role, account);
    }

    /**
     * @dev Revokes `role` from `account`.
     *
     * If `account` had been granted `role`, emits a {RoleRevoked} event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     *
     * May emit a {RoleRevoked} event.
     */
    function revokeRole(bytes32 role, address account) public virtual override onlyRole(getRoleAdmin(role)) {
        _revokeRole(role, account);
    }

    /**
     * @dev Revokes `role` from the calling account.
     *
     * Roles are often managed via {grantRole} and {revokeRole}: this function's
     * purpose is to provide a mechanism for accounts to lose their privileges
     * if they are compromised (such as when a trusted device is misplaced).
     *
     * If the calling account had been revoked `role`, emits a {RoleRevoked}
     * event.
     *
     * Requirements:
     *
     * - the caller must be `account`.
     *
     * May emit a {RoleRevoked} event.
     */
    function renounceRole(bytes32 role, address account) public virtual override {
        require(account == _msgSender(), "AccessControl: can only renounce roles for self");

        _revokeRole(role, account);
    }

    /**
     * @dev Grants `role` to `account`.
     *
     * If `account` had not been already granted `role`, emits a {RoleGranted}
     * event. Note that unlike {grantRole}, this function doesn't perform any
     * checks on the calling account.
     *
     * May emit a {RoleGranted} event.
     *
     * [WARNING]
     * ====
     * This function should only be called from the constructor when setting
     * up the initial roles for the system.
     *
     * Using this function in any other way is effectively circumventing the admin
     * system imposed by {AccessControl}.
     * ====
     *
     * NOTE: This function is deprecated in favor of {_grantRole}.
     */
    function _setupRole(bytes32 role, address account) internal virtual {
        _grantRole(role, account);
    }

    /**
     * @dev Sets `adminRole` as ``role``'s admin role.
     *
     * Emits a {RoleAdminChanged} event.
     */
    function _setRoleAdmin(bytes32 role, bytes32 adminRole) internal virtual {
        bytes32 previousAdminRole = getRoleAdmin(role);
        _roles[role].adminRole = adminRole;
        emit RoleAdminChanged(role, previousAdminRole, adminRole);
    }

    /**
     * @dev Grants `role` to `account`.
     *
     * Internal function without access restriction.
     *
     * May emit a {RoleGranted} event.
     */
    function _grantRole(bytes32 role, address account) internal virtual {
        if (!hasRole(role, account)) {
            _roles[role].members[account] = true;
            emit RoleGranted(role, account, _msgSender());
        }
    }

    /**
     * @dev Revokes `role` from `account`.
     *
     * Internal function without access restriction.
     *
     * May emit a {RoleRevoked} event.
     */
    function _revokeRole(bytes32 role, address account) internal virtual {
        if (hasRole(role, account)) {
            _roles[role].members[account] = false;
            emit RoleRevoked(role, account, _msgSender());
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/Address.sol)

pragma solidity ^0.8.1;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     *
     * Furthermore, `isContract` will also return true if the target contract within
     * the same transaction is already scheduled for destruction by `SELFDESTRUCT`,
     * which only has an effect at the end of a transaction.
     * ====
     *
     * [IMPORTANT]
     * ====
     * You shouldn't rely on `isContract` to protect against flash loan attacks!
     *
     * Preventing calls from contracts is highly discouraged. It breaks composability, breaks support for smart wallets
     * like Gnosis Safe, and does not provide security since it can be circumvented by calling from a contract
     * constructor.
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize/address.code.length, which returns 0
        // for contracts in construction, since the code is only stored at the end
        // of the constructor execution.

        return account.code.length > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.8.0/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        (bool success, ) = recipient.call{value: amount}("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionDelegateCall(target, data, "Address: low-level delegate call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and revert (either by bubbling
     * the revert reason or using the provided one) in case of unsuccessful call or if target was not a contract.
     *
     * _Available since v4.8._
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        if (success) {
            if (returndata.length == 0) {
                // only check isContract if the call was successful and the return data is empty
                // otherwise we already know that it was a contract
                require(isContract(target), "Address: call to non-contract");
            }
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and revert if it wasn't, either by bubbling the
     * revert reason or using the provided one.
     *
     * _Available since v4.3._
     */
    function verifyCallResult(
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal pure returns (bytes memory) {
        if (success) {
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    function _revert(bytes memory returndata, string memory errorMessage) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            /// @solidity memory-safe-assembly
            assembly {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert(errorMessage);
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Context.sol)

pragma solidity ^0.8.0;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.19;

import '@openzeppelin/contracts/access/AccessControl.sol';
import '@openzeppelin/contracts/security/Pausable.sol';
import '@openzeppelin/contracts/security/ReentrancyGuard.sol';
import '@openzeppelin/contracts/interfaces/IERC20.sol';
import '@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol';
import '../vesting/interfaces/DeFiMerkleVesting/IDeFiMerkleVestingActions.sol';
import './interfaces/IDeFiChef.sol';


contract DeFiChef is AccessControl, Pausable, ReentrancyGuard, IDeFiChef {
  using SafeERC20 for IERC20;
  bytes32 public constant PAUSER_ROLE = keccak256('PAUSER_ROLE');
  bytes32 public constant EXTERNAL_SOURCE_ROLE = keccak256('EXTERNAL_SOURCE_ROLE');

  uint256 public constant YEAR = 360 days;
  uint256 public constant PRECISION = 10 ** 18;

  /// @notice Address of the reward contract.
  IERC20 public immutable DEFI;

  /// @notice Address of the stake token.
  IERC20 public immutable STAKE;

  /// @notice Cool down timeout.
  uint256 private _cooldown = 1 days;

  /// @notice Pools index.
  uint16 private _poolsIndex = 1;

  /// @notice Total stake.
  uint256 private _totalStaked;

  /// @notice Mapping for pooltype/pool.
  mapping(PoolType => uint16) private _customPools;

  /// @notice Info of each reward pool.
  mapping(uint16 => Pool) private _pools;

  /// @notice Info of each beneficiary pool/stake.
  mapping(address => mapping(uint16 => mapping(uint256 => Stake))) private _stakes;

  /// @notice Info of beneficiary/pool/position
  mapping(address => mapping(uint16 => uint256)) private _positions;

  /// @notice Referral info.
  mapping(address => Referral) private _referrals;

  /// @notice Referral balances.
  mapping(address => uint256) private _referralsBalances;

  /**
   * @param DEFI_ The DEFI token contract address.
   * @param STAKE_ The STAKE token contract address.
   */
  constructor(IERC20 DEFI_, IERC20 STAKE_) {
    _setupRole(DEFAULT_ADMIN_ROLE, _msgSender());
    _setupRole(PAUSER_ROLE, _msgSender());

    if (address(DEFI_) == address(0)) revert TokenNullAddressErr();
    if (address(STAKE_) == address(0)) revert TokenNullAddressErr();

    DEFI = DEFI_;
    STAKE = STAKE_;
  }

  modifier whenReferralEnabled(address referral_) {
    if (_referrals[referral_].defined && !_referrals[referral_].enabled) revert ReferralDisabledErr(referral_);
    _;
  }

  modifier whenValidSource(address source_) {
    if (!hasRole(EXTERNAL_SOURCE_ROLE, source_)) revert ExternalSourceAuthErr();
    _;
  }

  function setupCooldown(uint256 cooldown_)
    external
    onlyRole(DEFAULT_ADMIN_ROLE)
  {
    _cooldown = cooldown_;

    emit CooldownSetup(cooldown_);
  }

  function pause()
    external
    onlyRole(PAUSER_ROLE)
  {
    _pause();
  }

  function unpause()
    external
    onlyRole(PAUSER_ROLE)
  {
    _unpause();
  }

  function setupPool(
    uint256 minAmount_,
    uint256 baseRate_,
    uint256 boostRate_,
    uint256 affRate_,
    uint256 refRate_,
    uint256 duration_,
    PoolType type_,
    bool enabled_
  )
    external
    onlyRole(DEFAULT_ADMIN_ROLE)
  {
    uint16 pid = _poolsIndex;
    _poolsIndex++;
    
    _pools[pid] = Pool({
      defined: true,
      enabled: enabled_,
      minAmount: minAmount_,
      baseRate: baseRate_,
      boostRate: boostRate_,
      affRate: affRate_,
      refRate: refRate_,
      duration: duration_,
      closedAt: 0,
      closed: false
    });

    if (type_ == PoolType.baseline) {
      _customPools[type_] = pid;
    }

    emit PoolAdded(pid, minAmount_, baseRate_, boostRate_, affRate_, refRate_, duration_, enabled_);
  }

  function updatePool(
    uint16 pid_,
    uint256 minAmount_,
    uint256 baseRate_,
    uint256 boostRate_,
    uint256 affRate_,
    uint256 refRate_,
    uint256 duration_,
    bool enabled_
  )
    external
    onlyRole(DEFAULT_ADMIN_ROLE)
  {
    if (pid_ == 0 || !_pools[pid_].defined) revert PoolUndefinedErr(pid_);
    if (_pools[pid_].closed) revert PoolClosedErr(pid_);

    _pools[pid_].minAmount = minAmount_;
    _pools[pid_].baseRate = baseRate_;
    _pools[pid_].boostRate = boostRate_;
    _pools[pid_].affRate = affRate_;
    _pools[pid_].refRate = refRate_;
    _pools[pid_].duration = duration_;
    _pools[pid_].enabled = enabled_;

    emit PoolUpdated(pid_, minAmount_, baseRate_, boostRate_, affRate_, refRate_, duration_, enabled_);
  }

  function enablePool(uint16 pid_)
    external
    onlyRole(DEFAULT_ADMIN_ROLE)
  {
    if (pid_ == 0 || !_pools[pid_].defined) revert PoolUndefinedErr(pid_);
    if (_pools[pid_].closed) revert PoolClosedErr(pid_);

    _pools[pid_].enabled = true;

    emit PoolUpdated(
      pid_,
      _pools[pid_].minAmount,
      _pools[pid_].baseRate,
      _pools[pid_].boostRate,
      _pools[pid_].affRate,
      _pools[pid_].refRate,
      _pools[pid_].duration,
      true
    );
  }

  function disablePool(uint16 pid_)
    external
    onlyRole(DEFAULT_ADMIN_ROLE)
  {
    if (pid_ == 0 || !_pools[pid_].defined) revert PoolUndefinedErr(pid_);
    if (_pools[pid_].closed) revert PoolClosedErr(pid_);

    _pools[pid_].enabled = false;

    emit PoolUpdated(
      pid_,
      _pools[pid_].minAmount,
      _pools[pid_].baseRate,
      _pools[pid_].boostRate,
      _pools[pid_].affRate,
      _pools[pid_].refRate,
      _pools[pid_].duration,
      false
    );
  }

  function closePool(uint16 pid_)
    external
    onlyRole(DEFAULT_ADMIN_ROLE)
  {
    if (pid_ == 0 || !_pools[pid_].defined) revert PoolUndefinedErr(pid_);
    if (_pools[pid_].closed) revert PoolClosedErr(pid_);

    _pools[pid_].enabled = false;
    _pools[pid_].closedAt = block.timestamp;
    _pools[pid_].closed = true;

    emit PoolClosed(pid_);
  }

  function setupReferrals(
    address[] calldata referrals_,
    uint16[] calldata pools_,
    uint256[] calldata rates_
  )
    external
    onlyRole(DEFAULT_ADMIN_ROLE)
  {
    if (pools_.length != rates_.length) revert ArrayParamsInvalidLengthErr();

    uint256 rlength = referrals_.length;
    uint256 plength = pools_.length;
    for (uint256 ri = 0; ri < rlength; ri++) {
      address referral = referrals_[ri];
      _referrals[referral].defined = true;
      _referrals[referral].enabled = true;

      for (uint16 pi = 0; pi < plength; pi++) {
        uint16 pid = pools_[pi];
        uint256 rate = rates_[pi];
        if (pid == 0 || !_pools[pid].defined) revert PoolUndefinedErr(pid);
        
        _referrals[referral].rates[pid] = rate;
      }

      emit ReferralAdded(referral);
    }
  }

  function enableReferral(address referral_)
    external
    onlyRole(DEFAULT_ADMIN_ROLE)
  {
    if (_referrals[referral_].defined && _referrals[referral_].enabled) revert ReferralEnabledErr(referral_);
    
    _referrals[referral_].defined = true;
    _referrals[referral_].enabled = true;

    emit ReferralEnabled(referral_);
  }

  function disableReferral(address referral_)
    external
    onlyRole(DEFAULT_ADMIN_ROLE)
  {
    if (_referrals[referral_].defined && !_referrals[referral_].enabled) revert ReferralDisabledErr(referral_);

    _referrals[referral_].defined = true;
    _referrals[referral_].enabled = false;

    emit ReferralDisabled(referral_);
  }

  function deposit(
    uint16 pid_,
    uint256 amount_,
    address referral_
  )
    external
    nonReentrant()
    whenNotPaused()
    whenReferralEnabled(referral_)
  {
    Pool memory pool = _pools[pid_];
    if (amount_ == 0) revert AmountZeroErr();
    if (_msgSender() == referral_) revert InvalidReferralErr();
    if (!pool.enabled) revert PoolDisabledErr(pid_);
    if (pid_ == _customPools[PoolType.baseline]) revert PoolBaselineErr(pid_);
    
    uint256 before = STAKE.balanceOf(address(this));
    STAKE.safeTransferFrom(_msgSender(), address(this), amount_);
    amount_ = STAKE.balanceOf(address(this)) - before;

    if (amount_ < pool.minAmount) revert PoolMinAmountErr(pid_);    

    uint256 rate = pool.baseRate + pool.boostRate;
    uint256 refRate;
    if (referral_ != address(0)) {
      rate = rate + pool.affRate;
      refRate = getReferralRate(referral_, pid_);
    }

    uint256 position = _positions[_msgSender()][pid_];
    Stake memory stake = Stake({
      defined: true,
      pid: pid_,
      amount: amount_,
      rate: rate,
      referral: referral_,
      refRate: refRate,
      lockAt: block.timestamp,
      duration: pool.duration,
      unlockAt: 0,
      closed: false
    });

    _stakes[_msgSender()][pid_][position] = stake;
    _positions[_msgSender()][pid_] = position + 1;
    _totalStaked += amount_;

    emit Deposited(_msgSender(), pid_, position, amount_, rate);
  }

  function depositFrom(
    address vesting_,
    uint256 vid_,
    uint16 pid_,
    bytes calldata message_
  )
    external
    nonReentrant()
    whenNotPaused()
    whenValidSource(vesting_)
  {
    Pool memory pool = _pools[pid_];
    if (!pool.enabled) revert PoolDisabledErr(pid_);
    if (pid_ == _customPools[PoolType.baseline]) revert PoolBaselineErr(pid_);

    uint256 before = STAKE.balanceOf(address(this));
    IDeFiMerkleVestingActions(vesting_).claimFrom(vid_, _msgSender(), address(this), message_);
    uint256 amount_ = STAKE.balanceOf(address(this)) - before;

    if (amount_ < pool.minAmount) revert PoolMinAmountErr(pid_);

    uint256 rate = pool.baseRate + pool.boostRate + pool.refRate + pool.affRate;
    uint256 position = _positions[_msgSender()][pid_];
    Stake memory stake = Stake({
      defined: true,
      pid: pid_,
      amount: amount_,
      rate: rate,
      referral: address(0),
      refRate: 0,
      lockAt: block.timestamp,
      duration: pool.duration,
      unlockAt: 0,
      closed: false
    });

    _stakes[_msgSender()][pid_][position] = stake;
    _positions[_msgSender()][pid_] = position + 1;
    _totalStaked += amount_;

    emit DepositedFrom(vesting_, _msgSender(), pid_, position, amount_, rate);
  }

  function withdraw(uint16 pid_, uint256 pos_)
    external
    nonReentrant()
    whenNotPaused()
    returns (uint256 amount, uint256 reward)
  {
    Stake memory stake = _stakes[_msgSender()][pid_][pos_];
    if (!stake.defined) revert StakeUndefinedErr();
    if (stake.closed) revert StakeClosedErr();
    if (!isStakeUnlocked(_msgSender(), pid_, pos_)) revert StakeLockedErr();

    amount = stake.amount;
    _totalStaked -= amount;
    uint256 baselineDuration = getBaselineDuration(_msgSender(), pid_, pos_);
    _stakes[_msgSender()][pid_][pos_].closed = true;

    reward = amount * stake.rate * stake.duration / YEAR / PRECISION;
    if (baselineDuration > 0) {
      Pool memory baselinePool = _pools[_customPools[PoolType.baseline]];
      uint256 baselineRate = baselinePool.baseRate + baselinePool.boostRate;
      reward += amount * baselineRate * baselineDuration / YEAR / PRECISION;
    }

    if (stake.referral != address(0)) {
      uint256 refReward = amount * stake.refRate * stake.duration / YEAR / PRECISION;
      _referralsBalances[stake.referral] += refReward;
      emit ReferralBalanceUpdated(stake.referral, refReward);
    }

    STAKE.safeTransfer(_msgSender(), amount);
    if (reward > 0) {
      DEFI.safeTransfer(_msgSender(), reward);
    }

    emit Withdrawn(_msgSender(), pid_, pos_, amount, reward);
  }

  function withdrawRequest(uint16 pid_, uint256 pos_)
    external
    nonReentrant()
    whenNotPaused()
  {
    Stake memory stake = _stakes[_msgSender()][pid_][pos_];
    if (!stake.defined) revert StakeUndefinedErr();
    if (stake.closed) revert StakeClosedErr();
    if (stake.lockAt + stake.duration > block.timestamp) revert StakeLockedErr();

    uint256 unlockAt = block.timestamp + _cooldown;
    _stakes[_msgSender()][pid_][pos_].unlockAt = unlockAt;

    emit WithdrawRequested(_msgSender(), pid_, pos_, unlockAt);
  }

  function claim()
    external
    nonReentrant()
    whenNotPaused()
    whenReferralEnabled(_msgSender())
    returns (uint256 amount)
  {
    amount = _referralsBalances[_msgSender()];
    if (amount == 0) revert ReferralZeroBalanceErr(_msgSender());

    _referralsBalances[_msgSender()] = 0;
    DEFI.safeTransfer(_msgSender(), amount);

    emit Claimed(_msgSender(), amount);
  }

  function recoverERC20(address token_, uint256 amount_)
    external
    onlyRole(DEFAULT_ADMIN_ROLE)
  {
    IERC20(token_).safeTransfer(_msgSender(), amount_);

    emit ERC20Recovered(token_, amount_);
  }

  function isStakeUnlocked(address beneficiary_, uint16 pid_, uint256 pos_)
    public
    view
    returns (bool)
  {
    Stake memory stake = _stakes[beneficiary_][pid_][pos_];
    if (!stake.defined || stake.closed) return false;

    if (_cooldown == 0) {
      uint256 mainlineTimestamp = stake.lockAt + stake.duration;
      return mainlineTimestamp < block.timestamp;
    }

    return stake.unlockAt > 0 ? stake.unlockAt < block.timestamp : false;
  }

  function getBaselineDuration(address beneficiary_, uint16 pid_, uint256 pos_)
    public
    view
    returns (uint256)
  {
    Pool memory baselinePool = _pools[_customPools[PoolType.baseline]];
    if (!baselinePool.defined) return 0;

    Stake memory stake = _stakes[beneficiary_][pid_][pos_];
    if (!stake.defined || stake.closed) return 0;

    uint256 mainlineTimestamp = stake.lockAt + stake.duration;
    uint256 baselineTimestamp = baselinePool.closed ? baselinePool.closedAt : block.timestamp;

    return baselineTimestamp > mainlineTimestamp ? baselineTimestamp - mainlineTimestamp : 0;
  }

  function getReferralRate(address referral_, uint16 pid_)
    public
    view
    returns (uint256)
  {
    Pool memory pool = _pools[pid_];
    uint256 rate = pool.refRate;
    if (_referrals[referral_].defined && _referrals[referral_].enabled) {
      rate = Math.max(_referrals[referral_].rates[pid_], rate);
    }
    return rate;
  }

  function referralBalanceOf(address referral_)
    public
    view
    returns (uint256)
  {
    return _referralsBalances[referral_];
  }

  function getStake(address beneficiary_, uint16 pid_, uint256 pos_)
    external
    view
    returns (Stake memory stake)
  {
    stake = _stakes[beneficiary_][pid_][pos_];
  }

  function getTotalStakeAmount()
    external
    view
    returns (uint256)
  {
    return _totalStaked;
  }

  function getTotalPoolsCount()
    external
    view
    returns (uint256)
  {
    return _poolsIndex - 1;
  }

  function getPosCount(address beneficiary_, uint16 pid_)
    external
    view
    returns (uint256)
  {
    return _positions[beneficiary_][pid_];
  }

  function getPool(uint16 pid_)
    external
    view
    returns (Pool memory pool)
  {
    pool = _pools[pid_];
  }

  function getBaselinePoolId()
    external
    view
    returns (uint256)
  {
    return _customPools[PoolType.baseline];
  }

  function getCooldown()
    external
    view
    returns (uint256)
  {
    return _cooldown;
  }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/introspection/ERC165.sol)

pragma solidity ^0.8.0;

import "./IERC165.sol";

/**
 * @dev Implementation of the {IERC165} interface.
 *
 * Contracts that want to implement ERC165 should inherit from this contract and override {supportsInterface} to check
 * for the additional interface id that will be supported. For example:
 *
 * ```solidity
 * function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
 *     return interfaceId == type(MyInterface).interfaceId || super.supportsInterface(interfaceId);
 * }
 * ```
 *
 * Alternatively, {ERC165Storage} provides an easier to use but more expensive implementation.
 */
abstract contract ERC165 is IERC165 {
    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
        return interfaceId == type(IERC165).interfaceId;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (access/IAccessControl.sol)

pragma solidity ^0.8.0;

/**
 * @dev External interface of AccessControl declared to support ERC165 detection.
 */
interface IAccessControl {
    /**
     * @dev Emitted when `newAdminRole` is set as ``role``'s admin role, replacing `previousAdminRole`
     *
     * `DEFAULT_ADMIN_ROLE` is the starting admin for all roles, despite
     * {RoleAdminChanged} not being emitted signaling this.
     *
     * _Available since v3.1._
     */
    event RoleAdminChanged(bytes32 indexed role, bytes32 indexed previousAdminRole, bytes32 indexed newAdminRole);

    /**
     * @dev Emitted when `account` is granted `role`.
     *
     * `sender` is the account that originated the contract call, an admin role
     * bearer except when using {AccessControl-_setupRole}.
     */
    event RoleGranted(bytes32 indexed role, address indexed account, address indexed sender);

    /**
     * @dev Emitted when `account` is revoked `role`.
     *
     * `sender` is the account that originated the contract call:
     *   - if using `revokeRole`, it is the admin role bearer
     *   - if using `renounceRole`, it is the role bearer (i.e. `account`)
     */
    event RoleRevoked(bytes32 indexed role, address indexed account, address indexed sender);

    /**
     * @dev Returns `true` if `account` has been granted `role`.
     */
    function hasRole(bytes32 role, address account) external view returns (bool);

    /**
     * @dev Returns the admin role that controls `role`. See {grantRole} and
     * {revokeRole}.
     *
     * To change a role's admin, use {AccessControl-_setRoleAdmin}.
     */
    function getRoleAdmin(bytes32 role) external view returns (bytes32);

    /**
     * @dev Grants `role` to `account`.
     *
     * If `account` had not been already granted `role`, emits a {RoleGranted}
     * event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     */
    function grantRole(bytes32 role, address account) external;

    /**
     * @dev Revokes `role` from `account`.
     *
     * If `account` had been granted `role`, emits a {RoleRevoked} event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     */
    function revokeRole(bytes32 role, address account) external;

    /**
     * @dev Revokes `role` from the calling account.
     *
     * Roles are often managed via {grantRole} and {revokeRole}: this function's
     * purpose is to provide a mechanism for accounts to lose their privileges
     * if they are compromised (such as when a trusted device is misplaced).
     *
     * If the calling account had been granted `role`, emits a {RoleRevoked}
     * event.
     *
     * Requirements:
     *
     * - the caller must be `account`.
     */
    function renounceRole(bytes32 role, address account) external;
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.19;

import './DeFiChef/IDeFiChefActions.sol';
import './DeFiChef/IDeFiChefErrors.sol';
import './DeFiChef/IDeFiChefEvents.sol';
import './DeFiChef/IDeFiChefState.sol';


interface IDeFiChef is IDeFiChefActions, IDeFiChefErrors, IDeFiChefEvents, IDeFiChefState {
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.19;

import './IDeFiChefState.sol';

interface IDeFiChefActions {

  /**
   * @notice Setups new cooldown duration.
   * @param cooldown_  the cooldown of the withdrawal.
   */
  function setupCooldown(uint256 cooldown_) external;

  /**
   * @notice Initializes new staking pool
   * @param minAmount_  min stake amount.
   * @param baseRate_  base allocation rate.
   * @param boostRate_  boosted allocation rate.
   * @param affRate_  affiliate allocation rate.
   * @param refRate_  referral allocation rate.
   * @param duration_  stake duration.
   * @param type_  pool type.
   * @param enabled_  if pool enabled.
   */
  function setupPool(
    uint256 minAmount_,
    uint256 baseRate_,
    uint256 boostRate_,
    uint256 affRate_,
    uint256 refRate_,
    uint256 duration_,
    IDeFiChefState.PoolType type_,
    bool enabled_
  ) external;

  /**
   * @notice Updates pool.
   * @param pid_  the id of the pool.
   * @param minAmount_  min stake amount.
   * @param baseRate_  base allocation rate.
   * @param boostRate_  boosted allocation rate.
   * @param affRate_  affiliate allocation rate.
   * @param refRate_  referral allocation rate.
   * @param duration_  stake duration.
   * @param enabled_  if pool enabled.
   */
  function updatePool(
    uint16 pid_,
    uint256 minAmount_,
    uint256 baseRate_,
    uint256 boostRate_,
    uint256 affRate_,
    uint256 refRate_,
    uint256 duration_,
    bool enabled_
  ) external;

  /**
   * @notice Closes the pool.
   * @param pid_  the id of the staking pool.
   */
  function closePool(uint16 pid_) external;

  /**
   * @notice Enables the pool.
   * @param pid_  the id of the staking pool.
   */
  function enablePool(uint16 pid_) external;

  /**
   * @notice Disables the pool.
   * @param pid_  the id of the staking pool.
   */
  function disablePool(uint16 pid_) external;

  /**
   * @notice Setups referrals.
   * @param referrals_  referral addresses.
   * @param pools_  pool ids.
   * @param rates_  rate by each pool.
   */
  function setupReferrals(
    address[] calldata referrals_,
    uint16[] calldata pools_,
    uint256[] calldata rates_
  ) external;

  /**
   * @notice Enables referral.
   * @param referral_  referral address.
   */
  function enableReferral(address referral_) external;

  /**
   * @notice Disables referral.
   * @param referral_  referral address.
   */
  function disableReferral(address referral_) external;

  /**
   * @notice Deposits tokens to the staking pool.
   * @param pid_  the id of the staking pool.
   * @param amount_  amount of the tokens to deposit.
   * @param referral_  referral address.
   */
  function deposit(uint16 pid_, uint256 amount_, address referral_) external;

  /**
   * @notice Deposit tokens to the staking pool from vesting SC.
   * @param vesting_  vesting SC address.
   * @param vid_  the id of the vesting pool.
   * @param pid_  the id of the staking pool.
   * @param message_  beneficiary message.
   */
  function depositFrom(address vesting_, uint256 vid_, uint16 pid_, bytes calldata message_) external;

  /**
   * @notice Withdraws staked tokens from the pool.
   * @param pid_  the id of the staking pool.
   * @param pos_  the position of the stake.
   */
  function withdraw(uint16 pid_, uint256 pos_) external returns (uint256 amount, uint256 reward);

  /**
   * @notice Requests a withdraw of the staked tokens from the pool.
   * @param pid_  the id of the staking pool.
   * @param pos_  the position of the stake.
   */
  function withdrawRequest(uint16 pid_, uint256 pos_) external;

  /**
   * @notice Claims referral rewards.
   */
  function claim() external returns (uint256 amount);

  /**
   * @dev Allows to recover erc20 tokens.
   * @param token_  token address.
   * @param amount_  amount to be recovered.
   */
  function recoverERC20(address token_, uint256 amount_) external;

  /**
   * @notice Returns stake info.
   * @param beneficiary_  beneficiary address.
   * @param pid_  the id of the staking pool.
   * @param pos_  stake position.
   */
  function getStake(address beneficiary_, uint16 pid_, uint256 pos_) external view returns (IDeFiChefState.Stake memory stake);

  /**
   * @notice Returns if stake unlocked.
   * @param beneficiary_  beneficiary address.
   * @param pid_  the id of the staking pool.
   * @param pos_  stake position.
   */
  function isStakeUnlocked(address beneficiary_, uint16 pid_, uint256 pos_) external view returns (bool);

  /**
   * @notice Returns baseline duration.
   * @param beneficiary_  beneficiary address.
   * @param pid_  the id of the staking pool.
   * @param pos_  stake position.
   */
  function getBaselineDuration(address beneficiary_, uint16 pid_, uint256 pos_) external view returns (uint256);

  /**
   * @notice Returns referral rate.
   * @param referral_  referral address.
   * @param pid_  the id of the staking pool.
   */
  function getReferralRate(address referral_, uint16 pid_) external view returns (uint256);

  /**
   * @notice Returns referral balance.
   * @param referral_  referral address.
   */
  function referralBalanceOf(address referral_) external view returns (uint256);

  /**
   * @notice Returns total staked amount.
   */
  function getTotalStakeAmount() external view returns (uint256);

  /**
   * @notice Returns total pools count.
   */
  function getTotalPoolsCount() external view returns (uint256);

  /**
   * @notice Returns pools info.
   * @param pid_  the id of the staking pool.
   */
  function getPool(uint16 pid_) external view returns (IDeFiChefState.Pool memory pool);

  /**
   * @notice Returns baseline pool id.
   */
  function getBaselinePoolId() external view returns (uint256);

  /**
   * @notice Returns cooldown duration.
   */
  function getCooldown() external view returns (uint256);

  /**
   * @notice Returns total position count per beneficiary/pool.
   * @param beneficiary_  beneficiary address.
   * @param pid_  the id of the staking pool.
   */
  function getPosCount(address beneficiary_, uint16 pid_) external view returns (uint256);
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.19;


interface IDeFiChefErrors {
  error ArrayParamsInvalidLengthErr();
  error AmountZeroErr();

  error PoolDefinedErr(uint16 pid_);
  error PoolUndefinedErr(uint16 pid_);
  error PoolBaselineErr(uint16 pid_);
  error PoolDisabledErr(uint16 pid_);
  error PoolClosedErr(uint16 pid_);
  error PoolMinAmountErr(uint16 pid_);

  error StakeUndefinedErr();
  error StakeEmergencyErr();
  error StakeLockedErr();
  error StakeClosedErr();

  error InvalidReferralErr();
  error ReferralUndefinedErr(address referral_);
  error ReferralEnabledErr(address referral_);
  error ReferralDisabledErr(address referral_);
  error ReferralZeroBalanceErr(address referral_);
  error ReferralEpochErr(address referral_);

  error TokenNullAddressErr();

  error ExternalSourceAuthErr();
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.19;


interface IDeFiChefEvents {
  event CooldownSetup(uint256 cooldown);

  event PoolAdded(uint16 indexed pid, uint256 minAmount, uint256 baseRate, uint256 boostRate, uint256 affRate, uint256 refRate, uint256 duration, bool enabled);
  event PoolUpdated(uint16 indexed pid, uint256 minAmount, uint256 baseRate, uint256 boostRate, uint256 affRate, uint256 refRate, uint256 duration, bool enabled);
  event PoolClosed(uint16 indexed pid);
  
  event ReferralAdded(address indexed referral);
  event ReferralEnabled(address indexed referral);
  event ReferralDisabled(address indexed referral);
  event ReferralClaimed(address indexed referral, uint256 amount);
  event ReferralBalanceUpdated(address indexed referral, uint256 amount);
  event ReferralVestingSetup(uint256 epoch, uint256 duration);
  
  event Deposited(address indexed user, uint16 pool, uint256 pos, uint256 amount, uint256 rate);
  event DepositedFrom(address indexed source, address indexed user, uint16 pool, uint256 pos, uint256 amount, uint256 rate);
  event Withdrawn(address indexed user, uint16 pool, uint256 pos, uint256 amount, uint256 reward);
  event WithdrawRequested(address indexed user, uint16 pool, uint256 pos, uint256 unlock);
  event Claimed(address indexed referral, uint256 amount);
  
  event ERC20Recovered(address token, uint256 amount);
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.19;


interface IDeFiChefState {
  struct Stake {
    bool defined;
    uint16 pid;
    uint256 amount;
    uint256 rate;
    address referral;
    uint256 refRate;
    uint256 lockAt;
    uint256 duration;
    uint256 unlockAt;
    bool closed;
  }

  enum PoolType {
    none,
    baseline
  }

  struct Pool {
    bool defined;
    bool enabled;
    uint256 minAmount;
    uint256 baseRate;
    uint256 boostRate;
    uint256 affRate;
    uint256 refRate;
    uint256 duration;
    uint256 closedAt;
    bool closed;
  }

  struct Referral {
    bool defined;
    bool enabled;
    mapping(uint16 => uint256) rates;
  }
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.19;


interface IDeFiMerkleVestingActions {
  /**
   * @dev Initialize new vesting pool.
   * @param startTime_  vesting start time.
   * @param endTime_  vesting end time.
   * @param merkleRoot_  merkle root.
   * @param lockable_  if pool lockable.
   * @param baseRate_  pool base rate.
   * @param boostRate_  pool boost rate.
   */
  function setupPool(
    uint256 startTime_,
    uint256 endTime_,
    bytes32 merkleRoot_,
    bool lockable_,
    uint256 baseRate_,
    uint256 boostRate_
  ) external returns (uint256 pid);

  /**
   * @dev Sets new timing parameters of the vesting pool.
   * @param pid_  pool id.
   * @param startTime_  vesting start time.
   * @param endTime_  vesting end time.
   */
  function updatePoolTiming(uint256 pid_, uint256 startTime_, uint256 endTime_) external;

  /**
   * @dev Sets new merkle root of the vesting pool.
   * @param pid_  pool id.
   * @param merkleRoot_  merkle root.
   */
  function updatePoolRoot(uint256 pid_, bytes32 merkleRoot_) external;

  /**
   * @dev Sets new rate parameters of the vesting pool.
   * @param pid_  pool id.
   * @param lockable_  if pool lockable.
   * @param baseRate_  pool base rate.
   * @param boostRate_  pool boost rate.
   */
  function updatePoolRate(uint256 pid_, bool lockable_, uint256 baseRate_, uint256 boostRate_) external;

  /**
   * @dev Enables beneficiary per pools.
   * @param pids_  pool ids.
   * @param beneficiary_  beneficiary address.
   */
  function enableBeneficiary(uint256[] calldata pids_, address beneficiary_) external;

  /**
   * @dev Disables beneficiary per pools(in case wallet was exploited).
   * @param pids_  pool ids.
   * @param beneficiary_  beneficiary address.
   */
  function disableBeneficiary(uint256[] calldata pids_, address beneficiary_) external;

  /**
   * @dev Recovers beneficiary to a predefined state(in case wallet was exploited).
   * @param pid_  pool id.
   * @param beneficiary_  beneficiary address.
   * @param disabled_  if beneficiary disabled.
   * @param withdrawn_  how many tokens beneficiary have withdrawn.
   * @param locked_  if beneficiary locked pool.
   * @param lockedAt_  if when beneficiary was locked.
   * @param rate_  beneficiary lock rate.
   */
  function recoverBeneficiary(uint256 pid_, address beneficiary_, bool disabled_, uint256 withdrawn_, bool locked_, uint256 lockedAt_, uint256 rate_) external;

  /**
   * @dev Allows beneficiary to claim vested tokens.
   * @param pid_  pool id.
   * @param message_  beneficiary message.
   */
  function claim(uint256 pid_, bytes calldata message_) external returns (uint256 amount);

  /**
   * @dev Allows third party to claim beneficiaries vested tokens(in case of integration with other contracts).
   * @param pid_  pool id.
   * @param from_  beneficiary address.
   * @param to_  address where the tokens will be transferred.
   * @param message_  beneficiary message.
   */
  function claimFrom(uint256 pid_, address from_, address to_, bytes calldata message_) external returns (uint256 amount);

  /**
   * @dev Allows beneficiary to lock vesting tokens(for the vesting duration) to earn interest rate.
   * @param pid_  pool id.
   * @param message_  beneficiary message.
   */
  function lock(uint256 pid_, bytes calldata message_) external;

  /**
   * @dev Allows to unlock vesting tokens.
   * @param pid_  pool id.
   * @param beneficiaries_  beneficiaries addresses.
   */
  function unlock(uint256 pid_, address[] calldata beneficiaries_) external;

  /**
   * @dev Allows to recover erc20 tokens.
   * @param token_  token address.
   * @param amount_  amount to be recovered.
   */
  function recoverERC20(address token_, uint256 amount_) external;

  /**
   * @dev Returns amount of releasable tokens per beneficiary per pool.
   * @param pid_  pool id.
   * @param beneficiary_  beneficiary address.
   * @param message_  beneficiary message.
   */
  function getReleasableAmount(uint256 pid_, address beneficiary_, bytes calldata message_) external view returns (uint256);

  /**
   * @dev Returns amount of vested tokens per beneficiary per timestamp.
   * @param pid_  pool id.
   * @param beneficiary_  beneficiary address.
   * @param message_  beneficiary message.
   * @param time_  time of vesting.
   */
  function getVestedAmount(uint256 pid_, address beneficiary_, bytes calldata message_, uint256 time_) external view returns (uint256);

  /**
   * @dev Returns beneficiary details per pool.
   * @param pid_  pool id.
   * @param beneficiary_  beneficiary address.
   * @param message_  beneficiary message.
   */
  function getBeneficiary(uint256 pid_, address beneficiary_, bytes calldata message_)
    external
    view
    returns (
      bool disabled,
      uint256 lockedAmount,
      uint256 withdrawn,
      uint256 releasableAmount,
      uint256 currentTime,
      bool locked,
      uint256 lockedAt,
      uint256 rate
    );

  /**
   * @dev Returns count of pools.
   */
  function getPoolsCount() external view returns (uint256 poolsCount);

  /**
   * @dev Returns pool details.
   * @param pid_  pool id.
   */
  function getPool(uint256 pid_)
    external
    view
    returns (
      uint256 startTime,
      uint256 endTime,
      bytes32 merkleRoot,
      bool lockable,
      uint256 baseRate,
      uint256 boostRate
    );
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/introspection/IERC165.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[EIP].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[EIP section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (interfaces/IERC20.sol)

pragma solidity ^0.8.0;

import "../token/ERC20/IERC20.sol";

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/extensions/IERC20Permit.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 Permit extension allowing approvals to be made via signatures, as defined in
 * https://eips.ethereum.org/EIPS/eip-2612[EIP-2612].
 *
 * Adds the {permit} method, which can be used to change an account's ERC20 allowance (see {IERC20-allowance}) by
 * presenting a message signed by the account. By not relying on {IERC20-approve}, the token holder account doesn't
 * need to send a transaction, and thus is not required to hold Ether at all.
 */
interface IERC20Permit {
    /**
     * @dev Sets `value` as the allowance of `spender` over ``owner``'s tokens,
     * given ``owner``'s signed approval.
     *
     * IMPORTANT: The same issues {IERC20-approve} has related to transaction
     * ordering also apply here.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `deadline` must be a timestamp in the future.
     * - `v`, `r` and `s` must be a valid `secp256k1` signature from `owner`
     * over the EIP712-formatted function arguments.
     * - the signature must use ``owner``'s current nonce (see {nonces}).
     *
     * For more information on the signature format, see the
     * https://eips.ethereum.org/EIPS/eip-2612#specification[relevant EIP
     * section].
     */
    function permit(
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external;

    /**
     * @dev Returns the current nonce for `owner`. This value must be
     * included whenever a signature is generated for {permit}.
     *
     * Every successful call to {permit} increases ``owner``'s nonce by one. This
     * prevents a signature from being used multiple times.
     */
    function nonces(address owner) external view returns (uint256);

    /**
     * @dev Returns the domain separator used in the encoding of the signature for {permit}, as defined by {EIP712}.
     */
    // solhint-disable-next-line func-name-mixedcase
    function DOMAIN_SEPARATOR() external view returns (bytes32);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/math/Math.sol)

pragma solidity ^0.8.0;

/**
 * @dev Standard math utilities missing in the Solidity language.
 */
library Math {
    enum Rounding {
        Down, // Toward negative infinity
        Up, // Toward infinity
        Zero // Toward zero
    }

    /**
     * @dev Returns the largest of two numbers.
     */
    function max(uint256 a, uint256 b) internal pure returns (uint256) {
        return a > b ? a : b;
    }

    /**
     * @dev Returns the smallest of two numbers.
     */
    function min(uint256 a, uint256 b) internal pure returns (uint256) {
        return a < b ? a : b;
    }

    /**
     * @dev Returns the average of two numbers. The result is rounded towards
     * zero.
     */
    function average(uint256 a, uint256 b) internal pure returns (uint256) {
        // (a + b) / 2 can overflow.
        return (a & b) + (a ^ b) / 2;
    }

    /**
     * @dev Returns the ceiling of the division of two numbers.
     *
     * This differs from standard division with `/` in that it rounds up instead
     * of rounding down.
     */
    function ceilDiv(uint256 a, uint256 b) internal pure returns (uint256) {
        // (a + b - 1) / b can overflow on addition, so we distribute.
        return a == 0 ? 0 : (a - 1) / b + 1;
    }

    /**
     * @notice Calculates floor(x * y / denominator) with full precision. Throws if result overflows a uint256 or denominator == 0
     * @dev Original credit to Remco Bloemen under MIT license (https://xn--2-umb.com/21/muldiv)
     * with further edits by Uniswap Labs also under MIT license.
     */
    function mulDiv(uint256 x, uint256 y, uint256 denominator) internal pure returns (uint256 result) {
        unchecked {
            // 512-bit multiply [prod1 prod0] = x * y. Compute the product mod 2^256 and mod 2^256 - 1, then use
            // use the Chinese Remainder Theorem to reconstruct the 512 bit result. The result is stored in two 256
            // variables such that product = prod1 * 2^256 + prod0.
            uint256 prod0; // Least significant 256 bits of the product
            uint256 prod1; // Most significant 256 bits of the product
            assembly {
                let mm := mulmod(x, y, not(0))
                prod0 := mul(x, y)
                prod1 := sub(sub(mm, prod0), lt(mm, prod0))
            }

            // Handle non-overflow cases, 256 by 256 division.
            if (prod1 == 0) {
                // Solidity will revert if denominator == 0, unlike the div opcode on its own.
                // The surrounding unchecked block does not change this fact.
                // See https://docs.soliditylang.org/en/latest/control-structures.html#checked-or-unchecked-arithmetic.
                return prod0 / denominator;
            }

            // Make sure the result is less than 2^256. Also prevents denominator == 0.
            require(denominator > prod1, "Math: mulDiv overflow");

            ///////////////////////////////////////////////
            // 512 by 256 division.
            ///////////////////////////////////////////////

            // Make division exact by subtracting the remainder from [prod1 prod0].
            uint256 remainder;
            assembly {
                // Compute remainder using mulmod.
                remainder := mulmod(x, y, denominator)

                // Subtract 256 bit number from 512 bit number.
                prod1 := sub(prod1, gt(remainder, prod0))
                prod0 := sub(prod0, remainder)
            }

            // Factor powers of two out of denominator and compute largest power of two divisor of denominator. Always >= 1.
            // See https://cs.stackexchange.com/q/138556/92363.

            // Does not overflow because the denominator cannot be zero at this stage in the function.
            uint256 twos = denominator & (~denominator + 1);
            assembly {
                // Divide denominator by twos.
                denominator := div(denominator, twos)

                // Divide [prod1 prod0] by twos.
                prod0 := div(prod0, twos)

                // Flip twos such that it is 2^256 / twos. If twos is zero, then it becomes one.
                twos := add(div(sub(0, twos), twos), 1)
            }

            // Shift in bits from prod1 into prod0.
            prod0 |= prod1 * twos;

            // Invert denominator mod 2^256. Now that denominator is an odd number, it has an inverse modulo 2^256 such
            // that denominator * inv = 1 mod 2^256. Compute the inverse by starting with a seed that is correct for
            // four bits. That is, denominator * inv = 1 mod 2^4.
            uint256 inverse = (3 * denominator) ^ 2;

            // Use the Newton-Raphson iteration to improve the precision. Thanks to Hensel's lifting lemma, this also works
            // in modular arithmetic, doubling the correct bits in each step.
            inverse *= 2 - denominator * inverse; // inverse mod 2^8
            inverse *= 2 - denominator * inverse; // inverse mod 2^16
            inverse *= 2 - denominator * inverse; // inverse mod 2^32
            inverse *= 2 - denominator * inverse; // inverse mod 2^64
            inverse *= 2 - denominator * inverse; // inverse mod 2^128
            inverse *= 2 - denominator * inverse; // inverse mod 2^256

            // Because the division is now exact we can divide by multiplying with the modular inverse of denominator.
            // This will give us the correct result modulo 2^256. Since the preconditions guarantee that the outcome is
            // less than 2^256, this is the final result. We don't need to compute the high bits of the result and prod1
            // is no longer required.
            result = prod0 * inverse;
            return result;
        }
    }

    /**
     * @notice Calculates x * y / denominator with full precision, following the selected rounding direction.
     */
    function mulDiv(uint256 x, uint256 y, uint256 denominator, Rounding rounding) internal pure returns (uint256) {
        uint256 result = mulDiv(x, y, denominator);
        if (rounding == Rounding.Up && mulmod(x, y, denominator) > 0) {
            result += 1;
        }
        return result;
    }

    /**
     * @dev Returns the square root of a number. If the number is not a perfect square, the value is rounded down.
     *
     * Inspired by Henry S. Warren, Jr.'s "Hacker's Delight" (Chapter 11).
     */
    function sqrt(uint256 a) internal pure returns (uint256) {
        if (a == 0) {
            return 0;
        }

        // For our first guess, we get the biggest power of 2 which is smaller than the square root of the target.
        //
        // We know that the "msb" (most significant bit) of our target number `a` is a power of 2 such that we have
        // `msb(a) <= a < 2*msb(a)`. This value can be written `msb(a)=2**k` with `k=log2(a)`.
        //
        // This can be rewritten `2**log2(a) <= a < 2**(log2(a) + 1)`
        // → `sqrt(2**k) <= sqrt(a) < sqrt(2**(k+1))`
        // → `2**(k/2) <= sqrt(a) < 2**((k+1)/2) <= 2**(k/2 + 1)`
        //
        // Consequently, `2**(log2(a) / 2)` is a good first approximation of `sqrt(a)` with at least 1 correct bit.
        uint256 result = 1 << (log2(a) >> 1);

        // At this point `result` is an estimation with one bit of precision. We know the true value is a uint128,
        // since it is the square root of a uint256. Newton's method converges quadratically (precision doubles at
        // every iteration). We thus need at most 7 iteration to turn our partial result with one bit of precision
        // into the expected uint128 result.
        unchecked {
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            return min(result, a / result);
        }
    }

    /**
     * @notice Calculates sqrt(a), following the selected rounding direction.
     */
    function sqrt(uint256 a, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = sqrt(a);
            return result + (rounding == Rounding.Up && result * result < a ? 1 : 0);
        }
    }

    /**
     * @dev Return the log in base 2, rounded down, of a positive value.
     * Returns 0 if given 0.
     */
    function log2(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >> 128 > 0) {
                value >>= 128;
                result += 128;
            }
            if (value >> 64 > 0) {
                value >>= 64;
                result += 64;
            }
            if (value >> 32 > 0) {
                value >>= 32;
                result += 32;
            }
            if (value >> 16 > 0) {
                value >>= 16;
                result += 16;
            }
            if (value >> 8 > 0) {
                value >>= 8;
                result += 8;
            }
            if (value >> 4 > 0) {
                value >>= 4;
                result += 4;
            }
            if (value >> 2 > 0) {
                value >>= 2;
                result += 2;
            }
            if (value >> 1 > 0) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 2, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log2(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log2(value);
            return result + (rounding == Rounding.Up && 1 << result < value ? 1 : 0);
        }
    }

    /**
     * @dev Return the log in base 10, rounded down, of a positive value.
     * Returns 0 if given 0.
     */
    function log10(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >= 10 ** 64) {
                value /= 10 ** 64;
                result += 64;
            }
            if (value >= 10 ** 32) {
                value /= 10 ** 32;
                result += 32;
            }
            if (value >= 10 ** 16) {
                value /= 10 ** 16;
                result += 16;
            }
            if (value >= 10 ** 8) {
                value /= 10 ** 8;
                result += 8;
            }
            if (value >= 10 ** 4) {
                value /= 10 ** 4;
                result += 4;
            }
            if (value >= 10 ** 2) {
                value /= 10 ** 2;
                result += 2;
            }
            if (value >= 10 ** 1) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 10, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log10(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log10(value);
            return result + (rounding == Rounding.Up && 10 ** result < value ? 1 : 0);
        }
    }

    /**
     * @dev Return the log in base 256, rounded down, of a positive value.
     * Returns 0 if given 0.
     *
     * Adding one to the result gives the number of pairs of hex symbols needed to represent `value` as a hex string.
     */
    function log256(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >> 128 > 0) {
                value >>= 128;
                result += 16;
            }
            if (value >> 64 > 0) {
                value >>= 64;
                result += 8;
            }
            if (value >> 32 > 0) {
                value >>= 32;
                result += 4;
            }
            if (value >> 16 > 0) {
                value >>= 16;
                result += 2;
            }
            if (value >> 8 > 0) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 256, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log256(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log256(value);
            return result + (rounding == Rounding.Up && 1 << (result << 3) < value ? 1 : 0);
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.7.0) (security/Pausable.sol)

pragma solidity ^0.8.0;

import "../utils/Context.sol";

/**
 * @dev Contract module which allows children to implement an emergency stop
 * mechanism that can be triggered by an authorized account.
 *
 * This module is used through inheritance. It will make available the
 * modifiers `whenNotPaused` and `whenPaused`, which can be applied to
 * the functions of your contract. Note that they will not be pausable by
 * simply including this module, only once the modifiers are put in place.
 */
abstract contract Pausable is Context {
    /**
     * @dev Emitted when the pause is triggered by `account`.
     */
    event Paused(address account);

    /**
     * @dev Emitted when the pause is lifted by `account`.
     */
    event Unpaused(address account);

    bool private _paused;

    /**
     * @dev Initializes the contract in unpaused state.
     */
    constructor() {
        _paused = false;
    }

    /**
     * @dev Modifier to make a function callable only when the contract is not paused.
     *
     * Requirements:
     *
     * - The contract must not be paused.
     */
    modifier whenNotPaused() {
        _requireNotPaused();
        _;
    }

    /**
     * @dev Modifier to make a function callable only when the contract is paused.
     *
     * Requirements:
     *
     * - The contract must be paused.
     */
    modifier whenPaused() {
        _requirePaused();
        _;
    }

    /**
     * @dev Returns true if the contract is paused, and false otherwise.
     */
    function paused() public view virtual returns (bool) {
        return _paused;
    }

    /**
     * @dev Throws if the contract is paused.
     */
    function _requireNotPaused() internal view virtual {
        require(!paused(), "Pausable: paused");
    }

    /**
     * @dev Throws if the contract is not paused.
     */
    function _requirePaused() internal view virtual {
        require(paused(), "Pausable: not paused");
    }

    /**
     * @dev Triggers stopped state.
     *
     * Requirements:
     *
     * - The contract must not be paused.
     */
    function _pause() internal virtual whenNotPaused {
        _paused = true;
        emit Paused(_msgSender());
    }

    /**
     * @dev Returns to normal state.
     *
     * Requirements:
     *
     * - The contract must be paused.
     */
    function _unpause() internal virtual whenPaused {
        _paused = false;
        emit Unpaused(_msgSender());
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (security/ReentrancyGuard.sol)

pragma solidity ^0.8.0;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant _NOT_ENTERED = 1;
    uint256 private constant _ENTERED = 2;

    uint256 private _status;

    constructor() {
        _status = _NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be _NOT_ENTERED
        require(_status != _ENTERED, "ReentrancyGuard: reentrant call");

        // Any calls to nonReentrant after this point will fail
        _status = _ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = _NOT_ENTERED;
    }

    /**
     * @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
     * `nonReentrant` function in the call stack.
     */
    function _reentrancyGuardEntered() internal view returns (bool) {
        return _status == _ENTERED;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.0;

import "../IERC20.sol";
import "../extensions/IERC20Permit.sol";
import "../../../utils/Address.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using Address for address;

    /**
     * @dev Transfer `value` amount of `token` from the calling contract to `to`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transfer.selector, to, value));
    }

    /**
     * @dev Transfer `value` amount of `token` from `from` to `to`, spending the approval given by `from` to the
     * calling contract. If `token` returns no value, non-reverting calls are assumed to be successful.
     */
    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transferFrom.selector, from, to, value));
    }

    /**
     * @dev Deprecated. This function has issues similar to the ones found in
     * {IERC20-approve}, and its usage is discouraged.
     *
     * Whenever possible, use {safeIncreaseAllowance} and
     * {safeDecreaseAllowance} instead.
     */
    function safeApprove(IERC20 token, address spender, uint256 value) internal {
        // safeApprove should only be called when setting an initial allowance,
        // or when resetting it to zero. To increase and decrease it, use
        // 'safeIncreaseAllowance' and 'safeDecreaseAllowance'
        require(
            (value == 0) || (token.allowance(address(this), spender) == 0),
            "SafeERC20: approve from non-zero to non-zero allowance"
        );
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, value));
    }

    /**
     * @dev Increase the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 oldAllowance = token.allowance(address(this), spender);
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, oldAllowance + value));
    }

    /**
     * @dev Decrease the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeDecreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        unchecked {
            uint256 oldAllowance = token.allowance(address(this), spender);
            require(oldAllowance >= value, "SafeERC20: decreased allowance below zero");
            _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, oldAllowance - value));
        }
    }

    /**
     * @dev Set the calling contract's allowance toward `spender` to `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful. Compatible with tokens that require the approval to be set to
     * 0 before setting it to a non-zero value.
     */
    function forceApprove(IERC20 token, address spender, uint256 value) internal {
        bytes memory approvalCall = abi.encodeWithSelector(token.approve.selector, spender, value);

        if (!_callOptionalReturnBool(token, approvalCall)) {
            _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, 0));
            _callOptionalReturn(token, approvalCall);
        }
    }

    /**
     * @dev Use a ERC-2612 signature to set the `owner` approval toward `spender` on `token`.
     * Revert on invalid signature.
     */
    function safePermit(
        IERC20Permit token,
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) internal {
        uint256 nonceBefore = token.nonces(owner);
        token.permit(owner, spender, value, deadline, v, r, s);
        uint256 nonceAfter = token.nonces(owner);
        require(nonceAfter == nonceBefore + 1, "SafeERC20: permit did not succeed");
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We use {Address-functionCall} to perform this call, which verifies that
        // the target address contains contract code and also asserts for success in the low-level call.

        bytes memory returndata = address(token).functionCall(data, "SafeERC20: low-level call failed");
        require(returndata.length == 0 || abi.decode(returndata, (bool)), "SafeERC20: ERC20 operation did not succeed");
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturn} that silents catches all reverts and returns a bool instead.
     */
    function _callOptionalReturnBool(IERC20 token, bytes memory data) private returns (bool) {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We cannot use {Address-functionCall} here since this should return false
        // and not revert is the subcall reverts.

        (bool success, bytes memory returndata) = address(token).call(data);
        return
            success && (returndata.length == 0 || abi.decode(returndata, (bool))) && Address.isContract(address(token));
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (utils/math/SignedMath.sol)

pragma solidity ^0.8.0;

/**
 * @dev Standard signed math utilities missing in the Solidity language.
 */
library SignedMath {
    /**
     * @dev Returns the largest of two signed numbers.
     */
    function max(int256 a, int256 b) internal pure returns (int256) {
        return a > b ? a : b;
    }

    /**
     * @dev Returns the smallest of two signed numbers.
     */
    function min(int256 a, int256 b) internal pure returns (int256) {
        return a < b ? a : b;
    }

    /**
     * @dev Returns the average of two signed numbers without overflow.
     * The result is rounded towards zero.
     */
    function average(int256 a, int256 b) internal pure returns (int256) {
        // Formula from the book "Hacker's Delight"
        int256 x = (a & b) + ((a ^ b) >> 1);
        return x + (int256(uint256(x) >> 255) & (a ^ b));
    }

    /**
     * @dev Returns the absolute unsigned value of a signed value.
     */
    function abs(int256 n) internal pure returns (uint256) {
        unchecked {
            // must be unchecked in order to support `n = type(int256).min`
            return uint256(n >= 0 ? n : -n);
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/Strings.sol)

pragma solidity ^0.8.0;

import "./math/Math.sol";
import "./math/SignedMath.sol";

/**
 * @dev String operations.
 */
library Strings {
    bytes16 private constant _SYMBOLS = "0123456789abcdef";
    uint8 private constant _ADDRESS_LENGTH = 20;

    /**
     * @dev Converts a `uint256` to its ASCII `string` decimal representation.
     */
    function toString(uint256 value) internal pure returns (string memory) {
        unchecked {
            uint256 length = Math.log10(value) + 1;
            string memory buffer = new string(length);
            uint256 ptr;
            /// @solidity memory-safe-assembly
            assembly {
                ptr := add(buffer, add(32, length))
            }
            while (true) {
                ptr--;
                /// @solidity memory-safe-assembly
                assembly {
                    mstore8(ptr, byte(mod(value, 10), _SYMBOLS))
                }
                value /= 10;
                if (value == 0) break;
            }
            return buffer;
        }
    }

    /**
     * @dev Converts a `int256` to its ASCII `string` decimal representation.
     */
    function toString(int256 value) internal pure returns (string memory) {
        return string(abi.encodePacked(value < 0 ? "-" : "", toString(SignedMath.abs(value))));
    }

    /**
     * @dev Converts a `uint256` to its ASCII `string` hexadecimal representation.
     */
    function toHexString(uint256 value) internal pure returns (string memory) {
        unchecked {
            return toHexString(value, Math.log256(value) + 1);
        }
    }

    /**
     * @dev Converts a `uint256` to its ASCII `string` hexadecimal representation with fixed length.
     */
    function toHexString(uint256 value, uint256 length) internal pure returns (string memory) {
        bytes memory buffer = new bytes(2 * length + 2);
        buffer[0] = "0";
        buffer[1] = "x";
        for (uint256 i = 2 * length + 1; i > 1; --i) {
            buffer[i] = _SYMBOLS[value & 0xf];
            value >>= 4;
        }
        require(value == 0, "Strings: hex length insufficient");
        return string(buffer);
    }

    /**
     * @dev Converts an `address` with fixed length of 20 bytes to its not checksummed ASCII `string` hexadecimal representation.
     */
    function toHexString(address addr) internal pure returns (string memory) {
        return toHexString(uint256(uint160(addr)), _ADDRESS_LENGTH);
    }

    /**
     * @dev Returns true if the two strings are equal.
     */
    function equal(string memory a, string memory b) internal pure returns (bool) {
        return keccak256(bytes(a)) == keccak256(bytes(b));
    }
}

{
  "compilationTarget": {
    "contracts/staking/DeFiChef.sol": "DeFiChef"
  },
  "evmVersion": "paris",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": true,
    "runs": 200
  },
  "remappings": [],
  "viaIR": true
}