// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Context.sol)

pragma solidity ^0.8.0;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/ERC20.sol)

pragma solidity 0.8.19;

import {IERC20} from "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import {IERC20Metadata} from "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
import {Context} from "@openzeppelin/contracts/utils/Context.sol";

interface IERC20Errors {
    error ERC20InvalidSender(address sender);
    error ERC20InvalidReceiver(address receiver);
    error ERC20InvalidApprover(address approver);
    error ERC20InvalidSpender(address spender);
    error ERC20InsufficientBalance(address owner, uint256 balance, uint256 value);
    error ERC20InsufficientAllowance(address spender, uint256 allowance, uint256 value);
}

/**
 * @dev Implementation of the {IERC20} interface.
 *
 * This implementation is agnostic to the way tokens are created. This means
 * that a supply mechanism has to be added in a derived contract using {_mint}.
 *
 * TIP: For a detailed writeup see our guide
 * https://forum.openzeppelin.com/t/how-to-implement-erc20-supply-mechanisms/226[How
 * to implement supply mechanisms].
 *
 * The default value of {decimals} is 18. To change this, you should override
 * this function so it returns a different value.
 *
 * We have followed general OpenZeppelin Contracts guidelines: functions revert
 * instead returning `false` on failure. This behavior is nonetheless
 * conventional and does not conflict with the expectations of ERC-20
 * applications.
 */
