// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.5.0) (access/AccessControl.sol)

pragma solidity ^0.8.0;

import "contracts/external/openzeppelin/contracts/access/IAccessControl.sol";
import "contracts/external/openzeppelin/contracts/utils/Context.sol";
import "contracts/external/openzeppelin/contracts/utils/Strings.sol";
import "contracts/external/openzeppelin/contracts/utils/ERC165.sol";

/**
 * @dev Contract module that allows children to implement role-based access
 * control mechanisms. This is a lightweight version that doesn't allow enumerating role
 * members except through off-chain means by accessing the contract event logs. Some
 * applications may benefit from on-chain enumerability, for those cases see
 * {AccessControlEnumerable}.
 *
 * Roles are referred to by their `bytes32` identifier. These should be exposed
 * in the external API and be unique. The best way to achieve this is by
 * using `public constant` hash digests:
 *
 * ```
 * bytes32 public constant MY_ROLE = keccak256("MY_ROLE");
 * ```
 *
 * Roles can be used to represent a set of permissions. To restrict access to a
 * function call, use {hasRole}:
 *
 * ```
 * function foo() public {
 *     require(hasRole(MY_ROLE, msg.sender));
 *     ...
 * }
 * ```
 *
 * Roles can be granted and revoked dynamically via the {grantRole} and
 * {revokeRole} functions. Each role has an associated admin role, and only
 * accounts that have a role's admin role can call {grantRole} and {revokeRole}.
 *
 * By default, the admin role for all roles is `DEFAULT_ADMIN_ROLE`, which means
 * that only accounts with this role will be able to grant or revoke other
 * roles. More complex role relationships can be created by using
 * {_setRoleAdmin}.
 *
 * WARNING: The `DEFAULT_ADMIN_ROLE` is also its own admin: it has permission to
 * grant and revoke this role. Extra precautions should be taken to secure
 * accounts that have been granted it.
 */
abstract contract AccessControl is Context, IAccessControl, ERC165 {
  struct RoleData {
    mapping(address => bool) members;
    bytes32 adminRole;
  }

  mapping(bytes32 => RoleData) private _roles;

  bytes32 public constant DEFAULT_ADMIN_ROLE = 0x00;

  /**
   * @dev Modifier that checks that an account has a specific role. Reverts
   * with a standardized message including the required role.
   *
   * The format of the revert reason is given by the following regular expression:
   *
   *  /^AccessControl: account (0x[0-9a-f]{40}) is missing role (0x[0-9a-f]{64})$/
   *
   * _Available since v4.1._
   */
  modifier onlyRole(bytes32 role) {
    _checkRole(role, _msgSender());
    _;
  }

  /**
   * @dev See {IERC165-supportsInterface}.
   */
  function supportsInterface(bytes4 interfaceId)
    public
    view
    virtual
    override
    returns (bool)
  {
    return
      interfaceId == type(IAccessControl).interfaceId ||
      super.supportsInterface(interfaceId);
  }

  /**
   * @dev Returns `true` if `account` has been granted `role`.
   */
  function hasRole(bytes32 role, address account)
    public
    view
    virtual
    override
    returns (bool)
  {
    return _roles[role].members[account];
  }

  /**
   * @dev Revert with a standard message if `account` is missing `role`.
   *
   * The format of the revert reason is given by the following regular expression:
   *
   *  /^AccessControl: account (0x[0-9a-f]{40}) is missing role (0x[0-9a-f]{64})$/
   */
  function _checkRole(bytes32 role, address account) internal view virtual {
    if (!hasRole(role, account)) {
      revert(
        string(
          abi.encodePacked(
            "AccessControl: account ",
            Strings.toHexString(uint160(account), 20),
            " is missing role ",
            Strings.toHexString(uint256(role), 32)
          )
        )
      );
    }
  }

  /**
   * @dev Returns the admin role that controls `role`. See {grantRole} and
   * {revokeRole}.
   *
   * To change a role's admin, use {_setRoleAdmin}.
   */
  function getRoleAdmin(bytes32 role)
    public
    view
    virtual
    override
    returns (bytes32)
  {
    return _roles[role].adminRole;
  }

  /**
   * @dev Grants `role` to `account`.
   *
   * If `account` had not been already granted `role`, emits a {RoleGranted}
   * event.
   *
   * Requirements:
   *
   * - the caller must have ``role``'s admin role.
   */
  function grantRole(bytes32 role, address account)
    public
    virtual
    override
    onlyRole(getRoleAdmin(role))
  {
    _grantRole(role, account);
  }

  /**
   * @dev Revokes `role` from `account`.
   *
   * If `account` had been granted `role`, emits a {RoleRevoked} event.
   *
   * Requirements:
   *
   * - the caller must have ``role``'s admin role.
   */
  function revokeRole(bytes32 role, address account)
    public
    virtual
    override
    onlyRole(getRoleAdmin(role))
  {
    _revokeRole(role, account);
  }

  /**
   * @dev Revokes `role` from the calling account.
   *
   * Roles are often managed via {grantRole} and {revokeRole}: this function's
   * purpose is to provide a mechanism for accounts to lose their privileges
   * if they are compromised (such as when a trusted device is misplaced).
   *
   * If the calling account had been revoked `role`, emits a {RoleRevoked}
   * event.
   *
   * Requirements:
   *
   * - the caller must be `account`.
   */
  function renounceRole(bytes32 role, address account) public virtual override {
    require(
      account == _msgSender(),
      "AccessControl: can only renounce roles for self"
    );

    _revokeRole(role, account);
  }

  /**
   * @dev Grants `role` to `account`.
   *
   * If `account` had not been already granted `role`, emits a {RoleGranted}
   * event. Note that unlike {grantRole}, this function doesn't perform any
   * checks on the calling account.
   *
   * [WARNING]
   * ====
   * This function should only be called from the constructor when setting
   * up the initial roles for the system.
   *
   * Using this function in any other way is effectively circumventing the admin
   * system imposed by {AccessControl}.
   * ====
   *
   * NOTE: This function is deprecated in favor of {_grantRole}.
   */
  function _setupRole(bytes32 role, address account) internal virtual {
    _grantRole(role, account);
  }

  /**
   * @dev Sets `adminRole` as ``role``'s admin role.
   *
   * Emits a {RoleAdminChanged} event.
   */
  function _setRoleAdmin(bytes32 role, bytes32 adminRole) internal virtual {
    bytes32 previousAdminRole = getRoleAdmin(role);
    _roles[role].adminRole = adminRole;
    emit RoleAdminChanged(role, previousAdminRole, adminRole);
  }

  /**
   * @dev Grants `role` to `account`.
   *
   * Internal function without access restriction.
   */
  function _grantRole(bytes32 role, address account) internal virtual {
    if (!hasRole(role, account)) {
      _roles[role].members[account] = true;
      emit RoleGranted(role, account, _msgSender());
    }
  }

  /**
   * @dev Revokes `role` from `account`.
   *
   * Internal function without access restriction.
   */
  function _revokeRole(bytes32 role, address account) internal virtual {
    if (hasRole(role, account)) {
      _roles[role].members[account] = false;
      emit RoleRevoked(role, account, _msgSender());
    }
  }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.5.0) (access/AccessControlEnumerable.sol)

