// SPDX-License-Identifier: GPL-3.0

pragma solidity >=0.8.0 <0.9.0;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     * ====
     *
     * [IMPORTANT]
     * ====
     * You shouldn't rely on `isContract` to protect against flash loan attacks!
     *
     * Preventing calls from contracts is highly discouraged. It breaks composability, breaks support for smart wallets
     * like Gnosis Safe, and does not provide security since it can be circumvented by calling from a contract
     * constructor.
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize/address.code.length, which returns 0
        // for contracts in construction, since the code is only stored at the end
        // of the constructor execution.

        return account.code.length > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://diligence.consensys.net/posts/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.5.11/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        (bool success, ) = recipient.call{value: amount}("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCall(target, data, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        require(isContract(target), "Address: call to non-contract");

        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        require(isContract(target), "Address: static call to non-contract");

        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionDelegateCall(target, data, "Address: low-level delegate call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(isContract(target), "Address: delegate call to non-contract");

        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Tool to verifies that a low level call was successful, and revert if it wasn't, either by bubbling the
     * revert reason using the provided one.
     *
     * _Available since v4.3._
     */
    function verifyCallResult(
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal pure returns (bytes memory) {
        if (success) {
            return returndata;
        } else {
            // Look for revert reason and bubble it up if present
            if (returndata.length > 0) {
                // The easiest way to bubble the revert reason is using memory via assembly

                assembly {
                    let returndata_size := mload(returndata)
                    revert(add(32, returndata), returndata_size)
                }
            } else {
                revert(errorMessage);
            }
        }
    }
}

// SPDX-License-Identifier: GPL-3.0

pragma solidity >=0.8.0 <0.9.0;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}

// SPDX-License-Identifier: GPL-3.0

pragma solidity >=0.8.0 <0.9.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `recipient`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address recipient, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `sender` to `recipient` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(
        address sender,
        address recipient,
        uint256 amount
    ) external returns (bool);

    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);
}

// SPDX-License-Identifier: GPL-3.0

pragma solidity >=0.8.0 <0.9.0;

/**
 * @dev Required interface of an ERC721 compliant contract.
 */
interface IERC721 {
    /**
     * @dev Emitted when `tokenId` token is transferred from `from` to `to`.
     */
    event Transfer(address indexed from, address indexed to, uint256 indexed tokenId);

    /**
     * @dev Emitted when `owner` enables `approved` to manage the `tokenId` token.
     */
    event Approval(address indexed owner, address indexed approved, uint256 indexed tokenId);

    /**
     * @dev Emitted when `owner` enables or disables (`approved`) `operator` to manage all of its assets.
     */
    event ApprovalForAll(address indexed owner, address indexed operator, bool approved);

    /**
     * @dev Returns the number of tokens in ``owner``'s account.
     */
    function balanceOf(address owner) external view returns (uint256 balance);

    /**
     * @dev Returns the owner of the `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function ownerOf(uint256 tokenId) external view returns (address owner);

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(address from, address to, uint256 tokenId, bytes calldata data) external;

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`, checking first that contract recipients
     * are aware of the ERC721 protocol to prevent tokens from being forever locked.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must be have been allowed to move this token by either {approve} or {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(address from, address to, uint256 tokenId) external;

    /**
     * @dev Transfers `tokenId` token from `from` to `to`.
     *
     * WARNING: Usage of this method is discouraged, use {safeTransferFrom} whenever possible.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 tokenId) external;

    /**
     * @dev Gives permission to `to` to transfer `tokenId` token to another account.
     * The approval is cleared when the token is transferred.
     *
     * Only a single account can be approved at a time, so approving the zero address clears previous approvals.
     *
     * Requirements:
     *
     * - The caller must own the token or be an approved operator.
     * - `tokenId` must exist.
     *
     * Emits an {Approval} event.
     */
    function approve(address to, uint256 tokenId) external;

