// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/Address.sol)

pragma solidity ^0.8.20;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev The ETH balance of the account is not enough to perform the operation.
     */
    error AddressInsufficientBalance(address account);

    /**
     * @dev There's no code at `target` (it is not a contract).
     */
    error AddressEmptyCode(address target);

    /**
     * @dev A call to an address target failed. The target may have reverted.
     */
    error FailedInnerCall();

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.8.20/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        if (address(this).balance < amount) {
            revert AddressInsufficientBalance(address(this));
        }

        (bool success, ) = recipient.call{value: amount}("");
        if (!success) {
            revert FailedInnerCall();
        }
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason or custom error, it is bubbled
     * up by this function (like regular Solidity function calls). However, if
     * the call reverted with no returned reason, this function reverts with a
     * {FailedInnerCall} error.
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        if (address(this).balance < value) {
            revert AddressInsufficientBalance(address(this));
        }
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and reverts if the target
     * was not a contract or bubbling up the revert reason (falling back to {FailedInnerCall}) in case of an
     * unsuccessful call.
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata
    ) internal view returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            // only check if target is a contract if the call was successful and the return data is empty
            // otherwise we already know that it was a contract
            if (returndata.length == 0 && target.code.length == 0) {
                revert AddressEmptyCode(target);
            }
            return returndata;
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and reverts if it wasn't, either by bubbling the
     * revert reason or with a default {FailedInnerCall} error.
     */
    function verifyCallResult(bool success, bytes memory returndata) internal pure returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            return returndata;
        }
    }

    /**
     * @dev Reverts with returndata if present. Otherwise reverts with {FailedInnerCall}.
     */
    function _revert(bytes memory returndata) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            /// @solidity memory-safe-assembly
            assembly {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert FailedInnerCall();
        }
    }
}

// SPDX-License-Identifier: BUSL-1.1
pragma solidity ^0.8.20;

import '@openzeppelin/contracts/token/ERC20/IERC20.sol';
import '@openzeppelin/contracts/utils/ReentrancyGuard.sol';
import '@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol';
import './interfaces/IFastPriceFeed.sol';
import './interfaces/IDoublerFactory.sol';
import './interfaces/IDoubler.sol';
import './interfaces/IRBToken.sol';
import './interfaces/IWETH.sol';

