// SPDX-License-Identifier: PRIVATE
pragma solidity >=0.7.0 < 0.8.0;
pragma abicoder v2;

import "./tmp4.sol";

struct InvestInfo {
  address Addr;
  uint256 ID;

  uint256 restCRFI;
  uint256 perTimeCRFI;
  
  uint256 nextTime;
  uint256 duration;
  uint256 totalNums;
}

contract Distribution is  ReentrancyGuard {
  //////////////////// for using
  using SafeMath for uint256;

  //////////////////// constant

  ////////////////////
  IERC20 CRFI;

  //////////////////// invest
  // invest
  uint256 public NewInvestID;
  mapping(uint256 => InvestInfo) Invests;
  mapping(address => uint256) public InvestAddrID;


  //////////////////// modifier
  constructor(address crfiAddr){
    CRFI = IERC20(crfiAddr);
    NewInvestID = 1;
  }
  
  //////////////////// public
  function Charge(address to,
                  uint256 totalCRFI,
                  uint256 nextTime,
                  uint256 duration,
                  uint256 totalNums)
    public
    nonReentrant(){

    uint256 uID = getUID(to);
    InvestInfo storage uInfo = Invests[uID];
    
    withdraw(uInfo);
    require(uInfo.restCRFI == 0, "have rest crfi");

    require(to != address(0x0), "user must not zero addr");
    require(totalCRFI > 0, "totalCRFI must > 0");
    require(duration > 0, "duration must > 0");
    require(totalNums > 0, "totalNums must > 0");
    require(totalCRFI > totalNums, "totalCRFI must > totalNums");

    CRFI.transferFrom(msg.sender, address(this), totalCRFI);

    uInfo.restCRFI = totalCRFI;
    uInfo.perTimeCRFI = totalCRFI / totalNums;
    uInfo.nextTime = nextTime;
    uInfo.duration = duration;
    uInfo.totalNums = totalNums;
  }

  function Withdraw(address addr)
    public
    nonReentrant(){
    if(addr == address(0x0)){
      addr = msg.sender;
    }
    
    uint256 uID = getUID(addr);
    InvestInfo storage uInfo = Invests[uID];
    
    withdraw(uInfo);
  }
    

  //////////////////// view
  function GetInvestInfo(address addr)
    public
    view
    returns(uint256 restCRFI,
            uint256 perTimeCRFI,
            uint256 nextTime,
            uint256 duration,
            uint256 totalNums,
            uint256 avaiCRFI){
    
    uint256 uID = InvestAddrID[addr];
    if(uID == 0){
      return(restCRFI,
             perTimeCRFI,
             nextTime,
             duration,
             totalNums,
             avaiCRFI);
    }
    
    InvestInfo storage uInfo = Invests[uID];
    (avaiCRFI, nextTime, totalNums) = calcNowAvaiCRFI(uInfo);

    restCRFI = uInfo.restCRFI.sub(avaiCRFI);
    return(restCRFI,
           uInfo.perTimeCRFI,
           nextTime,
           uInfo.duration,
           totalNums,
           avaiCRFI);
  }

  //////////////////// internal

  function withdraw(InvestInfo storage uInfo)
    internal{
    (uint256 avaiCRFI, uint256 nextTime, uint256 totalNums) = calcNowAvaiCRFI(uInfo);
    if(avaiCRFI == 0){
      return;
    }

    uInfo.restCRFI = uInfo.restCRFI.sub(avaiCRFI);
    uInfo.nextTime = nextTime;
    uInfo.totalNums = totalNums;

    CRFI.transfer(uInfo.Addr, avaiCRFI);
  }
    
  function calcNowAvaiCRFI(InvestInfo storage uInfo)
    internal
    view
    returns(uint256 avaiCRFI, uint256 nextTime, uint256 totalNums){
    if(block.timestamp < uInfo.nextTime || uInfo.restCRFI == 0 || uInfo.totalNums == 0){
      return (0, uInfo.nextTime, uInfo.totalNums);
    }

    uint256 times = block.timestamp.sub(uInfo.nextTime) / uInfo.duration;
    times++;
    if(times > uInfo.totalNums){
      times = uInfo.totalNums;
    }

    avaiCRFI = times.mul(uInfo.perTimeCRFI);
    nextTime = uInfo.nextTime.add(uInfo.duration.mul(times));
    
    totalNums = uInfo.totalNums.sub(times);
    if(totalNums == 0){
      avaiCRFI = uInfo.restCRFI;
    }

    return(avaiCRFI, nextTime, totalNums);
  }

  function getUID(address addr) internal returns(uint256 uID){
    uID = InvestAddrID[addr];
    if(uID != 0){
      return uID;
    }

    uID = NewInvestID;
    NewInvestID++;

    InvestInfo storage uInfo = Invests[uID];
    uInfo.Addr = addr;
    uInfo.ID = uID;
        
    InvestAddrID[addr] = uID;
    return uID;
  }

}

// SPDX-License-Identifier: PRIVATE
pragma solidity >=0.6.0 < 0.8.0;

// import "github.com/OpenZeppelin/openzeppelin-contracts/blob/v3.4.0/contracts/token/ERC20/IERC20.sol";
interface IERC20 {
    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `recipient`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address recipient, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `sender` to `recipient` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address sender, address recipient, uint256 amount) external returns (bool);

    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);
}

abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant _NOT_ENTERED = 1;
    uint256 private constant _ENTERED = 2;

    uint256 private _status;

    constructor () internal {
        _status = _NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and make it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        // On the first call to nonReentrant, _notEntered will be true
        require(_status != _ENTERED, "ReentrancyGuard: reentrant call");

        // Any calls to nonReentrant after this point will fail
        _status = _ENTERED;

        _;

        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = _NOT_ENTERED;
    }
}

