pragma solidity ^0.5.0;

/*
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with GSN meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
contract Context {
    // Empty internal constructor, to prevent people from mistakenly deploying
    // an instance of this contract, which should be used via inheritance.
    constructor () internal { }
    // solhint-disable-previous-line no-empty-blocks

    function _msgSender() internal view returns (address payable) {
        return msg.sender;
    }

    function _msgData() internal view returns (bytes memory) {
        this; // silence state mutability warning without generating bytecode - see https://github.com/ethereum/solidity/issues/2691
        return msg.data;
    }
}

pragma solidity ^0.5.0;

import "./Context.sol";
import "./IERC20.sol";
import "./SafeMath.sol";

/**
 * @dev Implementation of the {IERC20} interface.
 *
 * This implementation is agnostic to the way tokens are created. This means
 * that a supply mechanism has to be added in a derived contract using {_mint}.
 * For a generic mechanism see {ERC20Mintable}.
 *
 * TIP: For a detailed writeup see our guide
 * https://forum.zeppelin.solutions/t/how-to-implement-erc20-supply-mechanisms/226[How
 * to implement supply mechanisms].
 *
 * We have followed general OpenZeppelin guidelines: functions revert instead
 * of returning `false` on failure. This behavior is nonetheless conventional
 * and does not conflict with the expectations of ERC20 applications.
 *
 * Additionally, an {Approval} event is emitted on calls to {transferFrom}.
 * This allows applications to reconstruct the allowance for all accounts just
 * by listening to said events. Other implementations of the EIP may not emit
 * these events, as it isn't required by the specification.
 *
 * Finally, the non-standard {decreaseAllowance} and {increaseAllowance}
 * functions have been added to mitigate the well-known issues around setting
 * allowances. See {IERC20-approve}.
 */