/// @title Doubler Contract
/// @notice This contract handles the operations of a liquidity pool, including deposits, withdrawals, and rebalancing.
contract Doubler is IDoubler, ReentrancyGuard {
    using SafeERC20 for IERC20;

    /// @dev Slip percentage (basis points)
    uint16 private constant _slip = 50;
    /// @dev Basis points denominator
    uint16 private constant _perMil = 1000;

    /// @dev Factory contract address
    address private _factory;
    /// @dev Fast price feed contract address
    address private _fastPriceFeed;
    /// @dev Pool parameters
    Pool private _pool;
    /// @dev Mapping to track the last block called for each address
    mapping(address => uint256) private _lastBlockCalled;

    mapping(address => uint256) private _userExtraBToken;

    /**
     * @notice Constructor to initialize the Doubler contract
     * @param _initParent Address of the factory contract
     */
    constructor(address _initParent) {
        _factory = _initParent;
    }

    /**
     * @notice Initialize the Doubler contract with fast price feed and pool parameters
     * @param _initFastPriceFeed Address of the fast price feed contract
     * @param _initPool Pool parameters
     */
    function initialize(address _initFastPriceFeed, Pool memory _initPool) external {
        if (_factory != msg.sender) revert E_Ownable();
        _checkPoolParam(_initPool);
        _fastPriceFeed = _initFastPriceFeed;
        _pool = _initPool;
    }

    /// @notice Modifier to restrict access to the owner
    modifier onlyOwner() {
        if (IDoublerFactory(_factory).getFactoryOwner() != msg.sender) revert E_Ownable();
        _;
    }

    /// @notice Modifier to allow function calls only once per block
    modifier onlyOnce() {
        if (_pool.endPrice > 0 || _pool.startTime > block.timestamp || _pool.endTime < block.timestamp)
            revert E_Disable();
        if (_lastBlockCalled[tx.origin] >= block.number) revert E_BlockOnce();
        _;
        _lastBlockCalled[tx.origin] = block.number;
    }

    /**
     * @notice Get the current pool parameters
     * @return The pool parameters
     */
    function getPool() external view returns (Pool memory) {
        return _pool;
    }

     /**
     * @dev Get user's additional tokens exceeding 10x tokens
     * @param _to  User address
     * @return extraBToken additional tokens
     */    
    function getUserExtraBToken(address _to) external view returns(uint256) {
        return _userExtraBToken[_to];
    }

    /**
     * @dev Check the validity of the pool parameters
     * @param _pl The pool parameters to check
     */
    function _checkPoolParam(Pool memory _pl) internal pure {
        if (_pl.inputFee > 20) revert E_FeeLimit();
        if (_pl.withdrawFee > 20) revert E_FeeLimit();
        if (_pl.creator == address(0x0)) revert E_ZeroAddr();
    }

    /**
     * @notice Update the pool parameters
     * @param _updatePl New pool parameters
     */
    function updatePool(MPool calldata _updatePl) external onlyOwner {
        if (_pool.endPrice != 0) revert E_PoolEnd();
        if (_pool.endTime != _updatePl.endTime) {
            if (_updatePl.endTime <= _pool.endTime || block.timestamp < _pool.endTime - 7 days) revert E_EndTime();
            if (_getCurPrice(_pool.asset) >= _getAssetAvg(_pool.asset)) revert E_PriceLimit();
        }
        _pool.inputFee = _updatePl.inputFee;
        _pool.withdrawFee = _updatePl.withdrawFee;
        _pool.creator = _updatePl.creator;
        _pool.endTime = _updatePl.endTime;
        _checkPoolParam(_pool);
        emit UpdatePool(_pool.asset, _pool.creator, _pool.inputFee, _pool.withdrawFee, _pool.endTime);
    }

    /**
     * @notice Get the balance of a given asset in the contract
     * @param _asset Address of the asset
     * @return The balance of the asset
     */
    function _getAssetBalance(address _asset) private view returns (uint256) {
        return IERC20(_asset).balanceOf(address(this));
    }

    /**
     * @notice Get the service fee addresses
     * @param _creator Address of the pool creator
     * @return srvFeeAddr Array of service fee addresses
     */
    function _getSrvFeeAddr(address _creator) internal view returns (address[] memory srvFeeAddr) {
        srvFeeAddr = new address[](2);
        srvFeeAddr[0] = _creator;
        srvFeeAddr[1] = IDoublerFactory(_factory).getEcoAddr();
    }

    /**
     * @notice Get the average price of an asset in the pool
     * @param _asset Address of the asset
     * @return The average price of the asset
     */
    function _getAssetAvg(address _asset) private view returns (uint256) {
        uint256 assetTotal = _getAssetBalance(_asset);
        if (assetTotal == 0) {
            return 0;
        }
        return (IERC20(_pool.cToken).totalSupply() * _getUnitSize(_pool.asset)) / assetTotal;
    }

    /**
     * @notice Get the current price of an asset from the fast price feed
     * @param _asset Address of the asset
     * @return The current price of the asset
     */
    function _getCurPrice(address _asset) internal view returns (uint256) {
        return IFastPriceFeed(_fastPriceFeed).getPrice(_asset);
    }

    /**
     * @notice Get the unit size of an asset
     * @param _asset Address of the asset
     * @return The unit size of the asset
     */
    function _getUnitSize(address _asset) internal view returns (uint256) {
        return 10 ** IERC20Metadata(_asset).decimals();
    }

    /**
     * @notice Input ETH into the pool
     * @param _qAmount Amount of ETH to input
     * @param _to Address to credit
     */
    function inputEth(uint256 _qAmount, address _to) external payable nonReentrant onlyOnce {
        if (!_pool.isNative) revert E_Asset();
        if (msg.value != _qAmount) revert E_Balance();
        _input(_qAmount, _to, true);
    }

    /**
     * @notice Input an ERC20 token into the pool
     * @param _qAmount Amount of tokens to input
     * @param _to Address to credit
     */
    function input(uint256 _qAmount, address _to) external nonReentrant onlyOnce {
        if (IERC20(_pool.asset).balanceOf(msg.sender) < _qAmount) revert E_Balance();
        _input(_qAmount, _to, false);
    }

    /**
     * @dev Check the input quantity amount against limits
     * @param _qAmount Quantity amount to check
     * @param _curPrice Current price of the asset
     * @param _assetUnitSize Unit size of the asset
     * @param _lowerOfInputMaximum Lower limit of input maximum
     */
    function _checkInputQAmount(
        uint256 _qAmount,
        uint256 _curPrice,
        uint256 _assetUnitSize,
        uint256 _lowerOfInputMaximum
    ) internal view {
        uint256 inputValue = (_curPrice * _qAmount) / _assetUnitSize;
        uint256 inputMax = (_curPrice * _getAssetBalance(_pool.asset)) / _assetUnitSize / 100;
        inputMax = inputMax > _lowerOfInputMaximum ? inputMax : _lowerOfInputMaximum;
        if (inputValue < 1 ether || inputValue > inputMax) revert E_InputLimit();
    }

    /**
     * @dev Internal function to handle input logic
     * @param _qAmount Quantity amount
     * @param _to Address to credit
     * @param _isNative Boolean indicating if the asset is native
     */
    function _input(uint256 _qAmount, address _to, bool _isNative) internal {
        _rebaseCToken();
        uint256 curPrice = _getCurPrice(_pool.asset);
        uint256 avg = _getAssetAvg(_pool.asset); // get last avg
        uint256 assetUnitSize = _getUnitSize(_pool.asset);
        _checkInputQAmount(_qAmount, curPrice, assetUnitSize, _pool.lowerOfInputMaximum);
        uint256 bAmount;
        uint256 cAmount;
        uint256 bTotal = IERC20(_pool.bToken).totalSupply();
        uint256 cTotal = IERC20(_pool.cToken).totalSupply();
        uint256 extBAmount;
        if (cTotal == 0) {
            cAmount = (curPrice * _qAmount) / assetUnitSize;
            bAmount = cAmount / 10;
            avg = curPrice;
        } else {
            uint256 stmPrice = avg;
            if (curPrice <= avg) {
                stmPrice = curPrice;
                extBAmount = (curPrice * _qAmount - (curPrice * curPrice * _qAmount) / avg) / assetUnitSize;
                _userExtraBToken[_to] += extBAmount;
            }
            cAmount = (stmPrice * _qAmount) / assetUnitSize;
            bAmount = extBAmount + (cAmount * bTotal) / cTotal;
        }
        if (_isNative) {
            IWETH(_pool.asset).deposit{ value: msg.value }();
        } else {
            IERC20(_pool.asset).safeTransferFrom(msg.sender, address(this), _qAmount);
        }
        _mintBCToken(_to, bAmount, cAmount);
        emit Input(_pool.asset, _pool.id, _to, _qAmount, bAmount, cAmount, extBAmount);
        emit PoolStream(_pool.asset, _pool.id, _qAmount, bTotal, cTotal, curPrice, avg);
    }

    /**
     * @dev Mint B and C tokens
     * @param _to Address to credit
     * @param _bAmount Amount of B tokens to mint
     * @param _cAmount Amount of C tokens to mint
     */
    function _mintBCToken(address _to, uint256 _bAmount, uint256 _cAmount) internal {
        IRBToken(_pool.bToken).mintWithFee(_to, _bAmount, _getSrvFeeAddr(_pool.creator), _pool.inputFee);
        IRBToken(_pool.cToken).mint(_to, _cAmount);
    }

    /**
     * @dev Get the withdrawable asset amount
     * @param _bAmount Amount of B tokens
     * @param _cAmount Amount of C tokens
     * @param _bTotal Total supply of B tokens
     * @param _cTotal Total supply of C tokens
     * @param _curPrice Current price of the asset
     * @param _avgPrice Average price of the asset
     * @return assetAmount The withdrawable asset amount
     */
    function _getWithdrawAssetAmount(
        uint256 _bAmount,
        uint256 _cAmount,
        uint256 _bTotal,
        uint256 _cTotal,
        uint256 _curPrice,
        uint256 _avgPrice
    ) internal view returns (uint256 assetAmount) {
        uint256 assetUnitSize = _getUnitSize(_pool.asset);
        if (_curPrice >= _avgPrice) {
            uint256 profit = (((_getAssetBalance(_pool.asset) * _curPrice) / assetUnitSize - _cTotal) * _bAmount) /
                _bTotal;
            assetAmount = ((_cAmount + profit) * assetUnitSize) / _curPrice;
        } else {
            assetAmount = (_cAmount * assetUnitSize) / _avgPrice;
        }
    }

    /**
     * @dev Get the spendable B token amount
     * @param _cAmount Amount of C tokens
     * @param _bTotal Total supply of B tokens
     * @param _cTotal Total supply of C tokens
     * @return spendBAmount The spendable B token amount
     */
    function _getSpendBAmount(
        uint256 _cAmount,
        uint256 _bTotal,
        uint256 _cTotal
    ) internal view returns (uint256 spendBAmount) {
        spendBAmount = (_cAmount * _bTotal) / _cTotal;
        uint256 uBTokenBalance = IERC20(_pool.bToken).balanceOf(msg.sender);
        if (_pool.endPrice == 0 && _cTotal == _cAmount && spendBAmount > uBTokenBalance) {
            // The final withdrawal allows a precision error within 1/10 token.
            if (spendBAmount - uBTokenBalance <= _getUnitSize(_pool.bToken) / 10) spendBAmount = uBTokenBalance;
        }
        if (IERC20(_pool.cToken).balanceOf(msg.sender) < _cAmount) revert E_Balance();
        if (uBTokenBalance < spendBAmount) revert E_Balance();
    }

    /**
     * @dev Internal function to handle withdrawal logic
     * @param _curPrice Current price of the asset
     * @param _avgPrice Average price of the asset
     * @param _bAmount Amount of B tokens
     * @param _cAmount Amount of C tokens
     * @param _bTotal Total supply of B tokens
     * @param _cTotal Total supply of C tokens
     * @return assetAmount The withdrawable asset amount
     * @return srvFee The service fee
     */
    function _withdraw(
        uint256 _curPrice,
        uint256 _avgPrice,
        uint256 _bAmount,
        uint256 _cAmount,
        uint256 _bTotal,
        uint256 _cTotal
    ) internal returns (uint256 assetAmount, uint256 srvFee) {
        if (
            IRBToken(_pool.bToken).balanceOf(msg.sender) < _bAmount ||
            IRBToken(_pool.cToken).balanceOf(msg.sender) < _cAmount
        ) revert E_Balance();
        assetAmount = _getWithdrawAssetAmount(_bAmount, _cAmount, _bTotal, _cTotal, _curPrice, _avgPrice);
        uint256 qAmount = _getAssetBalance(_pool.asset);
        if (qAmount <= assetAmount) {
            assetAmount = _getAssetBalance(_pool.asset);
        }
        // burn c,b tokens
        if (_cAmount > 0) {
            IRBToken(_pool.cToken).burnFrom(msg.sender, _cAmount);
        }
        if (_bAmount > 0) {
            IRBToken(_pool.bToken).burnFrom(msg.sender, _bAmount);
        }
        // transfer asset
        srvFee = (assetAmount * _pool.withdrawFee) / _perMil;
        IERC20(_pool.asset).safeTransfer(_pool.creator, srvFee / 2);
        address ecoAddr = IDoublerFactory(_factory).getEcoAddr();
        IERC20(_pool.asset).safeTransfer(ecoAddr, srvFee - srvFee / 2);
        IERC20(_pool.asset).safeTransfer(msg.sender, assetAmount - srvFee);
        emit Withdraw(_pool.asset, _pool.id, msg.sender, _cAmount, _bAmount, assetAmount);
        emit PoolStream(_pool.asset, _pool.id, qAmount, _bTotal, _cTotal, _curPrice, _avgPrice);
    }

    /**
     * @notice Claim function for final withdrawal
     */
    function claim() external nonReentrant {
        if (_pool.endPrice == 0) revert E_PoolEnd();
        uint256 bAmount = IERC20(_pool.bToken).balanceOf(msg.sender);
        uint256 cAmount = IERC20(_pool.cToken).balanceOf(msg.sender);
        uint256 curPrice = _pool.endPrice;
        uint256 avgPrice = _getAssetAvg(_pool.asset);
        uint256 bTotal = IERC20(_pool.bToken).totalSupply();
        uint256 cTotal = IERC20(_pool.cToken).totalSupply();
        _withdraw(curPrice, avgPrice, bAmount, cAmount, bTotal, cTotal);
    }

    /**
     * @notice Withdraw function with additional slip check
     * @param _cAmount Amount of C tokens
     * @param _qAmount Expected quantity
     * @param _clientSlip Client slip percentage
     */
    function withdraw(uint256 _cAmount, uint256 _qAmount, uint16 _clientSlip) external nonReentrant onlyOnce {
        _rebaseCToken();
        uint256 curPrice = _getCurPrice(_pool.asset);
        uint256 avgPrice = _getAssetAvg(_pool.asset);
        uint256 bTotal = IERC20(_pool.bToken).totalSupply();
        uint256 cTotal = IERC20(_pool.cToken).totalSupply();
        uint256 bAmount = _getSpendBAmount(_cAmount, bTotal, cTotal);

        (uint256 assetAmount, uint256 srvFee) = _withdraw(curPrice, avgPrice, bAmount, _cAmount, bTotal, cTotal);
        _checkWithdrawLimit(_pool.asset, curPrice);
        _checkAmountSlip(_qAmount, assetAmount - srvFee, _clientSlip);
    }

    /**
     * @dev Check if the remaining balance after withdrawal is above the limit
     * @param _asset Address of the asset
     * @param _curPrice Current price of the asset
     */
    function _checkWithdrawLimit(address _asset, uint256 _curPrice) internal view {
        uint256 lastBalance = _getAssetBalance(_asset);
        // Check if the balance is not zero and if the remaining balance after withdrawal
        // multiplied by the current price divided by the unit size of the asset is less than 1 usd
        if (lastBalance != 0 && ((lastBalance * _curPrice) / _getUnitSize(_asset)) < 1 ether) {
            revert E_WithdrawLimit();
        }
    }

    /**
     * @dev Check if the amount slip is within the allowed limit
     * @param _eAmount Expected amount
     * @param _rAmount Received amount
     * @param _clientSlip Client slip percentage
     */
    function _checkAmountSlip(uint256 _eAmount, uint256 _rAmount, uint16 _clientSlip) internal pure {
        if (_clientSlip > _slip) revert E_SlipLimit();
        if ((_eAmount * (_perMil - _clientSlip)) / _perMil > _rAmount) {
            revert E_Expected();
        }
    }

    /**
     * @notice Rebase the C tokens
     */
    function rebaseCToken() external nonReentrant {
        if (block.timestamp > _pool.endTime || _pool.endPrice > 0) revert E_PoolEnd();
        _rebaseCToken();
    }

    /**
     * @dev Internal function to rebase the C tokens
     */
    function _rebaseCToken() internal {
        uint256 avg = _getAssetAvg(_pool.asset);
        uint256 curPrice = _getCurPrice(_pool.asset);
        if (avg == 0 || curPrice <= avg || block.timestamp - _pool.cLastRbTime <= 1 days) {
            // avg == 0 then cLastRbTime update
            if (avg == 0) _pool.cLastRbTime = block.timestamp;
            return;
        }
        // some ext reward
        IDoublerFactory(_factory).mintReward(_pool.asset, _pool.id, msg.sender, 1000 ether);
        _pool.cLastRbTime = block.timestamp;
        uint256 cTokenTotal = IERC20(_pool.cToken).totalSupply();
        // rebaseTotal =  cTokenTotal + cTokenTotal  * priceDiff / avg * 1%
        uint256 rbAmount = (cTokenTotal * (curPrice - avg)) / avg / 100;
        _pool.lastDayRate = (rbAmount * _perMil * _perMil) / cTokenTotal;
        cTokenTotal = cTokenTotal + rbAmount;
        IRBToken(_pool.cToken).rebase(cTokenTotal);
    }

    /**
     * @notice End the pool
     * @return True if the pool ended successfully
     */
    function endPool() external nonReentrant returns (bool) {
        if (block.timestamp <= _pool.endTime || _pool.endPrice > 0) revert E_PoolEnd();
        _pool.endTime = block.timestamp;
        _pool.endPrice = _getCurPrice(_pool.asset);
        IDoublerFactory(_factory).mintReward(_pool.asset, _pool.id, msg.sender, 10000 ether);
        emit EndPool(_pool.asset, _pool.id, block.timestamp, _pool.endPrice);
        return true;
    }
}

