pragma solidity ^0.4.24;

import './Ownable.sol';

contract Administratable is Ownable {
  mapping (address => bool) admins;

  modifier onlyAdmin() {
    require(msg.sender == owner || admins[msg.sender]);
    _;
  }
  
  function addAdmin(address _adminAddr) onlyAdmin public returns (bool success) {
    admins[_adminAddr] = true;
    emit AdminAdded(_adminAddr, msg.sender);
    return true;
  }

  function revokeAdmin(address _adminAddr) onlyAdmin public returns (bool success) {
    require(msg.sender != _adminAddr);
    admins[_adminAddr] = false;
    emit AdminRevoked(_adminAddr, msg.sender);
    return true;
  }
  
  event AdminAdded(address indexed _admin, address indexed _by);
  event AdminRevoked(address indexed _admin, address indexed _by);
}

pragma solidity ^0.4.23;


import "./ERC20Basic.sol";
import "./SafeMath.sol";


/**
 * @title Basic token
 * @dev Basic version of StandardToken, with no allowances.
 */
contract BasicToken is ERC20Basic {
  using SafeMath for uint256;

  mapping(address => uint256) balances;

  uint256 totalSupply_;

  /**
  * @dev total number of tokens in existence
  */
  function totalSupply() public view returns (uint256) {
    return totalSupply_;
  }

  /**
  * @dev transfer token for a specified address
  * @param _to The address to transfer to.
  * @param _value The amount to be transferred.
  */
  function transfer(address _to, uint256 _value) public returns (bool) {
    require(_to != address(0));
    require(_value <= balances[msg.sender]);

    balances[msg.sender] = balances[msg.sender].sub(_value);
    balances[_to] = balances[_to].add(_value);
    emit Transfer(msg.sender, _to, _value);
    return true;
  }

  /**
  * @dev Gets the balance of the specified address.
  * @param _owner The address to query the the balance of.
  * @return An uint256 representing the amount owned by the passed address.
  */
  function balanceOf(address _owner) public view returns (uint256) {
    return balances[_owner];
  }

}

pragma solidity ^0.4.24;

import './Pausable.sol';

contract DividendTokenStore is Pausable {

  function totalSupply() public view returns (uint256);

  function addLock(address _locked) public returns (bool);

  function revokeLock(address _unlocked) public returns (bool);
  
  function balanceOf(address _owner) public view returns (uint256);

  function transfer(address _from, address _to, uint256 _value) public returns (bool);
  
  function () public payable {
    payIn();
  }

  function payIn() public payable returns (bool);
  
  function claimDividends() public returns (uint256);
  
  function claimDividendsFor(address _address) public returns (uint256);
    
  function buyBack() public payable returns (bool);

  function claimBuyBack() public returns (bool);

  function claimBuyBackFor(address _address) public returns (bool);

  function mint(address _to, uint256 _amount) public returns (bool);
  
  event Paid(address indexed _sender, uint256 indexed _period, uint256 amount);

  event Claimed(address indexed _recipient, uint256 indexed _period, uint256 _amount);

  event Locked(address indexed _locked, uint256 indexed _at);

  event Unlocked(address indexed _unlocked, uint256 indexed _at);
}

pragma solidity ^0.4.23;

import "./ERC20Basic.sol";


/**
 * @title ERC20 interface
 * @dev see https://github.com/ethereum/EIPs/issues/20
 */
contract ERC20 is ERC20Basic {
  function allowance(address owner, address spender)
    public view returns (uint256);

  function transferFrom(address from, address to, uint256 value)
    public returns (bool);

  function approve(address spender, uint256 value) public returns (bool);
  event Approval(
    address indexed owner,
    address indexed spender,
    uint256 value
  );
}

pragma solidity ^0.4.23;


/**
 * @title ERC20Basic
 * @dev Simpler version of ERC20 interface
 * @dev see https://github.com/ethereum/EIPs/issues/179
 */
contract ERC20Basic {
  function totalSupply() public view returns (uint256);
  function balanceOf(address who) public view returns (uint256);
  function transfer(address to, uint256 value) public returns (bool);
  event Transfer(address indexed from, address indexed to, uint256 value);
}

pragma solidity ^0.4.24;

import './DividendTokenStore.sol';
import './Administratable.sol';
import './StandardToken.sol';