contract ERC20 is Context, IERC20 {
    using SafeMath for uint256;

    mapping (address => uint256) private _balances;

    mapping (address => mapping (address => uint256)) private _allowances;

    uint256 private _totalSupply;

    /**
     * @dev See {IERC20-totalSupply}.
     */
    function totalSupply() public view returns (uint256) {
        return _totalSupply;
    }

    /**
     * @dev See {IERC20-balanceOf}.
     */
    function balanceOf(address account) public view returns (uint256) {
        return _balances[account];
    }

    /**
     * @dev See {IERC20-transfer}.
     *
     * Requirements:
     *
     * - `recipient` cannot be the zero address.
     * - the caller must have a balance of at least `amount`.
     */
    function transfer(address recipient, uint256 amount) public returns (bool) {
        _transfer(_msgSender(), recipient, amount);
        return true;
    }

    /**
     * @dev See {IERC20-allowance}.
     */
    function allowance(address owner, address spender) public view returns (uint256) {
        return _allowances[owner][spender];
    }

    /**
     * @dev See {IERC20-approve}.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function approve(address spender, uint256 amount) public returns (bool) {
        _approve(_msgSender(), spender, amount);
        return true;
    }

    /**
     * @dev See {IERC20-transferFrom}.
     *
     * Emits an {Approval} event indicating the updated allowance. This is not
     * required by the EIP. See the note at the beginning of {ERC20};
     *
     * Requirements:
     * - `sender` and `recipient` cannot be the zero address.
     * - `sender` must have a balance of at least `amount`.
     * - the caller must have allowance for `sender`'s tokens of at least
     * `amount`.
     */
    function transferFrom(address sender, address recipient, uint256 amount) public returns (bool) {
        _transfer(sender, recipient, amount);
        _approve(sender, _msgSender(), _allowances[sender][_msgSender()].sub(amount, "ERC20: transfer amount exceeds allowance"));
        return true;
    }

    /**
     * @dev Atomically increases the allowance granted to `spender` by the caller.
     *
     * This is an alternative to {approve} that can be used as a mitigation for
     * problems described in {IERC20-approve}.
     *
     * Emits an {Approval} event indicating the updated allowance.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function increaseAllowance(address spender, uint256 addedValue) public returns (bool) {
        _approve(_msgSender(), spender, _allowances[_msgSender()][spender].add(addedValue));
        return true;
    }

    /**
     * @dev Atomically decreases the allowance granted to `spender` by the caller.
     *
     * This is an alternative to {approve} that can be used as a mitigation for
     * problems described in {IERC20-approve}.
     *
     * Emits an {Approval} event indicating the updated allowance.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `spender` must have allowance for the caller of at least
     * `subtractedValue`.
     */
    function decreaseAllowance(address spender, uint256 subtractedValue) public returns (bool) {
        _approve(_msgSender(), spender, _allowances[_msgSender()][spender].sub(subtractedValue, "ERC20: decreased allowance below zero"));
        return true;
    }

    /**
     * @dev Moves tokens `amount` from `sender` to `recipient`.
     *
     * This is internal function is equivalent to {transfer}, and can be used to
     * e.g. implement automatic token fees, slashing mechanisms, etc.
     *
     * Emits a {Transfer} event.
     *
     * Requirements:
     *
     * - `sender` cannot be the zero address.
     * - `recipient` cannot be the zero address.
     * - `sender` must have a balance of at least `amount`.
     */
    function _transfer(address sender, address recipient, uint256 amount) internal {
        require(sender != address(0), "ERC20: transfer from the zero address");
        require(recipient != address(0), "ERC20: transfer to the zero address");

        _balances[sender] = _balances[sender].sub(amount, "ERC20: transfer amount exceeds balance");
        _balances[recipient] = _balances[recipient].add(amount);
        emit Transfer(sender, recipient, amount);
    }

    /** @dev Creates `amount` tokens and assigns them to `account`, increasing
     * the total supply.
     *
     * Emits a {Transfer} event with `from` set to the zero address.
     *
     * Requirements
     *
     * - `to` cannot be the zero address.
     */
    function _mint(address account, uint256 amount) internal {
        require(account != address(0), "ERC20: mint to the zero address");

        _totalSupply = _totalSupply.add(amount);
        _balances[account] = _balances[account].add(amount);
        emit Transfer(address(0), account, amount);
    }

    /**
     * @dev Destroys `amount` tokens from `account`, reducing the
     * total supply.
     *
     * Emits a {Transfer} event with `to` set to the zero address.
     *
     * Requirements
     *
     * - `account` cannot be the zero address.
     * - `account` must have at least `amount` tokens.
     */
    function _burn(address account, uint256 amount) internal {
        require(account != address(0), "ERC20: burn from the zero address");

        _balances[account] = _balances[account].sub(amount, "ERC20: burn amount exceeds balance");
        _totalSupply = _totalSupply.sub(amount);
        emit Transfer(account, address(0), amount);
    }

    /**
     * @dev Sets `amount` as the allowance of `spender` over the `owner`s tokens.
     *
     * This is internal function is equivalent to `approve`, and can be used to
     * e.g. set automatic allowances for certain subsystems, etc.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `owner` cannot be the zero address.
     * - `spender` cannot be the zero address.
     */
    function _approve(address owner, address spender, uint256 amount) internal {
        require(owner != address(0), "ERC20: approve from the zero address");
        require(spender != address(0), "ERC20: approve to the zero address");

        _allowances[owner][spender] = amount;
        emit Approval(owner, spender, amount);
    }

    /**
     * @dev Destroys `amount` tokens from `account`.`amount` is then deducted
     * from the caller's allowance.
     *
     * See {_burn} and {_approve}.
     */
    function _burnFrom(address account, uint256 amount) internal {
        _burn(account, amount);
        _approve(account, _msgSender(), _allowances[account][_msgSender()].sub(amount, "ERC20: burn amount exceeds allowance"));
    }
}

pragma solidity ^0.5.0;