// SPDX-License-Identifier: BUSL-1.1
pragma solidity ^0.8.20;

/**
 * @title IDoubler
 * @dev Interface for the Doubler contract, including custom errors, structures, and event definitions.
 */
interface IDoubler {
    // Custom errors
    error E_Asset(); // Error for invalid asset operations
    error E_Disable(); // Error for disabled actions due to pool conditions
    error E_PoolEnd(); // Error indicating the pool has ended
    error E_FeeLimit(); // Error for exceeding fee limits
    error E_ZeroAddr(); // Error for zero address inputs
    error E_Balance(); // Error for insufficient balance
    error E_InputLimit(); // Error for input limit violations
    error E_Expected(); // Error for unmet expected conditions in slippage
    error E_SlipLimit(); // Error for exceeding slippage limit
    error E_BlockOnce(); // Error for multiple calls in the same block
    error E_WithdrawLimit(); // Error for exceeding withdraw limits
    error E_EndTime(); // Error for invalid end time settings
    error E_PriceLimit(); // Error for price limit violations
    error E_Ownable(); // Error for unauthorized access by non-owner

    // Structure for Pool information
    struct Pool {
        bool isNative; // Indicates if the asset is a native token (e.g., ETH)
        uint16 inputFee; // Fee percentage for inputs
        uint16 withdrawFee; // Fee percentage for withdrawals
        uint256 id; // Pool identifier
        uint256 lastPrice; // Last recorded price
        uint256 cLastRbTime; // Last rebalance time for cToken
        uint256 lowerOfInputMaximum; // Lower bound of input maximum limit
        uint256 endPrice; // Final price when the pool ends
        uint256 startTime; // Pool start time
        uint256 lastDayRate; // Last daily inflation rate
        uint256 endTime; // Pool end time
        address asset; // Address of the asset
        address cToken; // Address of the cToken
        address bToken; // Address of the bToken
        address creator; // Address of the pool creator
    }