library SafeMath {
    /**
     * @dev Returns the addition of two unsigned integers, with an overflow flag.
     *
     * _Available since v3.4._
     */
    function tryAdd(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        uint256 c = a + b;
        if (c < a) return (false, 0);
        return (true, c);
    }

    /**
     * @dev Returns the substraction of two unsigned integers, with an overflow flag.
     *
     * _Available since v3.4._
     */
    function trySub(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        if (b > a) return (false, 0);
        return (true, a - b);
    }

    /**
     * @dev Returns the multiplication of two unsigned integers, with an overflow flag.
     *
     * _Available since v3.4._
     */
    function tryMul(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        // Gas optimization: this is cheaper than requiring 'a' not being zero, but the
        // benefit is lost if 'b' is also tested.
        // See: https://github.com/OpenZeppelin/openzeppelin-contracts/pull/522
        if (a == 0) return (true, 0);
        uint256 c = a * b;
        if (c / a != b) return (false, 0);
        return (true, c);
    }

    /**
     * @dev Returns the division of two unsigned integers, with a division by zero flag.
     *
     * _Available since v3.4._
     */
    function tryDiv(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        if (b == 0) return (false, 0);
        return (true, a / b);
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers, with a division by zero flag.
     *
     * _Available since v3.4._
     */
    function tryMod(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        if (b == 0) return (false, 0);
        return (true, a % b);
    }

    /**
     * @dev Returns the addition of two unsigned integers, reverting on
     * overflow.
     *
     * Counterpart to Solidity's `+` operator.
     *
     * Requirements:
     *
     * - Addition cannot overflow.
     */
    function add(uint256 a, uint256 b) internal pure returns (uint256) {
        uint256 c = a + b;
        require(c >= a, "SafeMath: addition overflow");
        return c;
    }

    /**
     * @dev Returns the subtraction of two unsigned integers, reverting on
     * overflow (when the result is negative).
     *
     * Counterpart to Solidity's `-` operator.
     *
     * Requirements:
     *
     * - Subtraction cannot overflow.
     */
    function sub(uint256 a, uint256 b) internal pure returns (uint256) {
        require(b <= a, "SafeMath: subtraction overflow");
        return a - b;
    }

    /**
     * @dev Returns the multiplication of two unsigned integers, reverting on
     * overflow.
     *
     * Counterpart to Solidity's `*` operator.
     *
     * Requirements:
     *
     * - Multiplication cannot overflow.
     */
    function mul(uint256 a, uint256 b) internal pure returns (uint256) {
        if (a == 0) return 0;
        uint256 c = a * b;
        require(c / a == b, "SafeMath: multiplication overflow");
        return c;
    }

    /**
     * @dev Returns the integer division of two unsigned integers, reverting on
     * division by zero. The result is rounded towards zero.
     *
     * Counterpart to Solidity's `/` operator. Note: this function uses a
     * `revert` opcode (which leaves remaining gas untouched) while Solidity
     * uses an invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function div(uint256 a, uint256 b) internal pure returns (uint256) {
        require(b > 0, "SafeMath: division by zero");
        return a / b;
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers. (unsigned integer modulo),
     * reverting when dividing by zero.
     *
     * Counterpart to Solidity's `%` operator. This function uses a `revert`
     * opcode (which leaves remaining gas untouched) while Solidity uses an
     * invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function mod(uint256 a, uint256 b) internal pure returns (uint256) {
        require(b > 0, "SafeMath: modulo by zero");
        return a % b;
    }

    /**
     * @dev Returns the subtraction of two unsigned integers, reverting with custom message on
     * overflow (when the result is negative).
     *
     * CAUTION: This function is deprecated because it requires allocating memory for the error
     * message unnecessarily. For custom revert reasons use {trySub}.
     *
     * Counterpart to Solidity's `-` operator.
     *
     * Requirements:
     *
     * - Subtraction cannot overflow.
     */
    function sub(uint256 a, uint256 b, string memory errorMessage) internal pure returns (uint256) {
        require(b <= a, errorMessage);
        return a - b;
    }

    /**
     * @dev Returns the integer division of two unsigned integers, reverting with custom message on
     * division by zero. The result is rounded towards zero.
     *
     * CAUTION: This function is deprecated because it requires allocating memory for the error
     * message unnecessarily. For custom revert reasons use {tryDiv}.
     *
     * Counterpart to Solidity's `/` operator. Note: this function uses a
     * `revert` opcode (which leaves remaining gas untouched) while Solidity
     * uses an invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function div(uint256 a, uint256 b, string memory errorMessage) internal pure returns (uint256) {
        require(b > 0, errorMessage);
        return a / b;
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers. (unsigned integer modulo),
     * reverting with custom message when dividing by zero.
     *
     * CAUTION: This function is deprecated because it requires allocating memory for the error
     * message unnecessarily. For custom revert reasons use {tryMod}.
     *
     * Counterpart to Solidity's `%` operator. This function uses a `revert`
     * opcode (which leaves remaining gas untouched) while Solidity uses an
     * invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function mod(uint256 a, uint256 b, string memory errorMessage) internal pure returns (uint256) {
        require(b > 0, errorMessage);
        return a % b;
    }
}

{
  "compilationTarget": {
    "tmp3.sol": "Distribution"
  },
  "evmVersion": "istanbul",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": false,
    "runs": 200
  },
  "remappings": []
}