// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/cryptography/ECDSA.sol)

pragma solidity ^0.8.20;

/**
 * @dev Elliptic Curve Digital Signature Algorithm (ECDSA) operations.
 *
 * These functions can be used to verify that a message was signed by the holder
 * of the private keys of a given address.
 */
library ECDSA {
    enum RecoverError {
        NoError,
        InvalidSignature,
        InvalidSignatureLength,
        InvalidSignatureS
    }

    /**
     * @dev The signature derives the `address(0)`.
     */
    error ECDSAInvalidSignature();

    /**
     * @dev The signature has an invalid length.
     */
    error ECDSAInvalidSignatureLength(uint256 length);

    /**
     * @dev The signature has an S value that is in the upper half order.
     */
    error ECDSAInvalidSignatureS(bytes32 s);

    /**
     * @dev Returns the address that signed a hashed message (`hash`) with `signature` or an error. This will not
     * return address(0) without also returning an error description. Errors are documented using an enum (error type)
     * and a bytes32 providing additional information about the error.
     *
     * If no error is returned, then the address can be used for verification purposes.
     *
     * The `ecrecover` EVM precompile allows for malleable (non-unique) signatures:
     * this function rejects them by requiring the `s` value to be in the lower
     * half order, and the `v` value to be either 27 or 28.
     *
     * IMPORTANT: `hash` _must_ be the result of a hash operation for the
     * verification to be secure: it is possible to craft signatures that
     * recover to arbitrary addresses for non-hashed data. A safe way to ensure
     * this is by receiving a hash of the original message (which may otherwise
     * be too long), and then calling {MessageHashUtils-toEthSignedMessageHash} on it.
     *
     * Documentation for signature generation:
     * - with https://web3js.readthedocs.io/en/v1.3.4/web3-eth-accounts.html#sign[Web3.js]
     * - with https://docs.ethers.io/v5/api/signer/#Signer-signMessage[ethers]
     */
    function tryRecover(bytes32 hash, bytes memory signature) internal pure returns (address, RecoverError, bytes32) {
        if (signature.length == 65) {
            bytes32 r;
            bytes32 s;
            uint8 v;
            // ecrecover takes the signature parameters, and the only way to get them
            // currently is to use assembly.
            /// @solidity memory-safe-assembly
            assembly {
                r := mload(add(signature, 0x20))
                s := mload(add(signature, 0x40))
                v := byte(0, mload(add(signature, 0x60)))
            }
            return tryRecover(hash, v, r, s);
        } else {
            return (address(0), RecoverError.InvalidSignatureLength, bytes32(signature.length));
        }
    }

    /**
     * @dev Returns the address that signed a hashed message (`hash`) with
     * `signature`. This address can then be used for verification purposes.
     *
     * The `ecrecover` EVM precompile allows for malleable (non-unique) signatures:
     * this function rejects them by requiring the `s` value to be in the lower
     * half order, and the `v` value to be either 27 or 28.
     *
     * IMPORTANT: `hash` _must_ be the result of a hash operation for the
     * verification to be secure: it is possible to craft signatures that
     * recover to arbitrary addresses for non-hashed data. A safe way to ensure
     * this is by receiving a hash of the original message (which may otherwise
     * be too long), and then calling {MessageHashUtils-toEthSignedMessageHash} on it.
     */
    function recover(bytes32 hash, bytes memory signature) internal pure returns (address) {
        (address recovered, RecoverError error, bytes32 errorArg) = tryRecover(hash, signature);
        _throwError(error, errorArg);
        return recovered;
    }

    /**
     * @dev Overload of {ECDSA-tryRecover} that receives the `r` and `vs` short-signature fields separately.
     *
     * See https://eips.ethereum.org/EIPS/eip-2098[EIP-2098 short signatures]
     */
    function tryRecover(bytes32 hash, bytes32 r, bytes32 vs) internal pure returns (address, RecoverError, bytes32) {
        unchecked {
            bytes32 s = vs & bytes32(0x7fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffff);
            // We do not check for an overflow here since the shift operation results in 0 or 1.
            uint8 v = uint8((uint256(vs) >> 255) + 27);
            return tryRecover(hash, v, r, s);
        }
    }

    /**
     * @dev Overload of {ECDSA-recover} that receives the `r and `vs` short-signature fields separately.
     */
    function recover(bytes32 hash, bytes32 r, bytes32 vs) internal pure returns (address) {
        (address recovered, RecoverError error, bytes32 errorArg) = tryRecover(hash, r, vs);
        _throwError(error, errorArg);
        return recovered;
    }

    /**
     * @dev Overload of {ECDSA-tryRecover} that receives the `v`,
     * `r` and `s` signature fields separately.
     */
    function tryRecover(
        bytes32 hash,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) internal pure returns (address, RecoverError, bytes32) {
        // EIP-2 still allows signature malleability for ecrecover(). Remove this possibility and make the signature
        // unique. Appendix F in the Ethereum Yellow paper (https://ethereum.github.io/yellowpaper/paper.pdf), defines
        // the valid range for s in (301): 0 < s < secp256k1n ÷ 2 + 1, and for v in (302): v ∈ {27, 28}. Most
        // signatures from current libraries generate a unique signature with an s-value in the lower half order.
        //
        // If your library generates malleable signatures, such as s-values in the upper range, calculate a new s-value
        // with 0xFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFEBAAEDCE6AF48A03BBFD25E8CD0364141 - s1 and flip v from 27 to 28 or
        // vice versa. If your library also generates signatures with 0/1 for v instead 27/28, add 27 to v to accept
        // these malleable signatures as well.
        if (uint256(s) > 0x7FFFFFFFFFFFFFFFFFFFFFFFFFFFFFFF5D576E7357A4501DDFE92F46681B20A0) {
            return (address(0), RecoverError.InvalidSignatureS, s);
        }

        // If the signature is valid (and not malleable), return the signer address
        address signer = ecrecover(hash, v, r, s);
        if (signer == address(0)) {
            return (address(0), RecoverError.InvalidSignature, bytes32(0));
        }

        return (signer, RecoverError.NoError, bytes32(0));
    }

    /**
     * @dev Overload of {ECDSA-recover} that receives the `v`,
     * `r` and `s` signature fields separately.
     */
    function recover(bytes32 hash, uint8 v, bytes32 r, bytes32 s) internal pure returns (address) {
        (address recovered, RecoverError error, bytes32 errorArg) = tryRecover(hash, v, r, s);
        _throwError(error, errorArg);
        return recovered;
    }

    /**
     * @dev Optionally reverts with the corresponding custom error according to the `error` argument provided.
     */
    function _throwError(RecoverError error, bytes32 errorArg) private pure {
        if (error == RecoverError.NoError) {
            return; // no error: do nothing
        } else if (error == RecoverError.InvalidSignature) {
            revert ECDSAInvalidSignature();
        } else if (error == RecoverError.InvalidSignatureLength) {
            revert ECDSAInvalidSignatureLength(uint256(errorArg));
        } else if (error == RecoverError.InvalidSignatureS) {
            revert ECDSAInvalidSignatureS(errorArg);
        }
    }
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.26;

import "@openzeppelin/contracts/access/Ownable.sol";
import "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import "@openzeppelin/contracts/utils/cryptography/ECDSA.sol";
import "@openzeppelin/contracts/utils/Pausable.sol";

interface IClankerToken {
    function name() external returns (string memory);
    function symbol() external returns (string memory);
    function fid() external returns (uint256);
    function deployer() external returns (address);
    function image() external returns (string memory);
    function castHash() external returns (string memory);
}

interface IERC20Mintable {
    function mint(address to, uint256 amount) external;
}

contract HelloClankerViralGiftFactory is Ownable, Pausable {
    uint256 public constant BASE_DECIMAL = 1e18;
    address private verifyAccount;
    address public feeTo;
    IERC20Mintable public hcToken; 

    uint256 public referralRatio = 0.1 * 1e18;    // 10%
    uint256 public feeRatio = 0.01 * 1e18;    // 1%

    uint256 public createIncentive = 50000 * 1e18;
    uint256 public claimIncentive = 20000 * 1e18;
    uint256 public referralIncentive = 20000 * 1e18;
    uint256 public referralForCreatorIncentive = 10000 * 1e18;

    struct ViralGiftInfo {
        IERC20 token;
        uint256 totalAmount;
        uint256 remainAmount;
        uint256 perClaimAmount;
        uint256 perReferralRewards;
        uint256 starttime;
        uint256 fid;
        address account;
        mapping(uint256 => address) claimFids;
    }

    uint256 public expiration_time = 30 days;
    uint256 public globalIndex;

    mapping(uint256 => ViralGiftInfo) public viralGifts;

    event NewViralGift(
        uint256 index,
        IERC20 _token,
        uint256 _totalAmount,
        uint256 _perClaimAmount,
        uint256 _perReferralRewards,
        uint256 _fid,
        address _account,
        string _memo,
        uint256 incentive
    );

    event Claim(
        uint256 index,
        IERC20 _token,
        uint256 _claimAmount,
        uint256 _fid,
        address _account,
        uint256 _referralFid,
        uint256 _referralRewards,
        uint256 _claimIncentive,
        uint256 _referralIncentive,
        uint256 _referralForCreatorIncentive
    );

    event GetBack(
        uint256 index,
        IERC20 _token,
        uint256 _claimAmount,
        uint256 _fid,
        address _account
    );

    // ADMIN
    event NewReferralRatio(uint256 _oldRatio, uint256 _newRatio);

    event NewVerifyAccount(address _oldAddr, address _newAddr);

    event NewFee(address _feeTo, uint256 _feeRatio);

    event NewIncentive(uint256 _createIncentive, uint256 _claimIncentive, uint256 _referralIncentive);

    modifier onlyEOA() {
        require(
            tx.origin == msg.sender,
            "HelloClankerViralGiftFactory: Only EOA."
        );
        _;
    }

    modifier onlyFromFrame(uint256 _fid, bytes memory _sig) {
        require(
            _verifyRequest(_fid, _sig),
            "HelloClankerViralGiftFactory: Not From Frame."
        );
        _;
    }

    constructor() Ownable(msg.sender) {}

    function setReferralRatio(uint256 _referralRatio) external onlyOwner {
        uint256 oldReferralRatio = referralRatio;
        referralRatio = _referralRatio;

        emit NewReferralRatio(oldReferralRatio, _referralRatio);
    }

    function setVerifyAccount(address _verifyAccount) external onlyOwner {
        address oldVerifyAccount = verifyAccount;
        verifyAccount = _verifyAccount;

        emit NewVerifyAccount(oldVerifyAccount, _verifyAccount);
    }

    function setFee(address _feeTo, uint256 _feeRatio) external onlyOwner {
        feeTo = _feeTo;
        feeRatio = _feeRatio;

        emit NewFee(_feeTo, _feeRatio);
    }

    function setHCToken(IERC20Mintable _hcToken) external onlyOwner {
        hcToken = _hcToken;
    }

    function setNewIncentive(uint256 _createIncentive, uint256 _claimIncentive, uint256 _referralIncentive) external onlyOwner {
        createIncentive = _createIncentive;
        claimIncentive = _claimIncentive;
        referralIncentive = _referralIncentive;
    }

    function pause() external onlyOwner {
        _pause();
    }

    function unpause() external onlyOwner {
        _unpause();
    }

    function createViralGift(
        IERC20 _token,
        uint256 _totalAmount,
        uint256 _perClaimAmount,
        uint256 _fid,
        string memory _memo,
        bytes memory _sig
    ) external onlyEOA onlyFromFrame(_fid, _sig) whenNotPaused {
        require(_fid > 0, "Invalid fid.");
        ViralGiftInfo storage targetViralGift = viralGifts[globalIndex];

        _token.transferFrom(msg.sender, address(this), _totalAmount);

        targetViralGift.token = _token;
        targetViralGift.totalAmount = _totalAmount;
        targetViralGift.remainAmount = _totalAmount;
        targetViralGift.perClaimAmount = _perClaimAmount;
        targetViralGift.perReferralRewards = _perClaimAmount * referralRatio / BASE_DECIMAL;
        targetViralGift.starttime = block.timestamp;
        targetViralGift.fid = _fid;
        targetViralGift.account = msg.sender;

        hcToken.mint(msg.sender, createIncentive);
        
        emit NewViralGift(
            globalIndex,
            _token,
            _totalAmount,
            _perClaimAmount,
            targetViralGift.perReferralRewards,
            _fid,
            msg.sender,
            _memo,
            createIncentive
        );

        globalIndex++;
    }

    function claimGift(
        uint256 _fid,
        uint256 _referralFid,
        uint256 _targetIndex,
        bytes memory _sig
    ) external onlyEOA onlyFromFrame(_fid, _sig) whenNotPaused {
        ViralGiftInfo storage targetViralGift = viralGifts[_targetIndex];
        require(targetViralGift.fid > 0, "Not exist viral gift.");
        require(targetViralGift.fid != _fid, "Not allow creater claim the gift.");
        require(_fid > 0, "Invaild fid.");
        require(targetViralGift.claimFids[_fid] == address(0), "Already Claimed.");
        require(_referralFid == 0 || targetViralGift.claimFids[_referralFid] != address(0), "Invaild referral fid.");
        require(
            targetViralGift.starttime + expiration_time > block.timestamp,
            "Expiration."
        );

        if (_referralFid > 0) {
            require(targetViralGift.remainAmount >= targetViralGift.perClaimAmount + targetViralGift.perReferralRewards, "Not enough balance.");
            targetViralGift.token.transfer(targetViralGift.claimFids[_referralFid], targetViralGift.perReferralRewards);
            targetViralGift.remainAmount -= targetViralGift.perReferralRewards;
            hcToken.mint(targetViralGift.claimFids[_referralFid], referralIncentive);

        } else {
            require(targetViralGift.remainAmount >= targetViralGift.perClaimAmount, "Not enough balance.");
        }

        targetViralGift.token.transfer(msg.sender, targetViralGift.perClaimAmount);
        targetViralGift.remainAmount -= targetViralGift.perClaimAmount;

        targetViralGift.claimFids[_fid] = msg.sender;
        hcToken.mint(msg.sender, claimIncentive);
        hcToken.mint(targetViralGift.account, referralForCreatorIncentive);

        emit Claim(
            _targetIndex,
            targetViralGift.token,
            targetViralGift.perClaimAmount,
            _fid,
            msg.sender,
            _referralFid,
            targetViralGift.perReferralRewards,
            claimIncentive,
            referralIncentive,
            referralForCreatorIncentive
        );
    }

    function getBackExpiratedRedPackage(uint256 _targetIndex) external onlyEOA whenNotPaused {
        ViralGiftInfo storage targetViralGift = viralGifts[_targetIndex];
        require(targetViralGift.account == msg.sender, "Not viral gift sender.");
        require(targetViralGift.remainAmount > 0, "Zero remain amount.");
        require(targetViralGift.starttime + expiration_time >= block.timestamp, "Not Expiration.");
        uint256 claimedAmount = targetViralGift.remainAmount;

        targetViralGift.token.transfer(msg.sender, claimedAmount);

        targetViralGift.remainAmount = 0;

        emit GetBack(_targetIndex, targetViralGift.token, claimedAmount, targetViralGift.fid, msg.sender);
    }

    function _verifyRequest(
        uint256 _fid,
        bytes memory _sig
    ) internal view returns (bool) {
        bytes32 messageHash = keccak256(abi.encode(_fid, msg.sender));
        bytes32 requestHash = keccak256(abi.encodePacked("\x19Ethereum Signed Message:\n32", messageHash));
        (address sigAddress, ,) = ECDSA.tryRecover(requestHash, _sig);
        return sigAddress == verifyAccount;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable.sol)

pragma solidity ^0.8.20;

import {Context} from "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is set to the address provided by the deployer. This can
 * later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    /**
     * @dev The caller account is not authorized to perform an operation.
     */
    error OwnableUnauthorizedAccount(address account);

    /**
     * @dev The owner is not a valid owner account. (eg. `address(0)`)
     */
    error OwnableInvalidOwner(address owner);

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the address provided by the deployer as the initial owner.
     */
    constructor(address initialOwner) {
        if (initialOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(initialOwner);
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        if (owner() != _msgSender()) {
            revert OwnableUnauthorizedAccount(_msgSender());
        }
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        if (newOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/Pausable.sol)

pragma solidity ^0.8.20;

import {Context} from "../utils/Context.sol";

/**
 * @dev Contract module which allows children to implement an emergency stop
 * mechanism that can be triggered by an authorized account.
 *
 * This module is used through inheritance. It will make available the
 * modifiers `whenNotPaused` and `whenPaused`, which can be applied to
 * the functions of your contract. Note that they will not be pausable by
 * simply including this module, only once the modifiers are put in place.
 */
abstract contract Pausable is Context {
    bool private _paused;

    /**
     * @dev Emitted when the pause is triggered by `account`.
     */
    event Paused(address account);

    /**
     * @dev Emitted when the pause is lifted by `account`.
     */
    event Unpaused(address account);

    /**
     * @dev The operation failed because the contract is paused.
     */
    error EnforcedPause();

    /**
     * @dev The operation failed because the contract is not paused.
     */
    error ExpectedPause();

    /**
     * @dev Initializes the contract in unpaused state.
     */
    constructor() {
        _paused = false;
    }

    /**
     * @dev Modifier to make a function callable only when the contract is not paused.
     *
     * Requirements:
     *
     * - The contract must not be paused.
     */
    modifier whenNotPaused() {
        _requireNotPaused();
        _;
    }

    /**
     * @dev Modifier to make a function callable only when the contract is paused.
     *
     * Requirements:
     *
     * - The contract must be paused.
     */
    modifier whenPaused() {
        _requirePaused();
        _;
    }

    /**
     * @dev Returns true if the contract is paused, and false otherwise.
     */
    function paused() public view virtual returns (bool) {
        return _paused;
    }

    /**
     * @dev Throws if the contract is paused.
     */
    function _requireNotPaused() internal view virtual {
        if (paused()) {
            revert EnforcedPause();
        }
    }

    /**
     * @dev Throws if the contract is not paused.
     */
    function _requirePaused() internal view virtual {
        if (!paused()) {
            revert ExpectedPause();
        }
    }

    /**
     * @dev Triggers stopped state.
     *
     * Requirements:
     *
     * - The contract must not be paused.
     */
    function _pause() internal virtual whenNotPaused {
        _paused = true;
        emit Paused(_msgSender());
    }

    /**
     * @dev Returns to normal state.
     *
     * Requirements:
     *
     * - The contract must be paused.
     */
    function _unpause() internal virtual whenPaused {
        _paused = false;
        emit Unpaused(_msgSender());
    }
}

{
  "compilationTarget": {
    "contracts/HelloClankerViralGiftFactory.sol": "HelloClankerViralGiftFactory"
  },
  "evmVersion": "berlin",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs",
    "useLiteralContent": true
  },
  "optimizer": {
    "enabled": true,
    "runs": 100000
  },
  "remappings": []
}