    // Structure for modified pool parameters
    struct MPool {
        uint16 inputFee; // Fee percentage for inputs
        uint16 withdrawFee; // Fee percentage for withdrawals
        uint256 endTime; // New end time for the pool
        address creator; // Address of the pool creator
    }

    // Structure for withdrawal parameters
    struct WithdrawParam {
        address asset; // Address of the asset to withdraw
        uint256 cAmount; // Amount of cToken to withdraw
        uint256 qAmount; // Expected quantity of the asset to withdraw
        uint16 clientSlip; // Client slip percentage for slippage tolerance
    }

    // Events
    event Input(
        address indexed asset,
        uint256 indexed poolId,
        address to,
        uint256 qAmount,
        uint256 bAmount,
        uint256 cAmount,
        uint256 extBAmount
    );

    event Withdraw(
        address indexed asset,
        uint256 indexed poolId,
        address to,
        uint256 cAmount,
        uint256 bAmount,
        uint256 assetAmount
    );

    event UpdatePool(address indexed asset, address creator, uint16 inputFee, uint16 withdrawFee, uint256 endTime);
    event UpdateLowerOfInputMaximum(uint256 oldInputLowerOfMaximum, uint256 newInputLowerOfMaximum);
    event EndPool(address asset, uint256 poolId, uint256 endTime, uint256 endPrice);
    event PoolStream(
        address asset,
        uint256 poolId,
        uint256 qAmount,
        uint256 bTotal,
        uint256 cTotal,
        uint256 curPrice,
        uint256 avg
    );
    // Functions
    function getUserExtraBToken(address _to) external view returns(uint256);
    function updatePool(MPool calldata _updatePool) external;
    function inputEth(uint256 _qAmount, address _to) external payable;
    function input(uint256 _qAmount, address _to) external;
    function withdraw(uint256 _cAmount, uint256 _qAmount, uint16 _clientSlip) external;
    function claim() external;
    function getPool() external view returns (Pool memory pool);
    function rebaseCToken() external;
    function endPool() external returns (bool);
}