abstract contract ERC20 is Context, IERC20, IERC20Metadata, IERC20Errors {
    mapping(address account => uint256) internal _balances;

    mapping(address account => mapping(address spender => uint256)) private _allowances;

    uint256 internal _totalSupply;

    string private _name;
    string private _symbol;

    /**
     * @dev Sets the values for {name} and {symbol}.
     *
     * All two of these values are immutable: they can only be set once during
     * construction.
     */
    constructor(string memory name_, string memory symbol_) {
        _name = name_;
        _symbol = symbol_;
    }

    /**
     * @dev Returns the name of the token.
     */
    function name() public view virtual returns (string memory) {
        return _name;
    }

    /**
     * @dev Returns the symbol of the token, usually a shorter version of the
     * name.
     */
    function symbol() public view virtual returns (string memory) {
        return _symbol;
    }

    /**
     * @dev Returns the number of decimals used to get its user representation.
     * For example, if `decimals` equals `2`, a balance of `505` tokens should
     * be displayed to a user as `5.05` (`505 / 10 ** 2`).
     *
     * Tokens usually opt for a value of 18, imitating the relationship between
     * Ether and Wei. This is the default value returned by this function, unless
     * it's overridden.
     *
     * NOTE: This information is only used for _display_ purposes: it in
     * no way affects any of the arithmetic of the contract, including
     * {IERC20-balanceOf} and {IERC20-transfer}.
     */
    function decimals() public view virtual returns (uint8) {
        return 18;
    }

    /**
     * @dev See {IERC20-totalSupply}.
     */
    function totalSupply() public view virtual returns (uint256) {
        return _totalSupply;
    }

    /**
     * @dev See {IERC20-balanceOf}.
     */
    function balanceOf(address account) public view virtual returns (uint256) {
        return _balances[account];
    }

    /**
     * @dev See {IERC20-transfer}.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     * - the caller must have a balance of at least `value`.
     */
    function transfer(address to, uint256 value) public virtual returns (bool) {
        address owner = _msgSender();
        _transfer(owner, to, value);
        return true;
    }

    /**
     * @dev See {IERC20-allowance}.
     */
    function allowance(address owner, address spender) public view virtual returns (uint256) {
        return _allowances[owner][spender];
    }

    /**
     * @dev See {IERC20-approve}.
     *
     * NOTE: If `value` is the maximum `uint256`, the allowance is not updated on
     * `transferFrom`. This is semantically equivalent to an infinite approval.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function approve(address spender, uint256 value) public virtual returns (bool) {
        address owner = _msgSender();
        _approve(owner, spender, value);
        return true;
    }

    /**
     * @dev See {IERC20-transferFrom}.
     *
     * Skips emitting an {Approval} event indicating an allowance update. This is not
     * required by the ERC. See {xref-ERC20-_approve-address-address-uint256-bool-}[_approve].
     *
     * NOTE: Does not update the allowance if the current allowance
     * is the maximum `uint256`.
     *
     * Requirements:
     *
     * - `from` and `to` cannot be the zero address.
     * - `from` must have a balance of at least `value`.
     * - the caller must have allowance for ``from``'s tokens of at least
     * `value`.
     */
    function transferFrom(address from, address to, uint256 value) public virtual returns (bool) {
        address spender = _msgSender();
        _spendAllowance(from, spender, value);
        _transfer(from, to, value);
        return true;
    }

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to`.
     *
     * This internal function is equivalent to {transfer}, and can be used to
     * e.g. implement automatic token fees, slashing mechanisms, etc.
     *
     * Emits a {Transfer} event.
     *
     * NOTE: This function is not virtual, {_update} should be overridden instead.
     */
    function _transfer(address from, address to, uint256 value) internal {
        if (from == address(0)) {
            revert ERC20InvalidSender(address(0));
        }
        if (to == address(0)) {
            revert ERC20InvalidReceiver(address(0));
        }
        _update(from, to, value);
    }

    /**
     * @dev Transfers a `value` amount of tokens from `from` to `to`, or alternatively mints (or burns) if `from`
     * (or `to`) is the zero address. All customizations to transfers, mints, and burns should be done by overriding
     * this function.
     *
     * Emits a {Transfer} event.
     */
    function _update(address from, address to, uint256 value) internal virtual {
        if (from == address(0)) {
            // Overflow check required: The rest of the code assumes that totalSupply never overflows
            _totalSupply += value;
        } else {
            uint256 fromBalance = _balances[from];
            if (fromBalance < value) {
                revert ERC20InsufficientBalance(from, fromBalance, value);
            }
            unchecked {
                // Overflow not possible: value <= fromBalance <= totalSupply.
                _balances[from] = fromBalance - value;
            }
        }

        if (to == address(0)) {
            unchecked {
                // Overflow not possible: value <= totalSupply or value <= fromBalance <= totalSupply.
                _totalSupply -= value;
            }
        } else {
            unchecked {
                // Overflow not possible: balance + value is at most totalSupply, which we know fits into a uint256.
                _balances[to] += value;
            }
        }

        emit Transfer(from, to, value);
    }

    /**
     * @dev Creates a `value` amount of tokens and assigns them to `account`, by transferring it from address(0).
     * Relies on the `_update` mechanism
     *
     * Emits a {Transfer} event with `from` set to the zero address.
     *
     * NOTE: This function is not virtual, {_update} should be overridden instead.
     */
    function _mint(address account, uint256 value) internal {
        if (account == address(0)) {
            revert ERC20InvalidReceiver(address(0));
        }
        _update(address(0), account, value);
    }

    /**
     * @dev Destroys a `value` amount of tokens from `account`, lowering the total supply.
     * Relies on the `_update` mechanism.
     *
     * Emits a {Transfer} event with `to` set to the zero address.
     *
     * NOTE: This function is not virtual, {_update} should be overridden instead
     */
    function _burn(address account, uint256 value) internal {
        if (account == address(0)) {
            revert ERC20InvalidSender(address(0));
        }
        _update(account, address(0), value);
    }

    /**
     * @dev Sets `value` as the allowance of `spender` over the `owner` s tokens.
     *
     * This internal function is equivalent to `approve`, and can be used to
     * e.g. set automatic allowances for certain subsystems, etc.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `owner` cannot be the zero address.
     * - `spender` cannot be the zero address.
     *
     * Overrides to this logic should be done to the variant with an additional `bool emitEvent` argument.
     */
    function _approve(address owner, address spender, uint256 value) internal {
        _approve(owner, spender, value, true);
    }

    /**
     * @dev Variant of {_approve} with an optional flag to enable or disable the {Approval} event.
     *
     * By default (when calling {_approve}) the flag is set to true. On the other hand, approval changes made by
     * `_spendAllowance` during the `transferFrom` operation set the flag to false. This saves gas by not emitting any
     * `Approval` event during `transferFrom` operations.
     *
     * Anyone who wishes to continue emitting `Approval` events on the`transferFrom` operation can force the flag to
     * true using the following override:
     *
     * ```solidity
     * function _approve(address owner, address spender, uint256 value, bool) internal virtual override {
     *     super._approve(owner, spender, value, true);
     * }
     * ```
     *
     * Requirements are the same as {_approve}.
     */
    function _approve(address owner, address spender, uint256 value, bool emitEvent) internal virtual {
        if (owner == address(0)) {
            revert ERC20InvalidApprover(address(0));
        }
        if (spender == address(0)) {
            revert ERC20InvalidSpender(address(0));
        }
        _allowances[owner][spender] = value;
        if (emitEvent) {
            emit Approval(owner, spender, value);
        }
    }

    /**
     * @dev Updates `owner` s allowance for `spender` based on spent `value`.
     *
     * Does not update the allowance value in case of infinite allowance.
     * Revert if not enough allowance is available.
     *
     * Does not emit an {Approval} event.
     */
    function _spendAllowance(address owner, address spender, uint256 value) internal virtual {
        uint256 currentAllowance = allowance(owner, spender);
        if (currentAllowance != type(uint256).max) {
            if (currentAllowance < value) {
                revert ERC20InsufficientAllowance(spender, currentAllowance, value);
            }
            unchecked {
                _approve(owner, spender, currentAllowance - value, false);
            }
        }
    }
}

// SPDX-License-Identifier: UNLICENSED
pragma solidity 0.8.19;

contract GoatTypes {
    struct Pool {
        uint112 reserveEth;
        uint112 reserveToken;
        uint32 lastTrade;
        uint112 totalSupply;
        uint112 virtualEth;
        uint32 vestingUntil;
        uint112 bootstrapEth;
        uint112 feesPerTokenStored;
        bool exists;
        uint256 kLast;
    }

    struct LPInfo {
        uint224 balance;
        uint32 lockedUntil;
    }

    struct LaunchParams {
        uint112 virtualEth;
        uint112 bootstrapEth;
        uint112 initialEth;
        uint112 initialTokenMatch;
    }

    struct FractionalLiquidity {
        uint112 fractionalBalance;
        uint32 lastWithdraw;
        uint8 withdrawlLeft;
    }

    struct InitParams {
        uint112 virtualEth;
        uint112 bootstrapEth;
        uint112 initialEth;
        uint112 initialTokenMatch;
    }

    struct InitialLPInfo {
        address liquidityProvider;
        // it's safe to use uint104 as it can hold 20 trillion ether
        uint104 initialWethAdded;
        uint112 fractionalBalance;
        uint32 lastWithdraw;
        uint8 withdrawalLeft;
    }

    struct LocalVariables_AddLiquidity {
        bool isNewPair;
        address pair;
        uint256 actualTokenAmount;
        uint256 tokenAmount;
        uint256 wethAmount;
        uint256 liquidity;
        address token;
    }

    struct LocalVariables_MintLiquidity {
        uint112 virtualEth;
        uint112 initialTokenMatch;
        uint256 bootstrapEth;
        bool isFirstMint;
    }

    struct LocalVariables_Swap {
        bool isBuy;
        bool isPresale;
        uint256 initialReserveEth;
        uint256 initialReserveToken;
        uint256 finalReserveEth;
        uint256 finalReserveToken;
        uint256 amountWethIn;
        uint256 amountTokenIn;
        uint256 feesCollected;
        uint256 lpFeesCollected;
        uint256 tokenAmount;
        uint32 vestingUntil;
        uint256 bootstrapEth;
        uint256 virtualEthReserveBefore;
        uint256 virtualTokenReserveBefore;
        uint256 virtualEthReserveAfter;
        uint256 virtualTokenReserveAfter;
    }

    struct LocalVariables_PairStateInfo {
        uint112 reserveEth;
        uint112 reserveToken;
        uint112 virtualEth;
        uint112 initialTokenMatch;
        uint112 bootstrapEth;
        uint256 virtualToken;
    }

    struct LocalVariables_TokenAmountOutInfo {
        uint256 actualWethIn;
        uint256 numerator;
        uint256 denominator;
        uint256 amountTokenOutPresale;
        uint256 amountTokenOutAmm;
        uint256 wethForAmm;
        uint256 wethForPresale;
    }

    struct LocalVariables_TakeOverPool {
        uint256 minTokenNeeded;
        uint256 tokenAmountForPresaleOld;
        uint256 tokenAmountForAmmOld;
        uint256 tokenAmountForPresaleNew;
        uint256 tokenAmountForAmmNew;
        uint256 virtualEthOld;
        uint256 initialTokenMatchOld;
        uint256 bootstrapEthOld;
        uint256 reserveToken;
        uint256 reserveEth;
        uint256 pendingProtocolFees;
        uint256 pendingLiquidityFees;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `from` to `to` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 amount) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (token/ERC20/extensions/IERC20Metadata.sol)

pragma solidity ^0.8.0;

import "../IERC20.sol";

/**
 * @dev Interface for the optional metadata functions from the ERC20 standard.
 *
 * _Available since v4.1._
 */
interface IERC20Metadata is IERC20 {
    /**
     * @dev Returns the name of the token.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the symbol of the token.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the decimals places of the token.
     */
    function decimals() external view returns (uint8);
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.19;

import {GoatTypes} from "./../library/GoatTypes.sol";

interface IGoatV1Router {
    function WETH() external view returns (address);
    function FACTORY() external view returns (address);

    /* ----------------------------- ADD LIQUIDITY ----------------------------- */

    function addLiquidity(
        address token,
        uint256 tokenDesired,
        uint256 wethDesired,
        uint256 tokenMin,
        uint256 wethMin,
        address to,
        uint256 deadline,
        GoatTypes.InitParams memory initParams
    ) external returns (uint256, uint256, uint256);

    function addLiquidityETH(
        address token,
        uint256 tokenDesired,
        uint256 tokenMin,
        uint256 ethMin,
        address to,
        uint256 deadline,
        GoatTypes.InitParams memory initParams
    ) external payable returns (uint256, uint256, uint256);

    /* ----------------------------- REMOVE LIQUIDITY ----------------------------- */
    function removeLiquidity(
        address token,
        uint256 liquidity,
        uint256 tokenMin,
        uint256 wethMin,
        address to,
        uint256 deadline
    ) external returns (uint256 amountWeth, uint256 amountToken);

    function removeLiquidityETH(
        address token,
        uint256 liquidity,
        uint256 tokenMin,
        uint256 ethMin,
        address to,
        uint256 deadline
    ) external returns (uint256 amountWeth, uint256 amountToken);

    function removeLiquidityETHSupportingFeeOnTransferTokens(
        address token,
        uint256 liquidity,
        uint256 tokenMin,
        uint256 ethMin,
        address to,
        uint256 deadline
    ) external returns (uint256 amountWeth);

    /* ----------------------------- SWAP FUNCTIONS FOR FEE ON TRANSFER TOKENS ----------------------------- */
    function swapExactTokensForTokensSupportingFeeOnTransferTokens(
        uint256 amountIn,
        uint256 amountOutMin,
        address[] calldata path,
        address to,
        uint256 deadline
    ) external;

    function swapExactWethForTokensSupportingFeeOnTransferTokens(
        uint256 amountIn,
        uint256 amountOutMin,
        address token,
        address to,
        uint256 deadline
    ) external;

    function swapETHForExactTokensSupportingFeeOnTransferTokens(
        uint256 amountOutMin,
        address[] calldata path,
        address to,
        uint256 deadline
    ) external payable;

    function swapExactTokensForWethSupportingFeeOnTransferTokens(
        uint256 amountIn,
        uint256 amountOutMin,
        address token,
        address to,
        uint256 deadline
    ) external;

    function swapExactTokensForETHSupportingFeeOnTransferTokens(
        uint256 amountIn,
        uint256 amountOutMin,
        address token,
        address to,
        uint256 deadline
    ) external;

    /* ----------------------------- SWAP FUNCTIONS  ----------------------------- */
    function swapExactTokensForTokens(
        uint256 amountIn,
        uint256 amountOutMin,
        address[] calldata path,
        address to,
        uint256 deadline
    ) external returns (uint256[] memory amounts);

    function swapTokensForExactTokens(
        uint256 amountOut,
        uint256 amountInMax,
        address[] calldata path,
        address to,
        uint256 deadline
    ) external returns (uint256[] memory amounts);

    function swapExactWethForTokens(uint256 amountIn, uint256 amountOutMin, address token, address to, uint256 deadline)
        external
        returns (uint256 amountTokenOut);

    function swapExactETHForTokens(uint256 amountOutMin, address[] calldata path, address to, uint256 deadline)
        external
        payable
        returns (uint256 amountTokenOut);

    function swapExactTokensForWeth(uint256 amountIn, uint256 amountOutMin, address token, address to, uint256 deadline)
        external
        returns (uint256 amountWethOut);

    function swapExactTokensForETH(uint256 amountIn, uint256 amountOutMin, address token, address to, uint256 deadline)
        external
        returns (uint256 amountWethOut);

    /* ------------------------------ WITHDRAW FEES ----------------------------- */
    function withdrawFees(address token, address to) external;

    /* ----------------------------- VIEW FUNCTIONS ----------------------------- */
    function quote(uint256 amountA, uint256 reserveA, uint256 reserveB) external pure returns (uint256 amountB);

    function getAmountsOut(uint256 amountIn, address[] memory path) external view returns (uint256[] memory amounts);

    function getTokenAmountOut(uint256 amountWethIn, address token) external view returns (uint256 tokenAmountOut);

    function getWethAmountOut(uint256 amountTokenIn, address token) external view returns (uint256 wethAmountOut);

    function getAmountsIn(uint256 amountOut, address[] memory path) external view returns (uint256[] memory amounts);

    function getTokenAmountIn(uint256 wethAmountOut, address token) external view returns (uint256 tokenAmountIn);

    function getWethAmountIn(uint256 tokenAmountOut, address token) external view returns (uint256 wethAmountIn);

    function getActualBootstrapTokenAmount(
        uint256 virtualEth,
        uint256 bootstrapEth,
        uint256 initialEth,
        uint256 initialTokenMatch
    ) external pure returns (uint256 actualTokenAmount);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (access/Ownable.sol)

pragma solidity ^0.8.0;

import "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _transferOwnership(_msgSender());
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: UNLICENSED
pragma solidity 0.8.19;

import "./TaxToken.sol";
import {TokenErrors} from "./library/TokenErrors.sol";

/**
 * @title TaxShare Token
 * @author Robert M.C. Forster
 * @notice This is a type of tax token that shares a percent of taxes with users. Whenever taxes are
 *         taken from a transaction, a portion of the tokens are split between all holders proportionally.
 * @dev Balances in this contract automatically increase every time taxes are taken--sort of interest-bearing.
 *
 */
contract TaxShareToken is TaxToken {
    uint256 public rewardPerTokenStored;
    mapping(address => uint256) public userRewardPerTokenPaid;

    // Amount of taxes to be shared with users. 100 == 1%.
    uint256 public sharePercent;
    // Number of tokens that are not receiving rewards. This amount subtracted from total supply
    // when determining rewards per token so people get full rewards owed.
    uint256 public excludedSupply;

    constructor(
        string memory _name,
        string memory _symbol,
        uint256 _initialSupply,
        uint256 _sharePercent,
        address _weth
    ) TaxToken(_name, _symbol, _initialSupply, _weth) {
        sharePercent = _sharePercent;
    }

    // Not on tax token by default because Ether is only sent to treasury there.

    receive() external payable {}

    /* ********************************************* VIEW ********************************************* */

    /**
     * @notice Get the balance of a user including unclaimed rewards.
     * @param user Address of the account to check the balance of.
     *
     */
    function balanceOf(address user) public view override returns (uint256 balance) {
        balance = _balances[user];
        // taxed addresses, burned addresses and tax fees will not accrue rewards.
        if (user != address(0) && user != address(this) && !taxed[user]) {
            balance += _earned(user);
        }
    }

    /* ********************************************* INTERNAL ********************************************* */

    /**
     * @notice Find the amount earned by a user since the last update of their balance.
     * @dev Using this rather than coding it into each function individually will likely be less gas efficient,
     *      but it avoids any mistakes re-coding it.
     * @param _user Address of the user to find rewards for.
     *
     */
    function _earned(address _user) internal view returns (uint256 unclaimedRewards) {
        // 1e18 is removed from balance because rewardPerToken is in full tokens.
        unclaimedRewards = ((rewardPerTokenStored - userRewardPerTokenPaid[_user]) * _balances[_user]) / 1e18;
    }

    // TaxToken _update with only change being _updateRewards calls.
    function _update(address from, address to, uint256 value) internal override {
        // TaxShare: Add rewards to both user token balance.
        _updateRewards(from, to);
        // Update excluded supply.
        _updateExcluded(from, to, value);

        super._update(from, to, value);
    }

    /**
     * @notice Update user balance with unclaimed rewards. Store new point where user has been paid.
     * @dev It's imperative that this is called before any balance change or calcs will be off.
     * @param _from First address of which to update rewards.
     * @param _to Second address of which to update rewards.
     *
     */
    function _updateRewards(address _from, address _to) internal {
        if (_from != address(0) && _from != address(this) && !taxed[_from]) {
            _balances[_from] += _earned(_from);
        }
        if (_to != address(0) && _to != address(this) && !taxed[_to]) {
            _balances[_to] += _earned(_to);
        }
        userRewardPerTokenPaid[_to] = rewardPerTokenStored;
        userRewardPerTokenPaid[_from] = rewardPerTokenStored;
    }

    /**
     * @notice Update the amount of tokens excluded from reward calculations. Includes
     *         address(this) and taxed. Address(0) inherently excluded because totalSupply lowers.
     * @param _from The address sending tokens.
     * @param _to The address receiving tokens.
     * @param _value The amount of tokens being sent.
     *
     */
    function _updateExcluded(address _from, address _to, uint256 _value) internal {
        if (_to == address(this) || taxed[_to]) excludedSupply += _value;
        if (_from == address(this) || taxed[_from]) excludedSupply -= _value;
    }

    /**
     * @notice In addition to awarding taxes to this address, add them to the rewards for users.
     * @param _amount Amount of tax tokens to be awarded.
     *
     */
    function _awardTaxes(address _from, uint256 _amount) internal override {
        uint256 reward = _amount * sharePercent / _DIVISOR;
        // 1e18 is removed because rewardPerToken is in full tokens
        rewardPerTokenStored += (reward * 1e18) / (_totalSupply - excludedSupply);
        address to = address(this);
        _balances[to] += _amount - reward;

        // @note not sure whether to emit the full amount or just token balance change.
        emit Transfer(_from, to, _amount);
    }

    /* ********************************************* ONLY OWNER/TREASURY ********************************************* */

    /**
     * @notice Set taxes of a specific dex/address based on buy and sell.
     * @dev This is onlyOwner rather than including treasury so that a team can renounce ownership
     *      of this critical function while maintaining ownership of non-critical treasury functions.
     * @param _dex Address of the dex that taxes are being added to when a transfer is made from/to it.
     * @param _buyTax The tax for buys (transactions coming from the address). 1% == 100.
     * @param _sellTax The tax for sells (transactions going to the address). 1% == 100.
     *
     */
    function setTaxes(address _dex, uint256 _buyTax, uint256 _sellTax) external virtual override onlyOwner {
        if (_buyTax > _TAX_MAX || _sellTax > _TAX_MAX) revert TokenErrors.TaxTooHigh();
        if (_dex == address(this)) revert TokenErrors.CannotTaxSelf();
        _updateRewards(address(0), _dex);
        buyTax[_dex] = _buyTax;
        sellTax[_dex] = _sellTax;

        // check already taxed
        bool isTaxed = taxed[_dex];

        if (_buyTax > 0 || _sellTax > 0) {
            taxed[_dex] = true;
            // If taxed, add to excluded supply.
            if (!isTaxed) excludedSupply += _balances[_dex];
        } else {
            taxed[_dex] = false;
            if (isTaxed) {
                // If untaxed, remove from excluded supply.
                excludedSupply -= _balances[_dex];
            }
        }
    }
    /**
     * @notice Change the percent of taxes to be shared with users.
     * @param _newSharePercent New percent of taxes to be shared. 100 == 1%.
     *
     */

    function changeSharePercent(uint256 _newSharePercent) external onlyOwnerOrTreasury {
        if (_newSharePercent > _DIVISOR) revert TokenErrors.NewVaultPercentTooHigh();
        sharePercent = _newSharePercent;
    }
}

// SPDX-License-Identifier: UNLICENSED
pragma solidity 0.8.19;

import {Ownable} from "@openzeppelin/contracts/access/Ownable.sol";

import "./ERC20.sol";
import {TokenErrors} from "./library/TokenErrors.sol";
import {IGoatV1Router} from "./../interfaces/IGoatV1Router.sol";

/**
 * @title Plain Tax Token
 * @author Robert M.C. Forster
 * @notice This is a pretty plain tax token. When a transfer is made to or from a dex, a sell or buy tax is applied respectively.
 *         The tax is taken in tokens, then when it gets past a minimum amount a dex swap is automatically executed to trade the
 *         taxes for Ether. Ownership is split between "owner" and "treasury" so the power to change taxes can be relinquished
 *         without losing the power to change where taxes are sent or change what dex taxes are sold on.
 *
 */
contract TaxToken is ERC20, Ownable {
    uint256 internal constant _DIVISOR = 10_000;
    uint256 internal constant _TAX_MAX = 1_000;
    address internal immutable _WETH;

    // Team address that will receive tax profits.
    address public treasury;
    address public dex;

    // Pool address => % tax on the pool, 100 == 1%, 1000 (10%) maximum.
    mapping(address => uint256) public buyTax;
    mapping(address => uint256) public sellTax;

    // Used in some iterations such as TaxShare in a situation where a dex should be excluded from activity.
    mapping(address => bool) public taxed;

    /* ********************************************* CONSTRUCTOR ********************************************* */
    constructor(string memory _name, string memory _symbol, uint256 _initialSupply, address _weth)
        ERC20(_name, _symbol)
    {
        treasury = msg.sender;
        _WETH = _weth;
        _mint(msg.sender, _initialSupply);
    }

    /* ********************************************* INTERNAL ********************************************* */

    // If transfer is from a dex, apply buy tax
    // If transfer is to a dex, apply sell tax
    // Add tax to token contract balance and/or rewardAmount or lotteryAmount
    // If token contract balance is above a certain amount, sell tokens
    // OpenZeppelin ERC20 _update with only change being _updateRewards calls.
    function _update(address from, address to, uint256 value) internal virtual override {
        uint256 tax = _determineTax(from, to, value);

        // We need to sell taxes before updating balances because user transfer
        // to pair contract will trigger sell taxes and update reserves by using
        //  the new balance reverting the transaction.
        if (tax > 0) {
            _awardTaxes(from, tax);
            if (!taxed[from]) {
                _sellTaxes(tax);
            }
        }

        // Final value to be received by address.
        uint256 receiveValue = value - tax;
        if (from == address(0)) {
            // Overflow check required: The rest of the code assumes that totalSupply never overflows
            _totalSupply += value;
        } else {
            uint256 fromBalance = _balances[from];
            if (fromBalance < value) {
                revert ERC20InsufficientBalance(from, fromBalance, value);
            }
            unchecked {
                // Overflow not possible: value <= fromBalance <= totalSupply.
                _balances[from] = fromBalance - value;
            }
        }

        if (to == address(0)) {
            unchecked {
                // Overflow not possible: value <= totalSupply or value <= fromBalance <= totalSupply.
                _totalSupply -= receiveValue;
            }
        } else {
            unchecked {
                // Overflow not possible: balance + value is at most totalSupply, which we know fits into a uint256.
                // Default value here changed to receiveValue to account for possible taxes.
                _balances[to] += receiveValue;
            }
        }

        emit Transfer(from, to, receiveValue);
    }

    /**
     * @notice Determine how much tax needs to be paid.
     * @param _from User/contract that funds are being sent from.
     * @param _to User/contract that funds are being sent to.
     * @param _value Value of the funds being sent.
     *
     */
    function _determineTax(address _from, address _to, uint256 _value) internal view returns (uint256 taxAmount) {
        if (_from == address(this)) return 0;

        uint256 fromTax = buyTax[_from];
        uint256 toTax = sellTax[_to];

        // If there's no tax, will just equal 0.
        taxAmount += _value * fromTax / _DIVISOR;
        taxAmount += _value * toTax / _DIVISOR;
    }

    /**
     * @notice Give tax balances to a new address.
     * @dev In versions with more advanced tax features, this function will be overridden.
     * @param _amount Amount of tax tokens to be awarded.
     *
     */
    function _awardTaxes(address _from, uint256 _amount) internal virtual {
        address to = address(this);
        _balances[to] += _amount;
        emit Transfer(_from, to, _amount);
    }

    /**
     * @notice Sells the collected tax tokens.
     * @dev This function sells the tax tokens collected.
     * It limits the amount of tokens sold to twice the current tax amount
     * if there is pending tax to sell. If the DEX address is not set,
     * the tax tokens are transferred directly to the treasury. Otherwise, it
     * attempts to swap the tax tokens for WETH on the DEX and sends the WETH to
     * the treasury. If the swap fails, the tax
     * tokens are transferred to the treasury instead.
     * @param tokens The amount of tax tokens collected in current txn.
     */
    function _sellTaxes(uint256 tokens) internal virtual {
        uint256 balance = _balances[address(this)];

        // if taxes have been collected before from buy txns we don't want
        // huge slippage to occur because of tax dump. We only
        // allow 2X tax amount to be sold per transaction
        tokens = tokens * 2;

        if (tokens > balance) {
            tokens = balance;
        }

        if (dex.code.length == 0) {
            // transfer tax to treasury if dex is not set
            _transfer(address(this), treasury, tokens);
            return;
        }

        address[] memory path = new address[](2);
        path[0] = address(this);
        path[1] = _WETH;

        // Try/catch because this will revert on buy txns because of reentrancy
        try IGoatV1Router(dex).swapExactTokensForTokensSupportingFeeOnTransferTokens(
            tokens, 0, path, treasury, block.timestamp
        ) {} catch (bytes memory) {
            // if pool is not in presale don't transfer tax tokens to the treasury
            // transfer tax tokens to treasury sell of tax tokens fail
            _transfer(address(this), treasury, tokens);
        }
    }

    /* ********************************************* ONLY OWNER/TREASURY ********************************************* */

    /**
     * @dev We need treasury to have permissions along with owner so that adjustments that need to always be there
     *      such as changing the dex that tokens are sold on can still be used if people want to renounce owner
     *      so that users don't have a worry that taxes will be changed from under there.
     *
     */
    modifier onlyOwnerOrTreasury() {
        if (msg.sender != treasury && msg.sender != owner()) revert TokenErrors.OnlyOwnerOrTreasury();
        _;
    }

    /**
     * @notice Transfer treasury permissions to a new address.
     * @param _newTreasury Address to give treasury permissions to.
     *
     */
    function transferTreasury(address _newTreasury) external onlyOwnerOrTreasury {
        treasury = _newTreasury;
    }

    /**
     * @notice Change the dex that taxes are to be sold on. Requires a Uni V2 interface.
     * @param _dexAddress New address to sell tokens on.
     *
     */
    function changeDex(address _dexAddress) external onlyOwnerOrTreasury {
        if (dex != address(0)) {
            IERC20(address(this)).approve(dex, 0);
        }
        dex = _dexAddress;
        IERC20(address(this)).approve(_dexAddress, type(uint256).max);
    }

    /* ********************************************* ONLY OWNER ********************************************* */

    /**
     * @notice Set taxes of a specific dex/address based on buy and sell.
     * @dev This is onlyOwner rather than including treasury so that a team can renounce ownership
     *      of this critical function while maintaining ownership of non-critical treasury functions.
     * @param _dex Address of the dex that taxes are being added to when a transfer is made from/to it.
     * @param _buyTax The tax for buys (transactions coming from the address). 1% == 100.
     * @param _sellTax The tax for sells (transactions going to the address). 1% == 100.
     *
     */
    function setTaxes(address _dex, uint256 _buyTax, uint256 _sellTax) external virtual onlyOwner {
        if (_buyTax > _TAX_MAX || _sellTax > _TAX_MAX) revert TokenErrors.TaxTooHigh();
        if (_dex == address(this)) revert TokenErrors.CannotTaxSelf();
        buyTax[_dex] = _buyTax;
        sellTax[_dex] = _sellTax;

        if (_buyTax > 0 || _sellTax > 0) taxed[_dex] = true;
        else taxed[_dex] = false;
    }

    /* ********************************************* VIEW FUNCTIONS ********************************************* */
    function getTaxes(address _dex) external view returns (uint256 buy, uint256 sell) {
        return (buyTax[_dex], sellTax[_dex]);
    }
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.19;

contract TokenErrors {
    error BurnPercentTooHigh();
    error CannotTaxSelf();
    error InitialEthNotAccepted();
    error InvalidTokenType();
    error NewBurnPercentTooHigh();
    error NewPotPercentTooHigh();
    error NewVaultPercentTooHigh();
    error OnlyBeneficiaryOrOwner();
    error OnlyBeneficiaryOrRewarder();
    error OnlyLotteryMaster();
    error OnlyOwnerOrTreasury();
    error OnlyTeam();
    error ProvidedRewardsTooHigh();
    error TaxTooHigh();
    error TokenAmountForPoolTooLow();
}

{
  "compilationTarget": {
    "contracts/tokens/TaxShareToken.sol": "TaxShareToken"
  },
  "evmVersion": "paris",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": true,
    "runs": 200
  },
  "remappings": [
    ":@openzeppelin/contracts/=lib/openzeppelin-contracts/contracts/",
    ":ds-test/=lib/forge-std/lib/ds-test/src/",
    ":erc4626-tests/=lib/openzeppelin-contracts/lib/erc4626-tests/",
    ":eth-gas-reporter/=node_modules/eth-gas-reporter/",
    ":forge-std/=lib/forge-std/src/",
    ":hardhat/=node_modules/hardhat/",
    ":openzeppelin-contracts/=lib/openzeppelin-contracts/",
    ":openzeppelin/=lib/openzeppelin-contracts/contracts/"
  ]
}