// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/Address.sol)

pragma solidity ^0.8.20;

import {Errors} from "./Errors.sol";

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev There's no code at `target` (it is not a contract).
     */
    error AddressEmptyCode(address target);

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.8.20/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        if (address(this).balance < amount) {
            revert Errors.InsufficientBalance(address(this).balance, amount);
        }

        (bool success, ) = recipient.call{value: amount}("");
        if (!success) {
            revert Errors.FailedCall();
        }
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason or custom error, it is bubbled
     * up by this function (like regular Solidity function calls). However, if
     * the call reverted with no returned reason, this function reverts with a
     * {Errors.FailedCall} error.
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        if (address(this).balance < value) {
            revert Errors.InsufficientBalance(address(this).balance, value);
        }
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and reverts if the target
     * was not a contract or bubbling up the revert reason (falling back to {Errors.FailedCall}) in case
     * of an unsuccessful call.
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata
    ) internal view returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            // only check if target is a contract if the call was successful and the return data is empty
            // otherwise we already know that it was a contract
            if (returndata.length == 0 && target.code.length == 0) {
                revert AddressEmptyCode(target);
            }
            return returndata;
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and reverts if it wasn't, either by bubbling the
     * revert reason or with a default {Errors.FailedCall} error.
     */
    function verifyCallResult(bool success, bytes memory returndata) internal pure returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            return returndata;
        }
    }

    /**
     * @dev Reverts with returndata if present. Otherwise reverts with {Errors.FailedCall}.
     */
    function _revert(bytes memory returndata) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            /// @solidity memory-safe-assembly
            assembly {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert Errors.FailedCall();
        }
    }
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.20;

/**
 * @dev Collection of common custom errors used in multiple contracts
 *
 * IMPORTANT: Backwards compatibility is not guaranteed in future versions of the library.
 * It is recommended to avoid relying on the error API for critical functionality.
 */