// SPDX-License-Identifier: BUSL-1.1
pragma solidity ^0.8.20;

/**
 * @title IDoublerFactory
 * @dev Interface for the DoublerFactory contract, including custom errors, structures, and event definitions.
 */
interface IDoublerFactory {
    // Custom errors
    error E_Minter(); // Error for unauthorized minting actions
    error E_Initialized(); // Error indicating the contract has already been initialized
    error E_ZeroAddr(); // Error for zero address inputs
    error E_EndTime(); // Error for invalid end time settings
    error E_PoolId();

    // Structure for adding a new pool
    struct AddPool {
        uint16 inputFee; // Fee percentage for inputs
        uint16 withdrawFee; // Fee percentage for withdrawals
        uint256 lowerOfInputMaximum; // Lower bound of input maximum limit
        address asset; // Address of the asset
        uint256 poolId; // Pool identifier
        uint256 startTime; // Pool start time
        uint256 endTime; // Pool end time
        address creator; // Address of the pool creator
        string namePre; // Prefix for the pool's token name
        string symbolPre; // Prefix for the pool's token symbol
    }

    event NewPool(address indexed asset, uint256 poolId, address pool, address cToken, address bToken);
    event MintReward(address _asset, uint256 _poolId, address _to, uint256 _amount);
    event UpdateEcoAddr(address ecoAddr, address newEcoAddr);

