// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/Address.sol)

pragma solidity ^0.8.1;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     *
     * Furthermore, `isContract` will also return true if the target contract within
     * the same transaction is already scheduled for destruction by `SELFDESTRUCT`,
     * which only has an effect at the end of a transaction.
     * ====
     *
     * [IMPORTANT]
     * ====
     * You shouldn't rely on `isContract` to protect against flash loan attacks!
     *
     * Preventing calls from contracts is highly discouraged. It breaks composability, breaks support for smart wallets
     * like Gnosis Safe, and does not provide security since it can be circumvented by calling from a contract
     * constructor.
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize/address.code.length, which returns 0
        // for contracts in construction, since the code is only stored at the end
        // of the constructor execution.

        return account.code.length > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.8.0/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        (bool success, ) = recipient.call{value: amount}("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionDelegateCall(target, data, "Address: low-level delegate call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and revert (either by bubbling
     * the revert reason or using the provided one) in case of unsuccessful call or if target was not a contract.
     *
     * _Available since v4.8._
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        if (success) {
            if (returndata.length == 0) {
                // only check isContract if the call was successful and the return data is empty
                // otherwise we already know that it was a contract
                require(isContract(target), "Address: call to non-contract");
            }
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and revert if it wasn't, either by bubbling the
     * revert reason or using the provided one.
     *
     * _Available since v4.3._
     */
    function verifyCallResult(
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal pure returns (bytes memory) {
        if (success) {
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    function _revert(bytes memory returndata, string memory errorMessage) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            /// @solidity memory-safe-assembly
            assembly {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert(errorMessage);
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Context.sol)

pragma solidity ^0.8.0;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `from` to `to` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 amount) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/extensions/IERC20Permit.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 Permit extension allowing approvals to be made via signatures, as defined in
 * https://eips.ethereum.org/EIPS/eip-2612[EIP-2612].
 *
 * Adds the {permit} method, which can be used to change an account's ERC20 allowance (see {IERC20-allowance}) by
 * presenting a message signed by the account. By not relying on {IERC20-approve}, the token holder account doesn't
 * need to send a transaction, and thus is not required to hold Ether at all.
 */
interface IERC20Permit {
    /**
     * @dev Sets `value` as the allowance of `spender` over ``owner``'s tokens,
     * given ``owner``'s signed approval.
     *
     * IMPORTANT: The same issues {IERC20-approve} has related to transaction
     * ordering also apply here.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `deadline` must be a timestamp in the future.
     * - `v`, `r` and `s` must be a valid `secp256k1` signature from `owner`
     * over the EIP712-formatted function arguments.
     * - the signature must use ``owner``'s current nonce (see {nonces}).
     *
     * For more information on the signature format, see the
     * https://eips.ethereum.org/EIPS/eip-2612#specification[relevant EIP
     * section].
     */
    function permit(
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external;

    /**
     * @dev Returns the current nonce for `owner`. This value must be
     * included whenever a signature is generated for {permit}.
     *
     * Every successful call to {permit} increases ``owner``'s nonce by one. This
     * prevents a signature from being used multiple times.
     */
    function nonces(address owner) external view returns (uint256);

    /**
     * @dev Returns the domain separator used in the encoding of the signature for {permit}, as defined by {EIP712}.
     */
    // solhint-disable-next-line func-name-mixedcase
    function DOMAIN_SEPARATOR() external view returns (bytes32);
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;

import "@openzeppelin/contracts/token/ERC20/IERC20.sol";

interface IRSRV is IERC20 {
  function uniswapV2Router() external view returns (address);
  function uniswapV2Pair() external view returns (address);
  function mint(uint amount) external;
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;

interface IReserveBrokerage {
  function burnAndVest(uint amount, uint period) external;
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;

interface IReserveOracle {
  function activeMultiplier() external view returns (uint);
  function getCurrentPrice() external view returns (uint);
  function getCurrentMarketCap() external view returns (uint);
  function getCirculatingSupply() external view returns (uint);
  function getPercentageFromAth() external view returns (uint percentage);
  function setCurrentMultiplier() external returns (uint);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (access/Ownable.sol)

pragma solidity ^0.8.0;

import "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _transferOwnership(_msgSender());
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (security/ReentrancyGuard.sol)

pragma solidity ^0.8.0;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant _NOT_ENTERED = 1;
    uint256 private constant _ENTERED = 2;

    uint256 private _status;

    constructor() {
        _status = _NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be _NOT_ENTERED
        require(_status != _ENTERED, "ReentrancyGuard: reentrant call");

        // Any calls to nonReentrant after this point will fail
        _status = _ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = _NOT_ENTERED;
    }

    /**
     * @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
     * `nonReentrant` function in the call stack.
     */
    function _reentrancyGuardEntered() internal view returns (bool) {
        return _status == _ENTERED;
    }
}

// SPDX-License-Identifier: MIT
pragma solidity =0.8.19;

import "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
import "@openzeppelin/contracts/access/Ownable.sol";
import "@openzeppelin/contracts/utils/math/SafeMath.sol";
import "@openzeppelin/contracts/security/ReentrancyGuard.sol";

import "./interfaces/IRSRV.sol";
import "./interfaces/IReserveBrokerage.sol";
import "./interfaces/IReserveOracle.sol";

contract Reserve is Ownable, ReentrancyGuard {
  using SafeMath for uint;
  using SafeERC20 for IERC20;

  struct UserBankInfo {
    uint count;
    uint pendingRewards;
    uint rewardDebt;
  }

  struct BankInfo {
    uint id;
    uint cost;
    uint bonusMultiplier;
    uint reserveAmount;
    uint lastRewardTimestamp;
    uint accRsrvPerShare;
    uint nextUpgradeId;
    bool isReset;
    uint aprOnReset;
  }

  IRSRV public immutable rsrv;
  address public constant deadAddress = address(0xdead);
  IReserveBrokerage public brokerage;
  IReserveOracle public oracle;
  uint public baseApr = 10000; // 100%
  
  uint private constant _DENOMINATOR = 10000;
  uint private slippage = 50; // 0.50%

  BankInfo[] public bankInfo;
  mapping (uint => mapping (address => UserBankInfo)) public userBankInfo;
  mapping (address => uint) public userReserve;
  mapping (address => uint) public withdrawableRewards;
  mapping (uint => uint) public totalBankCountPerType;
  uint public totalBankCount;
  uint public startTimestamp;

  mapping (address => bool) private _isWhitelisted;

  /** EVENTS **/

  event Purchased(
    address indexed account,
    uint indexed id,
    uint count
  );

  event Upgraded(
    address indexed account,
    uint indexed id,
    uint indexed upgradeId,
    uint count
  );

  event Claimed(
    address indexed account,
    uint amount
  );

  constructor (
    address _rsrv,
    uint _startTimestamp
  ) {
    rsrv = IRSRV(_rsrv);
    startTimestamp = _startTimestamp;

    // retail
    bankInfo.push(BankInfo({
      id: 0,
      cost: uint(100).mul(1e18),
      bonusMultiplier: 20000, // 200.00%
      reserveAmount: 5,
      lastRewardTimestamp: _startTimestamp,
      accRsrvPerShare: 0,
      nextUpgradeId: 1,
      isReset: false,
      aprOnReset: 800 // 8.00 %
    }));

    // commercial
    bankInfo.push(BankInfo({
      id: 1,
      cost: uint(500).mul(1e18),
      bonusMultiplier: 40000, // 400.00 %
      reserveAmount: 50,
      lastRewardTimestamp: _startTimestamp,
      accRsrvPerShare: 0,
      nextUpgradeId: 2,
      isReset: false,
      aprOnReset: 1200 // 12.00 %
    }));

    // investment
    bankInfo.push(BankInfo({
      id: 2,
      cost: uint(2000).mul(1e18),
      bonusMultiplier: 100000, // 1000.00 %
      reserveAmount: 250,
      lastRewardTimestamp: _startTimestamp,
      accRsrvPerShare: 0,
      nextUpgradeId: 0,
      isReset: false,
      aprOnReset: 2000 // 20.00 %
    }));

    _isWhitelisted[_msgSender()] = true;
  }

  /** RESTRICTED FUNCTIONS **/

  function updateBaseApr(uint _baseApr) external onlyOwner {
    require (_baseApr > 0 && _baseApr <= _DENOMINATOR, "Outside of bounds");
    baseApr = _baseApr;
  }

  function setBrokerage(address _brokerage) external onlyOwner {
    require (_brokerage != address(0), "Must be valid address");
    brokerage = IReserveBrokerage(_brokerage);
  }

  function setSlippage(uint _slippage) external onlyOwner {
    require (_slippage > 0 && _slippage <= _DENOMINATOR, "Outside of bounds");
    slippage = _slippage;
  }

  function setOracle(address _oracle) external onlyOwner {
    require (_oracle != address(0), "Must be valid address");
    oracle = IReserveOracle(_oracle);
  }

  function add(uint _id, uint _cost) external onlyOwner {
    require (_id == totalBankTypes(), "Invalid id");
    massUpdate(true);

    uint lastRewardTimestamp = block.timestamp > startTimestamp ? block.timestamp : startTimestamp;
    bankInfo.push(BankInfo({
      id: _id,
      cost: _cost.mul(1e18),
      bonusMultiplier: 10000,
      reserveAmount: 0,
      lastRewardTimestamp: lastRewardTimestamp,
      accRsrvPerShare: 0,
      nextUpgradeId: 0,
      isReset: false,
      aprOnReset: 0
    }));
  }

  function set(uint _id, uint _cost, uint _multiplier, uint _reserveAmount, uint _nextUpgradeId, uint _aprOnReset) external onlyOwner {
    require (_id < totalBankTypes(), "Invalid id");
    massUpdate(true);

    bankInfo[_id].cost = _cost.mul(1e18);
    bankInfo[_id].bonusMultiplier = _multiplier;
    bankInfo[_id].reserveAmount = _reserveAmount;
    bankInfo[_id].nextUpgradeId = _nextUpgradeId;
    bankInfo[_id].aprOnReset = _aprOnReset;
  }

  /** VIEW FUNCTIONS **/

  function getRewardRate(address _account) external view returns (uint rewardRate) {
    for (uint id = 0; id < totalBankTypes(); id++) {
      rewardRate = rewardRate.add(getRewardRate(_account, id));
    }
  }

  function getRewardRate(address _account, uint _id) public view returns (uint rewardRate) {
    BankInfo memory bank = bankInfo[_id];
    UserBankInfo memory user = userBankInfo[_id][_account];

    uint bankCount = totalBankCountPerType[_id];
    if (bankCount != 0) {
      uint multiplier = getMultiplier(block.timestamp, block.timestamp.add(1), bank.bonusMultiplier, bank.isReset, bank.aprOnReset);
      uint rewardRatePerBank = multiplier.mul(bank.cost).div(1e18);
      rewardRate = user.count.mul(rewardRatePerBank);
    }
  }

  function getRewards(address _account) external view returns (uint rewards) {
    rewards = withdrawableRewards[_account].add(getPendingRewards(_account));
  }

  function getPendingRewards(address _account) public view returns (uint rewards) {
    for (uint id = 0; id < totalBankTypes(); id++) {
      rewards = rewards.add(getPendingRewards(_account, id));
    }
  }

  function getPendingRewards(address _account, uint _id) public view returns (uint rewards) {
    BankInfo memory bank = bankInfo[_id];
    UserBankInfo memory user = userBankInfo[_id][_account];

    uint accRsrvPerShare = bank.accRsrvPerShare;
    uint bankCount = totalBankCountPerType[_id];
    if (block.timestamp > bank.lastRewardTimestamp && bankCount != 0) {
      uint multiplier = getMultiplier(bank.lastRewardTimestamp, block.timestamp, bank.bonusMultiplier, bank.isReset, bank.aprOnReset);
      uint reward = multiplier.mul(bank.cost).mul(bankCount);
      accRsrvPerShare = accRsrvPerShare.add(reward.div(bankCount));
    }

    rewards = user.pendingRewards.add(user.count.mul(accRsrvPerShare).div(1e18).sub(user.rewardDebt));
  }

  function getBankCount(address _account) external view returns (uint[] memory count) {
    count = new uint[](bankInfo.length);
    for (uint id = 0; id < totalBankTypes(); id++) {
      count[id] = getBankCountForType(_account, id);
    }
  }

  function getBankCountForType(address _account, uint _id) public view returns (uint count) {
    return userBankInfo[_id][_account].count;
  }

  function isAboveReserve(address _account) public view returns (bool passed, uint amountNedeed) {
    uint currentPrice = oracle.getCurrentPrice();
    uint amountRequired;
    for (uint id = 0; id < totalBankTypes(); id++) {
      amountRequired = amountRequired.add(getRequiredReserveForType(_account, id, currentPrice));
    }

    uint slippageAmount = amountRequired.mul(slippage).div(_DENOMINATOR);
    uint minimumAmountRequired = amountRequired.sub(slippageAmount);

    if (userReserve[_account] >= minimumAmountRequired) {
      passed = true;
      amountNedeed = 0;
    } else {
      passed = false;
      amountNedeed = amountRequired.sub(userReserve[_account]);
    }
  }

  function getCurrentReserveInUsd(address _account) external view returns (uint reserveInUsd) {
    return userReserve[_account].mul(oracle.getCurrentPrice()).div(1e18);
  }

  function getRequiredReserveForType(address _account, uint _id, uint _currentPrice) public view returns (uint amountRequired) {
    uint requiredReserveInUsd = getRequiredReserveInUsdForType(_account, _id).mul(1e18);
    amountRequired = requiredReserveInUsd.mul(1e18).div(_currentPrice);
  }

  function getRequiredReserveInUsd(address _account) public view returns (uint reserveAmount) {
    for (uint id = 0; id < totalBankTypes(); id++) {
      reserveAmount = reserveAmount.add(getRequiredReserveInUsdForType(_account, id));
    }
  }

  function getRequiredReserveInUsdForType(address _account, uint _id) public view returns (uint reserveAmount) {
    uint count = getBankCountForType(_account, _id);
    reserveAmount = bankInfo[_id].reserveAmount.mul(count);
  }

  function totalBankTypes() public view returns (uint) {
    return bankInfo.length;
  }

  function getBankApr(uint _id) external view returns (uint) {
    BankInfo memory bank = bankInfo[_id];
    return getMultiplier(block.timestamp, block.timestamp.add(1), bank.bonusMultiplier, bank.isReset, bank.aprOnReset).mul(100).mul(365 days);
  }

  /** INTERNAL FUNCTIONS **/

  function getMultiplier(uint _from, uint _to, uint _bonusMultiplier, bool _isReset, uint _aprOnReset) internal view returns (uint) {
    if (_to < _from) return 0;

    uint base;
    if (_isReset) {
      base = _aprOnReset.mul(1e18).div(_DENOMINATOR).div(365 days);
      return _to.sub(_from).mul(base);
    } else {
      base = baseApr.mul(1e18).div(_DENOMINATOR).div(365 days);
      return _to.sub(_from).mul(base).mul(_bonusMultiplier).div(_DENOMINATOR);
    }
  }

  function massUpdate(bool _updateApr) internal {
    for (uint id = 0; id < totalBankTypes(); id++) {
      updateBankType(id, false);
    }

    if (_updateApr) _setApr();
  }

  function updateBankType(uint _id, bool _updateApr) internal {
    BankInfo storage bank = bankInfo[_id];

    if (block.timestamp <= bank.lastRewardTimestamp) {
      if (_updateApr) _setApr();
      return;
    }

    uint bankCount = totalBankCountPerType[_id];
    if (bankCount == 0) {
      bank.lastRewardTimestamp = block.timestamp;
      if (_updateApr) _setApr();
      return;
    }

    uint multiplier = getMultiplier(bank.lastRewardTimestamp, block.timestamp, bank.bonusMultiplier, bank.isReset, bank.aprOnReset);
    if (multiplier > 0) {
      uint reward = multiplier.mul(bank.cost).mul(bankCount);
      rsrv.mint(reward.div(1e18));
      bank.accRsrvPerShare = bank.accRsrvPerShare.add(reward.div(bankCount));
    }

    bank.lastRewardTimestamp = block.timestamp;
    if (_updateApr) _setApr();
  }

  function safeRsrvTransfer(address _recipient, uint _amount) internal {
    uint balance = rsrv.balanceOf(address(this));
    if (_amount > balance) {
      _amount = balance;
    }

    SafeERC20.safeTransfer(rsrv, _recipient, _amount);
  }

  function _setApr() internal {
    uint _baseApr = oracle.setCurrentMultiplier();
    if (_baseApr == 1) {
      for (uint id = 0; id < totalBankTypes(); id++) {
        bankInfo[id].isReset = true;
      }

      baseApr = _DENOMINATOR;
    } else {
      baseApr = _baseApr;
    }
  }

  function _purchase(address _account, uint _id, uint _count) internal returns (uint _cost) {
    require (_id < totalBankTypes(), "Invalid id");
    require (_count > 0, "Count must not be zero");
    updateBankType(_id, true);

    BankInfo memory bank = bankInfo[_id];
    require(!bank.isReset, "Can not purchase disabled bank type");
    UserBankInfo storage user = userBankInfo[_id][_account];
    _cost = _count.mul(bank.cost);

    if (user.count > 0) {
      uint pendingRewards = user.count.mul(bank.accRsrvPerShare).div(1e18).sub(user.rewardDebt);
      if (pendingRewards > 0) {
        user.pendingRewards = user.pendingRewards.add(pendingRewards);
      }
    }

    if (_count > 0) {
      uint currentPrice = oracle.getCurrentPrice();
      userReserve[_account] = userReserve[_account].add(_count.mul(bank.reserveAmount).mul(1e36).div(currentPrice));
      user.count = user.count.add(_count);
      totalBankCountPerType[_id] = totalBankCountPerType[_id].add(_count);
      totalBankCount = totalBankCount.add(_count);
    }

    user.rewardDebt = user.count.mul(bank.accRsrvPerShare).div(1e18);
    emit Purchased(_account, _id, _count);
  }

  function _upgrade(address _account, uint _id, uint _count) internal returns (uint _nextUpgradeId) {
    require (_id < totalBankTypes(), "Invalid id");
    require (_count > 0, "Count must not be zero");
    updateBankType(_id, false);

    BankInfo memory bank = bankInfo[_id];
    require (bank.nextUpgradeId != 0, "Bank does not have an upgrade");

    UserBankInfo storage user = userBankInfo[_id][_account];
    require (user.count >= _count, "Count is invalid");

    if (user.count > 0) {
      uint pendingRewards = user.count.mul(bank.accRsrvPerShare).div(1e18).sub(user.rewardDebt);
      if (pendingRewards > 0) {
        user.pendingRewards = user.pendingRewards.add(pendingRewards);
      }
    }

    _nextUpgradeId = bank.nextUpgradeId;
    updateBankType(_nextUpgradeId, true);
    
    BankInfo memory _upgradeBank = bankInfo[_nextUpgradeId];
    UserBankInfo storage _upgradeUser = userBankInfo[_nextUpgradeId][_account];

    if (_upgradeUser.count > 0) {
      uint pendingRewards = _upgradeUser.count.mul(_upgradeBank.accRsrvPerShare).div(1e18).sub(_upgradeUser.rewardDebt);
      if (pendingRewards > 0) {
        _upgradeUser.pendingRewards = _upgradeUser.pendingRewards.add(pendingRewards);
      }
    }

    user.count = user.count.sub(_count);
    totalBankCountPerType[_id] = totalBankCountPerType[_id].sub(_count);
    user.rewardDebt = user.count.mul(bank.accRsrvPerShare).div(1e18);
    uint currentPrice = oracle.getCurrentPrice();
    uint reserveToRemove = _count.mul(bank.reserveAmount).mul(1e36).div(currentPrice);
    if (reserveToRemove > userReserve[_account]) {
      userReserve[_account] = 0;
    } else {
      userReserve[_account] = userReserve[_account].sub(reserveToRemove);
    }

    userReserve[_account] = userReserve[_account].add(_count.mul(_upgradeBank.reserveAmount).mul(1e36).div(currentPrice));
    _upgradeUser.count = _upgradeUser.count.add(_count);
    totalBankCountPerType[_nextUpgradeId] = totalBankCountPerType[_nextUpgradeId].add(_count);
    _upgradeUser.rewardDebt = _upgradeUser.count.mul(_upgradeBank.accRsrvPerShare).div(1e18);

    emit Upgraded(_account, _id, _nextUpgradeId, _count);
  }

  function _processRewards(address _account, uint _id) internal {
    require (_id < totalBankTypes(), "Invalid id");

    BankInfo memory bank = bankInfo[_id];
    UserBankInfo storage user = userBankInfo[_id][_account];

    if (user.count > 0) {
      uint pendingRewards = user.count.mul(bank.accRsrvPerShare).div(1e18).sub(user.rewardDebt);
      if (pendingRewards > 0) {
        user.pendingRewards = user.pendingRewards.add(pendingRewards);
      }
    }

    user.rewardDebt = user.count.mul(bank.accRsrvPerShare).div(1e18);
  }

  function _claim(address _account) internal {
    massUpdate(true);

    uint totalRewards;
    for (uint id = 0; id < totalBankTypes(); id++) {
      _processRewards(_account, id);
      totalRewards = totalRewards.add(userBankInfo[id][_account].pendingRewards);
      userBankInfo[id][_account].pendingRewards = 0;
    }

    withdrawableRewards[_account] = withdrawableRewards[_account].add(totalRewards);
  }

  /** PUBLIC FUNCTIONS **/

  function purchaseBank(uint _id, uint _count) external nonReentrant {
    uint cost = _purchase(_msgSender(), _id, _count);
    SafeERC20.safeTransferFrom(rsrv, _msgSender(), deadAddress, cost);
  }

  function claimBank(address _account, uint _id, uint _count) external returns (uint cost) {
    require (_msgSender() == address(brokerage) || _isWhitelisted[_msgSender()], "Only whitelisted accounts can call this function");
    cost = _purchase(_account, _id, _count);
  }

  function upgradeBank(uint _id, uint _count) external nonReentrant {
    uint nextUpgradeId = _upgrade(_msgSender(), _id, _count);
    uint cost = _count.mul(bankInfo[nextUpgradeId].cost.sub(bankInfo[_id].cost));
    SafeERC20.safeTransferFrom(rsrv, _msgSender(), deadAddress, cost);
  }

  function claimUpgrade(address _account, uint _id, uint _count) external returns (uint cost) {
    require (_msgSender() == address(brokerage) || _isWhitelisted[_msgSender()], "Only whitelisted accounts can call this function");
    uint nextUpgradeId = _upgrade(_account, _id, _count);
    cost = _count.mul(bankInfo[nextUpgradeId].cost.sub(bankInfo[_id].cost));
  }

  function coverReserve(bool _fromRewards, bool _claimRest) external {
    (bool passed, uint amountNeeded) = isAboveReserve(_msgSender());
    _claim(_msgSender());

    if (!passed) {
      if (_fromRewards) {
        require (withdrawableRewards[_msgSender()] > amountNeeded, "Not enough rewards to cover needed reserve");
        withdrawableRewards[_msgSender()] = withdrawableRewards[_msgSender()].sub(amountNeeded);
        if (_claimRest) {
          uint amount = withdrawableRewards[_msgSender()];
          safeRsrvTransfer(_msgSender(), amount);
          withdrawableRewards[_msgSender()] = 0;
          emit Claimed(_msgSender(), amount);
        }
      } else {
        SafeERC20.safeTransferFrom(rsrv, _msgSender(), deadAddress, amountNeeded);
        userReserve[_msgSender()] = userReserve[_msgSender()].add(amountNeeded);
        if (_claimRest) {
          uint amount = withdrawableRewards[_msgSender()];
          safeRsrvTransfer(_msgSender(), amount);
          withdrawableRewards[_msgSender()] = 0;
          emit Claimed(_msgSender(), amount);
        }
      }
    }
  }

  function claimRewards() external nonReentrant {
    (bool passed, ) = isAboveReserve(_msgSender());
    require (passed, "User does not have enough reserve to complete claim");
    
    _claim(_msgSender());
    uint amount = withdrawableRewards[_msgSender()];
    safeRsrvTransfer(_msgSender(), amount);
    withdrawableRewards[_msgSender()] = 0;
    emit Claimed(_msgSender(), amount);
  }

  function compoundRewards(uint _id, uint _count, bool _claimRest) external nonReentrant {
    (bool passed, ) = isAboveReserve(_msgSender());
    require (passed, "User does not have enough reserve to complete compound");

    _claim(_msgSender());
    uint cost = _purchase(_msgSender(), _id, _count);
    require (withdrawableRewards[_msgSender()] >= cost, "Reward amount is insufficient to cover bank cost");

    uint left = withdrawableRewards[_msgSender()].sub(cost);
    withdrawableRewards[_msgSender()] = left;
    if (left > 0 && _claimRest) {
      safeRsrvTransfer(_msgSender(), left);
      withdrawableRewards[_msgSender()] = 0;
      emit Claimed(_msgSender(), left);
    }
  }

  function burnAndVestRewards(uint _amount, uint _period, bool _claimRest) external nonReentrant {
    require (address(brokerage) != address(0), "Brokerage is not set");
    (bool passed, ) = isAboveReserve(_msgSender());
    require (passed, "User does not have enough reserve to complete burn and vest");

    _claim(_msgSender());
    require (withdrawableRewards[_msgSender()] >= _amount, "Amount is bigger than total rewards available");
    brokerage.burnAndVest(_amount, _period);
    SafeERC20.safeTransfer(rsrv, deadAddress, _amount);

    uint left = withdrawableRewards[_msgSender()].sub(_amount);
    withdrawableRewards[_msgSender()] = left;
    if (left > 0 && _claimRest) {
      safeRsrvTransfer(_msgSender(), left);
      withdrawableRewards[_msgSender()] = 0;
      emit Claimed(_msgSender(), left);
    }
  }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.0;

import "../IERC20.sol";
import "../extensions/IERC20Permit.sol";
import "../../../utils/Address.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using Address for address;

    /**
     * @dev Transfer `value` amount of `token` from the calling contract to `to`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transfer.selector, to, value));
    }

    /**
     * @dev Transfer `value` amount of `token` from `from` to `to`, spending the approval given by `from` to the
     * calling contract. If `token` returns no value, non-reverting calls are assumed to be successful.
     */
    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transferFrom.selector, from, to, value));
    }

    /**
     * @dev Deprecated. This function has issues similar to the ones found in
     * {IERC20-approve}, and its usage is discouraged.
     *
     * Whenever possible, use {safeIncreaseAllowance} and
     * {safeDecreaseAllowance} instead.
     */
    function safeApprove(IERC20 token, address spender, uint256 value) internal {
        // safeApprove should only be called when setting an initial allowance,
        // or when resetting it to zero. To increase and decrease it, use
        // 'safeIncreaseAllowance' and 'safeDecreaseAllowance'
        require(
            (value == 0) || (token.allowance(address(this), spender) == 0),
            "SafeERC20: approve from non-zero to non-zero allowance"
        );
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, value));
    }

    /**
     * @dev Increase the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 oldAllowance = token.allowance(address(this), spender);
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, oldAllowance + value));
    }

    /**
     * @dev Decrease the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeDecreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        unchecked {
            uint256 oldAllowance = token.allowance(address(this), spender);
            require(oldAllowance >= value, "SafeERC20: decreased allowance below zero");
            _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, oldAllowance - value));
        }
    }

    /**
     * @dev Set the calling contract's allowance toward `spender` to `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful. Compatible with tokens that require the approval to be set to
     * 0 before setting it to a non-zero value.
     */
    function forceApprove(IERC20 token, address spender, uint256 value) internal {
        bytes memory approvalCall = abi.encodeWithSelector(token.approve.selector, spender, value);

        if (!_callOptionalReturnBool(token, approvalCall)) {
            _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, 0));
            _callOptionalReturn(token, approvalCall);
        }
    }

    /**
     * @dev Use a ERC-2612 signature to set the `owner` approval toward `spender` on `token`.
     * Revert on invalid signature.
     */
    function safePermit(
        IERC20Permit token,
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) internal {
        uint256 nonceBefore = token.nonces(owner);
        token.permit(owner, spender, value, deadline, v, r, s);
        uint256 nonceAfter = token.nonces(owner);
        require(nonceAfter == nonceBefore + 1, "SafeERC20: permit did not succeed");
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We use {Address-functionCall} to perform this call, which verifies that
        // the target address contains contract code and also asserts for success in the low-level call.

        bytes memory returndata = address(token).functionCall(data, "SafeERC20: low-level call failed");
        require(returndata.length == 0 || abi.decode(returndata, (bool)), "SafeERC20: ERC20 operation did not succeed");
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturn} that silents catches all reverts and returns a bool instead.
     */
    function _callOptionalReturnBool(IERC20 token, bytes memory data) private returns (bool) {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We cannot use {Address-functionCall} here since this should return false
        // and not revert is the subcall reverts.

        (bool success, bytes memory returndata) = address(token).call(data);
        return
            success && (returndata.length == 0 || abi.decode(returndata, (bool))) && Address.isContract(address(token));
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/math/SafeMath.sol)

pragma solidity ^0.8.0;

// CAUTION
// This version of SafeMath should only be used with Solidity 0.8 or later,
// because it relies on the compiler's built in overflow checks.

/**
 * @dev Wrappers over Solidity's arithmetic operations.
 *
 * NOTE: `SafeMath` is generally not needed starting with Solidity 0.8, since the compiler
 * now has built in overflow checking.
 */
library SafeMath {
    /**
     * @dev Returns the addition of two unsigned integers, with an overflow flag.
     *
     * _Available since v3.4._
     */
    function tryAdd(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            uint256 c = a + b;
            if (c < a) return (false, 0);
            return (true, c);
        }
    }

    /**
     * @dev Returns the subtraction of two unsigned integers, with an overflow flag.
     *
     * _Available since v3.4._
     */
    function trySub(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            if (b > a) return (false, 0);
            return (true, a - b);
        }
    }

    /**
     * @dev Returns the multiplication of two unsigned integers, with an overflow flag.
     *
     * _Available since v3.4._
     */
    function tryMul(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            // Gas optimization: this is cheaper than requiring 'a' not being zero, but the
            // benefit is lost if 'b' is also tested.
            // See: https://github.com/OpenZeppelin/openzeppelin-contracts/pull/522
            if (a == 0) return (true, 0);
            uint256 c = a * b;
            if (c / a != b) return (false, 0);
            return (true, c);
        }
    }

    /**
     * @dev Returns the division of two unsigned integers, with a division by zero flag.
     *
     * _Available since v3.4._
     */
    function tryDiv(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            if (b == 0) return (false, 0);
            return (true, a / b);
        }
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers, with a division by zero flag.
     *
     * _Available since v3.4._
     */
    function tryMod(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            if (b == 0) return (false, 0);
            return (true, a % b);
        }
    }

    /**
     * @dev Returns the addition of two unsigned integers, reverting on
     * overflow.
     *
     * Counterpart to Solidity's `+` operator.
     *
     * Requirements:
     *
     * - Addition cannot overflow.
     */
    function add(uint256 a, uint256 b) internal pure returns (uint256) {
        return a + b;
    }

    /**
     * @dev Returns the subtraction of two unsigned integers, reverting on
     * overflow (when the result is negative).
     *
     * Counterpart to Solidity's `-` operator.
     *
     * Requirements:
     *
     * - Subtraction cannot overflow.
     */
    function sub(uint256 a, uint256 b) internal pure returns (uint256) {
        return a - b;
    }

    /**
     * @dev Returns the multiplication of two unsigned integers, reverting on
     * overflow.
     *
     * Counterpart to Solidity's `*` operator.
     *
     * Requirements:
     *
     * - Multiplication cannot overflow.
     */
    function mul(uint256 a, uint256 b) internal pure returns (uint256) {
        return a * b;
    }

    /**
     * @dev Returns the integer division of two unsigned integers, reverting on
     * division by zero. The result is rounded towards zero.
     *
     * Counterpart to Solidity's `/` operator.
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function div(uint256 a, uint256 b) internal pure returns (uint256) {
        return a / b;
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers. (unsigned integer modulo),
     * reverting when dividing by zero.
     *
     * Counterpart to Solidity's `%` operator. This function uses a `revert`
     * opcode (which leaves remaining gas untouched) while Solidity uses an
     * invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function mod(uint256 a, uint256 b) internal pure returns (uint256) {
        return a % b;
    }

    /**
     * @dev Returns the subtraction of two unsigned integers, reverting with custom message on
     * overflow (when the result is negative).
     *
     * CAUTION: This function is deprecated because it requires allocating memory for the error
     * message unnecessarily. For custom revert reasons use {trySub}.
     *
     * Counterpart to Solidity's `-` operator.
     *
     * Requirements:
     *
     * - Subtraction cannot overflow.
     */
    function sub(uint256 a, uint256 b, string memory errorMessage) internal pure returns (uint256) {
        unchecked {
            require(b <= a, errorMessage);
            return a - b;
        }
    }

    /**
     * @dev Returns the integer division of two unsigned integers, reverting with custom message on
     * division by zero. The result is rounded towards zero.
     *
     * Counterpart to Solidity's `/` operator. Note: this function uses a
     * `revert` opcode (which leaves remaining gas untouched) while Solidity
     * uses an invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function div(uint256 a, uint256 b, string memory errorMessage) internal pure returns (uint256) {
        unchecked {
            require(b > 0, errorMessage);
            return a / b;
        }
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers. (unsigned integer modulo),
     * reverting with custom message when dividing by zero.
     *
     * CAUTION: This function is deprecated because it requires allocating memory for the error
     * message unnecessarily. For custom revert reasons use {tryMod}.
     *
     * Counterpart to Solidity's `%` operator. This function uses a `revert`
     * opcode (which leaves remaining gas untouched) while Solidity uses an
     * invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function mod(uint256 a, uint256 b, string memory errorMessage) internal pure returns (uint256) {
        unchecked {
            require(b > 0, errorMessage);
            return a % b;
        }
    }
}

{
  "compilationTarget": {
    "contracts/Reserve.sol": "Reserve"
  },
  "evmVersion": "paris",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": false,
    "runs": 200
  },
  "remappings": []
}