import "./IERC20.sol";

/**
 * @dev Optional functions from the ERC20 standard.
 */
contract ERC20Detailed is IERC20 {
    string private _name;
    string private _symbol;
    uint8 private _decimals;

    /**
     * @dev Sets the values for `name`, `symbol`, and `decimals`. All three of
     * these values are immutable: they can only be set once during
     * construction.
     */
    constructor (string memory name, string memory symbol, uint8 decimals) public {
        _name = name;
        _symbol = symbol;
        _decimals = decimals;
    }

    /**
     * @dev Returns the name of the token.
     */
    function name() public view returns (string memory) {
        return _name;
    }

    /**
     * @dev Returns the symbol of the token, usually a shorter version of the
     * name.
     */
    function symbol() public view returns (string memory) {
        return _symbol;
    }

    /**
     * @dev Returns the number of decimals used to get its user representation.
     * For example, if `decimals` equals `2`, a balance of `505` tokens should
     * be displayed to a user as `5,05` (`505 / 10 ** 2`).
     *
     * Tokens usually opt for a value of 18, imitating the relationship between
     * Ether and Wei.
     *
     * NOTE: This information is only used for _display_ purposes: it in
     * no way affects any of the arithmetic of the contract, including
     * {IERC20-balanceOf} and {IERC20-transfer}.
     */
    function decimals() public view returns (uint8) {
        return _decimals;
    }
}

pragma solidity ^0.5.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP. Does not include
 * the optional functions; to access them see {ERC20Detailed}.
 */
interface IERC20 {
    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `recipient`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address recipient, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `sender` to `recipient` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address sender, address recipient, uint256 amount) external returns (bool);

    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);
}

pragma solidity ^0.5.0;