    function newPool(AddPool calldata _addPool) external;
    function mintReward(address _asset, uint256 _poolId, address _to, uint256 _amount) external;
    function getFastPriceFeed() external view returns (address);
    function getFactoryOwner() external view returns (address);
    function getWethAddr() external view returns (address);
    function getEcoAddr() external view returns (address);
    function getLatestPoolId(address _asset) external view returns (uint256);
    function getPoolAddr(address _asset, uint256 _poolId) external view returns (address);
    function getRewardAddr() external view returns (address);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/extensions/IERC20Metadata.sol)

pragma solidity ^0.8.20;

import {IERC20} from "../IERC20.sol";

/**
 * @dev Interface for the optional metadata functions from the ERC20 standard.
 */
interface IERC20Metadata is IERC20 {
    /**
     * @dev Returns the name of the token.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the symbol of the token.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the decimals places of the token.
     */
    function decimals() external view returns (uint8);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/extensions/IERC20Permit.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC20 Permit extension allowing approvals to be made via signatures, as defined in
 * https://eips.ethereum.org/EIPS/eip-2612[EIP-2612].
 *
 * Adds the {permit} method, which can be used to change an account's ERC20 allowance (see {IERC20-allowance}) by
 * presenting a message signed by the account. By not relying on {IERC20-approve}, the token holder account doesn't
 * need to send a transaction, and thus is not required to hold Ether at all.
 *
 * ==== Security Considerations
 *
 * There are two important considerations concerning the use of `permit`. The first is that a valid permit signature
 * expresses an allowance, and it should not be assumed to convey additional meaning. In particular, it should not be
 * considered as an intention to spend the allowance in any specific way. The second is that because permits have
 * built-in replay protection and can be submitted by anyone, they can be frontrun. A protocol that uses permits should
 * take this into consideration and allow a `permit` call to fail. Combining these two aspects, a pattern that may be
 * generally recommended is:
 *
 * ```solidity
 * function doThingWithPermit(..., uint256 value, uint256 deadline, uint8 v, bytes32 r, bytes32 s) public {
 *     try token.permit(msg.sender, address(this), value, deadline, v, r, s) {} catch {}
 *     doThing(..., value);
 * }
 *
 * function doThing(..., uint256 value) public {
 *     token.safeTransferFrom(msg.sender, address(this), value);
 *     ...
 * }
 * ```
 *
 * Observe that: 1) `msg.sender` is used as the owner, leaving no ambiguity as to the signer intent, and 2) the use of
 * `try/catch` allows the permit to fail and makes the code tolerant to frontrunning. (See also
 * {SafeERC20-safeTransferFrom}).
 *
 * Additionally, note that smart contract wallets (such as Argent or Safe) are not able to produce permit signatures, so
 * contracts should have entry points that don't rely on permit.
 */
