// SPDX-License-Identifier: GPL-3.0

pragma solidity >=0.8.0 <0.9.0;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant _NOT_ENTERED = 1;
    uint256 private constant _ENTERED = 2;

    uint256 private _status;

    constructor() {
        _status = _NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be _NOT_ENTERED
        require(_status != _ENTERED, "ReentrancyGuard: reentrant call");

        // Any calls to nonReentrant after this point will fail
        _status = _ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = _NOT_ENTERED;
    }

    /**
     * @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
     * `nonReentrant` function in the call stack.
     */
    function _reentrancyGuardEntered() internal view returns (bool) {
        return _status == _ENTERED;
    }
}

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `from` to `to` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(
        address from,
        address to,
        uint256 amount
    ) external returns (bool);
}

contract FeeRecipientCommission is ReentrancyGuard {
    address adminAddress;
    address mainAddress;
    address commissionAddress;

    address proposedNewAdminAddress;
    address proposedNewMainAddress;
    address proposedNewCommissionAddress;

    uint256 commissionPercent;
    uint256 constant one_hundred = 100;

    event NewAdminAddressProposed(address _address);
    event NewMainAddressProposed(address _address);
    event NewCommissionAddressProposed(address _address);

    event NewAdminAddressConfirmed(address _old, address _new);
    event NewMainAddressConfirmed(address _old, address _new);
    event NewCommissionAddressConfirmed(address _old, address _new);

    event Distribute(address mainAddress, address commissionAddress, uint256 _mainAmount, uint256 _commissionAmount, uint256 commissionPercent);
    event ETHReceived(address _from, uint256 _amount);
    event ETHRecovered(address _to, uint256 _amount);
    event ERC20Recovered(address _to, address _tokenAddress, uint256 _amount);
    event CommissionPercentageUpdated(uint256 _old, uint256 _new);
    
    constructor(address _admin, address _main, address _commission, uint256 _percent) {
        adminAddress = _admin;
        mainAddress = _main;
        commissionAddress = _commission;
        commissionPercent = _percent;
    }

    receive() external payable {
        emit ETHReceived(msg.sender, msg.value);
    }

    modifier isValidAddress(address _address) {
        require(_address != address(0), "Invalid address.");
        _;
    }

    modifier isAdmin(address _address) {
        require(adminAddress == _address, "Is not admin.");
        _;
    }

    modifier isAdminOrMainAddress(address _address) {
        require(mainAddress == _address || adminAddress == _address, "Is not admin or main address.");
        _;
    }

    modifier isAdminOrCommissionAddress(address _address) {
        require(commissionAddress == _address || adminAddress == _address, "Is not admin or commission address.");
        _;
    }

    modifier isProposedNewAdminAddress(address _address) {
        require(proposedNewAdminAddress == _address, "Is not the proposed new admin address.");
        _;
    }

    modifier isProposedNewMainAddress(address _address) {
        require(proposedNewMainAddress == _address, "Is not the proposed new main address.");
        _;
    }

    modifier isProposedNewCommissionAddress(address _address) {
        require(proposedNewCommissionAddress == _address, "Is not the proposed new commission address.");
        _;
    }

    modifier isAdminMainOrCommissionAddress(address _address) {
        require(adminAddress == _address || mainAddress == _address || commissionAddress == _address, "Is not a user of this contract.");
        _;
    }

    function updateAdminAddress(address _address) isAdmin(msg.sender) isValidAddress(_address) public {
        proposedNewAdminAddress = _address;

        emit NewAdminAddressProposed(_address);
    }

    function updateMainAddress(address _address) isAdminOrMainAddress(msg.sender) isValidAddress(_address) public {
        proposedNewMainAddress = _address;

        emit NewMainAddressProposed(_address);
    }

    function updateCommissionAddress(address _address) isAdminOrCommissionAddress(msg.sender) isValidAddress(_address) public {
        proposedNewCommissionAddress = _address;

        emit NewCommissionAddressProposed(_address);
    }

    function updateCommissionPercentage(uint256 _newCommissionPercentage) isAdmin(msg.sender) public {
        uint256 oldCommissionPercentage = commissionPercent;
        commissionPercent = _newCommissionPercentage;

        emit CommissionPercentageUpdated(oldCommissionPercentage, commissionPercent);
    }

    function confirmAdminAddress() isProposedNewAdminAddress(msg.sender) public {
        address oldAdminAddress = adminAddress;
        adminAddress = proposedNewAdminAddress;
        proposedNewAdminAddress = address(0);

        emit NewAdminAddressConfirmed(oldAdminAddress, adminAddress);
    }

    function confirmMainAddress() isProposedNewMainAddress(msg.sender) public {
        address oldMainAddress = mainAddress;
        mainAddress = proposedNewMainAddress;
        proposedNewMainAddress = address(0);

        emit NewMainAddressConfirmed(oldMainAddress, mainAddress);
    }

    function confirmCommissionAddress() isProposedNewCommissionAddress(msg.sender) public {
        address oldCommissionAddress = commissionAddress;
        commissionAddress = proposedNewCommissionAddress;
        proposedNewCommissionAddress = address(0);

        emit NewCommissionAddressConfirmed(oldCommissionAddress, commissionAddress);
    }

    function getAdminAddress() public view returns (address)  {
        return adminAddress;
    }

    function getCommissionAddress() public view returns (address)  {
        return commissionAddress;
    }

    function getMainAddress() public view returns (address)  {
        return mainAddress;
    }

    function getCommissionPercentage() public view returns (uint256) {
        return commissionPercent;
    }

    function getProposedNewAdminAddress() public view returns (address)  {
        return proposedNewAdminAddress;
    }

    function getProposedNewCommissionAddress() public view returns (address)  {
        return proposedNewCommissionAddress;
    }

    function getProposedNewMainAddress() public view returns (address)  {
        return proposedNewMainAddress;
    }

    function distribute() nonReentrant public {
        uint256 balance = address(this).balance;
        require(balance > 0, "No ETH to transfer.");

        uint256 commissionAmount = balance * commissionPercent / one_hundred;
        (bool commissionSuccess, ) = commissionAddress.call{value: commissionAmount}("");
        require(commissionSuccess, "Failed to transfer commission.");

        uint256 mainAmount = balance - commissionAmount;
        (bool mainSuccess, ) = mainAddress.call{value: mainAmount}("");
        require(mainSuccess, "Failed to transfer main balance.");

        emit Distribute(mainAddress, commissionAddress, mainAmount, commissionAmount, commissionPercent);
    }

    function recoverERC20(address _tokenAddress) isAdmin(msg.sender) public {
        IERC20 token = IERC20(_tokenAddress);

        uint256 balance = token.balanceOf(address(this));
        require(balance > 0, "This token has no balance.");

        bool success = token.transfer(adminAddress, balance);
        require(success, "Token transfer failed.");

        emit ERC20Recovered(adminAddress, _tokenAddress, balance);
    }

    function recoverETH() isAdmin(msg.sender) public {
        uint256 balance = address(this).balance;
        require(balance > 0, "No ETH to transfer.");

        (bool success,) = adminAddress.call{value: balance}("");
        require(success, "ETH transfer failed.");

        emit ETHRecovered(adminAddress, balance);
    }
}

{
  "compilationTarget": {
    "FeeRecipientCommission.sol": "FeeRecipientCommission"
  },
  "evmVersion": "paris",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": true,
    "runs": 200
  },
  "remappings": []
}