    /**
     * @dev Approve or remove `operator` as an operator for the caller.
     * Operators can call {transferFrom} or {safeTransferFrom} for any token owned by the caller.
     *
     * Requirements:
     *
     * - The `operator` cannot be the caller.
     *
     * Emits an {ApprovalForAll} event.
     */
    function setApprovalForAll(address operator, bool _approved) external;

    /**
     * @dev Returns the account approved for `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function getApproved(uint256 tokenId) external view returns (address operator);

    /**
     * @dev Returns if the `operator` is allowed to manage all of the assets of `owner`.
     *
     * See {setApprovalForAll}
     */
    function isApprovedForAll(address owner, address operator) external view returns (bool);
}

// SPDX-License-Identifier: GPL-3.0

pragma solidity >=0.8.0 <0.9.0;

/**
 * @title ERC721 token receiver interface
 * @dev Interface for any contract that wants to support safeTransfers
 * from ERC721 asset contracts.
 */
interface IERC721Receiver {
    /**
     * @dev Whenever an {IERC721} `tokenId` token is transferred to this contract via {IERC721-safeTransferFrom}
     * by `operator` from `from`, this function is called.
     *
     * It must return its Solidity selector to confirm the token transfer.
     * If any other value is returned or the interface is not implemented by the recipient, the transfer will be reverted.
     *
     * The selector can be obtained in Solidity with `IERC721Receiver.onERC721Received.selector`.
     */
    function onERC721Received(address operator, address from, uint256 tokenId, bytes calldata data) external returns (bytes4);
}

// SPDX-License-Identifier: GPL-3.0

pragma solidity >=0.8.0 <0.9.0;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `Mutex` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */

contract Mutex {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant _NOT_ENTERED = 1;
    uint256 private constant _ENTERED = 2;

    uint256 private _status;

    constructor() {
        _status = _NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        // On the first call to nonReentrant, _notEntered will be true
        require(_status != _ENTERED, "Mutex: reentrant call");

        // Any calls to nonReentrant after this point will fail
        _status = _ENTERED;

        _;

        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = _NOT_ENTERED;
    }
}

// SPDX-License-Identifier: GPL-3.0

pragma solidity >=0.8.0 <0.9.0;

import "./Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _transferOwnership(_msgSender());
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
        _;
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions anymore. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby removing any functionality that is only available to the owner.
     */
    function renounceOwnership() external onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) external onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: GPL-3.0

pragma solidity >=0.8.0 <0.9.0;

import "./Ownable.sol";
import "./Mutex.sol";
import "./IERC20.sol";
import "./IERC721.sol";
import "./IERC721Receiver.sol";
import "./Address.sol";

