// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Context.sol)

pragma solidity ^0.8.0;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (token/ERC20/ERC20.sol)

pragma solidity ^0.8.0;

import "./IERC20.sol";
import "./extensions/IERC20Metadata.sol";
import "../../utils/Context.sol";

/**
 * @dev Implementation of the {IERC20} interface.
 *
 * This implementation is agnostic to the way tokens are created. This means
 * that a supply mechanism has to be added in a derived contract using {_mint}.
 * For a generic mechanism see {ERC20PresetMinterPauser}.
 *
 * TIP: For a detailed writeup see our guide
 * https://forum.openzeppelin.com/t/how-to-implement-erc20-supply-mechanisms/226[How
 * to implement supply mechanisms].
 *
 * We have followed general OpenZeppelin Contracts guidelines: functions revert
 * instead returning `false` on failure. This behavior is nonetheless
 * conventional and does not conflict with the expectations of ERC20
 * applications.
 *
 * Additionally, an {Approval} event is emitted on calls to {transferFrom}.
 * This allows applications to reconstruct the allowance for all accounts just
 * by listening to said events. Other implementations of the EIP may not emit
 * these events, as it isn't required by the specification.
 *
 * Finally, the non-standard {decreaseAllowance} and {increaseAllowance}
 * functions have been added to mitigate the well-known issues around setting
 * allowances. See {IERC20-approve}.
 */