interface IERC20Permit {
    /**
     * @dev Sets `value` as the allowance of `spender` over ``owner``'s tokens,
     * given ``owner``'s signed approval.
     *
     * IMPORTANT: The same issues {IERC20-approve} has related to transaction
     * ordering also apply here.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `deadline` must be a timestamp in the future.
     * - `v`, `r` and `s` must be a valid `secp256k1` signature from `owner`
     * over the EIP712-formatted function arguments.
     * - the signature must use ``owner``'s current nonce (see {nonces}).
     *
     * For more information on the signature format, see the
     * https://eips.ethereum.org/EIPS/eip-2612#specification[relevant EIP
     * section].
     *
     * CAUTION: See Security Considerations above.
     */
    function permit(
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external;

    /**
     * @dev Returns the current nonce for `owner`. This value must be
     * included whenever a signature is generated for {permit}.
     *
     * Every successful call to {permit} increases ``owner``'s nonce by one. This
     * prevents a signature from being used multiple times.
     */
    function nonces(address owner) external view returns (uint256);

    /**
     * @dev Returns the domain separator used in the encoding of the signature for {permit}, as defined by {EIP712}.
     */
    // solhint-disable-next-line func-name-mixedcase
    function DOMAIN_SEPARATOR() external view returns (bytes32);
}

// SPDX-License-Identifier: BUSL-1.1
pragma solidity ^0.8.20;

/// @title Fast Price Feed Interface
/// @notice Provides interface for the fast price feed functionality, allowing for efficient price updates and access.
interface IFastPriceFeed {
    error E_PriceLimits();
    error E_ZeroAddr();
    error E_AssetSupported();
    error E_AssetExist();
    error E_PlanExist();
    error E_Switch();
    error E_PlanNotExist();
    error E_TimeLimit();
    error E_PriceRange();
    error E_InitOracle();
    error E_TwapInterval();

    /// @dev Enum representing the various types of price feed plans.
    enum Plan {
        DEX, // Decentralized Exchange
        CHAINLINK // Chainlink Oracle
    }

    struct PriceFeed {
        Plan plan;
        address oracleAddr;
        uint32 timeLimit; // dex: twapIntervals, other: ttl
        uint256 priceMin; // Minimum price
        uint256 priceMax; // Maximum price
    }

    event SetAssetTimeLimit(address asset, uint256 oldTimeLimit, uint256 newTimeLimit);
    event SetPriceLimit(address indexed asset, Plan plan, uint256 priceMin, uint256 priceMax);
    event SetPriceFee(
        address indexed asset,
        Plan plan,
        address oracleAddr,
        uint256 timeLimit,
        uint256 priceMin,
        uint256 priceMax
    );

    function getPrice(address _asset) external view returns (uint256 price);

    function getAssetPlan(address _asset) external view returns (Plan);

    function getPriceFeeds(address _asset, Plan _plan) external view returns (PriceFeed memory);
}

// SPDX-License-Identifier: BUSL-1.1
pragma solidity ^0.8.20;

import '@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol';

/**
 * @title IRBToken
 * @dev Interface for the RBToken contract, extending IERC20Metadata and including custom errors and events.
 */
interface IRBToken is IERC20Metadata {
    // Custom errors
    error E_ZeroAddr(); // Error for zero address
    error E_Rebase(); // Error for rebase operation failure
    error E_AllowanceInvalid(); // Error for invalid allowance
    error E_TransferRBContract(); // Error for transfer to RBToken contract itself
    error E_BalanceInvalid(); // Error for invalid balance
    error E_AmountInvalid(); // Error for invalid amount

    // Events
    event TransferShares(address indexed from, address indexed to, uint256 sharesValue); // Event for shares transfer
    event SharesBurnt(
        address indexed account,
        uint256 preRebaseTokenAmount,
        uint256 postRebaseTokenAmount,
        uint256 sharesAmount
    ); // Event for shares burnt during rebase
    event Rebase(address asset, uint256 originTotalSupply, uint256 newTotalSupply); // Event for rebase operation

    /**
     * @dev Mints new tokens for a recipient.
     * @param _recipient The address of the recipient.
     * @param _tokenAmount The amount of tokens to mint.
     */
    function mint(address _recipient, uint256 _tokenAmount) external;

    /**
     * @dev Mints new tokens with a limit and service fee.
     * @param _recipient The address of the recipient.
     * @param _tokenAmount The amount of tokens to mint.
     * @param _srvFeeAddr The addresses for the service fee.
     * @param _srvFeeRatio The ratio for the service fee.
     */
    function mintWithFee(
        address _recipient,
        uint256 _tokenAmount,
        address[] memory _srvFeeAddr,
        uint16 _srvFeeRatio
    ) external returns (uint256 recipientTokenAmount);

    /**
     * @dev Burns tokens from a specified address.
     * @param _from The address from which to burn tokens.
     * @param _tokenAmount The amount of tokens to burn.
     */
    function burnFrom(address _from, uint256 _tokenAmount) external;

    /**
     * @dev Rebases the pooled tokens to a new total.
     * @param _newTotalSupply The new total of pooled tokens.
     */
    function rebase(uint256 _newTotalSupply) external;