contract ParaStaking is Ownable, Mutex, IERC721Receiver {
    using Address for address;

    // ----- STRUCTS ----- //
    struct TokenInfo {
        address collection;
        uint256 tokenId;
    }

    struct StakeInfo {
        uint256 id;
        bool state;
        uint256 amount;
        uint256 startTime;
        uint256 lockPeriod;
        address staker;
    }

    struct RewardInfo {
        uint256 amount;
        uint256 updateTime;
    }

    struct UserInfo {
        uint256 amount;
        uint256 tokenCnt;
        uint256 reward;
        uint256[] stakes;
    }

    // ----- STATE VARIABLES ----- //
    StakeInfo[] _stakes;  // array of all stakes
    mapping(uint256 => TokenInfo[]) _tokens;  // indexing token id to array of token infos
    mapping(uint256 => RewardInfo) _rewards;  // indexing token id to reward info
    mapping(address => UserInfo) _users;  // indexing address to user info
    mapping(address => uint256) _multipliers;  // indexing collection address to multiplier value

    IERC20 _token;
    uint256 _totalStake;
    uint256 _totalToken;
    uint256 _baseReward = 5800000 * (10 ** 18);
    uint256 constant _denominator = 100;
    bool public isUnlocked;
    address public rewardPool;

    // ----- CONSTRUCTOR ----- //
    constructor(address token) {
        _token = IERC20(token);
        rewardPool = _msgSender();
    }

    // ----- EVENTS ----- //
    event Stake(uint256 indexed id, address indexed account, uint256 amount, uint8 lockDays, TokenInfo[] tokens);
    event Unstake(uint256 indexed id);
    event Claim(uint256 indexed id, uint256 amount);
    event Update(uint256 indexed id, uint256 amount, uint256 updateTime);
    
    // ----- VIEWS ----- //
    function isStakeholder(address account) external view returns (bool) {
        return _users[account].stakes.length > 0;
    }

    function stakeOf(address account) external view returns (uint256) {
        return _users[account].amount;
    }

    function numOfToken(address account) external view returns (uint256) {
        return _users[account].tokenCnt;
    }

    function rewardOf(address account) external view returns (uint256) {
        return _users[account].reward;
    }

    function totalStake() external view returns (uint256) {
        return _totalStake;
    }

    function totalToken() external view returns (uint256) {
        return _totalToken;
    }

    function multiplierOf(address collection) external view returns (uint256) {
        return _multipliers[collection];
    }

    function baseReward() external view returns (uint256) {
        return _baseReward;
    }

    function getReward(uint256 id) external view returns (uint256) {
        uint dayCnt = (block.timestamp - _rewards[id].updateTime) / 1 days;
        uint256 reward = _rewards[id].amount + dayCnt * _calculateReward(id);
        return reward;
    }
    // ----- MUTATION FUNCTIONS ----- //
    function stake(uint256 amount, uint8 lockDays, address[] memory collections, uint256[] memory tokenIds) external {
        require(amount > 0, "Stake: deposit zero");
        require(lockDays == 0 || lockDays == 30 || lockDays == 60 || lockDays == 90 || lockDays == 120, "Stake: invalid lock option");
        require(collections.length == tokenIds.length, "Stake: array length mismatch");
        require(tokenIds.length < 21, "Stake: token limit exceeds");
        require(_token.transferFrom(_msgSender(), address(this), amount), "Stake: failed to transfer deposit");

        StakeInfo memory newStake;
        newStake.id = _stakes.length;
        newStake.state = true;
        newStake.amount = amount;
        newStake.startTime = block.timestamp;
        newStake.lockPeriod = lockDays * 1 days;
        newStake.staker = _msgSender();
        
        for(uint8 i; i < collections.length; i++) {
            require(IERC721(collections[i]).isApprovedForAll(_msgSender(), address(this)), "Stake: unapproved collection");
            IERC721(collections[i]).safeTransferFrom(_msgSender(), address(this), tokenIds[i]);
            _tokens[newStake.id].push(TokenInfo(collections[i], tokenIds[i]));
        }

        _stakes.push(newStake);
        _rewards[newStake.id].updateTime = block.timestamp;
        _totalStake += amount;
        _totalToken += collections.length;
        _users[_msgSender()].amount += amount;
        _users[_msgSender()].tokenCnt += collections.length;
        _users[_msgSender()].stakes.push(newStake.id);

        emit Stake(newStake.id, _msgSender(), amount, lockDays, _tokens[newStake.id]);
    }

    function unstake(uint256 id) external nonReentrant {
        require(_stakes[id].state, "Unstake: invalid stake");
        require(_msgSender() == _stakes[id].staker, "Unstake: caller is not staker");
        if(!isUnlocked)
            require(block.timestamp > _stakes[id].startTime + _stakes[id].lockPeriod, "Unstake: lock is not expired");
        require(_token.transfer(_msgSender(), _stakes[id].amount), "Unstake: failed to transfer tokens");

        if(block.timestamp > _rewards[id].updateTime + 1 days)
            _updateReward(id);

        if(_rewards[id].amount > 0) {
            require(_token.transferFrom(rewardPool, _msgSender(), _rewards[id].amount), "Claim: failed to transfer tokens");
            emit Claim(id, _rewards[id].amount);
            _users[_msgSender()].reward -= _rewards[id].amount;
            _rewards[id].amount = 0;
        }

        for(uint8 i; i < _tokens[id].length; i++) {
            IERC721(_tokens[id][i].collection).safeTransferFrom(address(this), _msgSender(), _tokens[id][i].tokenId);
            delete _tokens[id][i];
        }

        _users[_msgSender()].amount -= _stakes[id].amount;
        _users[_msgSender()].tokenCnt -= _tokens[id].length;
        _totalStake -= _stakes[id].amount;
        _totalToken -= _tokens[id].length;

        _stakes[id].state = false;
        _stakes[id].amount = 0;

        emit Unstake(id);
    }

    function updateReward(uint256 id) external {
        require(_stakes[id].state, "Update: invalid stake");
        require(block.timestamp > _rewards[id].updateTime + 1 days, "Update: early time for update");

        _updateReward(id);
    }

    function claimReward(uint256 id) external nonReentrant {
        require(_stakes[id].state, "Claim: invalid stake");
        require(block.timestamp > _rewards[id].updateTime + 1 days, "Claim: to early for claim.");
        _updateReward(id);

        require(_rewards[id].amount > 0, "Claim: no reward");
        require(_token.transferFrom(rewardPool, _msgSender(), _rewards[id].amount), "Claim: failed to transfer token");

        emit Claim(id, _rewards[id].amount);
        _users[_msgSender()].reward -= _rewards[id].amount;
        _rewards[id].amount = 0;
    }

    function onERC721Received(address operator, address from, uint256 tokenId, bytes calldata data) external override returns (bytes4) {
        return this.onERC721Received.selector;
    }

    // ----- INTERNAL FUNCTIONS ----- //
    function _updateReward(uint256 id) internal {
        uint dayCnt = (block.timestamp - _rewards[id].updateTime) / 1 days;
        uint256 reward = dayCnt * _calculateReward(id);
        _rewards[id].amount += reward;
        _rewards[id].updateTime += dayCnt * 1 days;
        _users[_msgSender()].reward += reward;

        

        emit Update(id, reward, _rewards[id].updateTime);
    }

    function _calculateReward(uint256 id) internal view returns (uint256) {
        uint lockMultiplier = (_stakes[id].lockPeriod / 30 days) * 25;
        uint tokenMultiplier;
        for(uint8 i; i < _tokens[id].length; i++) {
            tokenMultiplier += _multipliers[_tokens[id][i].collection];
        }
        uint256 bonus = _stakes[id].amount * (lockMultiplier + tokenMultiplier) / _denominator;
        return _baseReward * (_stakes[id].amount + bonus) / (_totalStake + bonus);
    }

    // ----- RESTRICTED FUNCTIONS ----- //
    function setBaseReward(uint256 value) external onlyOwner {
        _baseReward = value;
    }

    function setMultiplier(address collection, uint256 value) external onlyOwner {
        require(collection.isContract(), "invalid address");
        _multipliers[collection] = value;
    }

    function unlock(bool flag) external onlyOwner {
        isUnlocked = flag;
    }

    function setRewardPool(address account) external onlyOwner {
        rewardPool = account;
    }
    function updateTokenAddress(address tokenAddress) external onlyOwner {
         _token = IERC20(tokenAddress);
    }
    function stakeIds(address stakeAddress) external returns (uint[] memory _stakeIds){
        _users[stakeAddress].stakes = new uint[](_users[stakeAddress].stakes.length);
        for(uint i=0;i<_users[stakeAddress].stakes.length;i++)
        {
            _stakeIds[i] = _users[stakeAddress].stakes[i];
        }
    }

}

{
  "compilationTarget": {
    "staking.sol": "ParaStaking"
  },
  "evmVersion": "london",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": true,
    "runs": 200
  },
  "remappings": []
}