contract MoriaToken is StandardToken, Administratable {
  
  string public constant name = "MoriaToken";
  string public constant symbol = "MOR";
  uint8 public constant decimals = 18;

  DividendTokenStore public store;
  bool public canDestroy = true;
  bool public minting = true;

  modifier isDestroyable() {
    require(canDestroy);
    _;
  }

  modifier canMint() {
    require(minting);
    _;
  }

  constructor() public {
  }

  function () public payable {
    require(store.payIn.value(msg.value)());
  }

  function totalSupply() public view returns (uint256) {
    return store.totalSupply();
  }

  function balanceOf(address _owner) public view returns (uint256 balance) {
    return store.balanceOf(_owner);
  }

  function transfer(address _to, uint256 _value) public returns (bool) {
    store.transfer(msg.sender, _to, _value);
    emit Transfer(msg.sender, _to, _value);
    return true;
  }

  function transferFrom(address _from, address _to, uint256 _value) public returns (bool) {
    require(_value <= allowed[_from][msg.sender]);
    store.transfer(_from, _to, _value);
    allowed[_from][msg.sender] = allowed[_from][msg.sender].sub(_value);
    emit Transfer(_from, _to, _value);
    return true;
  }

  function pause() public onlyOwner {
    store.pause();
  }

  function unpause() public onlyOwner {
    store.unpause();
  }

  function addLock(address _address) onlyAdmin public returns (bool) {
    return store.addLock(_address);
  }

  function revokeLock(address _address) onlyAdmin public returns (bool) {
    return store.revokeLock(_address);
  }

  function claimDividends() public returns (uint256 amount) {
    return store.claimDividendsFor(msg.sender);
  }

  function claimDividendsFor(address _address) public onlyAdmin returns (uint256 amount) {
    return store.claimDividendsFor(_address);
  }

  function buyBack() public onlyAdmin payable returns (bool) {
    require(store.buyBack.value(msg.value)());
    return true;
  }

  function claimBuyBack() public returns (bool) {
    return claimBuyBackFor(msg.sender);
  }

  function claimBuyBackFor(address _address) public onlyAdmin returns (bool) {
    return claimBuyBackFor(_address);
  }
 
  // admin

  function mint(address _from, address _to, uint256 _amount) public onlyOwner canMint returns (bool) {
    store.mint(_to, _amount);
    emit Transfer(_from, _to, _amount);
  }

  function endMinting() public onlyOwner canMint returns (bool) {
    minting = false;
  }

  function upgradeEvent(address _from, address _to) public onlyAdmin {
    emit Transfer(_from, _to,  store.balanceOf(_to));
  }

  function changeStore(DividendTokenStore _store) public onlyOwner returns (bool) {
    store = _store;
    emit StoreChanged(address(store));
    return true;
  }

  function transferStoreOwnership() public onlyOwner {
    store.transferOwnership(owner);
  }

  function destroyToken() public onlyOwner isDestroyable {
    transferStoreOwnership();
    selfdestruct(owner);
  }

  function disableSelfDestruct() public onlyOwner isDestroyable {
    canDestroy = false;
  } 

  event StoreChanged(address indexed _newStore);
  
}

pragma solidity ^0.4.23;


/**
 * @title Ownable
 * @dev The Ownable contract has an owner address, and provides basic authorization control
 * functions, this simplifies the implementation of "user permissions".
 */
contract Ownable {
  address public owner;


  event OwnershipRenounced(address indexed previousOwner);
  event OwnershipTransferred(
    address indexed previousOwner,
    address indexed newOwner
  );


  /**
   * @dev The Ownable constructor sets the original `owner` of the contract to the sender
   * account.
   */
  constructor() public {
    owner = msg.sender;
  }

  /**
   * @dev Throws if called by any account other than the owner.
   */
  modifier onlyOwner() {
    require(msg.sender == owner);
    _;
  }

  /**
   * @dev Allows the current owner to relinquish control of the contract.
   */
  function renounceOwnership() public onlyOwner {
    emit OwnershipRenounced(owner);
    owner = address(0);
  }

  /**
   * @dev Allows the current owner to transfer control of the contract to a newOwner.
   * @param _newOwner The address to transfer ownership to.
   */
  function transferOwnership(address _newOwner) public onlyOwner {
    _transferOwnership(_newOwner);
  }

  /**
   * @dev Transfers control of the contract to a newOwner.
   * @param _newOwner The address to transfer ownership to.
   */
  function _transferOwnership(address _newOwner) internal {
    require(_newOwner != address(0));
    emit OwnershipTransferred(owner, _newOwner);
    owner = _newOwner;
  }
}

pragma solidity ^0.4.23;


import "./Ownable.sol";


/**
 * @title Pausable
 * @dev Base contract which allows children to implement an emergency stop mechanism.
 */
contract Pausable is Ownable {
  event Pause();
  event Unpause();

  bool public paused = false;


  /**
   * @dev Modifier to make a function callable only when the contract is not paused.
   */
  modifier whenNotPaused() {
    require(!paused);
    _;
  }

  /**
   * @dev Modifier to make a function callable only when the contract is paused.
   */
  modifier whenPaused() {
    require(paused);
    _;
  }

  /**
   * @dev called by the owner to pause, triggers stopped state
   */
  function pause() onlyOwner whenNotPaused public {
    paused = true;
    emit Pause();
  }

  /**
   * @dev called by the owner to unpause, returns to normal state
   */
  function unpause() onlyOwner whenPaused public {
    paused = false;
    emit Unpause();
  }
}

pragma solidity ^0.4.23;


/**
 * @title SafeMath
 * @dev Math operations with safety checks that throw on error
 */