    /**
     * @dev Returns the total shares in the pool.
     */
    function totalShare() external view returns (uint256);

    /**
     * @dev Returns the shares of a specific account.
     * @param _account The address of the account.
     * @return The shares of the account.
     */
    function sharesOf(address _account) external view returns (uint256);

    /**
     * @dev Transfers shares to the recipient and returns the corresponding token amount.
     * @param _recipient The address of the recipient.
     * @param _sharesAmount The amount of shares to transfer.
     * @return The corresponding token amount.
     */
    function transferShares(address _recipient, uint256 _sharesAmount) external returns (uint256);

    /**
     * @dev Transfers shares from the sender to the recipient using an allowance mechanism, and returns the corresponding token amount.
     * @param _sender The address of the sender.
     * @param _recipient The address of the recipient.
     * @param _sharesAmount The amount of shares to transfer.
     * @return The corresponding token amount.
     */
    function transferSharesFrom(address _sender, address _recipient, uint256 _sharesAmount) external returns (uint256);
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

interface IWETH {
    function deposit() external payable;
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/ReentrancyGuard.sol)

pragma solidity ^0.8.20;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant NOT_ENTERED = 1;
    uint256 private constant ENTERED = 2;

    uint256 private _status;

    /**
     * @dev Unauthorized reentrant call.
     */
    error ReentrancyGuardReentrantCall();

    constructor() {
        _status = NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be NOT_ENTERED
        if (_status == ENTERED) {
            revert ReentrancyGuardReentrantCall();
        }

        // Any calls to nonReentrant after this point will fail
        _status = ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = NOT_ENTERED;
    }

    /**
     * @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
     * `nonReentrant` function in the call stack.
     */
    function _reentrancyGuardEntered() internal view returns (bool) {
        return _status == ENTERED;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.20;

import {IERC20} from "../IERC20.sol";
import {IERC20Permit} from "../extensions/IERC20Permit.sol";
import {Address} from "../../../utils/Address.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using Address for address;

    /**
     * @dev An operation with an ERC20 token failed.
     */
    error SafeERC20FailedOperation(address token);

    /**
     * @dev Indicates a failed `decreaseAllowance` request.
     */
    error SafeERC20FailedDecreaseAllowance(address spender, uint256 currentAllowance, uint256 requestedDecrease);

    /**
     * @dev Transfer `value` amount of `token` from the calling contract to `to`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transfer, (to, value)));
    }

    /**
     * @dev Transfer `value` amount of `token` from `from` to `to`, spending the approval given by `from` to the
     * calling contract. If `token` returns no value, non-reverting calls are assumed to be successful.
     */
    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transferFrom, (from, to, value)));
    }

    /**
     * @dev Increase the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 oldAllowance = token.allowance(address(this), spender);
        forceApprove(token, spender, oldAllowance + value);
    }

    /**
     * @dev Decrease the calling contract's allowance toward `spender` by `requestedDecrease`. If `token` returns no
     * value, non-reverting calls are assumed to be successful.
     */
    function safeDecreaseAllowance(IERC20 token, address spender, uint256 requestedDecrease) internal {
        unchecked {
            uint256 currentAllowance = token.allowance(address(this), spender);
            if (currentAllowance < requestedDecrease) {
                revert SafeERC20FailedDecreaseAllowance(spender, currentAllowance, requestedDecrease);
            }
            forceApprove(token, spender, currentAllowance - requestedDecrease);
        }
    }

    /**
     * @dev Set the calling contract's allowance toward `spender` to `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful. Meant to be used with tokens that require the approval
     * to be set to zero before setting it to a non-zero value, such as USDT.
     */
    function forceApprove(IERC20 token, address spender, uint256 value) internal {
        bytes memory approvalCall = abi.encodeCall(token.approve, (spender, value));

        if (!_callOptionalReturnBool(token, approvalCall)) {
            _callOptionalReturn(token, abi.encodeCall(token.approve, (spender, 0)));
            _callOptionalReturn(token, approvalCall);
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We use {Address-functionCall} to perform this call, which verifies that
        // the target address contains contract code and also asserts for success in the low-level call.

        bytes memory returndata = address(token).functionCall(data);
        if (returndata.length != 0 && !abi.decode(returndata, (bool))) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturn} that silents catches all reverts and returns a bool instead.
     */
    function _callOptionalReturnBool(IERC20 token, bytes memory data) private returns (bool) {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We cannot use {Address-functionCall} here since this should return false
        // and not revert is the subcall reverts.

        (bool success, bytes memory returndata) = address(token).call(data);
        return success && (returndata.length == 0 || abi.decode(returndata, (bool))) && address(token).code.length > 0;
    }
}

{
  "compilationTarget": {
    "contracts/Doubler.sol": "Doubler"
  },
  "evmVersion": "paris",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs",
    "useLiteralContent": true
  },
  "optimizer": {
    "enabled": true,
    "runs": 200
  },
  "remappings": []
}