contract ERC20 is Context, IERC20, IERC20Metadata {
    mapping(address => uint256) private _balances;

    mapping(address => mapping(address => uint256)) private _allowances;

    uint256 private _totalSupply;

    string private _name;
    string private _symbol;

    /**
     * @dev Sets the values for {name} and {symbol}.
     *
     * The default value of {decimals} is 18. To select a different value for
     * {decimals} you should overload it.
     *
     * All two of these values are immutable: they can only be set once during
     * construction.
     */
    constructor(string memory name_, string memory symbol_) {
        _name = name_;
        _symbol = symbol_;
    }

    /**
     * @dev Returns the name of the token.
     */
    function name() public view virtual override returns (string memory) {
        return _name;
    }

    /**
     * @dev Returns the symbol of the token, usually a shorter version of the
     * name.
     */
    function symbol() public view virtual override returns (string memory) {
        return _symbol;
    }

    /**
     * @dev Returns the number of decimals used to get its user representation.
     * For example, if `decimals` equals `2`, a balance of `505` tokens should
     * be displayed to a user as `5.05` (`505 / 10 ** 2`).
     *
     * Tokens usually opt for a value of 18, imitating the relationship between
     * Ether and Wei. This is the value {ERC20} uses, unless this function is
     * overridden;
     *
     * NOTE: This information is only used for _display_ purposes: it in
     * no way affects any of the arithmetic of the contract, including
     * {IERC20-balanceOf} and {IERC20-transfer}.
     */
    function decimals() public view virtual override returns (uint8) {
        return 18;
    }

    /**
     * @dev See {IERC20-totalSupply}.
     */
    function totalSupply() public view virtual override returns (uint256) {
        return _totalSupply;
    }

    /**
     * @dev See {IERC20-balanceOf}.
     */
    function balanceOf(address account) public view virtual override returns (uint256) {
        return _balances[account];
    }

    /**
     * @dev See {IERC20-transfer}.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     * - the caller must have a balance of at least `amount`.
     */
    function transfer(address to, uint256 amount) public virtual override returns (bool) {
        address owner = _msgSender();
        _transfer(owner, to, amount);
        return true;
    }

    /**
     * @dev See {IERC20-allowance}.
     */
    function allowance(address owner, address spender) public view virtual override returns (uint256) {
        return _allowances[owner][spender];
    }

    /**
     * @dev See {IERC20-approve}.
     *
     * NOTE: If `amount` is the maximum `uint256`, the allowance is not updated on
     * `transferFrom`. This is semantically equivalent to an infinite approval.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function approve(address spender, uint256 amount) public virtual override returns (bool) {
        address owner = _msgSender();
        _approve(owner, spender, amount);
        return true;
    }

    /**
     * @dev See {IERC20-transferFrom}.
     *
     * Emits an {Approval} event indicating the updated allowance. This is not
     * required by the EIP. See the note at the beginning of {ERC20}.
     *
     * NOTE: Does not update the allowance if the current allowance
     * is the maximum `uint256`.
     *
     * Requirements:
     *
     * - `from` and `to` cannot be the zero address.
     * - `from` must have a balance of at least `amount`.
     * - the caller must have allowance for ``from``'s tokens of at least
     * `amount`.
     */
    function transferFrom(
        address from,
        address to,
        uint256 amount
    ) public virtual override returns (bool) {
        address spender = _msgSender();
        _spendAllowance(from, spender, amount);
        _transfer(from, to, amount);
        return true;
    }

    /**
     * @dev Atomically increases the allowance granted to `spender` by the caller.
     *
     * This is an alternative to {approve} that can be used as a mitigation for
     * problems described in {IERC20-approve}.
     *
     * Emits an {Approval} event indicating the updated allowance.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function increaseAllowance(address spender, uint256 addedValue) public virtual returns (bool) {
        address owner = _msgSender();
        _approve(owner, spender, allowance(owner, spender) + addedValue);
        return true;
    }

    /**
     * @dev Atomically decreases the allowance granted to `spender` by the caller.
     *
     * This is an alternative to {approve} that can be used as a mitigation for
     * problems described in {IERC20-approve}.
     *
     * Emits an {Approval} event indicating the updated allowance.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `spender` must have allowance for the caller of at least
     * `subtractedValue`.
     */
    function decreaseAllowance(address spender, uint256 subtractedValue) public virtual returns (bool) {
        address owner = _msgSender();
        uint256 currentAllowance = allowance(owner, spender);
        require(currentAllowance >= subtractedValue, "ERC20: decreased allowance below zero");
        unchecked {
            _approve(owner, spender, currentAllowance - subtractedValue);
        }

        return true;
    }

    /**
     * @dev Moves `amount` of tokens from `from` to `to`.
     *
     * This internal function is equivalent to {transfer}, and can be used to
     * e.g. implement automatic token fees, slashing mechanisms, etc.
     *
     * Emits a {Transfer} event.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `from` must have a balance of at least `amount`.
     */
    function _transfer(
        address from,
        address to,
        uint256 amount
    ) internal virtual {
        require(from != address(0), "ERC20: transfer from the zero address");
        require(to != address(0), "ERC20: transfer to the zero address");

        _beforeTokenTransfer(from, to, amount);

        uint256 fromBalance = _balances[from];
        require(fromBalance >= amount, "ERC20: transfer amount exceeds balance");
        unchecked {
            _balances[from] = fromBalance - amount;
            // Overflow not possible: the sum of all balances is capped by totalSupply, and the sum is preserved by
            // decrementing then incrementing.
            _balances[to] += amount;
        }

        emit Transfer(from, to, amount);

        _afterTokenTransfer(from, to, amount);
    }

    /** @dev Creates `amount` tokens and assigns them to `account`, increasing
     * the total supply.
     *
     * Emits a {Transfer} event with `from` set to the zero address.
     *
     * Requirements:
     *
     * - `account` cannot be the zero address.
     */
    function _mint(address account, uint256 amount) internal virtual {
        require(account != address(0), "ERC20: mint to the zero address");

        _beforeTokenTransfer(address(0), account, amount);

        _totalSupply += amount;
        unchecked {
            // Overflow not possible: balance + amount is at most totalSupply + amount, which is checked above.
            _balances[account] += amount;
        }
        emit Transfer(address(0), account, amount);

        _afterTokenTransfer(address(0), account, amount);
    }

    /**
     * @dev Destroys `amount` tokens from `account`, reducing the
     * total supply.
     *
     * Emits a {Transfer} event with `to` set to the zero address.
     *
     * Requirements:
     *
     * - `account` cannot be the zero address.
     * - `account` must have at least `amount` tokens.
     */
    function _burn(address account, uint256 amount) internal virtual {
        require(account != address(0), "ERC20: burn from the zero address");

        _beforeTokenTransfer(account, address(0), amount);

        uint256 accountBalance = _balances[account];
        require(accountBalance >= amount, "ERC20: burn amount exceeds balance");
        unchecked {
            _balances[account] = accountBalance - amount;
            // Overflow not possible: amount <= accountBalance <= totalSupply.
            _totalSupply -= amount;
        }

        emit Transfer(account, address(0), amount);

        _afterTokenTransfer(account, address(0), amount);
    }

    /**
     * @dev Sets `amount` as the allowance of `spender` over the `owner` s tokens.
     *
     * This internal function is equivalent to `approve`, and can be used to
     * e.g. set automatic allowances for certain subsystems, etc.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `owner` cannot be the zero address.
     * - `spender` cannot be the zero address.
     */
    function _approve(
        address owner,
        address spender,
        uint256 amount
    ) internal virtual {
        require(owner != address(0), "ERC20: approve from the zero address");
        require(spender != address(0), "ERC20: approve to the zero address");

        _allowances[owner][spender] = amount;
        emit Approval(owner, spender, amount);
    }

    /**
     * @dev Updates `owner` s allowance for `spender` based on spent `amount`.
     *
     * Does not update the allowance amount in case of infinite allowance.
     * Revert if not enough allowance is available.
     *
     * Might emit an {Approval} event.
     */
    function _spendAllowance(
        address owner,
        address spender,
        uint256 amount
    ) internal virtual {
        uint256 currentAllowance = allowance(owner, spender);
        if (currentAllowance != type(uint256).max) {
            require(currentAllowance >= amount, "ERC20: insufficient allowance");
            unchecked {
                _approve(owner, spender, currentAllowance - amount);
            }
        }
    }

    /**
     * @dev Hook that is called before any transfer of tokens. This includes
     * minting and burning.
     *
     * Calling conditions:
     *
     * - when `from` and `to` are both non-zero, `amount` of ``from``'s tokens
     * will be transferred to `to`.
     * - when `from` is zero, `amount` tokens will be minted for `to`.
     * - when `to` is zero, `amount` of ``from``'s tokens will be burned.
     * - `from` and `to` are never both zero.
     *
     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
     */
    function _beforeTokenTransfer(
        address from,
        address to,
        uint256 amount
    ) internal virtual {}

    /**
     * @dev Hook that is called after any transfer of tokens. This includes
     * minting and burning.
     *
     * Calling conditions:
     *
     * - when `from` and `to` are both non-zero, `amount` of ``from``'s tokens
     * has been transferred to `to`.
     * - when `from` is zero, `amount` tokens have been minted for `to`.
     * - when `to` is zero, `amount` of ``from``'s tokens have been burned.
     * - `from` and `to` are never both zero.
     *
     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
     */
    function _afterTokenTransfer(
        address from,
        address to,
        uint256 amount
    ) internal virtual {}
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.6.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `from` to `to` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(
        address from,
        address to,
        uint256 amount
    ) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (token/ERC20/extensions/IERC20Metadata.sol)

pragma solidity ^0.8.0;

import "../IERC20.sol";

/**
 * @dev Interface for the optional metadata functions from the ERC20 standard.
 *
 * _Available since v4.1._
 */
interface IERC20Metadata is IERC20 {
    /**
     * @dev Returns the name of the token.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the symbol of the token.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the decimals places of the token.
     */
    function decimals() external view returns (uint8);
}

// SPDX-License-Identifier: UNLICENSED
pragma solidity ^0.8.17;

import {ERC20} from "@openzeppelin/contracts/token/ERC20/ERC20.sol";
import {IERC20} from "@openzeppelin/contracts/token/ERC20/IERC20.sol";

error NotOwner();
error BalanceLessThanAmount();
error StakingPeriodMismatch();
error ZeroAmount();
error ZeroAddress();
error StakingIdMismatch();
error StakeNotMature();
error StakeAlreadyMature();
error AlreadyClaimed();
error LengthMismatch();
error NonTransferable();
error StakeCompleted();
error NoRewardsToClaim();

contract Stake is ERC20 {
    /*//////////////////////////////////////////////////////////////
                                 EVENTS
    //////////////////////////////////////////////////////////////*/

    event OwnerUpdate(address indexed owner);
    event Withdraw(address indexed tokenAddress, uint256 balance);
    event AddInterestRate(uint8 period, uint96 rate);
    event AddgStfxMultiplier(uint8 period, uint32 multiplier);
    event UpdateBurnPercent(uint32 percent);
    event UpdateBurnAddress(address indexed burnAddress);
    event AddStake(
        address indexed staker, uint256 stakeNumber, uint96 amount, uint96 expiryAmount, uint40 expiryTime, uint8 period
    );
    event Unstake(address indexed staker, uint256[] stakeNumber, uint96 totalTransferAmount, uint96 totalBurnAmount);
    event Claim(
        address indexed staker, uint256[] stakeNumber, uint96 amount, uint96 expiryAmount, uint96 transferAmount
    );
    event ClaimRewards(address indexed staker, uint256[] stakeNumber, uint96 totalRewards);

    /*//////////////////////////////////////////////////////////////
                                 STATE
    //////////////////////////////////////////////////////////////*/

    struct StakingInfo {
        StakingPeriod period;
        uint40 startTime;
        uint40 expiryTime;
        uint96 amount;
        uint96 expiryAmount;
        uint96 claimedAmount;
        uint96 gStfxAmount;
        bool isCompleted;
    }

    enum StakingPeriod {
        MONTH, // 1 months - 30 days
        QUARTER, // 3 months - 90 days
        HALF, // 6 months - 180 days
        YEAR, // 1 year - 365 days
        TWO_YEAR // 2 years - 730 days
    }

    address public owner;

    address public token;

    uint32 public burnPercent;

    address public burnAddress;

    uint96 public totalStaked;

    uint96 public burntToDate;

    uint96 public rewardsToDate;

    mapping(address => StakingInfo[]) public stakingInfo;

    mapping(uint8 => uint96) public interestRate;

    mapping(uint8 => uint32) public gStfxMultiplier;

    /*//////////////////////////////////////////////////////////////
                        CONSTRUCTOR/MODIFIERS
    //////////////////////////////////////////////////////////////*/

    constructor(address _token) ERC20("gSTFX", "gSTFX") {
        owner = msg.sender;
        token = _token;
        burnPercent = 20000; // 20%
        burnAddress = address(0x000000000000000000000000000000000000dEaD);
    }

    modifier onlyOwner() {
        if (msg.sender != owner) revert NotOwner();
        _;
    }

    /*//////////////////////////////////////////////////////////////
                                VIEW
    //////////////////////////////////////////////////////////////*/

    function getNumberOfStakes(address staker) public view returns (uint256) {
        return stakingInfo[staker].length;
    }

    function getAllStakes(address staker) public view returns (StakingInfo[] memory) {
        uint256 length = stakingInfo[staker].length;
        StakingInfo[] memory allStakes = new StakingInfo[](length);
        for (uint256 i = 0; i < length;) {
            allStakes[i] = stakingInfo[staker][i];
            unchecked {
                ++i;
            }
        }
        return allStakes;
    }

    function getStakingInfo(address staker, uint256 n) public view returns (StakingInfo memory) {
        return stakingInfo[staker][n];
    }

    function getIsStakeMature(address staker, uint256 n) public view returns (bool isMature) {
        if (block.timestamp >= stakingInfo[staker][n].expiryTime) isMature = true;
    }

    function getStakeAmount(address staker, uint256[] memory n) public view returns (uint96 amount) {
        if (n.length > getNumberOfStakes(staker)) revert LengthMismatch();
        for (uint256 i = 0; i < n.length;) {
            StakingInfo memory s = stakingInfo[staker][n[i]];
            amount += s.amount;
            unchecked {
                ++i;
            }
        }
    }

    function getExpiryAmount(address staker, uint256[] memory n) public view returns (uint96 expiryAmount) {
        if (n.length > getNumberOfStakes(staker)) revert LengthMismatch();
        for (uint256 i = 0; i < n.length;) {
            StakingInfo memory s = stakingInfo[staker][n[i]];
            expiryAmount += s.expiryAmount;
            unchecked {
                ++i;
            }
        }
    }

    function getClaimedAmount(address staker, uint256[] memory n) public view returns (uint96 claimedAmount) {
        if (n.length > getNumberOfStakes(staker)) revert LengthMismatch();
        for (uint256 i = 0; i < n.length;) {
            StakingInfo memory s = stakingInfo[staker][n[i]];
            claimedAmount += s.claimedAmount;
            unchecked {
                ++i;
            }
        }
    }

    function getAccruedRewards(address staker, uint256[] memory n) public view returns (uint96 claimableAmount) {
        if (n.length > getNumberOfStakes(staker)) revert LengthMismatch();
        for (uint256 i = 0; i < n.length;) {
            StakingInfo memory s = stakingInfo[staker][n[i]];
            if (s.isCompleted) {
                claimableAmount += 0;
            } else {
                if (block.timestamp >= s.expiryTime) {
                    claimableAmount += uint96(s.expiryAmount - s.amount);
                } else {
                    claimableAmount += uint96(
                        ((s.expiryAmount - s.amount) * (block.timestamp - s.startTime)) / (s.expiryTime - s.startTime)
                    );
                }
            }
            unchecked {
                ++i;
            }
        }
    }

    function getBurnAmount(address staker, uint256[] memory n) public view returns (uint96 burnAmount) {
        if (n.length > getNumberOfStakes(staker)) revert LengthMismatch();
        for (uint256 i = 0; i < n.length;) {
            StakingInfo memory s = stakingInfo[staker][n[i]];
            if ((block.timestamp >= s.expiryTime) || s.isCompleted) {
                burnAmount += 0;
            } else {
                burnAmount += uint96(
                    (uint256(burnPercent) * s.amount * (s.expiryTime - block.timestamp))
                        / (uint256(s.expiryTime - s.startTime) * 100000)
                );
            }
            unchecked {
                ++i;
            }
        }
    }

    function getAccruedRewardsPerStake(address staker, uint256 n) public view returns (uint96 claimableAmount) {
        StakingInfo memory s = stakingInfo[staker][n];
        if (s.isCompleted) {
            claimableAmount = 0;
        } else {
            if (block.timestamp >= s.expiryTime) {
                claimableAmount = uint96(s.expiryAmount - s.amount);
            } else {
                claimableAmount = uint96(
                    ((s.expiryAmount - s.amount) * (block.timestamp - s.startTime)) / (s.expiryTime - s.startTime)
                );
            }
        }
    }

    function getBurnAmountPerStake(address staker, uint256 n) public view returns (uint96 burnAmount) {
        StakingInfo memory s = stakingInfo[staker][n];
        if ((block.timestamp >= s.expiryTime) || s.isCompleted) {
            burnAmount = 0;
        } else {
            burnAmount = uint96(
                (uint256(burnPercent) * s.amount * (s.expiryTime - block.timestamp))
                    / (uint256(s.expiryTime - s.startTime) * 100000)
            );
        }
    }

    function getStats() public view returns (uint96, uint96, uint96) {
        return (totalStaked, rewardsToDate, burntToDate);
    }

    function getStatsPerStaker(address staker)
        public
        view
        returns (uint96 amount, uint96 expiryAmount, uint96 claimedAmount, uint96 accruedRewards)
    {
        uint256 length = getNumberOfStakes(staker);
        for (uint256 i = 0; i < length;) {
            StakingInfo memory s = stakingInfo[staker][i];
            amount += s.amount;
            expiryAmount += s.expiryAmount;
            claimedAmount += s.claimedAmount;
            accruedRewards += getAccruedRewardsPerStake(staker, i);
            unchecked {
                ++i;
            }
        }
    }

    function getIdsForClaimRewards(address staker) public view returns (uint256[] memory n) {
        uint256 length = getNumberOfStakes(staker);
        for (uint256 i = 0; i < length;) {
            StakingInfo memory s = stakingInfo[staker][i];
            if (!s.isCompleted && (block.timestamp < s.expiryTime)) {
                assembly {
                    let currentLength := mload(n)
                    mstore(n, add(currentLength, 1))
                    mstore(add(n, mul(add(currentLength, 1), 32)), i)
                }
            }
            unchecked {
                ++i;
            }
        }
    }

    /*//////////////////////////////////////////////////////////////
                                SETTERS
    //////////////////////////////////////////////////////////////*/

    function setOwner(address newOwner) external onlyOwner {
        if (newOwner == address(0)) revert ZeroAddress();
        owner = newOwner;
        emit OwnerUpdate(newOwner);
    }

    function addInterestRate(StakingPeriod period, uint96 rate) external onlyOwner {
        if (rate < 1) revert ZeroAmount();
        interestRate[uint8(period)] = rate;
        emit AddInterestRate(uint8(period), rate);
    }

    function addgStfxMultiplier(StakingPeriod period, uint32 multiplier) external onlyOwner {
        if (multiplier < 1) revert ZeroAmount();
        gStfxMultiplier[uint8(period)] = multiplier;
        emit AddgStfxMultiplier(uint8(period), multiplier);
    }

    function updateBurnPercent(uint32 percent) external onlyOwner {
        if (percent < 1) revert ZeroAmount();
        burnPercent = percent;
        emit UpdateBurnPercent(percent);
    }

    function updateBurnAddress(address burn) external onlyOwner {
        burnAddress = burn;
        emit UpdateBurnAddress(burn);
    }

    /*//////////////////////////////////////////////////////////////
                                INTERNAL
    //////////////////////////////////////////////////////////////*/

    function _setStakingPeriod(StakingPeriod period) internal view returns (uint40 expiryTime) {
        if (period == StakingPeriod.MONTH) {
            expiryTime = uint40(block.timestamp + 30 days);
        } else if (period == StakingPeriod.QUARTER) {
            expiryTime = uint40(block.timestamp + 90 days);
        } else if (period == StakingPeriod.HALF) {
            expiryTime = uint40(block.timestamp + 180 days);
        } else if (period == StakingPeriod.YEAR) {
            expiryTime = uint40(block.timestamp + 365 days);
        } else if (period == StakingPeriod.TWO_YEAR) {
            expiryTime = uint40(block.timestamp + 730 days);
        } else {
            revert StakingPeriodMismatch();
        }
    }

    function _stake(uint96 amount, StakingPeriod period) internal view returns (StakingInfo memory s) {
        s.startTime = uint40(block.timestamp);
        s.amount = amount;
        s.expiryAmount = uint96(((uint256(amount) * uint256(interestRate[uint8(period)])) / 100e18) + uint256(amount));
        s.period = period;
        s.expiryTime = _setStakingPeriod(period);
        s.gStfxAmount = uint96((uint256(gStfxMultiplier[uint8(period)]) * uint256(s.amount)) / 1000);
    }

    /*//////////////////////////////////////////////////////////////
                                EXTERNAL
    //////////////////////////////////////////////////////////////*/

    /// @notice add a stake with the input amount for the address calling this function
    /// @dev approve has to be called before calling this function
    /// @param amount the amount of tokens the staker wants to stake
    /// @param period the time period from the enum
    function stake(uint96 amount, StakingPeriod period) external {
        if (IERC20(token).balanceOf(msg.sender) < amount) revert BalanceLessThanAmount();
        if (interestRate[uint8(period)] == 0) revert StakingPeriodMismatch();

        StakingInfo memory s = _stake(amount, period);
        stakingInfo[msg.sender].push(s);
        totalStaked += amount;
        uint256 length = stakingInfo[msg.sender].length;

        _mint(msg.sender, s.gStfxAmount);
        IERC20(token).transferFrom(msg.sender, address(this), amount);
        emit AddStake(msg.sender, length - 1, amount, s.expiryAmount, s.expiryTime, uint8(period));
    }

    /// @notice restakes the initial amount with the rewards accrued till now and restakes it for the new time period
    /// @dev the new period has to be more than the existing stake period
    /// @param n the id of the stake
    /// @param period the new period of the stake which can only be more than the existing stake
    function restake(uint256 n, StakingPeriod period) external {
        uint256 length = getNumberOfStakes(msg.sender);
        if (n >= length) revert StakingIdMismatch();

        StakingInfo memory s = getStakingInfo(msg.sender, n);
        if (block.timestamp >= s.expiryTime) revert StakeAlreadyMature();
        if (uint8(period) < uint8(s.period)) revert StakingPeriodMismatch();

        uint96 stakedRewardTillNow = getAccruedRewardsPerStake(msg.sender, n);
        StakingInfo memory sAfterRestake = _stake(s.amount + (stakedRewardTillNow - s.claimedAmount), period);
        stakingInfo[msg.sender][n] = sAfterRestake;
        totalStaked += stakedRewardTillNow - s.claimedAmount;

        _mint(msg.sender, sAfterRestake.gStfxAmount - s.gStfxAmount);

        emit AddStake(
            msg.sender,
            n,
            sAfterRestake.amount,
            sAfterRestake.expiryAmount,
            sAfterRestake.expiryTime,
            uint8(sAfterRestake.period)
        );
    }

    /// @notice unstakes prematurely and transfers `amount + rewards - burnAmount` to the staker
    /// @dev burns `burnPercent` of the remaining amount of stake
    /// @param n array of all the staking ids
    function unstake(uint256[] memory n) external {
        uint256 length = getNumberOfStakes(msg.sender);
        if (n.length > length) revert LengthMismatch();

        uint96 totalRewards;
        uint96 totalTransferAmount;
        uint96 totalBurnAmount;
        uint96 gStfxToBurn;

        for (uint256 i = 0; i < n.length;) {
            if (n[i] >= length) revert StakingIdMismatch();

            StakingInfo memory s = getStakingInfo(msg.sender, n[i]);
            if (block.timestamp >= s.expiryTime) revert StakeAlreadyMature();
            if (s.isCompleted) revert StakeCompleted();

            uint96 accruedRewards = getAccruedRewardsPerStake(msg.sender, n[i]);
            uint96 burnAmount = getBurnAmountPerStake(msg.sender, n[i]);

            totalRewards += accruedRewards - s.claimedAmount;
            totalTransferAmount += (s.amount - burnAmount) + (accruedRewards - s.claimedAmount);
            totalBurnAmount += burnAmount;
            gStfxToBurn += s.gStfxAmount;
            stakingInfo[msg.sender][n[i]].claimedAmount = accruedRewards;
            stakingInfo[msg.sender][n[i]].isCompleted = true;

            unchecked {
                ++i;
            }
        }

        rewardsToDate += totalRewards;
        burntToDate += totalBurnAmount;
        _burn(msg.sender, gStfxToBurn);
        IERC20(token).transfer(msg.sender, totalTransferAmount);
        IERC20(token).transfer(burnAddress, totalBurnAmount);

        emit Unstake(msg.sender, n, totalTransferAmount, totalBurnAmount);
    }

    /// @notice transfers the initial amount with the remaining rewards after the stake matures to the staker
    /// @dev can be called after all the stakes in the array are matured
    /// @param n array of the staking ids
    function claim(uint256[] memory n) external {
        uint96 totalStakeAmount;
        uint96 totalExpiryAmount;
        uint96 transferAmount;
        uint96 gStfxToBurn;
        uint96 totalRewardsToDate;
        uint256 length = getNumberOfStakes(msg.sender);
        if (n.length > length) revert LengthMismatch();

        for (uint256 i = 0; i < n.length;) {
            if (n[i] >= length) revert StakingIdMismatch();

            StakingInfo memory s = getStakingInfo(msg.sender, n[i]);
            if (block.timestamp < s.expiryTime) revert StakeNotMature();
            if (s.isCompleted) revert StakeCompleted();

            totalStakeAmount += s.amount;
            totalExpiryAmount += s.expiryAmount;
            transferAmount += s.expiryAmount - s.claimedAmount;
            totalRewardsToDate += s.expiryAmount - s.amount - s.claimedAmount;
            gStfxToBurn += s.gStfxAmount;
            stakingInfo[msg.sender][n[i]].claimedAmount = s.expiryAmount - s.amount;
            stakingInfo[msg.sender][n[i]].isCompleted = true;

            unchecked {
                ++i;
            }
        }

        rewardsToDate += totalRewardsToDate;
        _burn(msg.sender, gStfxToBurn);
        IERC20(token).transfer(msg.sender, transferAmount);

        emit Claim(msg.sender, n, totalStakeAmount, totalExpiryAmount, transferAmount);
    }

    /// @notice transfers all the eligible rewards of all the stakes in the array to the staker
    /// @param n array of the staking ids
    function claimRewards(uint256[] memory n) external {
        uint256 length = getNumberOfStakes(msg.sender);
        if (n.length > length) revert LengthMismatch();

        uint96 transferAmount;

        for (uint256 i = 0; i < n.length;) {
            if (n[i] >= length) revert StakingIdMismatch();

            StakingInfo memory s = getStakingInfo(msg.sender, n[i]);
            uint96 claimableAmount = getAccruedRewardsPerStake(msg.sender, n[i]);
            if ((s.claimedAmount < claimableAmount) && !s.isCompleted) {
                uint96 claimedAmountTillNow = s.claimedAmount;
                transferAmount += claimableAmount - claimedAmountTillNow;
                stakingInfo[msg.sender][n[i]].claimedAmount = claimableAmount;
            }

            unchecked {
                ++i;
            }
        }

        if (transferAmount == 0) revert NoRewardsToClaim();
        rewardsToDate += transferAmount;
        IERC20(token).transfer(msg.sender, transferAmount);

        emit ClaimRewards(msg.sender, n, transferAmount);
    }

    function withdraw(address tokenAddress) external onlyOwner {
        uint256 balance = IERC20(tokenAddress).balanceOf(address(this));
        IERC20(tokenAddress).transfer(owner, balance);
        emit Withdraw(tokenAddress, balance);
    }

    /*//////////////////////////////////////////////////////////////
                                ERC20
    //////////////////////////////////////////////////////////////*/

    function approve(address, uint256) public virtual override returns (bool) {
        revert NonTransferable();
    }

    function transfer(address, uint256) public virtual override returns (bool) {
        revert NonTransferable();
    }

    function transferFrom(address, address, uint256) public virtual override returns (bool) {
        revert NonTransferable();
    }
}

{
  "compilationTarget": {
    "src/Stake.sol": "Stake"
  },
  "evmVersion": "paris",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": true,
    "runs": 200
  },
  "remappings": [
    ":@openzeppelin-upgradeable/=lib/openzeppelin-contracts-upgradeable/",
    ":@openzeppelin/=lib/openzeppelin-contracts/",
    ":@synthetix/=src/interfaces/synthetix/",
    ":ds-test/=lib/forge-std/lib/ds-test/src/",
    ":forge-std/=lib/forge-std/src/",
    ":openzeppelin-contracts/=lib/openzeppelin-contracts/",
    ":solmate/=lib/solmate/src/"
  ]
}