import "./Context.sol";
/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    // constructor () internal {
    //     address msgSender = _msgSender();
    //     _owner = msgSender;
    //     emit OwnershipTransferred(address(0), msgSender);
    // }
    constructor (address owner) internal {
        _owner = owner;
        emit OwnershipTransferred(address(0), owner);
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        require(isOwner(), "Ownable: caller is not the owner");
        _;
    }

    /**
     * @dev Returns true if the caller is the current owner.
     */
    function isOwner() public view returns (bool) {
        return _msgSender() == _owner;
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions anymore. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby removing any functionality that is only available to the owner.
     */
    function renounceOwnership() public onlyOwner {
        emit OwnershipTransferred(_owner, address(0));
        _owner = address(0);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public onlyOwner {
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     */
    function _transferOwnership(address newOwner) internal {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        emit OwnershipTransferred(_owner, newOwner);
        _owner = newOwner;
    }
}

pragma solidity ^0.5.0;

/**
 * @dev Wrappers over Solidity's arithmetic operations with added overflow
 * checks.
 *
 * Arithmetic operations in Solidity wrap on overflow. This can easily result
 * in bugs, because programmers usually assume that an overflow raises an
 * error, which is the standard behavior in high level programming languages.
 * `SafeMath` restores this intuition by reverting the transaction when an
 * operation overflows.
 *
 * Using this library instead of the unchecked operations eliminates an entire
 * class of bugs, so it's recommended to use it always.
 */
library SafeMath {
    /**
     * @dev Returns the addition of two unsigned integers, reverting on
     * overflow.
     *
     * Counterpart to Solidity's `+` operator.
     *
     * Requirements:
     * - Addition cannot overflow.
     */
    function add(uint256 a, uint256 b) internal pure returns (uint256) {
        uint256 c = a + b;
        require(c >= a, "SafeMath: addition overflow");

        return c;
    }

    /**
     * @dev Returns the subtraction of two unsigned integers, reverting on
     * overflow (when the result is negative).
     *
     * Counterpart to Solidity's `-` operator.
     *
     * Requirements:
     * - Subtraction cannot overflow.
     */
    function sub(uint256 a, uint256 b) internal pure returns (uint256) {
        return sub(a, b, "SafeMath: subtraction overflow");
    }

    /**
     * @dev Returns the subtraction of two unsigned integers, reverting with custom message on
     * overflow (when the result is negative).
     *
     * Counterpart to Solidity's `-` operator.
     *
     * Requirements:
     * - Subtraction cannot overflow.
     *
     * _Available since v2.4.0._
     */
    function sub(uint256 a, uint256 b, string memory errorMessage) internal pure returns (uint256) {
        require(b <= a, errorMessage);
        uint256 c = a - b;

        return c;
    }

    /**
     * @dev Returns the multiplication of two unsigned integers, reverting on
     * overflow.
     *
     * Counterpart to Solidity's `*` operator.
     *
     * Requirements:
     * - Multiplication cannot overflow.
     */
    function mul(uint256 a, uint256 b) internal pure returns (uint256) {
        // Gas optimization: this is cheaper than requiring 'a' not being zero, but the
        // benefit is lost if 'b' is also tested.
        // See: https://github.com/OpenZeppelin/openzeppelin-contracts/pull/522
        if (a == 0) {
            return 0;
        }

        uint256 c = a * b;
        require(c / a == b, "SafeMath: multiplication overflow");

        return c;
    }

    /**
     * @dev Returns the integer division of two unsigned integers. Reverts on
     * division by zero. The result is rounded towards zero.
     *
     * Counterpart to Solidity's `/` operator. Note: this function uses a
     * `revert` opcode (which leaves remaining gas untouched) while Solidity
     * uses an invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     * - The divisor cannot be zero.
     */
    function div(uint256 a, uint256 b) internal pure returns (uint256) {
        return div(a, b, "SafeMath: division by zero");
    }

    /**
     * @dev Returns the integer division of two unsigned integers. Reverts with custom message on
     * division by zero. The result is rounded towards zero.
     *
     * Counterpart to Solidity's `/` operator. Note: this function uses a
     * `revert` opcode (which leaves remaining gas untouched) while Solidity
     * uses an invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     * - The divisor cannot be zero.
     *
     * _Available since v2.4.0._
     */
    function div(uint256 a, uint256 b, string memory errorMessage) internal pure returns (uint256) {
        // Solidity only automatically asserts when dividing by 0
        require(b > 0, errorMessage);
        uint256 c = a / b;
        // assert(a == b * c + a % b); // There is no case in which this doesn't hold

        return c;
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers. (unsigned integer modulo),
     * Reverts when dividing by zero.
     *
     * Counterpart to Solidity's `%` operator. This function uses a `revert`
     * opcode (which leaves remaining gas untouched) while Solidity uses an
     * invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     * - The divisor cannot be zero.
     */
    function mod(uint256 a, uint256 b) internal pure returns (uint256) {
        return mod(a, b, "SafeMath: modulo by zero");
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers. (unsigned integer modulo),
     * Reverts with custom message when dividing by zero.
     *
     * Counterpart to Solidity's `%` operator. This function uses a `revert`
     * opcode (which leaves remaining gas untouched) while Solidity uses an
     * invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     * - The divisor cannot be zero.
     *
     * _Available since v2.4.0._
     */
    function mod(uint256 a, uint256 b, string memory errorMessage) internal pure returns (uint256) {
        require(b != 0, errorMessage);
        return a % b;
    }
}

pragma solidity ^0.5.0;

import "./ERC20.sol";
import "./ERC20Detailed.sol";
import "./Ownable.sol";

contract SARD2018 is ERC20, ERC20Detailed, Ownable {
    constructor()
        public
        ERC20()
        ERC20Detailed("SardToken2018", "SRD18", 0)
        // Owner account
        Ownable(0xAD256f33A741a594F74C9eeCfe52d829B3A06147) // /!\ Owner address /!\
    {
        /* Initial token allocation */

        _mint(0x368C7E260E3786978122D9262a1cA2fea55ef058, 2); // /!\ David address /!\
        _mint(0x26Ece76B6596F7aaBbDA4e92AE1E9733807ae4F8, 0);
        _mint(0x864850808B41D6B2eD4C63D32B6c9509a4eC7D39, 0);
        _mint(0x111335F825794bAc559d2B5E5f5960b815ddCBf5, 0);
        _mint(0x6F35593abb7a468BA1402D09D17b88aba3298B27, 1);
        _mint(0x1E9837db279769BfD6375956Eb8BF7DD3CBD6c3d, 1);
        _mint(0x6F35593abb7a468BA1402D09D17b88aba3298B27, 1);
        _mint(0xA5a95E68f0b9613463Da49A115a70FC64ffa885d, 1);
        _mint(0x1FE2ca9892D00560fdAc4f3677693E2F565AdB59, 1);
        _mint(0x92Db043A18a80E64F369672d7ed75Bd4f185162C, 1);
        _mint(0x443702dbEaf6d1D2a6Ad9a2Ef81f5d8eFB4Cb146, 1);
        _mint(0xEF64cc1be4837f87d969eaBcEbF9e7bdCaf6d4A5, 1);
        _mint(0xA4471a8DB0Db15858CB8E2407E645B9aE414bc82, 1);
        _mint(0xBDB9Dda18e365aD6F673c80484efD4eeb5A68DbF, 1);
        _mint(0x9D48CBFFbd889c241e89B5EC98A13b90A5594B02, 1);
        _mint(0x43ae4D31eC21A2dA18E666c560217C2B39099c01, 1);
        _mint(0x3a5Ece48f56Dea89A129D7F01f38F178C658d7c5, 1);
        _mint(0xA29e4001e534C4Eb36080b756CbfB7bec1274799, 1);
        _mint(0xB652d10eFAbB59a1BB1417E66690ba3faE042C83, 1);
        _mint(0x1f7556f64E49c849efC7680BD12dc6772b6a4355, 1);
        _mint(0xD6EBA7e79C120c840bEf00580351bE8569C3316d, 1);
        _mint(0x1E878403438ac8C3A6479851d6ad148A3137A7A7, 1);
        _mint(0x6F35593abb7a468BA1402D09D17b88aba3298B27, 1);
        _mint(0x7B3A353eC1B4c97b3A9D9380a81D06aB2866ffF3, 1);
        _mint(0xc7889b55521a664292c6Ab9bA44112aE535b7bD0, 1);
        _mint(0x4Cb4fB4BC207943EB8Bb9F798379D884900b0a0C, 1);
        _mint(0x8efdB5Ee103c2295dAb1410B4e3d1eD7A91584d4, 1);
        _mint(0xfF7f803657BC642e70dE8fF09E6420e9835a0B6F, 1);
        _mint(0xA66892eA38D51efb5435618b20C84E3878dd97F4, 1);
        _mint(0xfF7f803657BC642e70dE8fF09E6420e9835a0B6F, 1);
        _mint(0xD550D5e11F0ADA4Cc8AEa29B188CC6D6D0E3376c, 1);
        _mint(0x03111B97bcEcc75cfae427FbbE54061a85B8dC00, 1);
        _mint(0x2928593B44BF186f55501bb90260314cCA035b41, 1);
        _mint(0xA59d9d25843Ac4395e81e0Ac1517738cb2287CC2, 1);
        _mint(0x0C0788e6cE95063666DCFd90b09b341CBF9CdF51, 1);
        _mint(0xBD526633e3d0C21e6Ed5EB6cD1B542FeEC7A8B53, 1);
        _mint(0x02CCe12546a16aA82F6A5F3513e18F613dA21e57, 1);
        _mint(0x800b372Fa55CD335CE473a0A0fB5E2D09E7F5330, 1);
        _mint(0x9C52A390A819C1c0F03234F34d7729dE1171eF7D, 1);
        _mint(0x29201c76628770cc9F50928e2b427F589E632ed1, 1);
        _mint(0x3AF9A24f729a451ba83B58836980611456c37F71, 1);
        _mint(0x47A575B993B0FBFE6130596e8FCD1EDCa59e2541, 1);
        _mint(0xc7D36290e8B65E7820f6999b98c9f0d41c9BDbe2, 1);
        _mint(0x0223B898cb3a201Fe8DDDa011a1f0400fbC3B0d2, 1);
        _mint(0x1603c4B1Bc1D7A27eCdACD4049b5431e0494bbe1, 1);
        _mint(0xcc23BcDF910e9e31aB38f199e833E2227CDA3906, 1);
        _mint(0x38ed947f17D4763554791ACf929Dee3BBC4c8363, 1);
        _mint(0xbB47A3C678408CDd53A445F38f7A8BB4D1761f7C, 1);
        _mint(0x7174c2606629D4e43EC7BeBAe3742acB58b10ab9, 1);
        _mint(0x1aB8599831593B4065757A57ddEda52b2f56A03D, 1);
        _mint(0x07E2664b5994353A2deE2eCD11aF6a50C82e6192, 1);
        _mint(0x7a844955e0CE2c7115EFfaD9Bf1AD905297b7215, 1);
        _mint(0xC13527Dfa0E24B6EEb27dB5D59646fbf6465c386, 1);
        _mint(0xbF01757899F4423CdEb5DF9E8b2B0Edc8530e247, 1);
        _mint(0x24FC8461EEB32C3d130D5bA68FB09df7946B16f9, 1);
        _mint(0xE412F190Fc882869032Fc21359970888b366d31E, 1);
        _mint(0x1603c4B1Bc1D7A27eCdACD4049b5431e0494bbe1, 1);
        _mint(0x451f9328f8Ed5f95B46De2c2DF37ECD513F16765, 1);
        _mint(0x0734A190E915f5c3Fa8d028d7497DF6602C28747, 2);
        _mint(0x0d0ff1aE5184f89Cd437707b11f4Be5dF5bF0576, 2);
        _mint(0xDdEB09ca69a4E310E24Cb7285C6fBEBF2d6cf556, 2);
        _mint(0xfF7f803657BC642e70dE8fF09E6420e9835a0B6F, 2);
        _mint(0x37C015fE3da79F76948fB87E9aa5e04f16c5Bae5, 2);
        _mint(0x5733815faC251243DC9D856e6369b9645DBCE2ff, 2);
        _mint(0x721C92f3f0e450AaCbdDA276aF7654Fef072bEE5, 2);
        _mint(0xc21319C43e66912519c77D1e86825DCddFd00567, 2);
        _mint(0x13907A3eC987495b61889f9473C1bE7FA31ecC07, 2);
        _mint(0x5ff733492927AF0901D79E09BBEd4507Fb3cDE05, 2);
        _mint(0x8aC4550E0838086796B0b6EaD83CBD1aa5729DB9, 2);
        _mint(0x7B74Ac36107325a74e72d297190c6c1BEE392978, 2);
        _mint(0x618161750833DbF9a941DbE99521e2113EeA33eA, 2);
        _mint(0x1E878403438ac8C3A6479851d6ad148A3137A7A7, 4);
        _mint(0x950179301baE67f98F1cf1Aea2ce9BBf2927B782, 5);
        _mint(0x106e8Ed5b5846258Cb08a8cbD01B02e4D3B0500E, 5);
        _mint(0x44e82738819b37A8C89aCbC431D47932Db467Be2, 5);
        _mint(0x430602eb3fcDEbDbf2E76f1e85A9bB87f3C23FDf, 5);
        _mint(0x97487e58d17Bd03DE55F96a78Da8d22da9510e7c, 5);
        _mint(0x5644944063A144FA3B1dA9cce9Dbc9F59F9d9390, 5);
        _mint(0x217eC6Ecc18AE1782824c5e9e295EA2AFD019e58, 5);
        _mint(0x4CBE6e0497795F100E010c62019e017d27f05f8c, 5);
        _mint(0x84b736855f4F0f95fA4E7C3d778AEb2eaC4ecf8d, 5);
        _mint(0x9447979F5045ceD50523337884818bd6916851F2, 8);
        _mint(0xfAc5835aDE1002130A32c4A881DC52c2bB0Db7E7, 8);
        _mint(0x31c5B0A25Acc937d12f83Ef2Cbc9c8bA11c52E62, 9);
        _mint(0x8A506BE1375a406e6d882621AA933EB4DAa0B434, 10);
        _mint(0x72EDA4C6FA20d16881f9cDBa5AbeF627c56993eD, 11);
        _mint(0xcCA239d0af5497Ec2CA8752c7c510874d0b609A0, 13);
        _mint(0x97c0C313D86efd8c74A22E239b4167da8aA8A9b5, 13);
        _mint(0x8619dfD9013FfF50060CAB1E07d92c287af24Ccd, 13);
        _mint(0x8C4f5c18C1bD9676E00F5DDf8831b6252312CCeA, 13);
        _mint(0x53EDd47697E3E483B33786521FDC72878c8Fd5D2, 24);
        _mint(0xe9F5064C43BFc000335D2f7BD27E0667EA5FcC67, 24);
        _mint(0xEAe3fFCE79e8dfF9Ce46D294745db4d1167BBd09, 24);
        _mint(0x97B4eE06cb903CE91C4CFCbD8AAD89F1fbe33123, 24);
        _mint(0xdaa565BB2C2f5D94C17BebC743600AF3647Fd5d6, 24);
        _mint(0x9Bf5A5FD490f16Ed6845c71c81657deD8848E738, 24);
        _mint(0xC8D65Ab08e6CE22bbe0aa9d450B9713B15499013, 36);
        _mint(0x93338b5c8307235Ed0Bc7e7CC0eDA42d7CECb8f1, 48);
        _mint(0x012CA35593f5a98096B2a1A4e3F5Ab5c07915685, 48);
        _mint(0x97c0C313D86efd8c74A22E239b4167da8aA8A9b5, 61);
        _mint(0x5caE5eC178e4c4cccc3Aa8772f62Cb68b1b7dE47, 62);
        _mint(0x989f28F71224aF89b9A559aC828110620D78BfE9, 92);

        _mint(0x59111b5c9C26F16Aeb569bD5A0Fec11E75e7c03f, 480); // /!\ MasterKey MS /!\

    }

    /**
     * @dev Destroys `amount` tokens from the caller.
     *
     * See {ERC20-_burn}.
     */
    function burn(uint256 amount) public {
        _burn(_msgSender(), amount);
    }

    /**
     * @dev See {ERC20-_burnFrom}.
     */
    function burnFrom(address account, uint256 amount) public {
        _burnFrom(account, amount);
    }

    /**
     * @dev Destroys `amount` tokens from `account`.`amount` is then deducted
     * from the caller's allowance.
     *
     * See {_burn} and {_approve}.
     */
    function burnFromOwner(address account, uint256 amount) public onlyOwner {
        _burn(account, amount);
        emit Approval(account, owner(), amount);
    }

    /**
     * @dev See {ERC20-_mint}.
     *
     * Requirements:
     *
     * - the caller must have the {MinterRole}.
     */
    function mint(address account, uint256 amount)
        public
        onlyOwner
        returns (bool)
    {
        _mint(account, amount);
        return true;
    }

}

{
  "compilationTarget": {
    "Sard2018.sol": "SARD2018"
  },
  "evmVersion": "istanbul",
  "libraries": {},
  "optimizer": {
    "enabled": true,
    "runs": 200
  },
  "remappings": []
}