library SafeMath {

  /**
  * @dev Multiplies two numbers, throws on overflow.
  */
  function mul(uint256 a, uint256 b) internal pure returns (uint256 c) {
    // Gas optimization: this is cheaper than asserting 'a' not being zero, but the
    // benefit is lost if 'b' is also tested.
    // See: https://github.com/OpenZeppelin/openzeppelin-solidity/pull/522
    if (a == 0) {
      return 0;
    }

    c = a * b;
    assert(c / a == b);
    return c;
  }

  /**
  * @dev Integer division of two numbers, truncating the quotient.
  */
  function div(uint256 a, uint256 b) internal pure returns (uint256) {
    // assert(b > 0); // Solidity automatically throws when dividing by 0
    // uint256 c = a / b;
    // assert(a == b * c + a % b); // There is no case in which this doesn't hold
    return a / b;
  }

  /**
  * @dev Subtracts two numbers, throws on overflow (i.e. if subtrahend is greater than minuend).
  */
  function sub(uint256 a, uint256 b) internal pure returns (uint256) {
    assert(b <= a);
    return a - b;
  }

  /**
  * @dev Adds two numbers, throws on overflow.
  */
  function add(uint256 a, uint256 b) internal pure returns (uint256 c) {
    c = a + b;
    assert(c >= a);
    return c;
  }
}

pragma solidity ^0.4.23;

import "./BasicToken.sol";
import "./ERC20.sol";


/**
 * @title Standard ERC20 token
 *
 * @dev Implementation of the basic standard token.
 * @dev https://github.com/ethereum/EIPs/issues/20
 * @dev Based on code by FirstBlood: https://github.com/Firstbloodio/token/blob/master/smart_contract/FirstBloodToken.sol
 */
contract StandardToken is ERC20, BasicToken {

  mapping (address => mapping (address => uint256)) internal allowed;


  /**
   * @dev Transfer tokens from one address to another
   * @param _from address The address which you want to send tokens from
   * @param _to address The address which you want to transfer to
   * @param _value uint256 the amount of tokens to be transferred
   */
  function transferFrom(
    address _from,
    address _to,
    uint256 _value
  )
    public
    returns (bool)
  {
    require(_to != address(0));
    require(_value <= balances[_from]);
    require(_value <= allowed[_from][msg.sender]);

    balances[_from] = balances[_from].sub(_value);
    balances[_to] = balances[_to].add(_value);
    allowed[_from][msg.sender] = allowed[_from][msg.sender].sub(_value);
    emit Transfer(_from, _to, _value);
    return true;
  }

  /**
   * @dev Approve the passed address to spend the specified amount of tokens on behalf of msg.sender.
   *
   * Beware that changing an allowance with this method brings the risk that someone may use both the old
   * and the new allowance by unfortunate transaction ordering. One possible solution to mitigate this
   * race condition is to first reduce the spender's allowance to 0 and set the desired value afterwards:
   * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
   * @param _spender The address which will spend the funds.
   * @param _value The amount of tokens to be spent.
   */
  function approve(address _spender, uint256 _value) public returns (bool) {
    allowed[msg.sender][_spender] = _value;
    emit Approval(msg.sender, _spender, _value);
    return true;
  }

  /**
   * @dev Function to check the amount of tokens that an owner allowed to a spender.
   * @param _owner address The address which owns the funds.
   * @param _spender address The address which will spend the funds.
   * @return A uint256 specifying the amount of tokens still available for the spender.
   */
  function allowance(
    address _owner,
    address _spender
   )
    public
    view
    returns (uint256)
  {
    return allowed[_owner][_spender];
  }

  /**
   * @dev Increase the amount of tokens that an owner allowed to a spender.
   *
   * approve should be called when allowed[_spender] == 0. To increment
   * allowed value is better to use this function to avoid 2 calls (and wait until
   * the first transaction is mined)
   * From MonolithDAO Token.sol
   * @param _spender The address which will spend the funds.
   * @param _addedValue The amount of tokens to increase the allowance by.
   */
  function increaseApproval(
    address _spender,
    uint _addedValue
  )
    public
    returns (bool)
  {
    allowed[msg.sender][_spender] = (
      allowed[msg.sender][_spender].add(_addedValue));
    emit Approval(msg.sender, _spender, allowed[msg.sender][_spender]);
    return true;
  }

  /**
   * @dev Decrease the amount of tokens that an owner allowed to a spender.
   *
   * approve should be called when allowed[_spender] == 0. To decrement
   * allowed value is better to use this function to avoid 2 calls (and wait until
   * the first transaction is mined)
   * From MonolithDAO Token.sol
   * @param _spender The address which will spend the funds.
   * @param _subtractedValue The amount of tokens to decrease the allowance by.
   */
  function decreaseApproval(
    address _spender,
    uint _subtractedValue
  )
    public
    returns (bool)
  {
    uint oldValue = allowed[msg.sender][_spender];
    if (_subtractedValue > oldValue) {
      allowed[msg.sender][_spender] = 0;
    } else {
      allowed[msg.sender][_spender] = oldValue.sub(_subtractedValue);
    }
    emit Approval(msg.sender, _spender, allowed[msg.sender][_spender]);
    return true;
  }

}

{
  "compilationTarget": {
    "MoriaToken.sol": "MoriaToken"
  },
  "evmVersion": "byzantium",
  "libraries": {},
  "optimizer": {
    "enabled": true,
    "runs": 200
  },
  "remappings": []
}