pragma solidity ^0.8.0;

import "contracts/external/openzeppelin/contracts/access/IAccessControlEnumerable.sol";
import "contracts/external/openzeppelin/contracts/access/AccessControl.sol";
import "contracts/external/openzeppelin/contracts/utils/EnumerableSet.sol";

/**
 * @dev Extension of {AccessControl} that allows enumerating the members of each role.
 */
abstract contract AccessControlEnumerable is
  IAccessControlEnumerable,
  AccessControl
{
  using EnumerableSet for EnumerableSet.AddressSet;

  mapping(bytes32 => EnumerableSet.AddressSet) private _roleMembers;

  /**
   * @dev See {IERC165-supportsInterface}.
   */
  function supportsInterface(bytes4 interfaceId)
    public
    view
    virtual
    override
    returns (bool)
  {
    return
      interfaceId == type(IAccessControlEnumerable).interfaceId ||
      super.supportsInterface(interfaceId);
  }

  /**
   * @dev Returns one of the accounts that have `role`. `index` must be a
   * value between 0 and {getRoleMemberCount}, non-inclusive.
   *
   * Role bearers are not sorted in any particular way, and their ordering may
   * change at any point.
   *
   * WARNING: When using {getRoleMember} and {getRoleMemberCount}, make sure
   * you perform all queries on the same block. See the following
   * https://forum.openzeppelin.com/t/iterating-over-elements-on-enumerableset-in-openzeppelin-contracts/2296[forum post]
   * for more information.
   */
  function getRoleMember(bytes32 role, uint256 index)
    public
    view
    virtual
    override
    returns (address)
  {
    return _roleMembers[role].at(index);
  }

  /**
   * @dev Returns the number of accounts that have `role`. Can be used
   * together with {getRoleMember} to enumerate all bearers of a role.
   */
  function getRoleMemberCount(bytes32 role)
    public
    view
    virtual
    override
    returns (uint256)
  {
    return _roleMembers[role].length();
  }

  /**
   * @dev Overload {_grantRole} to track enumerable memberships
   */
  function _grantRole(bytes32 role, address account) internal virtual override {
    super._grantRole(role, account);
    _roleMembers[role].add(account);
  }

  /**
   * @dev Overload {_revokeRole} to track enumerable memberships
   */
  function _revokeRole(bytes32 role, address account)
    internal
    virtual
    override
  {
    super._revokeRole(role, account);
    _roleMembers[role].remove(account);
  }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Context.sol)

pragma solidity ^0.8.0;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
  function _msgSender() internal view virtual returns (address) {
    return msg.sender;
  }

  function _msgData() internal view virtual returns (bytes calldata) {
    return msg.data;
  }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/introspection/ERC165.sol)

pragma solidity ^0.8.0;

import "contracts/external/openzeppelin/contracts/utils/IERC165.sol";

/**
 * @dev Implementation of the {IERC165} interface.
 *
 * Contracts that want to implement ERC165 should inherit from this contract and override {supportsInterface} to check
 * for the additional interface id that will be supported. For example:
 *
 * ```solidity
 * function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
 *     return interfaceId == type(MyInterface).interfaceId || super.supportsInterface(interfaceId);
 * }
 * ```
 *
 * Alternatively, {ERC165Storage} provides an easier to use but more expensive implementation.
 */
abstract contract ERC165 is IERC165 {
  /**
   * @dev See {IERC165-supportsInterface}.
   */
  function supportsInterface(bytes4 interfaceId)
    public
    view
    virtual
    override
    returns (bool)
  {
    return interfaceId == type(IERC165).interfaceId;
  }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/structs/EnumerableSet.sol)

pragma solidity ^0.8.0;

/**
 * @dev Library for managing
 * https://en.wikipedia.org/wiki/Set_(abstract_data_type)[sets] of primitive
 * types.
 *
 * Sets have the following properties:
 *
 * - Elements are added, removed, and checked for existence in constant time
 * (O(1)).
 * - Elements are enumerated in O(n). No guarantees are made on the ordering.
 *
 * ```
 * contract Example {
 *     // Add the library methods
 *     using EnumerableSet for EnumerableSet.AddressSet;
 *
 *     // Declare a set state variable
 *     EnumerableSet.AddressSet private mySet;
 * }
 * ```
 *
 * As of v3.3.0, sets of type `bytes32` (`Bytes32Set`), `address` (`AddressSet`)
 * and `uint256` (`UintSet`) are supported.
 */