library Errors {
    /**
     * @dev The ETH balance of the account is not enough to perform the operation.
     */
    error InsufficientBalance(uint256 balance, uint256 needed);

    /**
     * @dev A call to an address target failed. The target may have reverted.
     */
    error FailedCall();

    /**
     * @dev The deployment failed.
     */
    error FailedDeployment();
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (interfaces/IERC1363.sol)

pragma solidity ^0.8.20;

import {IERC20} from "./IERC20.sol";
import {IERC165} from "./IERC165.sol";

/**
 * @title IERC1363
 * @dev Interface of the ERC-1363 standard as defined in the https://eips.ethereum.org/EIPS/eip-1363[ERC-1363].
 *
 * Defines an extension interface for ERC-20 tokens that supports executing code on a recipient contract
 * after `transfer` or `transferFrom`, or code on a spender contract after `approve`, in a single transaction.
 */
interface IERC1363 is IERC20, IERC165 {
    /*
     * Note: the ERC-165 identifier for this interface is 0xb0202a11.
     * 0xb0202a11 ===
     *   bytes4(keccak256('transferAndCall(address,uint256)')) ^
     *   bytes4(keccak256('transferAndCall(address,uint256,bytes)')) ^
     *   bytes4(keccak256('transferFromAndCall(address,address,uint256)')) ^
     *   bytes4(keccak256('transferFromAndCall(address,address,uint256,bytes)')) ^
     *   bytes4(keccak256('approveAndCall(address,uint256)')) ^
     *   bytes4(keccak256('approveAndCall(address,uint256,bytes)'))
     */

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferAndCall(address to, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @param data Additional data with no specified format, sent in call to `to`.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferAndCall(address to, uint256 value, bytes calldata data) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the allowance mechanism
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param from The address which you want to send tokens from.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferFromAndCall(address from, address to, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the allowance mechanism
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param from The address which you want to send tokens from.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @param data Additional data with no specified format, sent in call to `to`.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferFromAndCall(address from, address to, uint256 value, bytes calldata data) external returns (bool);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens and then calls {IERC1363Spender-onApprovalReceived} on `spender`.
     * @param spender The address which will spend the funds.
     * @param value The amount of tokens to be spent.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function approveAndCall(address spender, uint256 value) external returns (bool);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens and then calls {IERC1363Spender-onApprovalReceived} on `spender`.
     * @param spender The address which will spend the funds.
     * @param value The amount of tokens to be spent.
     * @param data Additional data with no specified format, sent in call to `spender`.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function approveAndCall(address spender, uint256 value, bytes calldata data) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (interfaces/IERC165.sol)

pragma solidity ^0.8.20;

import {IERC165} from "../utils/introspection/IERC165.sol";

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC-20 standard as defined in the ERC.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/extensions/IERC20Metadata.sol)

pragma solidity ^0.8.20;

import {IERC20} from "../IERC20.sol";

/**
 * @dev Interface for the optional metadata functions from the ERC-20 standard.
 */
interface IERC20Metadata is IERC20 {
    /**
     * @dev Returns the name of the token.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the symbol of the token.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the decimals places of the token.
     */
    function decimals() external view returns (uint8);
}

// SPDX-License-Identifier: GPL-3.0
pragma solidity ^0.8.13;

import {IERC20Metadata} from "openzeppelin-contracts/contracts/token/ERC20/extensions/IERC20Metadata.sol";

interface ILeveragedToken is IERC20Metadata {
    event Minted(
        address indexed recipient,
        uint256 baseAssetAmount,
        uint256 leveragedTokenAmount,
        bytes32 indexed referralCode
    );
    event Redeemed(
        address indexed recipient,
        address indexed caller,
        uint256 baseAssetAmount,
        uint256 leveragedTokenAmount,
        bytes32 indexed referralCode
    );
    event MintedAmountIncreased(address indexed user, uint256 amount);
    event Rebalanced(uint256 currentLeverage);
    event PausedSet(bool isPaused);

    error InsufficientAmount();
    error CannotRebalance();
    error RebalanceNotSubmittedDueToSlippage();
    error LeverageUpdatePending();
    error Paused();
    error Inactive();
    error NoMargin();
    error MaxMarketValueExceeded();
    error MaxMarketSizeExceeded();
    error NegativeSize();
    error Liquidatable();

    /**
     * @notice Mints some leveraged tokens to the caller with the given baseAmountIn of the base asset.
     * @dev Requires the price oracle data to be up-to-date
     * @param baseAmountIn The amount of the base asset to mint with.
     * @param minLeveragedTokenAmountOut The minimum amount of leveragedTokens to mint (reverts otherwise).
     * @param recipient The recipient address to mint the leveraged tokens for.
     * @param updateData The price update data.
     * @param referralCode The referral code.
     * @return leveragedTokenAmountOut The amount of leveragedTokens minted.
     */
    function mintFor(
        uint256 baseAmountIn,
        uint256 minLeveragedTokenAmountOut,
        address recipient,
        bytes memory updateData,
        bytes32 referralCode
    ) external returns (uint256 leveragedTokenAmountOut);

    /**
     * @notice Redeems leveragedTokenAmount of the leveraged token and returns the base asset.
     * @dev Requires the price oracle data to be up-to-date
     * @param leveragedTokenAmount The amount of the leveraged token to redeem.
     * @param minBaseAmountReceived The minimum amount of the base asset to receive (reverts otherwise).
     * @param recipient The address that receives the proceeds from redeeming.
     * @param caller The address that inititated the transaction (incl. the caller of a zap swap).
     * @param updateData The price update data.
     * @param referralCode The referral code.
     * @return baseAmountReceived The amount of the base asset received.
     */
    function redeemFor(
        uint256 leveragedTokenAmount,
        uint256 minBaseAmountReceived,
        address recipient,
        address caller,
        bytes memory updateData,
        bytes32 referralCode
    ) external returns (uint256 baseAmountReceived);

    /**
     * @notice Rebalances the position to the target leverage.
     */
    function rebalance() external;

    /**
     * @notice Updates price and then rebalances the position to the target leverage.
     * @param updateData The price update data.
     */
    function rebalanceWithPriceUpdate(bytes memory updateData) external;

    /**
     * @notice Destroys a `value` amount of tokens from the caller.
     * @param value The amount of tokens to burn.
     */
    function burn(uint256 value) external;

    /**
     * @notice Sets if the leveraged token is paused.
     * @dev Only callable by the contract owner.
     * @param newIsPaused If the leveraged token should be paused or not.
     */
    function setIsPaused(bool newIsPaused) external;

    /**
     * @notice Returns the target asset of the leveraged token.
     * @return targetAsset The target asset of the leveraged token.
     */
    function targetAsset() external view returns (string memory targetAsset);

    /**
     * @notice Returns the marketId of the leveraged token.
     * @return marketId The marketId of the leveraged token.
     */
    function marketId() external view returns (uint128 marketId);

    /**
     * @notice Returns the target leverage of the leveraged token.
     * @return targetLeverage The target leverage of the leveraged token.
     */
    function targetLeverage() external view returns (uint256 targetLeverage);

    /**
     * @notice Returns if the leveraged token is long or short.
     * @return isLong `true` if the leveraged token is long and `false` if the leveraged token is short.
     */
    function isLong() external view returns (bool isLong);

    /**
     * @notice Returns if the leveraged token is active,
     * @dev A token is active if it still has some positive exchange rate (i.e. has not been liquidated).
     * @return isActive If the leveraged token is active.
     */
    function isActive() external view returns (bool isActive);

    /**
     * @notice Returns if the leveraged token is paused,
     * @dev If a token is paused, deposits are disabled.
     * @return isPaused If the leveraged token is paused.
     */
    function isPaused() external view returns (bool isPaused);

    /**
     * @notice Returns the Synthetix V3 Account ID of the Leveraged Token.
     * @return accountId The Synthetix V3 Account ID of the Leveraged Token.
     */
    function accountId() external view returns (uint128 accountId);

    /**
     * @notice Returns the minting timestamp for a user.
     * @param user Address to get the minting timestamp for.
     * @return mintedTimestamp Minting timestamp for a user.
     */
    function mintedTimestamp(
        address user
    ) external view returns (uint256 mintedTimestamp);

    /**
     * @notice Returns the rebalance threshold.
     * @dev Represented as a percent in 18 decimals, e.g. 20% = 0.2e18.
     * @return rebalanceThreshold The rebalance threshold.
     */
    function rebalanceThreshold()
        external
        view
        returns (uint256 rebalanceThreshold);

    /**
     * @notice Returns the exchange rate from one leveraged token to one base asset.
     * @dev In 18 decimals.
     * @return exchangeRate The exchange rate.
     */
    function exchangeRate() external view returns (uint256 exchangeRate);

    /**
     * @notice Updates the oracle data and returns the exchange rate from one leveraged token to one base asset.
     * @param updateData The price oracle update data.
     * @dev In 18 decimals.
     * @return exchangeRate The exchange rate.
     */
    function exchangeRate(
        bytes memory updateData
    ) external returns (uint256 exchangeRate);

    /**
     * @notice Returns the expected slippage from making an adjustment to a position.
     * @param baseAmount Margin amount to deposit in units of base asset.
     * @param isDeposit If the adjustment is a deposit.
     * @return slippage Slippage in units of base asset.
     */
    function computePriceImpact(
        uint256 baseAmount,
        bool isDeposit
    ) external view returns (uint256 slippage);

    /**
     * @notice Returns if the leveraged token can be rebalanced.
     * @return canRebalance If the leveraged token can be rebalanced.
     */
    function canRebalance() external view returns (bool canRebalance);

    /**
     * @notice Returns the amount of decaying fee in underlying chargeable for a redemption.
     * @param user Address to compute the fee for.
     * @param ltAmount Amount of leveraged tokens to withdraw.
     * @return fee Fee in underlying chargeable for the redemption.
     */
    function decayingRedemptionFee(
        address user,
        uint256 ltAmount
    ) external view returns (uint256 fee);

    /**
     * @notice Returns if the token has a pending leverage update.
     * @return hasPendingLeverageUpdate Whether the token has a pending leverage update.
     */
    function hasPendingLeverageUpdate()
        external
        view
        returns (bool hasPendingLeverageUpdate);

    /**
     * @notice Returns if the token has an open position.
     * @return hasOpenPosition Whether the token has an open position.
     */
    function hasOpenPosition() external view returns (bool hasOpenPosition);

    /**
     * @notice Returns the total value of the token's position for the market in the Base Asset.
     * @return totalValue The total value of the token's position for the market in the Base Asset.
     */
    function totalValue() external view returns (uint256 totalValue);

    /**
     * @notice Returns the deviation factor from our target leverage.
     * @dev Used for rebalances, if |1 - leverageDeviationFactor| exceeds our `rebalanceThreshold` then a rebalance is triggered.
     * When this factoris below 1, it means we are underleveraged, when it is above 1, it means we are overleveraged.
     * @return leverageDeviationFactor The deviation factor from our target leverage.
     */
    function leverageDeviationFactor()
        external
        view
        returns (uint256 leverageDeviationFactor);

    /**
     * @notice Returns the leverage of the token's position.
     * @return leverage The leverage of the token's position.
     */
    function leverage() external view returns (uint256 leverage);

    /**
     * @notice Returns the notional value of the token's position for the market in the Base Asset.
     * @return notionalValue The notional value of the token's position for the market in the Base Asset.
     */
    function notionalValue() external view returns (uint256 notionalValue);

    /**
     * @notice Returns the initial margin of the tokens's position for the market.
     * This does not take into account any profit or loss
     * @return initialMargin The initial margin of the tokens's position for the market.
     */
    function initialMargin() external view returns (uint256 initialMargin);

    /**
     * @notice Returns the remaining margin of the token's position for the market.
     * @return remainingMargin The remaining margin of the token's position for the market.
     */
    function remainingMargin() external view returns (uint256 remainingMargin);

    /**
     * @notice Returns the price of the target asset.
     * @return assetPrice The price of the target asset.
     */
    function assetPrice() external view returns (uint256 assetPrice);
}

// SPDX-License-Identifier: UNLICENSED
// !! THIS FILE WAS AUTOGENERATED BY abi-to-sol v0.8.0. SEE SOURCE BELOW. !!
pragma solidity ^0.8.4;

interface ISpotMarket {
    error ImplementationIsSterile(address implementation);
    error NoChange();
    error NotAContract(address contr);
    error NotNominated(address addr);
    error Unauthorized(address addr);
    error UpgradeSimulationFailed();
    error ZeroAddress();

    event OwnerChanged(address oldOwner, address newOwner);
    event OwnerNominated(address newOwner);
    event Upgraded(address indexed self, address implementation);

    function acceptOwnership() external;

    function getImplementation() external view returns (address);

    function nominateNewOwner(address newNominatedOwner) external;

    function nominatedOwner() external view returns (address);

    function owner() external view returns (address);

    function renounceNomination() external;

    function simulateUpgradeTo(address newImplementation) external;

    function upgradeTo(address newImplementation) external;

    error FeatureUnavailable(bytes32 which);
    error InvalidMarketOwner();
    error InvalidSynthImplementation(uint256 synthImplementation);
    error MismatchAssociatedSystemKind(bytes32 expected, bytes32 actual);
    error MissingAssociatedSystem(bytes32 id);
    error OnlyMarketOwner(address marketOwner, address sender);
    error OverflowInt256ToUint256();

    event AssociatedSystemSet(
        bytes32 indexed kind,
        bytes32 indexed id,
        address proxy,
        address impl
    );
    event DecayRateUpdated(uint128 indexed marketId, uint256 rate);
    event MarketNominationRenounced(uint128 indexed marketId, address nominee);
    event MarketOwnerChanged(
        uint128 indexed marketId,
        address oldOwner,
        address newOwner
    );
    event MarketOwnerNominated(uint128 indexed marketId, address newOwner);
    event SynthImplementationSet(address synthImplementation);
    event SynthImplementationUpgraded(
        uint256 indexed synthMarketId,
        address indexed proxy,
        address implementation
    );
    event SynthPriceDataUpdated(
        uint256 indexed synthMarketId,
        bytes32 indexed buyFeedId,
        bytes32 indexed sellFeedId,
        uint256 strictStalenessTolerance
    );
    event SynthRegistered(
        uint256 indexed synthMarketId,
        address synthTokenAddress
    );
    event SynthetixSystemSet(
        address synthetix,
        address usdTokenAddress,
        address oracleManager
    );

    function acceptMarketOwnership(uint128 synthMarketId) external;

    function createSynth(
        string memory tokenName,
        string memory tokenSymbol,
        address synthOwner
    ) external returns (uint128 synthMarketId);

    function getAssociatedSystem(
        bytes32 id
    ) external view returns (address addr, bytes32 kind);

    function getMarketOwner(
        uint128 synthMarketId
    ) external view returns (address marketOwner);

    function getNominatedMarketOwner(
        uint128 synthMarketId
    ) external view returns (address marketOwner);

    function getPriceData(
        uint128 synthMarketId
    )
        external
        view
        returns (
            bytes32 buyFeedId,
            bytes32 sellFeedId,
            uint256 strictPriceStalenessTolerance
        );

    function getSynth(
        uint128 marketId
    ) external view returns (address synthAddress);

    function getSynthImpl(
        uint128 marketId
    ) external view returns (address implAddress);

    function initOrUpgradeNft(
        bytes32 id,
        string memory name,
        string memory symbol,
        string memory uri,
        address impl
    ) external;

    function initOrUpgradeToken(
        bytes32 id,
        string memory name,
        string memory symbol,
        uint8 decimals,
        address impl
    ) external;

    function minimumCredit(
        uint128 marketId
    ) external view returns (uint256 lockedAmount);

    function name(
        uint128 marketId
    ) external view returns (string memory marketName);

    function nominateMarketOwner(
        uint128 synthMarketId,
        address newNominatedOwner
    ) external;

    function registerUnmanagedSystem(bytes32 id, address endpoint) external;

    function renounceMarketNomination(uint128 synthMarketId) external;

    function renounceMarketOwnership(uint128 synthMarketId) external;

    function reportedDebt(
        uint128 marketId
    ) external view returns (uint256 reportedDebtAmount);

    function setDecayRate(uint128 marketId, uint256 rate) external;

    function setSynthImplementation(address synthImplementation) external;

    function setSynthetix(address synthetix) external;

    function supportsInterface(
        bytes4 interfaceId
    ) external view returns (bool isSupported);

    function updatePriceData(
        uint128 synthMarketId,
        bytes32 buyFeedId,
        bytes32 sellFeedId,
        uint256 strictPriceStalenessTolerance
    ) external;

    function upgradeSynthImpl(uint128 marketId) external;

    error ExceedsMaxSynthAmount(
        uint256 maxSynthAmount,
        uint256 synthAmountCharged
    );
    error ExceedsMaxUsdAmount(uint256 maxUsdAmount, uint256 usdAmountCharged);
    error InsufficientAmountReceived(uint256 expected, uint256 current);
    error InvalidMarket(uint128 marketId);
    error InvalidPrices();
    error OverflowUint256ToInt256();

    event SynthBought(
        uint256 indexed synthMarketId,
        uint256 synthReturned,
        OrderFees.Data fees,
        uint256 collectedFees,
        address referrer,
        uint256 price
    );
    event SynthSold(
        uint256 indexed synthMarketId,
        uint256 amountReturned,
        OrderFees.Data fees,
        uint256 collectedFees,
        address referrer,
        uint256 price
    );

    function buy(
        uint128 marketId,
        uint256 usdAmount,
        uint256 minAmountReceived,
        address referrer
    ) external returns (uint256 synthAmount, OrderFees.Data memory fees);

    function buyExactIn(
        uint128 marketId,
        uint256 usdAmount,
        uint256 minAmountReceived,
        address referrer
    ) external returns (uint256 synthAmount, OrderFees.Data memory fees);

    function buyExactOut(
        uint128 marketId,
        uint256 synthAmount,
        uint256 maxUsdAmount,
        address referrer
    ) external returns (uint256 usdAmountCharged, OrderFees.Data memory fees);

    function getMarketSkew(
        uint128 marketId
    ) external view returns (int256 marketSkew);

    function quoteBuyExactIn(
        uint128 marketId,
        uint256 usdAmount,
        uint8 stalenessTolerance
    ) external view returns (uint256 synthAmount, OrderFees.Data memory fees);

    function quoteBuyExactOut(
        uint128 marketId,
        uint256 synthAmount,
        uint8 stalenessTolerance
    )
        external
        view
        returns (uint256 usdAmountCharged, OrderFees.Data memory fees);

    function quoteSellExactIn(
        uint128 marketId,
        uint256 synthAmount,
        uint8 stalenessTolerance
    ) external view returns (uint256 returnAmount, OrderFees.Data memory fees);

    function quoteSellExactOut(
        uint128 marketId,
        uint256 usdAmount,
        uint8 stalenessTolerance
    ) external view returns (uint256 synthToBurn, OrderFees.Data memory fees);

    function sell(
        uint128 marketId,
        uint256 synthAmount,
        uint256 minUsdAmount,
        address referrer
    ) external returns (uint256 usdAmountReceived, OrderFees.Data memory fees);

    function sellExactIn(
        uint128 marketId,
        uint256 synthAmount,
        uint256 minAmountReceived,
        address referrer
    ) external returns (uint256 returnAmount, OrderFees.Data memory fees);

    function sellExactOut(
        uint128 marketId,
        uint256 usdAmount,
        uint256 maxSynthAmount,
        address referrer
    ) external returns (uint256 synthToBurn, OrderFees.Data memory fees);

    error IneligibleForCancellation(uint256 timestamp, uint256 expirationTime);
    error InsufficientSharesAmount(uint256 expected, uint256 actual);
    error InvalidAsyncTransactionType(uint8 transactionType);
    error InvalidClaim(uint256 asyncOrderId);
    error InvalidCommitmentAmount(uint256 minimumAmount, uint256 amount);
    error InvalidSettlementStrategy(uint256 settlementStrategyId);
    error OrderAlreadySettled(uint256 asyncOrderId, uint256 settledAt);

    event OrderCancelled(
        uint128 indexed marketId,
        uint128 indexed asyncOrderId,
        AsyncOrderClaim.Data asyncOrderClaim,
        address indexed sender
    );
    event OrderCommitted(
        uint128 indexed marketId,
        uint8 indexed orderType,
        uint256 amountProvided,
        uint128 asyncOrderId,
        address indexed sender,
        address referrer
    );

    function cancelOrder(uint128 marketId, uint128 asyncOrderId) external;

    function commitOrder(
        uint128 marketId,
        uint8 orderType,
        uint256 amountProvided,
        uint256 settlementStrategyId,
        uint256 minimumSettlementAmount,
        address referrer
    ) external returns (AsyncOrderClaim.Data memory asyncOrderClaim);

    function getAsyncOrderClaim(
        uint128 marketId,
        uint128 asyncOrderId
    ) external pure returns (AsyncOrderClaim.Data memory asyncOrderClaim);

    error InvalidVerificationResponse();
    error MinimumSettlementAmountNotMet(uint256 minimum, uint256 actual);
    error OutsideSettlementWindow(
        uint256 timestamp,
        uint256 startTime,
        uint256 expirationTime
    );
    error OverflowUint256ToUint64();
    error SettlementStrategyNotFound(uint8 strategyType);

    event OrderSettled(
        uint128 indexed marketId,
        uint128 indexed asyncOrderId,
        uint256 finalOrderAmount,
        OrderFees.Data fees,
        uint256 collectedFees,
        address indexed settler,
        uint256 price,
        uint8 orderType
    );

    function settleOrder(
        uint128 marketId,
        uint128 asyncOrderId
    ) external returns (uint256 finalOrderAmount, OrderFees.Data memory fees);

    error InvalidSettlementWindowDuration(uint256 duration);

    event SettlementStrategyAdded(
        uint128 indexed synthMarketId,
        uint256 indexed strategyId
    );
    event SettlementStrategySet(
        uint128 indexed synthMarketId,
        uint256 indexed strategyId,
        SettlementStrategy.Data strategy
    );

    function addSettlementStrategy(
        uint128 marketId,
        SettlementStrategy.Data memory strategy
    ) external returns (uint256 strategyId);

    function getSettlementStrategy(
        uint128 marketId,
        uint256 strategyId
    ) external view returns (SettlementStrategy.Data memory settlementStrategy);

    function setSettlementStrategy(
        uint128 marketId,
        uint256 strategyId,
        SettlementStrategy.Data memory strategy
    ) external;

    function setSettlementStrategyEnabled(
        uint128 marketId,
        uint256 strategyId,
        bool enabled
    ) external;

    error FailedTransfer(address from, address to, uint256 value);
    error InvalidCollateralType(address configuredCollateralType);
    error WrapperExceedsMaxAmount(
        uint256 maxWrappableAmount,
        uint256 currentSupply,
        uint256 amountToWrap
    );

    event SynthUnwrapped(
        uint256 indexed synthMarketId,
        uint256 amountUnwrapped,
        OrderFees.Data fees,
        uint256 feesCollected
    );
    event SynthWrapped(
        uint256 indexed synthMarketId,
        uint256 amountWrapped,
        OrderFees.Data fees,
        uint256 feesCollected
    );
    event WrapperSet(
        uint256 indexed synthMarketId,
        address indexed wrapCollateralType,
        uint256 maxWrappableAmount
    );

    function getWrapper(
        uint128 marketId
    )
        external
        view
        returns (address wrapCollateralType, uint256 maxWrappableAmount);

    function setWrapper(
        uint128 marketId,
        address wrapCollateralType,
        uint256 maxWrappableAmount
    ) external;

    function unwrap(
        uint128 marketId,
        uint256 unwrapAmount,
        uint256 minAmountReceived
    )
        external
        returns (uint256 returnCollateralAmount, OrderFees.Data memory fees);

    function wrap(
        uint128 marketId,
        uint256 wrapAmount,
        uint256 minAmountReceived
    ) external returns (uint256 amountToMint, OrderFees.Data memory fees);

    error InvalidCollateralLeverage(uint256);
    error InvalidFeeCollectorInterface(address invalidFeeCollector);
    error InvalidWrapperFees();

    event AsyncFixedFeeSet(
        uint256 indexed synthMarketId,
        uint256 asyncFixedFee
    );
    event AtomicFixedFeeSet(
        uint256 indexed synthMarketId,
        uint256 atomicFixedFee
    );
    event CollateralLeverageSet(
        uint256 indexed synthMarketId,
        uint256 collateralLeverage
    );
    event FeeCollectorSet(uint256 indexed synthMarketId, address feeCollector);
    event MarketSkewScaleSet(uint256 indexed synthMarketId, uint256 skewScale);
    event MarketUtilizationFeesSet(
        uint256 indexed synthMarketId,
        uint256 utilizationFeeRate
    );
    event ReferrerShareUpdated(
        uint128 indexed marketId,
        address referrer,
        uint256 sharePercentage
    );
    event TransactorFixedFeeSet(
        uint256 indexed synthMarketId,
        address transactor,
        uint256 fixedFeeAmount
    );
    event WrapperFeesSet(
        uint256 indexed synthMarketId,
        int256 wrapFee,
        int256 unwrapFee
    );

    function getCollateralLeverage(
        uint128 synthMarketId
    ) external view returns (uint256 collateralLeverage);

    function getCustomTransactorFees(
        uint128 synthMarketId,
        address transactor
    ) external view returns (uint256 fixedFeeAmount);

    function getFeeCollector(
        uint128 synthMarketId
    ) external view returns (address feeCollector);

    function getMarketFees(
        uint128 synthMarketId
    )
        external
        view
        returns (
            uint256 atomicFixedFee,
            uint256 asyncFixedFee,
            int256 wrapFee,
            int256 unwrapFee
        );

    function getMarketSkewScale(
        uint128 synthMarketId
    ) external view returns (uint256 skewScale);

    function getMarketUtilizationFees(
        uint128 synthMarketId
    ) external view returns (uint256 utilizationFeeRate);

    function getReferrerShare(
        uint128 synthMarketId,
        address referrer
    ) external view returns (uint256 sharePercentage);

    function setAsyncFixedFee(
        uint128 synthMarketId,
        uint256 asyncFixedFee
    ) external;

    function setAtomicFixedFee(
        uint128 synthMarketId,
        uint256 atomicFixedFee
    ) external;

    function setCollateralLeverage(
        uint128 synthMarketId,
        uint256 collateralLeverage
    ) external;

    function setCustomTransactorFees(
        uint128 synthMarketId,
        address transactor,
        uint256 fixedFeeAmount
    ) external;

    function setFeeCollector(
        uint128 synthMarketId,
        address feeCollector
    ) external;

    function setMarketSkewScale(
        uint128 synthMarketId,
        uint256 skewScale
    ) external;

    function setMarketUtilizationFees(
        uint128 synthMarketId,
        uint256 utilizationFeeRate
    ) external;

    function setWrapperFees(
        uint128 synthMarketId,
        int256 wrapFee,
        int256 unwrapFee
    ) external;

    function updateReferrerShare(
        uint128 synthMarketId,
        address referrer,
        uint256 sharePercentage
    ) external;

    error ValueAlreadyInSet();
    error ValueNotInSet();

    event FeatureFlagAllowAllSet(bytes32 indexed feature, bool allowAll);
    event FeatureFlagAllowlistAdded(bytes32 indexed feature, address account);
    event FeatureFlagAllowlistRemoved(bytes32 indexed feature, address account);
    event FeatureFlagDeniersReset(bytes32 indexed feature, address[] deniers);
    event FeatureFlagDenyAllSet(bytes32 indexed feature, bool denyAll);

    function addToFeatureFlagAllowlist(
        bytes32 feature,
        address account
    ) external;

    function getDeniers(
        bytes32 feature
    ) external view returns (address[] memory);

    function getFeatureFlagAllowAll(
        bytes32 feature
    ) external view returns (bool);

    function getFeatureFlagAllowlist(
        bytes32 feature
    ) external view returns (address[] memory);

    function getFeatureFlagDenyAll(
        bytes32 feature
    ) external view returns (bool);

    function isFeatureAllowed(
        bytes32 feature,
        address account
    ) external view returns (bool);

    function removeFromFeatureFlagAllowlist(
        bytes32 feature,
        address account
    ) external;

    function setDeniers(bytes32 feature, address[] memory deniers) external;

    function setFeatureFlagAllowAll(bytes32 feature, bool allowAll) external;

    function setFeatureFlagDenyAll(bytes32 feature, bool denyAll) external;
}

interface OrderFees {
    struct Data {
        uint256 fixedFees;
        uint256 utilizationFees;
        int256 skewFees;
        int256 wrapperFees;
    }
}

interface AsyncOrderClaim {
    struct Data {
        uint128 id;
        address owner;
        uint8 orderType;
        uint256 amountEscrowed;
        uint256 settlementStrategyId;
        uint256 commitmentTime;
        uint256 minimumSettlementAmount;
        uint256 settledAt;
        address referrer;
    }
}

interface SettlementStrategy {
    struct Data {
        uint8 strategyType;
        uint256 settlementDelay;
        uint256 settlementWindowDuration;
        address priceVerificationContract;
        bytes32 feedId;
        string url;
        uint256 settlementReward;
        uint256 priceDeviationTolerance;
        uint256 minimumUsdExchangeAmount;
        uint256 maxRoundingLoss;
        bool disabled;
    }
}

// SPDX-License-Identifier: GPL-3.0
pragma solidity ^0.8.13;

import {ISpotMarket} from "../interfaces/synthetix/ISpotMarket.sol";

/**
 * @title IWrapperHelper
 * @dev Interface for the WrapperHelper contract.
 */
interface IWrapperHelper {
    /**
     * @notice Returns the spot market contract.
     * @return spotMarket The spot market contract.
     */
    function spotMarket() external view returns (ISpotMarket spotMarket);

    /**
     * @notice Mints a leveraged token by providing USDC.
     * @param leveragedTokenAddress The address of the leveraged token to mint.
     * @param usdcAmount Amount of USDC (6 decimals) to spend.
     * @param minLeveragedTokenAmountOut Minimum leveraged token units expected.
     * @param updateData Additional data required by the leveraged token (if any).
     * @param referralCode Optional referral code (if any).
     */
    function mintWithUSDC(
        address leveragedTokenAddress,
        uint256 usdcAmount,
        uint256 minLeveragedTokenAmountOut,
        bytes calldata updateData,
        bytes32 referralCode
    ) external returns (uint256);

    /**
     * @notice Redeems a leveraged token back into USDC.
     * @param leveragedTokenAddress The address of the leveraged token to redeem.
     * @param amount Amount of leveraged tokens (18 decimals) to redeem.
     * @param minUsdOut Minimum snxUSD tokens (18 decimals) expected upon redemption.
     * @param updateData Additional data required by the leveraged token (if any).
     * @param referralCode Optional referral code (if any).
     */
    function redeemIntoUSDC(
        address leveragedTokenAddress,
        uint256 amount,
        uint256 minUsdOut,
        bytes calldata updateData,
        bytes32 referralCode
    ) external returns (uint256);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.20;

import {IERC20} from "../IERC20.sol";
import {IERC1363} from "../../../interfaces/IERC1363.sol";
import {Address} from "../../../utils/Address.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC-20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using Address for address;

    /**
     * @dev An operation with an ERC-20 token failed.
     */
    error SafeERC20FailedOperation(address token);

    /**
     * @dev Indicates a failed `decreaseAllowance` request.
     */
    error SafeERC20FailedDecreaseAllowance(address spender, uint256 currentAllowance, uint256 requestedDecrease);

    /**
     * @dev Transfer `value` amount of `token` from the calling contract to `to`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transfer, (to, value)));
    }

    /**
     * @dev Transfer `value` amount of `token` from `from` to `to`, spending the approval given by `from` to the
     * calling contract. If `token` returns no value, non-reverting calls are assumed to be successful.
     */
    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transferFrom, (from, to, value)));
    }

    /**
     * @dev Increase the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 oldAllowance = token.allowance(address(this), spender);
        forceApprove(token, spender, oldAllowance + value);
    }

    /**
     * @dev Decrease the calling contract's allowance toward `spender` by `requestedDecrease`. If `token` returns no
     * value, non-reverting calls are assumed to be successful.
     */
    function safeDecreaseAllowance(IERC20 token, address spender, uint256 requestedDecrease) internal {
        unchecked {
            uint256 currentAllowance = token.allowance(address(this), spender);
            if (currentAllowance < requestedDecrease) {
                revert SafeERC20FailedDecreaseAllowance(spender, currentAllowance, requestedDecrease);
            }
            forceApprove(token, spender, currentAllowance - requestedDecrease);
        }
    }

    /**
     * @dev Set the calling contract's allowance toward `spender` to `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful. Meant to be used with tokens that require the approval
     * to be set to zero before setting it to a non-zero value, such as USDT.
     */
    function forceApprove(IERC20 token, address spender, uint256 value) internal {
        bytes memory approvalCall = abi.encodeCall(token.approve, (spender, value));

        if (!_callOptionalReturnBool(token, approvalCall)) {
            _callOptionalReturn(token, abi.encodeCall(token.approve, (spender, 0)));
            _callOptionalReturn(token, approvalCall);
        }
    }

    /**
     * @dev Performs an {ERC1363} transferAndCall, with a fallback to the simple {ERC20} transfer if the target has no
     * code. This can be used to implement an {ERC721}-like safe transfer that rely on {ERC1363} checks when
     * targeting contracts.
     *
     * Reverts if the returned value is other than `true`.
     */
    function transferAndCallRelaxed(IERC1363 token, address to, uint256 value, bytes memory data) internal {
        if (to.code.length == 0) {
            safeTransfer(token, to, value);
        } else if (!token.transferAndCall(to, value, data)) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Performs an {ERC1363} transferFromAndCall, with a fallback to the simple {ERC20} transferFrom if the target
     * has no code. This can be used to implement an {ERC721}-like safe transfer that rely on {ERC1363} checks when
     * targeting contracts.
     *
     * Reverts if the returned value is other than `true`.
     */
    function transferFromAndCallRelaxed(
        IERC1363 token,
        address from,
        address to,
        uint256 value,
        bytes memory data
    ) internal {
        if (to.code.length == 0) {
            safeTransferFrom(token, from, to, value);
        } else if (!token.transferFromAndCall(from, to, value, data)) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Performs an {ERC1363} approveAndCall, with a fallback to the simple {ERC20} approve if the target has no
     * code. This can be used to implement an {ERC721}-like safe transfer that rely on {ERC1363} checks when
     * targeting contracts.
     *
     * NOTE: When the recipient address (`to`) has no code (i.e. is an EOA), this function behaves as {forceApprove}.
     * Opposedly, when the recipient address (`to`) has code, this function only attempts to call {ERC1363-approveAndCall}
     * once without retrying, and relies on the returned value to be true.
     *
     * Reverts if the returned value is other than `true`.
     */
    function approveAndCallRelaxed(IERC1363 token, address to, uint256 value, bytes memory data) internal {
        if (to.code.length == 0) {
            forceApprove(token, to, value);
        } else if (!token.approveAndCall(to, value, data)) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We use {Address-functionCall} to perform this call, which verifies that
        // the target address contains contract code and also asserts for success in the low-level call.

        bytes memory returndata = address(token).functionCall(data);
        if (returndata.length != 0 && !abi.decode(returndata, (bool))) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturn} that silents catches all reverts and returns a bool instead.
     */
    function _callOptionalReturnBool(IERC20 token, bytes memory data) private returns (bool) {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We cannot use {Address-functionCall} here since this should return false
        // and not revert is the subcall reverts.

        (bool success, bytes memory returndata) = address(token).call(data);
        return success && (returndata.length == 0 || abi.decode(returndata, (bool))) && address(token).code.length > 0;
    }
}

// SPDX-License-Identifier: GPL-3.0
pragma solidity ^0.8.13;

library ScaledNumber {
    uint8 internal constant _DEFAULT_DECIMALS = 18;
    uint256 public constant ONE = 10 ** _DEFAULT_DECIMALS;

    function div(
        uint256 value,
        uint256 divisor
    ) internal pure returns (uint256) {
        return (value * 10 ** _DEFAULT_DECIMALS) / divisor;
    }

    function mul(
        uint256 value,
        uint256 multiplier
    ) internal pure returns (uint256) {
        return (value * multiplier) / 10 ** _DEFAULT_DECIMALS;
    }

    function absSub(uint256 a, uint256 b) internal pure returns (uint256) {
        return a > b ? a - b : b - a;
    }
}

// SPDX-License-Identifier: GPL-3.0
pragma solidity ^0.8.13;

import {IERC20} from "openzeppelin-contracts/contracts/token/ERC20/IERC20.sol";
import {SafeERC20} from "openzeppelin-contracts/contracts/token/ERC20/utils/SafeERC20.sol";

import {ScaledNumber} from "../libraries/ScaledNumber.sol";
import {ILeveragedToken} from "../interfaces/ILeveragedToken.sol";
import {ISpotMarket} from "../interfaces/synthetix/ISpotMarket.sol";

// Import the interface
import {IWrapperHelper} from "../interfaces/IWrapperHelper.sol";

/**
 * @title WrapperHelper
 * @dev Implementation of the IWrapperHelper interface
 */
contract WrapperHelper is IWrapperHelper {
    using SafeERC20 for IERC20;
    using ScaledNumber for uint256;

    // ------------------------------------------------
    //                Constants / Addresses
    // ------------------------------------------------
    uint128 internal constant _SPOT_MARKET_ID = 1;
    uint256 internal constant _USDC_DECIMALS = 6;
    uint256 internal constant _SYNTH_DECIMALS = 18;

    address internal constant _USDC =
        0x833589fCD6eDb6E08f4c7C32D4f71b54bdA02913;
    address internal constant _SUSDC =
        0xC74eA762cF06c9151cE074E6a569a5945b6302E7;
    address internal constant _SNXUSD =
        0x09d51516F38980035153a554c26Df3C6f51a23C3;
    address internal constant _SPOT_MARKET_ADDRESS =
        0x18141523403e2595D31b22604AcB8Fc06a4CaA61;

    // ------------------------------------------------
    //                State Variables
    // ------------------------------------------------
    ISpotMarket public immutable override spotMarket;

    // ------------------------------------------------
    //                   Constructor
    // ------------------------------------------------
    constructor() {
        spotMarket = ISpotMarket(_SPOT_MARKET_ADDRESS);
        IERC20(_USDC).approve(_SPOT_MARKET_ADDRESS, type(uint256).max);
        IERC20(_SUSDC).approve(_SPOT_MARKET_ADDRESS, type(uint256).max);
        IERC20(_SNXUSD).approve(_SPOT_MARKET_ADDRESS, type(uint256).max);
    }

    // ------------------------------------------------
    //             External/Public Functions
    // ------------------------------------------------

    /// @inheritdoc IWrapperHelper
    function mintWithUSDC(
        address leveragedTokenAddress,
        uint256 usdcAmount, // 6 decimals
        uint256 minLeveragedTokenAmountOut,
        bytes calldata updateData,
        bytes32 referralCode
    ) external override returns (uint256) {
        // Convert from 6 decimal USDC to 18 decimal
        uint256 convertedAmount = (usdcAmount * 10 ** _SYNTH_DECIMALS) /
            10 ** _USDC_DECIMALS;

        // Transfer USDC from caller
        IERC20(_USDC).safeTransferFrom(msg.sender, address(this), usdcAmount);

        // Wrap sUSDC from USDC
        spotMarket.wrap(_SPOT_MARKET_ID, usdcAmount, convertedAmount);

        // Sell sUSDC -> snxUSD at a 1:1 (or close) market
        (uint256 snxUsdAmount, ) = spotMarket.sellExactIn(
            _SPOT_MARKET_ID,
            convertedAmount,
            convertedAmount,
            address(0)
        );

        // Approve the leveragedToken to pull snxUSD
        IERC20(_SNXUSD).approve(leveragedTokenAddress, snxUsdAmount);

        // Mint leveraged token for the caller
        return
            ILeveragedToken(leveragedTokenAddress).mintFor(
                snxUsdAmount,
                minLeveragedTokenAmountOut,
                msg.sender,
                updateData,
                referralCode
            );
    }

    /// @inheritdoc IWrapperHelper
    function redeemIntoUSDC(
        address leveragedTokenAddress,
        uint256 amount, // 18 decimals
        uint256 minUsdOut, // 18 decimals
        bytes calldata updateData,
        bytes32 referralCode
    ) external override returns (uint256) {
        // Transfer leveraged tokens from caller
        IERC20(leveragedTokenAddress).safeTransferFrom(
            msg.sender,
            address(this),
            amount
        );

        // Redeem leveraged tokens -> snxUSD
        uint256 amountRecieved = ILeveragedToken(leveragedTokenAddress)
            .redeemFor(
                amount,
                minUsdOut,
                address(this),
                msg.sender,
                updateData,
                referralCode
            );

        // Buy sUSDC with snxUSD at a 1:1 (or close) market
        (uint256 synthAmount, ) = spotMarket.buyExactIn(
            _SPOT_MARKET_ID,
            amountRecieved,
            amountRecieved,
            address(0)
        );

        // Convert from 18 decimal sUSDC to 6 decimal USDC
        uint256 usdcAmount = (synthAmount * 10 ** _USDC_DECIMALS) /
            10 ** _SYNTH_DECIMALS;

        // Unwrap sUSDC into USDC
        spotMarket.unwrap(_SPOT_MARKET_ID, synthAmount, usdcAmount);

        // Finally, transfer USDC back to user
        IERC20(_USDC).safeTransfer(msg.sender, usdcAmount);

        return usdcAmount;
    }
}

{
  "compilationTarget": {
    "src/helpers/WrapperHelper.sol": "WrapperHelper"
  },
  "evmVersion": "cancun",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": true,
    "runs": 200
  },
  "remappings": [
    ":@openzeppelin/contracts-upgradeable/=lib/openzeppelin-contracts-upgradeable/contracts/",
    ":@openzeppelin/contracts/=lib/openzeppelin-contracts/contracts/",
    ":chainlink/=lib/chainlink/contracts/",
    ":ds-test/=lib/forge-std/lib/ds-test/src/",
    ":erc4626-tests/=lib/openzeppelin-contracts-upgradeable/lib/erc4626-tests/",
    ":forge-std/=lib/forge-std/src/",
    ":openzeppelin-contracts-upgradeable/=lib/openzeppelin-contracts-upgradeable/",
    ":openzeppelin-contracts/=lib/openzeppelin-contracts/",
    ":pyth-sdk-solidity/=lib/pyth-sdk-solidity/"
  ]
}