library EnumerableSet {
  // To implement this library for multiple types with as little code
  // repetition as possible, we write it in terms of a generic Set type with
  // bytes32 values.
  // The Set implementation uses private functions, and user-facing
  // implementations (such as AddressSet) are just wrappers around the
  // underlying Set.
  // This means that we can only create new EnumerableSets for types that fit
  // in bytes32.

  struct Set {
    // Storage of set values
    bytes32[] _values;
    // Position of the value in the `values` array, plus 1 because index 0
    // means a value is not in the set.
    mapping(bytes32 => uint256) _indexes;
  }

  /**
   * @dev Add a value to a set. O(1).
   *
   * Returns true if the value was added to the set, that is if it was not
   * already present.
   */
  function _add(Set storage set, bytes32 value) private returns (bool) {
    if (!_contains(set, value)) {
      set._values.push(value);
      // The value is stored at length-1, but we add 1 to all indexes
      // and use 0 as a sentinel value
      set._indexes[value] = set._values.length;
      return true;
    } else {
      return false;
    }
  }

  /**
   * @dev Removes a value from a set. O(1).
   *
   * Returns true if the value was removed from the set, that is if it was
   * present.
   */
  function _remove(Set storage set, bytes32 value) private returns (bool) {
    // We read and store the value's index to prevent multiple reads from the same storage slot
    uint256 valueIndex = set._indexes[value];

    if (valueIndex != 0) {
      // Equivalent to contains(set, value)
      // To delete an element from the _values array in O(1), we swap the element to delete with the last one in
      // the array, and then remove the last element (sometimes called as 'swap and pop').
      // This modifies the order of the array, as noted in {at}.

      uint256 toDeleteIndex = valueIndex - 1;
      uint256 lastIndex = set._values.length - 1;

      if (lastIndex != toDeleteIndex) {
        bytes32 lastvalue = set._values[lastIndex];

        // Move the last value to the index where the value to delete is
        set._values[toDeleteIndex] = lastvalue;
        // Update the index for the moved value
        set._indexes[lastvalue] = valueIndex; // Replace lastvalue's index to valueIndex
      }

      // Delete the slot where the moved value was stored
      set._values.pop();

      // Delete the index for the deleted slot
      delete set._indexes[value];

      return true;
    } else {
      return false;
    }
  }

  /**
   * @dev Returns true if the value is in the set. O(1).
   */
  function _contains(Set storage set, bytes32 value)
    private
    view
    returns (bool)
  {
    return set._indexes[value] != 0;
  }

  /**
   * @dev Returns the number of values on the set. O(1).
   */
  function _length(Set storage set) private view returns (uint256) {
    return set._values.length;
  }

  /**
   * @dev Returns the value stored at position `index` in the set. O(1).
   *
   * Note that there are no guarantees on the ordering of values inside the
   * array, and it may change when more values are added or removed.
   *
   * Requirements:
   *
   * - `index` must be strictly less than {length}.
   */
  function _at(Set storage set, uint256 index) private view returns (bytes32) {
    return set._values[index];
  }

  /**
   * @dev Return the entire set in an array
   *
   * WARNING: This operation will copy the entire storage to memory, which can be quite expensive. This is designed
   * to mostly be used by view accessors that are queried without any gas fees. Developers should keep in mind that
   * this function has an unbounded cost, and using it as part of a state-changing function may render the function
   * uncallable if the set grows to a point where copying to memory consumes too much gas to fit in a block.
   */
  function _values(Set storage set) private view returns (bytes32[] memory) {
    return set._values;
  }

  // Bytes32Set

  struct Bytes32Set {
    Set _inner;
  }

  /**
   * @dev Add a value to a set. O(1).
   *
   * Returns true if the value was added to the set, that is if it was not
   * already present.
   */
  function add(Bytes32Set storage set, bytes32 value) internal returns (bool) {
    return _add(set._inner, value);
  }

  /**
   * @dev Removes a value from a set. O(1).
   *
   * Returns true if the value was removed from the set, that is if it was
   * present.
   */
  function remove(Bytes32Set storage set, bytes32 value)
    internal
    returns (bool)
  {
    return _remove(set._inner, value);
  }

  /**
   * @dev Returns true if the value is in the set. O(1).
   */
  function contains(Bytes32Set storage set, bytes32 value)
    internal
    view
    returns (bool)
  {
    return _contains(set._inner, value);
  }

  /**
   * @dev Returns the number of values in the set. O(1).
   */
  function length(Bytes32Set storage set) internal view returns (uint256) {
    return _length(set._inner);
  }

  /**
   * @dev Returns the value stored at position `index` in the set. O(1).
   *
   * Note that there are no guarantees on the ordering of values inside the
   * array, and it may change when more values are added or removed.
   *
   * Requirements:
   *
   * - `index` must be strictly less than {length}.
   */
  function at(Bytes32Set storage set, uint256 index)
    internal
    view
    returns (bytes32)
  {
    return _at(set._inner, index);
  }

  /**
   * @dev Return the entire set in an array
   *
   * WARNING: This operation will copy the entire storage to memory, which can be quite expensive. This is designed
   * to mostly be used by view accessors that are queried without any gas fees. Developers should keep in mind that
   * this function has an unbounded cost, and using it as part of a state-changing function may render the function
   * uncallable if the set grows to a point where copying to memory consumes too much gas to fit in a block.
   */
  function values(Bytes32Set storage set)
    internal
    view
    returns (bytes32[] memory)
  {
    return _values(set._inner);
  }

  // AddressSet

  struct AddressSet {
    Set _inner;
  }

  /**
   * @dev Add a value to a set. O(1).
   *
   * Returns true if the value was added to the set, that is if it was not
   * already present.
   */
  function add(AddressSet storage set, address value) internal returns (bool) {
    return _add(set._inner, bytes32(uint256(uint160(value))));
  }

  /**
   * @dev Removes a value from a set. O(1).
   *
   * Returns true if the value was removed from the set, that is if it was
   * present.
   */
  function remove(AddressSet storage set, address value)
    internal
    returns (bool)
  {
    return _remove(set._inner, bytes32(uint256(uint160(value))));
  }

  /**
   * @dev Returns true if the value is in the set. O(1).
   */
  function contains(AddressSet storage set, address value)
    internal
    view
    returns (bool)
  {
    return _contains(set._inner, bytes32(uint256(uint160(value))));
  }

  /**
   * @dev Returns the number of values in the set. O(1).
   */
  function length(AddressSet storage set) internal view returns (uint256) {
    return _length(set._inner);
  }

  /**
   * @dev Returns the value stored at position `index` in the set. O(1).
   *
   * Note that there are no guarantees on the ordering of values inside the
   * array, and it may change when more values are added or removed.
   *
   * Requirements:
   *
   * - `index` must be strictly less than {length}.
   */
  function at(AddressSet storage set, uint256 index)
    internal
    view
    returns (address)
  {
    return address(uint160(uint256(_at(set._inner, index))));
  }

  /**
   * @dev Return the entire set in an array
   *
   * WARNING: This operation will copy the entire storage to memory, which can be quite expensive. This is designed
   * to mostly be used by view accessors that are queried without any gas fees. Developers should keep in mind that
   * this function has an unbounded cost, and using it as part of a state-changing function may render the function
   * uncallable if the set grows to a point where copying to memory consumes too much gas to fit in a block.
   */
  function values(AddressSet storage set)
    internal
    view
    returns (address[] memory)
  {
    bytes32[] memory store = _values(set._inner);
    address[] memory result;

    assembly {
      result := store
    }

    return result;
  }

  // UintSet

  struct UintSet {
    Set _inner;
  }

  /**
   * @dev Add a value to a set. O(1).
   *
   * Returns true if the value was added to the set, that is if it was not
   * already present.
   */
  function add(UintSet storage set, uint256 value) internal returns (bool) {
    return _add(set._inner, bytes32(value));
  }

  /**
   * @dev Removes a value from a set. O(1).
   *
   * Returns true if the value was removed from the set, that is if it was
   * present.
   */
  function remove(UintSet storage set, uint256 value) internal returns (bool) {
    return _remove(set._inner, bytes32(value));
  }

  /**
   * @dev Returns true if the value is in the set. O(1).
   */
  function contains(UintSet storage set, uint256 value)
    internal
    view
    returns (bool)
  {
    return _contains(set._inner, bytes32(value));
  }

  /**
   * @dev Returns the number of values on the set. O(1).
   */
  function length(UintSet storage set) internal view returns (uint256) {
    return _length(set._inner);
  }

  /**
   * @dev Returns the value stored at position `index` in the set. O(1).
   *
   * Note that there are no guarantees on the ordering of values inside the
   * array, and it may change when more values are added or removed.
   *
   * Requirements:
   *
   * - `index` must be strictly less than {length}.
   */
  function at(UintSet storage set, uint256 index)
    internal
    view
    returns (uint256)
  {
    return uint256(_at(set._inner, index));
  }

  /**
   * @dev Return the entire set in an array
   *
   * WARNING: This operation will copy the entire storage to memory, which can be quite expensive. This is designed
   * to mostly be used by view accessors that are queried without any gas fees. Developers should keep in mind that
   * this function has an unbounded cost, and using it as part of a state-changing function may render the function
   * uncallable if the set grows to a point where copying to memory consumes too much gas to fit in a block.
   */
  function values(UintSet storage set)
    internal
    view
    returns (uint256[] memory)
  {
    bytes32[] memory store = _values(set._inner);
    uint256[] memory result;

    assembly {
      result := store
    }

    return result;
  }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (access/IAccessControl.sol)

pragma solidity ^0.8.0;

/**
 * @dev External interface of AccessControl declared to support ERC165 detection.
 */
interface IAccessControl {
  /**
   * @dev Emitted when `newAdminRole` is set as ``role``'s admin role, replacing `previousAdminRole`
   *
   * `DEFAULT_ADMIN_ROLE` is the starting admin for all roles, despite
   * {RoleAdminChanged} not being emitted signaling this.
   *
   * _Available since v3.1._
   */
  event RoleAdminChanged(
    bytes32 indexed role,
    bytes32 indexed previousAdminRole,
    bytes32 indexed newAdminRole
  );

  /**
   * @dev Emitted when `account` is granted `role`.
   *
   * `sender` is the account that originated the contract call, an admin role
   * bearer except when using {AccessControl-_setupRole}.
   */
  event RoleGranted(
    bytes32 indexed role,
    address indexed account,
    address indexed sender
  );

  /**
   * @dev Emitted when `account` is revoked `role`.
   *
   * `sender` is the account that originated the contract call:
   *   - if using `revokeRole`, it is the admin role bearer
   *   - if using `renounceRole`, it is the role bearer (i.e. `account`)
   */
  event RoleRevoked(
    bytes32 indexed role,
    address indexed account,
    address indexed sender
  );

  /**
   * @dev Returns `true` if `account` has been granted `role`.
   */
  function hasRole(bytes32 role, address account) external view returns (bool);

  /**
   * @dev Returns the admin role that controls `role`. See {grantRole} and
   * {revokeRole}.
   *
   * To change a role's admin, use {AccessControl-_setRoleAdmin}.
   */
  function getRoleAdmin(bytes32 role) external view returns (bytes32);

  /**
   * @dev Grants `role` to `account`.
   *
   * If `account` had not been already granted `role`, emits a {RoleGranted}
   * event.
   *
   * Requirements:
   *
   * - the caller must have ``role``'s admin role.
   */
  function grantRole(bytes32 role, address account) external;

  /**
   * @dev Revokes `role` from `account`.
   *
   * If `account` had been granted `role`, emits a {RoleRevoked} event.
   *
   * Requirements:
   *
   * - the caller must have ``role``'s admin role.
   */
  function revokeRole(bytes32 role, address account) external;

  /**
   * @dev Revokes `role` from the calling account.
   *
   * Roles are often managed via {grantRole} and {revokeRole}: this function's
   * purpose is to provide a mechanism for accounts to lose their privileges
   * if they are compromised (such as when a trusted device is misplaced).
   *
   * If the calling account had been granted `role`, emits a {RoleRevoked}
   * event.
   *
   * Requirements:
   *
   * - the caller must be `account`.
   */
  function renounceRole(bytes32 role, address account) external;
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (access/IAccessControlEnumerable.sol)

pragma solidity ^0.8.0;

import "contracts/external/openzeppelin/contracts/access/IAccessControl.sol";

/**
 * @dev External interface of AccessControlEnumerable declared to support ERC165 detection.
 */
interface IAccessControlEnumerable is IAccessControl {
  /**
   * @dev Returns one of the accounts that have `role`. `index` must be a
   * value between 0 and {getRoleMemberCount}, non-inclusive.
   *
   * Role bearers are not sorted in any particular way, and their ordering may
   * change at any point.
   *
   * WARNING: When using {getRoleMember} and {getRoleMemberCount}, make sure
   * you perform all queries on the same block. See the following
   * https://forum.openzeppelin.com/t/iterating-over-elements-on-enumerableset-in-openzeppelin-contracts/2296[forum post]
   * for more information.
   */
  function getRoleMember(bytes32 role, uint256 index)
    external
    view
    returns (address);

  /**
   * @dev Returns the number of accounts that have `role`. Can be used
   * together with {getRoleMember} to enumerate all bearers of a role.
   */
  function getRoleMemberCount(bytes32 role) external view returns (uint256);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/introspection/IERC165.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[EIP].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
  /**
   * @dev Returns true if this contract implements the interface defined by
   * `interfaceId`. See the corresponding
   * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[EIP section]
   * to learn more about how these ids are created.
   *
   * This function call must use less than 30 000 gas.
   */
  function supportsInterface(bytes4 interfaceId) external view returns (bool);
}

/**SPDX-License-Identifier: BUSL-1.1

      ▄▄█████████▄
   ╓██▀└ ,╓▄▄▄, '▀██▄
  ██▀ ▄██▀▀╙╙▀▀██▄ └██µ           ,,       ,,      ,     ,,,            ,,,
 ██ ,██¬ ▄████▄  ▀█▄ ╙█▄      ▄███▀▀███▄   ███▄    ██  ███▀▀▀███▄    ▄███▀▀███,
██  ██ ╒█▀'   ╙█▌ ╙█▌ ██     ▐██      ███  █████,  ██  ██▌    └██▌  ██▌     └██▌
██ ▐█▌ ██      ╟█  █▌ ╟█     ██▌      ▐██  ██ └███ ██  ██▌     ╟██ j██       ╟██
╟█  ██ ╙██    ▄█▀ ▐█▌ ██     ╙██      ██▌  ██   ╙████  ██▌    ▄██▀  ██▌     ,██▀
 ██ "██, ╙▀▀███████████⌐      ╙████████▀   ██     ╙██  ███████▀▀     ╙███████▀`
  ██▄ ╙▀██▄▄▄▄▄,,,                ¬─                                    '─¬
   ╙▀██▄ '╙╙╙▀▀▀▀▀▀▀▀
      ╙▀▀██████R⌐

 */
pragma solidity 0.8.16;

interface IInvestorBasedRateLimiter {
  /**
   * @notice Rate limits mints for the provided investor
   *
   * @param investorAddress Address of the investor
   * @param mintAmount Amount of token to be minted
   *
   */
  function checkAndUpdateMintLimit(
    address investorAddress,
    uint256 mintAmount
  ) external;

  /**
   * @notice Rate limits redemptions for the provided investor
   *
   * @param investorAddress Address of the investor
   * @param redemptionAmount Amount of token to be redeemed
   *
   */
  function checkAndUpdateRedemptionLimit(
    address investorAddress,
    uint256 redemptionAmount
  ) external;
}

/**SPDX-License-Identifier: BUSL-1.1

      ▄▄█████████▄
   ╓██▀└ ,╓▄▄▄, '▀██▄
  ██▀ ▄██▀▀╙╙▀▀██▄ └██µ           ,,       ,,      ,     ,,,            ,,,
 ██ ,██¬ ▄████▄  ▀█▄ ╙█▄      ▄███▀▀███▄   ███▄    ██  ███▀▀▀███▄    ▄███▀▀███,
██  ██ ╒█▀'   ╙█▌ ╙█▌ ██     ▐██      ███  █████,  ██  ██▌    └██▌  ██▌     └██▌
██ ▐█▌ ██      ╟█  █▌ ╟█     ██▌      ▐██  ██ └███ ██  ██▌     ╟██ j██       ╟██
╟█  ██ ╙██    ▄█▀ ▐█▌ ██     ╙██      ██▌  ██   ╙████  ██▌    ▄██▀  ██▌     ,██▀
 ██ "██, ╙▀▀███████████⌐      ╙████████▀   ██     ╙██  ███████▀▀     ╙███████▀`
  ██▄ ╙▀██▄▄▄▄▄,,,                ¬─                                    '─¬
   ╙▀██▄ '╙╙╙▀▀▀▀▀▀▀▀
      ╙▀▀██████R⌐

 */
pragma solidity 0.8.16;
import "contracts/interfaces/IInvestorBasedRateLimiter.sol";
import "contracts/external/openzeppelin/contracts/access/AccessControlEnumerable.sol";

/**
 * @title InvestorBasedRateLimiter
 *
 * @notice This contract allows for mint and redemption limits to be set
 *         for a given interval on a per-investor basis. Investors can be assigned
 *         multiple addresses through admin functions and the limits are independent
 *         of each other (i.e. minting does not affect redemptions). Investors are
 *         assigned IDs automatically based on a monotonically increasing counter
 *         starting from 1. Limits and durations are set to default values for new
 *         investors, but can also be overridden by the admin.
 *
 * @dev The limits are reset after a given duration has elapsed and an onchain action
 *      (mint or redeem) has occured. When the limits are reset, the associated `currentAmount`
 *      is set to 0 and the `lastResetTime` is updated to the current block timestamp.
 *
 * @dev Admins have the capability to "reset" an investors current rate limit state.
 * @dev If a duration is zero, the limit resets before each mint/redemption.
 * @dev If a limit is zero, the relevant check always fails.
 *
 */
contract InvestorBasedRateLimiter is
  IInvestorBasedRateLimiter,
  AccessControlEnumerable
{
  // Role for the client contract using this rate limiter
  bytes32 public constant CLIENT_ROLE = keccak256("CLIENT_ROLE");

  // Role for the admin who can configure the rate limit state for investors
  bytes32 public constant CONFIGURER_ROLE = keccak256("CONFIGURER_ROLE");

  // Rate limit state for each action (i.e. minting and redeeming)
  struct RateLimit {
    // Amount used for an action in the current interval
    uint256 currentAmount;
    // Maximum amount that can be used for an action in the current interval
    uint256 limit;
    // unix timestamp (seconds) of the last time the limit was reset
    uint256 lastResetTime;
    // Duration of the limit interval in seconds
    uint256 limitDuration;
  }

  // Mapping of investor ID to mint rate limit state
  mapping(uint256 => RateLimit) public investorIdToMintState;

  // Mapping of investor ID to redeem rate limit state
  mapping(uint256 => RateLimit) public investorIdToRedemptionState;

  // Mapping of investor address to investor ID
  mapping(address => uint256) public addressToInvestorId;

  // Mapping of investor ID to the number of addresses associated with the investor
  mapping(uint256 => uint256) public investorAddressCount;

  // Default mint limit value in the decimals of the amount provided to client functions
  uint256 public defaultMintLimit = 5_000_000 * 1e6;

  // Default redeem limit value in the decimals of the amount provided to client functions
  uint256 public defaultRedemptionLimit = 5_000_000 * 1e6;

  // Default duration for mint limit in seconds
  uint256 public defaultMintLimitDuration = 1 days;

  // Default duration for redeem limit in seconds
  uint256 public defaultRedemptionLimitDuration = 1 days;

  // Counter used for automatically assigning the investor IDs
  uint256 public investorIdCounter;

  /**
   * @notice In the constructor, we grant the administrative and client roles to the
   *         respective addresses provided.
   *
   * @param admin `CONFIGURER_ROLE` and `DEFAULT_ADMIN_ROLE` roles are assigned to this
   * @param client `CLIENT_ROLE` role is assigned to this
   *

   */
  constructor(address admin, address client) {
    _setupRole(DEFAULT_ADMIN_ROLE, admin);
    _setupRole(CONFIGURER_ROLE, admin);
    _setupRole(CLIENT_ROLE, client);
  }

  /*//////////////////////////////////////////////////////////////
                        Client calls
  //////////////////////////////////////////////////////////////*/

  /**
   * @notice Checks the investor's requested mint amount against
   *         the limit and updates the current mint amount
   *         if the check passes
   *
   * @param investorAddress The address of the investor
   * @param mintAmount      The requested mint amount
   *
   * @dev Reverts if the requested mint amount exceeds the current limit
   * @dev The client must ensure the decimals being used for the limits match
   *      the decimals of the mint amount
   */
  function checkAndUpdateMintLimit(
    address investorAddress,
    uint256 mintAmount
  ) external override onlyRole(CLIENT_ROLE) {
    if (mintAmount == 0) {
      revert InvalidAmount();
    }

    uint256 investorId = addressToInvestorId[investorAddress];
    if (investorId == 0) {
      // If this is a new investor, initialize their state with the default values
      address[] memory addresses = new address[](1);
      addresses[0] = investorAddress;
      investorId = _initializeInvestorState(
        addresses,
        defaultMintLimit,
        defaultRedemptionLimit,
        defaultMintLimitDuration,
        defaultRedemptionLimitDuration
      );
    }

    RateLimit storage mintState = investorIdToMintState[investorId];
    uint256 prevAmount = mintState.currentAmount;
    _checkAndUpdateRateLimitState(mintState, mintAmount);
    emit MintStateUpdated(
      investorAddress,
      investorId,
      prevAmount,
      mintState.currentAmount,
      mintState.limit - mintState.currentAmount
    );
  }

  /**
   * @notice Checks the investor's requested redemption amount against
   *         the limit and updates the current redemption amount
   *         if the check passes
   *
   * @param investorAddress  The address of the investor
   * @param redemptionAmount The requested redemption amount
   *
   * @dev Reverts if the requested redemption amount exceeds the current limit
   * @dev The client must ensure the decimals being used for the limits match
   *      the decimals of the redemption amount
   */
  function checkAndUpdateRedemptionLimit(
    address investorAddress,
    uint256 redemptionAmount
  ) external override onlyRole(CLIENT_ROLE) {
    if (redemptionAmount == 0) {
      revert InvalidAmount();
    }

    uint256 investorId = addressToInvestorId[investorAddress];
    if (investorId == 0) {
      // If this is a new investor, initialize their state with the default values
      address[] memory addresses = new address[](1);
      addresses[0] = investorAddress;
      investorId = _initializeInvestorState(
        addresses,
        defaultMintLimit,
        defaultRedemptionLimit,
        defaultMintLimitDuration,
        defaultRedemptionLimitDuration
      );
    }
    RateLimit storage redemptionState = investorIdToRedemptionState[investorId];

    uint256 prevAmount = redemptionState.currentAmount;
    _checkAndUpdateRateLimitState(redemptionState, redemptionAmount);
    emit RedemptionStateUpdated(
      investorAddress,
      investorId,
      prevAmount,
      redemptionState.currentAmount,
      redemptionState.limit - redemptionState.currentAmount
    );
  }

  function _checkAndUpdateRateLimitState(
    RateLimit storage rateLimit,
    uint256 amount
  ) internal {
    if (block.timestamp >= rateLimit.lastResetTime + rateLimit.limitDuration) {
      rateLimit.currentAmount = 0;
      rateLimit.lastResetTime = block.timestamp;
    }

    if (rateLimit.currentAmount + amount > rateLimit.limit) {
      revert RateLimitExceeded();
    }

    rateLimit.currentAmount += amount;
  }

  /*//////////////////////////////////////////////////////////////
                   Investor/Address Configuration
  //////////////////////////////////////////////////////////////*/

  /**
   * @notice Administrative call to initialize the rate limit state for
   *         a new investor with the default values for both minting and
   *         redeeming
   *
   * @param addresses The list of addresses that should be associated with the investor
   *
   * @dev Reverts if any of the provided addresses are already associated with an investor
   *      (`setAddressToInvestorId` must be used to "switch" addresses between investors).
   *
   */
  function initializeInvestorStateDefault(
    address[] memory addresses
  ) external onlyRole(CONFIGURER_ROLE) {
    _initializeInvestorState(
      addresses,
      defaultMintLimit,
      defaultRedemptionLimit,
      defaultMintLimitDuration,
      defaultRedemptionLimitDuration
    );
  }

  function _initializeInvestorState(
    address[] memory addresses,
    uint256 mintLimit,
    uint256 redemptionLimit,
    uint256 mintLimitDuration,
    uint256 redemptionLimitDuration
  ) internal returns (uint256 investorId) {
    if (addresses.length == 0) revert AddressesNotProvided();

    investorId = ++investorIdCounter;
    for (uint256 i; i < addresses.length; ++i) {
      // Safety check to ensure the address is not already associated with an investor
      // before associating it with a new investor
      if (addressToInvestorId[addresses[i]] != 0) {
        revert AddressAlreadyAssociated();
      }
      _setAddressToInvestorId(addresses[i], investorId);
    }
    investorIdToMintState[investorId] = RateLimit({
      currentAmount: 0,
      limit: mintLimit,
      lastResetTime: block.timestamp,
      limitDuration: mintLimitDuration
    });
    investorIdToRedemptionState[investorId] = RateLimit({
      currentAmount: 0,
      limit: redemptionLimit,
      lastResetTime: block.timestamp,
      limitDuration: redemptionLimitDuration
    });
  }

  /**
   * @notice Administrative call to associate an address with an investor
   *
   * @param investorAddress the address being associated with `newInvestorId`
   * @param newInvestorId   the ID of the investor `investorAddress` is being associated with
   *
   * @dev This reverts if the `newInvestorId` is 0 or if the investor ID is not already
   *      initialized.
   */
  function setAddressToInvestorId(
    address investorAddress,
    uint256 newInvestorId
  ) external onlyRole(CONFIGURER_ROLE) {
    if (newInvestorId == 0) {
      revert InvalidInvestorId();
    }

    if (investorIdToMintState[newInvestorId].lastResetTime == 0) {
      revert InvestorNotFound();
    }

    _setAddressToInvestorId(investorAddress, newInvestorId);
  }

  /**
   * @notice Administrative call to disassociate an address from an investor
   *
   * @param investorAddress the address being disassociated
   *
   * @dev This reverts if the `investorAddress` is already disassociated
   */
  function removeAddress(
    address investorAddress
  ) external onlyRole(CONFIGURER_ROLE) {
    _setAddressToInvestorId(investorAddress, 0);
  }

  function _setAddressToInvestorId(
    address investorAddress,
    uint256 newInvestorId
  ) internal {
    if (investorAddress == address(0)) revert AddressCannotBeZero();
    if (addressToInvestorId[investorAddress] == newInvestorId) {
      revert AddressAlreadyAssociated();
    }

    uint256 previousInvestorId = addressToInvestorId[investorAddress];
    // If the address was previously associated with an investor, decrement the count
    // for that investor.
    if (previousInvestorId != 0) {
      --investorAddressCount[previousInvestorId];
      emit AddressRemovedFromInvestorId(
        investorAddress,
        previousInvestorId,
        investorAddressCount[previousInvestorId]
      );
    }

    // If the address is not being disassociated from all investors, increment the count
    // for the investor the address is being associated with.
    if (newInvestorId != 0) {
      ++investorAddressCount[newInvestorId];
      emit AddressToInvestorIdSet(
        investorAddress,
        newInvestorId,
        investorAddressCount[newInvestorId]
      );
    }
    addressToInvestorId[investorAddress] = newInvestorId;
  }

  /*//////////////////////////////////////////////////////////////
              Admin Overrides for specific investors
  //////////////////////////////////////////////////////////////*/

  /**
   * @notice Admin call to set the mint limit for a specific investor
   *
   * @param investorId The ID of the investor
   * @param mintLimit  The maximum amount that can be minted by the investor
   *                   in a given interval
   *
   * @dev Reverts if the investor ID is not initialized
   */
  function setInvestorMintLimit(
    uint256 investorId,
    uint256 mintLimit
  ) external onlyRole(CONFIGURER_ROLE) {
    RateLimit storage mintState = investorIdToMintState[investorId];
    if (mintState.lastResetTime == 0) {
      revert InvestorNotFound();
    }

    emit MintLimitSet(investorId, mintState.limit, mintLimit);
    mintState.limit = mintLimit;
  }

  /**
   * @notice Admin call to set the redemption limit for a specific investor
   *
   * @param investorId      The ID of the investor
   * @param redemptionLimit The maximum amount that can be redeemed by the investor
   *                        in a given interval
   *
   * @dev Reverts if the investor ID is not initialized
   */
  function setInvestorRedemptionLimit(
    uint256 investorId,
    uint256 redemptionLimit
  ) external onlyRole(CONFIGURER_ROLE) {
    RateLimit storage redemptionState = investorIdToRedemptionState[investorId];
    if (redemptionState.lastResetTime == 0) {
      revert InvestorNotFound();
    }

    emit RedemptionLimitSet(investorId, redemptionState.limit, redemptionLimit);
    redemptionState.limit = redemptionLimit;
  }

  /**
   * @notice Admin call to update the duration for the mint rate limiter
   *
   * @param investorId        The ID of the investor
   * @param mintLimitDuration The duration in seconds for the mint rate limiter
   *
   * @dev Reverts if the investor ID is not initialized
   */
  function setInvestorMintLimitDuration(
    uint256 investorId,
    uint256 mintLimitDuration
  ) external onlyRole(CONFIGURER_ROLE) {
    RateLimit storage mintState = investorIdToMintState[investorId];
    if (mintState.lastResetTime == 0) {
      revert InvestorNotFound();
    }

    emit MintLimitDurationSet(
      investorId,
      mintState.limitDuration,
      mintLimitDuration
    );
    mintState.limitDuration = mintLimitDuration;
  }

  /**
   * @notice Admin call to update the duration for the redemption rate limiter
   *
   * @param investorId              The ID of the investor
   * @param redemptionLimitDuration The duration in seconds for the mint rate limiter
   *
   * @dev Reverts if the investor ID is not initialized
   */
  function setInvestorRedemptionLimitDuration(
    uint256 investorId,
    uint256 redemptionLimitDuration
  ) external onlyRole(CONFIGURER_ROLE) {
    RateLimit storage redemptionState = investorIdToRedemptionState[investorId];
    if (redemptionState.lastResetTime == 0) {
      revert InvestorNotFound();
    }

    emit RedemptionLimitDurationSet(
      investorId,
      redemptionState.limitDuration,
      redemptionLimitDuration
    );
    redemptionState.limitDuration = redemptionLimitDuration;
  }

  /**
   * @notice Admin call to reset the mint rate limter for a specific investor
   *
   * @param investorId              The ID of the investor
   * @param prevLastMintResetTime   The existing last reset time for the mint rate limiter
   * @param prevMintAmount          The existing mint amount for the investor
   *
   * @dev Reverts if the investor ID is not initialized
   * @dev Reverts if the existing mint amount does not match the provided `prevMintAmount`
   *      (Front-running protection)
   * @dev Reverts if the existing last reset time does not match the provided `prevLastMintResetTime`
   *      (Front-running protection)
   */
  function resetInvestorMintState(
    uint256 investorId,
    uint256 prevLastMintResetTime,
    uint256 prevMintAmount
  ) external onlyRole(CONFIGURER_ROLE) {
    RateLimit storage mintState = investorIdToMintState[investorId];
    if (mintState.lastResetTime == 0) {
      revert InvestorNotFound();
    }

    if (mintState.currentAmount != prevMintAmount) {
      revert CurrentAmountMismatch();
    }

    if (mintState.lastResetTime != prevLastMintResetTime) {
      revert InvalidResetTime();
    }

    mintState.lastResetTime = block.timestamp;
    mintState.currentAmount = 0;
    emit MintStateReset(investorId, prevLastMintResetTime, block.timestamp);
  }

  /**
   * @notice Admin call to reset the redemption rate limiter for a specific investor
   *
   * @param investorId                  The ID of the investor
   * @param prevLastRedemptionResetTime The existing last reset time for the redemption rate limiter
   * @param prevRedemptionAmount        The existing redemption amount for the investor
   *
   * @dev Reverts if the investor ID is not initialized
   * @dev Reverts if the existing redemption amount does not match the provided `prevRedemptionAmount`
   *      (Front-running protection)
   * @dev Reverts if the existing last reset time does not match the provided `prevLastRedemptionResetTime`
   *      (Front-running protection)
   */
  function resetInvestorRedemptionState(
    uint256 investorId,
    uint256 prevLastRedemptionResetTime,
    uint256 prevRedemptionAmount
  ) external onlyRole(CONFIGURER_ROLE) {
    RateLimit storage redemptionState = investorIdToRedemptionState[investorId];
    if (redemptionState.lastResetTime == 0) {
      revert InvestorNotFound();
    }

    if (redemptionState.currentAmount != prevRedemptionAmount) {
      revert CurrentAmountMismatch();
    }

    if (redemptionState.lastResetTime != prevLastRedemptionResetTime) {
      revert InvalidResetTime();
    }

    redemptionState.lastResetTime = block.timestamp;
    redemptionState.currentAmount = 0;
    emit RedemptionStateReset(
      investorId,
      prevLastRedemptionResetTime,
      block.timestamp
    );
  }

  /*//////////////////////////////////////////////////////////////
                 Default State Values
  //////////////////////////////////////////////////////////////*/
  /**
   * @notice Admin call to update the default amount that can be minted during
   *         one duration
   *
   * @param _defaultMintLimit The new default mint limit for new investors
   */
  function setDefaultMintLimit(
    uint256 _defaultMintLimit
  ) external onlyRole(DEFAULT_ADMIN_ROLE) {
    emit DefaultMintLimitSet(defaultMintLimit, _defaultMintLimit);
    defaultMintLimit = _defaultMintLimit;
  }

  /**
   * @notice Admin call to update the default amount that can be redeemed during
   *         one duration
   *
   * @param _defaultRedemptionLimit The new default redemption limit for new investors
   */
  function setDefaultRedemptionLimit(
    uint256 _defaultRedemptionLimit
  ) external onlyRole(DEFAULT_ADMIN_ROLE) {
    emit DefaultRedemptionLimitSet(
      defaultRedemptionLimit,
      _defaultRedemptionLimit
    );
    defaultRedemptionLimit = _defaultRedemptionLimit;
  }

  /**
   * @notice Admin call to update the default duration for the mint rate limiter
   *
   * @param _defaultMintLimitDuration The new default mint limit duration for new investors
   */
  function setDefaultMintLimitDuration(
    uint256 _defaultMintLimitDuration
  ) external onlyRole(DEFAULT_ADMIN_ROLE) {
    emit DefaultMintLimitDurationSet(
      defaultMintLimitDuration,
      _defaultMintLimitDuration
    );
    defaultMintLimitDuration = _defaultMintLimitDuration;
  }

  /**
   * @notice Admin call to update the default duration for the redemption rate limiter
   *
   * @param _defaultRedemptionLimitDuration The new default redemption limit duration for new investors
   */
  function setDefaultRedemptionLimitDuration(
    uint256 _defaultRedemptionLimitDuration
  ) external onlyRole(DEFAULT_ADMIN_ROLE) {
    emit DefaultRedemptionLimitDurationSet(
      defaultRedemptionLimitDuration,
      _defaultRedemptionLimitDuration
    );
    defaultRedemptionLimitDuration = _defaultRedemptionLimitDuration;
  }

  /*//////////////////////////////////////////////////////////////
                          Events
  //////////////////////////////////////////////////////////////*/

  event MintStateUpdated(
    address indexed investorAddress,
    uint256 indexed investorId,
    uint256 prevAmount,
    uint256 currentAmount,
    uint256 remainingAmount
  );

  event RedemptionStateUpdated(
    address indexed investorAddress,
    uint256 indexed investorId,
    uint256 prevAmount,
    uint256 currentAmount,
    uint256 remainingAmount
  );

  event AddressToInvestorIdSet(
    address indexed investorAddress,
    uint256 indexed investorId,
    uint256 indexed investorWallets
  );

  event AddressRemovedFromInvestorId(
    address indexed investorAddress,
    uint256 indexed investorId,
    uint256 indexed investorWallets
  );

  event MintLimitSet(
    uint256 indexed investorId,
    uint256 oldLimit,
    uint256 newLimit
  );

  event RedemptionLimitSet(
    uint256 indexed investorId,
    uint256 oldLimit,
    uint256 newLimit
  );

  event MintLimitDurationSet(
    uint256 indexed investorId,
    uint256 oldDuration,
    uint256 newDuration
  );

  event RedemptionLimitDurationSet(
    uint256 indexed investorId,
    uint256 oldDuration,
    uint256 newDuration
  );

  event MintStateReset(
    uint256 indexed investorId,
    uint256 oldTime,
    uint256 newTime
  );

  event RedemptionStateReset(
    uint256 indexed investorId,
    uint256 oldTime,
    uint256 newTime
  );

  event DefaultMintLimitSet(uint256 oldLimit, uint256 newLimit);

  event DefaultRedemptionLimitSet(uint256 oldLimit, uint256 newLimit);

  event DefaultMintLimitDurationSet(uint256 oldDuration, uint256 newDuration);

  event DefaultRedemptionLimitDurationSet(
    uint256 oldDuration,
    uint256 newDuration
  );

  /*//////////////////////////////////////////////////////////////
                          Errors
  //////////////////////////////////////////////////////////////*/
  error AddressAlreadyAssociated();
  error AddressCannotBeZero();
  error AddressesNotProvided();
  error InvestorNotIntialized();
  error InvestorAlreadyInitialized();
  error InvestorNotFound();
  error InvalidInvestorId();
  error InvalidResetTime();
  error CurrentAmountMismatch();
  error InvalidAmount();
  error RateLimitExceeded();
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Strings.sol)

pragma solidity ^0.8.0;

/**
 * @dev String operations.
 */
library Strings {
  bytes16 private constant _HEX_SYMBOLS = "0123456789abcdef";

  /**
   * @dev Converts a `uint256` to its ASCII `string` decimal representation.
   */
  function toString(uint256 value) internal pure returns (string memory) {
    // Inspired by OraclizeAPI's implementation - MIT licence
    // https://github.com/oraclize/ethereum-api/blob/b42146b063c7d6ee1358846c198246239e9360e8/oraclizeAPI_0.4.25.sol

    if (value == 0) {
      return "0";
    }
    uint256 temp = value;
    uint256 digits;
    while (temp != 0) {
      digits++;
      temp /= 10;
    }
    bytes memory buffer = new bytes(digits);
    while (value != 0) {
      digits -= 1;
      buffer[digits] = bytes1(uint8(48 + uint256(value % 10)));
      value /= 10;
    }
    return string(buffer);
  }

  /**
   * @dev Converts a `uint256` to its ASCII `string` hexadecimal representation.
   */
  function toHexString(uint256 value) internal pure returns (string memory) {
    if (value == 0) {
      return "0x00";
    }
    uint256 temp = value;
    uint256 length = 0;
    while (temp != 0) {
      length++;
      temp >>= 8;
    }
    return toHexString(value, length);
  }

  /**
   * @dev Converts a `uint256` to its ASCII `string` hexadecimal representation with fixed length.
   */
  function toHexString(uint256 value, uint256 length)
    internal
    pure
    returns (string memory)
  {
    bytes memory buffer = new bytes(2 * length + 2);
    buffer[0] = "0";
    buffer[1] = "x";
    for (uint256 i = 2 * length + 1; i > 1; --i) {
      buffer[i] = _HEX_SYMBOLS[value & 0xf];
      value >>= 4;
    }
    require(value == 0, "Strings: hex length insufficient");
    return string(buffer);
  }
}

{
  "compilationTarget": {
    "contracts/ousg/InvestorBasedRateLimiter.sol": "InvestorBasedRateLimiter"
  },
  "evmVersion": "london",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs",
    "useLiteralContent": true
  },
  "optimizer": {
    "enabled": true,
    "runs": 100
  },
  "remappings": []
}