// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.7.0) (utils/Address.sol)

pragma solidity ^0.8.1;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     * ====
     *
     * [IMPORTANT]
     * ====
     * You shouldn't rely on `isContract` to protect against flash loan attacks!
     *
     * Preventing calls from contracts is highly discouraged. It breaks composability, breaks support for smart wallets
     * like Gnosis Safe, and does not provide security since it can be circumvented by calling from a contract
     * constructor.
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize/address.code.length, which returns 0
        // for contracts in construction, since the code is only stored at the end
        // of the constructor execution.

        return account.code.length > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://diligence.consensys.net/posts/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.5.11/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        (bool success, ) = recipient.call{value: amount}("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCall(target, data, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        require(isContract(target), "Address: call to non-contract");

        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        require(isContract(target), "Address: static call to non-contract");

        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionDelegateCall(target, data, "Address: low-level delegate call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(isContract(target), "Address: delegate call to non-contract");

        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Tool to verifies that a low level call was successful, and revert if it wasn't, either by bubbling the
     * revert reason using the provided one.
     *
     * _Available since v4.3._
     */
    function verifyCallResult(
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal pure returns (bytes memory) {
        if (success) {
            return returndata;
        } else {
            // Look for revert reason and bubble it up if present
            if (returndata.length > 0) {
                // The easiest way to bubble the revert reason is using memory via assembly
                /// @solidity memory-safe-assembly
                assembly {
                    let returndata_size := mload(returndata)
                    revert(add(32, returndata), returndata_size)
                }
            } else {
                revert(errorMessage);
            }
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Context.sol)

pragma solidity ^0.8.0;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}

// SPDX-License-Identifier: MIT

pragma solidity 0.8.7;

import "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
import "@openzeppelin/contracts/access/Ownable.sol";
import "./IDolzToken.sol";

struct SaleSettings {
    address token;
    address wallet;
    uint256 saleStart;
    uint256 saleEnd;
    uint256 withdrawalStart;
    uint256 withdrawPeriodDuration;
    uint256 withdrawPeriodNumber;
    uint256 minBuyValue;
    uint256 maxTokenAmountPerAddress;
    uint256 exchangeRate;
    uint256 referralRewardPercentage;
    uint256 amountToSell;
}

/**
 * @notice ICO smart contract with start and end, vesting and referral reward.
 * Payments are meant to be made in ERC20 stable coins.
 * @dev Only the address of the token to be sold has to be set at deployment.
 * The rest is accessible via setters until the start of the sale.
 */
contract DolzCrowdsale2 is Ownable {
    using SafeERC20 for IERC20;

    // Token to be sold
    address private immutable token;
    // Wallet that receives the payment tokens
    address private wallet;
    // Timestamp in seconds of the start of the ICO
    uint256 internal saleStart;
    // Timestamp in seconds of the end of the ICO
    uint256 internal saleEnd;
    // Timestamp in seconds when users can start to withdraw
    uint256 internal withdrawalStart;
    // Duration in seconds of each vesting period
    uint256 private withdrawPeriodDuration;
    // Number of vesting period
    uint256 private withdrawPeriodNumber;
    // Minimum value to buy in dollars
    uint256 private minBuyValue;
    // Maximum token amount to be bought per address
    uint256 private maxTokenAmountPerAddress;
    // Exchange rate between stable coins and token
    // E.g. 125 would mean you get 83,3333 tokens for 1 dollar, so the price would be
    // 1,2cts per token (1 dollar / 83,333333 = 0.012)
    uint256 private exchangeRate;
    // Percentage of the tokens bought that referrals get
    // E.g. for a 30 value, if a buyer buys 100 tokens the referral will get 30
    uint256 private referralRewardPercentage;
    // Total number of tokens sold (exculdes referral rewards)
    uint256 internal soldAmount;
    // Total number of tokens given to referral rewards
    uint256 internal rewardsAmount;
    // Amount of tokens available to buyers
    uint256 private amountToSell;
    // Burn remaining tokens already called
    bool private burnCalled;

    // Set the address of token authorized for payments to true
    mapping(address => bool) private authorizedPaymentCurrencies;
    // Map buyers and referrals addresses to the amount they can claim
    mapping(address => uint256) private userToClaimableAmount;
    // Map buyers and referrals addresses to the amount they already claimed
    mapping(address => uint256) private userToWithdrewAmount;
    // Track referral amounts
    mapping(address => uint256) private userToReferralRewardAmount;

    event WalletUpdated(address newWallet, address indexed updater);
    event SaleStartUpdated(uint256 newSaleStart, address indexed updater);
    event SaleEndUpdated(uint256 newSaleEnd, address indexed updater);
    event WithdrawalStartUpdated(
        uint256 newWithdrawalStart,
        address indexed updater
    );
    event WithdrawPeriodDurationUpdated(
        uint256 newWithdrawPeriodDuration,
        address indexed updater
    );
    event WithdrawPeriodNumberUpdated(
        uint256 newWithdrawPeriodNumber,
        address indexed updater
    );
    event MinBuyValueUpdated(uint256 newMinBuyValue, address indexed updater);
    event MaxTokenAmountPerAddressUpdated(
        uint256 newMaxTokenAmountPerAddress,
        address indexed updater
    );
    event ExchangeRateUpdated(uint256 newExchangeRate, address indexed updater);
    event ReferralRewardPercentageUpdated(
        uint256 newReferralRewardPercentage,
        address indexed updater
    );
    event AmountToSellUpdated(uint256 newAmountToSell, address indexed updater);

    event PaymentCurrenciesAuthorized(
        address[] tokens,
        address indexed updater
    );
    event PaymentCurrenciesRevoked(
        address[] tokens,
        address indexed updater
    );

    event ReferralRegistered(address newReferral);
    event TokenBought(
        address indexed account,
        address indexed stableCoin,
        uint256 value,
        address indexed referral
    );

    event TokenWithdrew(address indexed account, uint256 amount);
    event RemainingTokensBurnt(uint256 remainingBalance);

    /**
     * @dev Check if the sale has already started.
     */
    modifier onlyBeforeSaleStart() {
        if (saleStart > 0) {
            require(
                block.timestamp < saleStart,
                "DolzCrowdsale: sale already started"
            );
        }
        _;
    }

    /// @dev Check if the withdrawal period has start
    modifier withdrawalStarted(){
        require(block.timestamp >= withdrawalStart);
        _;
    }
    
    constructor(
        address _token,
        address _wallet,
        uint256 _saleStart,
        uint256 _saleEnd,
        uint256 _withdrawalStart,
        uint256 _withdrawPeriodDuration,
        uint256 _withdrawPeriodNumber,
        uint256 _minBuyValue,
        uint256 _maxTokenAmountPerAddress,
        uint256 _exchangeRate,
        uint256 _referralRewardPercentage,
        uint256 _amountToSell
    ) {
        token = _token;
        wallet = _wallet;
        saleStart = _saleStart;
        saleEnd = _saleEnd;
        withdrawalStart = _withdrawalStart;
        withdrawPeriodDuration = _withdrawPeriodDuration;
        withdrawPeriodNumber = _withdrawPeriodNumber;
        minBuyValue = _minBuyValue;
        maxTokenAmountPerAddress = _maxTokenAmountPerAddress;
        exchangeRate = _exchangeRate;
        referralRewardPercentage = _referralRewardPercentage;
        amountToSell = _amountToSell;
        burnCalled = false;
    }

    /**
     * @notice Enable to get all the infos about the sale.
     * @return See state variables comments.
     */
    function getSaleSettings() external view returns (SaleSettings memory) {
        return
            SaleSettings(
                token,
                wallet,
                saleStart,
                saleEnd,
                withdrawalStart,
                withdrawPeriodDuration,
                withdrawPeriodNumber,
                minBuyValue,
                maxTokenAmountPerAddress,
                exchangeRate,
                referralRewardPercentage,
                amountToSell
            );
    }

    function getSoldAmount() external view returns (uint256) {
        return soldAmount;
    }

    /**
     * @notice Returns the amount of token a user will be able to withdraw after withdrawal start,
     * depending on vesting periods.
     * @param account Address to get claimable amount of.
     * @return Number of claimable tokens.
     */
    function getClaimableAmount(address account)
        external
        view
        returns (uint256)
    {
        return userToClaimableAmount[account];
    }

    /**
     * @notice Returns the amount earned as a referral,
     *
     * @param account Address to get referral amount.
     * @return Number of rewards.
     */
    function getReferralRewardsAmount(address account)
        external
        view
        returns (uint256)
    {
        return userToReferralRewardAmount[account];
    }

    /**
     * @notice Returns the amount of token a user has already withdrew.
     * @param account Address to get withdrew amount of.
     * @return Number of withdrew tokens.
     */
    function getWithdrewAmount(address account)
        external
        view
        returns (uint256)
    {
        return userToWithdrewAmount[account];
    }

    /**
     * @notice Enable to know if a token is authorized to buy the ICO token.
     * @param paymentCurrency Address of the token to check.
     * @return True if the token is authorized, false if not.
     */
    function isAuthorizedPaymentCurrency(address paymentCurrency)
        external
        view
        returns (bool)
    {
        return authorizedPaymentCurrencies[paymentCurrency];
    }

    /**
     * @notice Enable to update the address that will receive the payments for token sales.
     * @dev The wallet address can be updated at any time, even after the start of the sale.
     * Only executable by the owner of the contract.
     * @param newWallet Address of the account that will receive the payments.
     */
    function setWallet(address newWallet) external onlyOwner {
        wallet = newWallet;
        emit WalletUpdated(newWallet, msg.sender);
    }

    /**
     * @notice Enable to update the start date of the sale.
     * @dev Only executable before the start of the sale.
     * Only executable by the owner of the contract.
     * @param newSaleStart Timestamp in seconds from when the users will be able to buy the tokens.
     */
    function setSaleStart(uint256 newSaleStart)
        external
        onlyBeforeSaleStart
        onlyOwner
    {
        saleStart = newSaleStart;
        emit SaleStartUpdated(newSaleStart, msg.sender);
    }

    /**
     * @notice Enable to update the end date of the sale.
     * @dev Only executable before the start of the sale.
     * Only executable by the owner of the contract.
     * @param newSaleEnd Timestamp in seconds from when the users will not be able to buy the tokens anymore.
     */
    function setSaleEnd(uint256 newSaleEnd)
        external
        onlyBeforeSaleStart
        onlyOwner
    {
        saleEnd = newSaleEnd;
        emit SaleEndUpdated(newSaleEnd, msg.sender);
    }

    /**
     * @notice Enable to update the start date of the withdrawal period.
     * @dev Only executable before the start of the sale.
     * Only executable by the owner of the contract.
     * @param newWithdrawalStart Timestamp in seconds from when the users will be able to withdraw their
     * claimable amount, according to the vesting configuration.
     */
    function setWithdrawalStart(uint256 newWithdrawalStart)
        external
        onlyBeforeSaleStart
        onlyOwner
    {
        withdrawalStart = newWithdrawalStart;
        emit WithdrawalStartUpdated(newWithdrawalStart, msg.sender);
    }

    /**
     * @notice Enable to update the duration of each withdrawal period.
     * @dev Only executable before the start of the sale.
     * Only executable by the owner of the contract.
     * @param newWithdrawPeriodDuration Duration in seconds of 1 withdrawal period.
     */
    function setWithdrawPeriodDuration(uint256 newWithdrawPeriodDuration)
        external
        onlyBeforeSaleStart
        onlyOwner
    {
        withdrawPeriodDuration = newWithdrawPeriodDuration;
        emit WithdrawPeriodDurationUpdated(
            newWithdrawPeriodDuration,
            msg.sender
        );
    }

    /**
     * @notice Enable to update the number of withdrawal periods.
     * @dev Only executable before the start of the sale.
     * Only executable by the owner of the contract.
     * @param newWithdrawPeriodNumber Integer representing the number of withdrawal period. Also defines
     * how much of the claimable amount will be withdrawal at each period.
     * E.g. with 10 withdrawal periods, the claimable amount will be split into 10 parts, resulting in
     * a 10% withdrawal for each period.
     */
    function setWithdrawPeriodNumber(uint256 newWithdrawPeriodNumber)
        external
        onlyBeforeSaleStart
        onlyOwner
    {
        withdrawPeriodNumber = newWithdrawPeriodNumber;
        emit WithdrawPeriodNumberUpdated(newWithdrawPeriodNumber, msg.sender);
    }

    /**
     * @notice Enable to update the minimum value in dollars to buy per sale.
     * @dev Only executable before the start of the sale.
     * Only executable by the owner of the contract.
     * @param newMinBuyValue Integer representing the minimum amount of stable coins to receive at
     * each sale.
     */
    function setMinBuyValue(uint256 newMinBuyValue)
        external
        onlyBeforeSaleStart
        onlyOwner
    {
        minBuyValue = newMinBuyValue;
        emit MinBuyValueUpdated(newMinBuyValue, msg.sender);
    }

    /**
     * @notice Enable to update the maximum amount of tokens an address can buy.
     * @dev Only executable before the start of the sale.
     * Only executable by the owner of the contract.
     * @param newMaxTokenAmountPerAddress Integer representing the maximum amount of tokens buyable
     * per address.
     */
    function setMaxTokenAmountPerAddress(uint256 newMaxTokenAmountPerAddress)
        external
        onlyBeforeSaleStart
        onlyOwner
    {
        maxTokenAmountPerAddress = newMaxTokenAmountPerAddress;
        emit MaxTokenAmountPerAddressUpdated(
            newMaxTokenAmountPerAddress,
            msg.sender
        );
    }

    /**
     * @notice Enable to update the exchange rate per token (tokens/USD).
     * @dev Only executable before the start of the sale.
     * Only executable by the owner of the contract.
     * @param newExchangeRate Integer representing the exchange rate.
     */
    function setExchangeRate(uint256 newExchangeRate)
        external
        onlyBeforeSaleStart
        onlyOwner
    {
        exchangeRate = newExchangeRate;
        emit ExchangeRateUpdated(newExchangeRate, msg.sender);
    }

    /**
     * @notice Enable to update the referral reward percentage.
     * @dev Only executable before the start of the sale.
     * Only executable by the owner of the contract.
     * @param newReferralRewardPercentage Integer representing the reward percentage.
     * E.g. 30 means the referral reward will be 30% of the amount of token bought by the sponsored user.
     */
    function setReferralRewardPercentage(uint256 newReferralRewardPercentage)
        external
        onlyBeforeSaleStart
        onlyOwner
    {
        referralRewardPercentage = newReferralRewardPercentage;
        emit ReferralRewardPercentageUpdated(
            newReferralRewardPercentage,
            msg.sender
        );
    }

    /**
     * @notice Enable to update the amount of token available to sell.
     * @dev Only executable before the start of the sale.
     * Only executable by the owner of the contract.
     * @param newAmountToSell Integer representing the amount of token to sell.
     */
    function setAmountToSell(uint256 newAmountToSell)
        external
        onlyBeforeSaleStart
        onlyOwner
    {
        amountToSell = newAmountToSell;
        emit AmountToSellUpdated(newAmountToSell, msg.sender);
    }

    /**
     * @notice Enable to authorize tokens to be used as payment during sales.
     * @dev Only executable before the start of the sale.
     * Only executable by the owner of the contract.
     * @param tokens Array of addresses of the tokens to authorize. Meant to be stable coins.
     */
    function authorizePaymentCurrencies(address[] memory tokens)
        external
        onlyBeforeSaleStart
        onlyOwner
    {
        for (uint256 i = 0; i < tokens.length; i += 1) {
            authorizedPaymentCurrencies[tokens[i]] = true;
        }
        emit PaymentCurrenciesAuthorized(tokens, msg.sender);
    }

    /// @notice Allow owner to revoke token's authorization to be used as payment during sales.
    /// @dev Only executable before the start of the sale & by the contract owner.
    /// @param tokens Array of addresses of the tokens to revoke authorization.
    function revokeAuthorizationPaymentCurrencies(address[] memory tokens)
        external
        onlyBeforeSaleStart
        onlyOwner
    {
        for (uint256 i = 0; i < tokens.length; i += 1) {
            authorizedPaymentCurrencies[tokens[i]] = false;
        }
        emit PaymentCurrenciesRevoked(tokens, msg.sender);
    }

    /**
     * @notice Enable users to buy tokens.
     * @dev User needs to approve this contract to spend the `value` parameter on the `stableCoin`
     * parameter.
     * @param stableCoin Address of the token to be used as payment for the sale.
     * @param value Amount of payment tokens to be spent.
     * @param referral Address of the referral of the user. Use zero address if no referral.
     */
    function buyToken(
        address stableCoin,
        uint256 value,
        address referral
    ) external {
        // Checks if the `stableCoin` address is authorized
        require(
            authorizedPaymentCurrencies[stableCoin],
            "DolzCrowdsale: unauthorized token"
        );
        // Checks if the sale has started
        require(
            block.timestamp >= saleStart,
            "DolzCrowdsale: sale not started yet"
        );
        // Checks if the sale has not ended
        require(block.timestamp <= saleEnd, "DolzCrowdsale: sale ended");
        // Checks if the minimum buy value is provided
        require(value >= minBuyValue, "DolzCrowdsale: under minimum buy value");

        // Computes the number of tokens the user will receive
        uint256 claimableAmount = (value * exchangeRate) / 1e6;

        // Checks if this sale will exceed the maximum token amount per address allowed
        require(
            userToClaimableAmount[msg.sender] + claimableAmount <=
                maxTokenAmountPerAddress,
            "DolzCrowdsale: above maximum token amount per address"
        );
        // Checks if this sale will exceed the number of tokens avaible to sell
        require(
            soldAmount + claimableAmount <= amountToSell,
            "DolzCrowdsale: not enough tokens available"
        );
        userToClaimableAmount[msg.sender] += claimableAmount;
        soldAmount += claimableAmount;

        // If a referral is mentioned, adds the reward to its claimable balance
        // Checks if the referral is not the buyer
        if (referral != address(0) && referral != msg.sender) {
            uint256 referralReward = (claimableAmount *
                referralRewardPercentage) / 100;

            userToClaimableAmount[referral] += referralReward;

            //track referral amount
            userToReferralRewardAmount[referral] += referralReward;

            //total referral amount
            rewardsAmount += referralReward;
        }

        emit TokenBought(msg.sender, stableCoin, value, referral);

        IERC20(stableCoin).safeTransferFrom(msg.sender, wallet, value);
    }

    /**
     * @notice Enable users to withdraw their tokens, depending on withdrawal start and vesting configuration.
     */
    function withdrawToken() external withdrawalStarted{
        // Computes the number of withdrawal periods that have passed
        // Reverts if before withdrawalStart, so there is no need to check for that
        uint256 periodsElapsed = (block.timestamp - withdrawalStart) /
            withdrawPeriodDuration +
            1;

        uint256 amountToSend;
        // Checks if all the withdrawal periods have passed, to be able to delete claimable and withdrew
        // balances if so and make substantial gas savings
        if (periodsElapsed >= withdrawPeriodNumber) {
            // All the withdrawal periods have passed, so we send all the remaining claimable balance
            amountToSend =
                userToClaimableAmount[msg.sender] -
                userToWithdrewAmount[msg.sender];
            delete userToClaimableAmount[msg.sender];
            delete userToWithdrewAmount[msg.sender];
        } else {
            // Computes how many tokens the user can withdraw per period
            uint256 withdrawableAmountPerPeriod = userToClaimableAmount[
                msg.sender
            ] / withdrawPeriodNumber;
            // Computes how much the user can withdraw since the begining, minest the amount it already withdrew
            amountToSend =
                withdrawableAmountPerPeriod *
                periodsElapsed -
                userToWithdrewAmount[msg.sender];
            userToWithdrewAmount[msg.sender] += amountToSend;
        }

        emit TokenWithdrew(msg.sender, amountToSend);

        // We know our implementation returns true if success, so no need to use safeTransfer
        require(
            IERC20(token).transfer(msg.sender, amountToSend),
            "DolzCrowdsale: transfer failed"
        );
    }

    /**
     * @notice Enable to burn all the unsold tokens after the end of the sale.
     * @dev Anyone can call this function.
     */
    function burnRemainingTokens() external onlyOwner {
        // Checks if the sale has ended
        require(block.timestamp > saleEnd, "DolzCrowdsale: sale not ended yet");
        // must be called before the withdrawal start
        require(
            block.timestamp < withdrawalStart,
            "Too late to burn, withdrawal already started"
        );
        // avoid to be called several times
        require(burnCalled == false, "Burn already called!");

        uint256 balance = IERC20(token).balanceOf(address(this));

        //sold out ?
        require(balance - soldAmount - rewardsAmount > 0, "Nothing to burn");

        emit RemainingTokensBurnt(balance - soldAmount - rewardsAmount);
        IDolzToken(token).burn(balance - soldAmount - rewardsAmount);

        burnCalled = true;
    }
}

// SPDX-License-Identifier: MIT

pragma solidity 0.8.7;

import "@openzeppelin/contracts/token/ERC20/IERC20.sol";

interface IDolzToken is IERC20 {
    function mintFromBridge(address account, uint256 amount) external;

    function burnFromBridge(address account, uint256 amount) external;

    function burn(uint256 amount) external;

    event BridgeUpdateLaunched(address indexed newBridge, uint256 endGracePeriod);

    event BridgeUpdateExecuted(address indexed newBridge);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.6.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `from` to `to` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(
        address from,
        address to,
        uint256 amount
    ) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.7.0) (access/Ownable.sol)

pragma solidity ^0.8.0;

import "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _transferOwnership(_msgSender());
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions anymore. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby removing any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.7.0) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.0;

import "../IERC20.sol";
import "../extensions/draft-IERC20Permit.sol";
import "../../../utils/Address.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using Address for address;

    function safeTransfer(
        IERC20 token,
        address to,
        uint256 value
    ) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transfer.selector, to, value));
    }

    function safeTransferFrom(
        IERC20 token,
        address from,
        address to,
        uint256 value
    ) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transferFrom.selector, from, to, value));
    }

    /**
     * @dev Deprecated. This function has issues similar to the ones found in
     * {IERC20-approve}, and its usage is discouraged.
     *
     * Whenever possible, use {safeIncreaseAllowance} and
     * {safeDecreaseAllowance} instead.
     */
    function safeApprove(
        IERC20 token,
        address spender,
        uint256 value
    ) internal {
        // safeApprove should only be called when setting an initial allowance,
        // or when resetting it to zero. To increase and decrease it, use
        // 'safeIncreaseAllowance' and 'safeDecreaseAllowance'
        require(
            (value == 0) || (token.allowance(address(this), spender) == 0),
            "SafeERC20: approve from non-zero to non-zero allowance"
        );
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, value));
    }

    function safeIncreaseAllowance(
        IERC20 token,
        address spender,
        uint256 value
    ) internal {
        uint256 newAllowance = token.allowance(address(this), spender) + value;
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, newAllowance));
    }

    function safeDecreaseAllowance(
        IERC20 token,
        address spender,
        uint256 value
    ) internal {
        unchecked {
            uint256 oldAllowance = token.allowance(address(this), spender);
            require(oldAllowance >= value, "SafeERC20: decreased allowance below zero");
            uint256 newAllowance = oldAllowance - value;
            _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, newAllowance));
        }
    }

    function safePermit(
        IERC20Permit token,
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) internal {
        uint256 nonceBefore = token.nonces(owner);
        token.permit(owner, spender, value, deadline, v, r, s);
        uint256 nonceAfter = token.nonces(owner);
        require(nonceAfter == nonceBefore + 1, "SafeERC20: permit did not succeed");
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We use {Address.functionCall} to perform this call, which verifies that
        // the target address contains contract code and also asserts for success in the low-level call.

        bytes memory returndata = address(token).functionCall(data, "SafeERC20: low-level call failed");
        if (returndata.length > 0) {
            // Return data is optional
            require(abi.decode(returndata, (bool)), "SafeERC20: ERC20 operation did not succeed");
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (token/ERC20/extensions/draft-IERC20Permit.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 Permit extension allowing approvals to be made via signatures, as defined in
 * https://eips.ethereum.org/EIPS/eip-2612[EIP-2612].
 *
 * Adds the {permit} method, which can be used to change an account's ERC20 allowance (see {IERC20-allowance}) by
 * presenting a message signed by the account. By not relying on {IERC20-approve}, the token holder account doesn't
 * need to send a transaction, and thus is not required to hold Ether at all.
 */
interface IERC20Permit {
    /**
     * @dev Sets `value` as the allowance of `spender` over ``owner``'s tokens,
     * given ``owner``'s signed approval.
     *
     * IMPORTANT: The same issues {IERC20-approve} has related to transaction
     * ordering also apply here.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `deadline` must be a timestamp in the future.
     * - `v`, `r` and `s` must be a valid `secp256k1` signature from `owner`
     * over the EIP712-formatted function arguments.
     * - the signature must use ``owner``'s current nonce (see {nonces}).
     *
     * For more information on the signature format, see the
     * https://eips.ethereum.org/EIPS/eip-2612#specification[relevant EIP
     * section].
     */
    function permit(
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external;

    /**
     * @dev Returns the current nonce for `owner`. This value must be
     * included whenever a signature is generated for {permit}.
     *
     * Every successful call to {permit} increases ``owner``'s nonce by one. This
     * prevents a signature from being used multiple times.
     */
    function nonces(address owner) external view returns (uint256);

    /**
     * @dev Returns the domain separator used in the encoding of the signature for {permit}, as defined by {EIP712}.
     */
    // solhint-disable-next-line func-name-mixedcase
    function DOMAIN_SEPARATOR() external view returns (bytes32);
}

{
  "compilationTarget": {
    "contracts/DolzCrowdsale2.sol": "DolzCrowdsale2"
  },
  "evmVersion": "london",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs",
    "useLiteralContent": true
  },
  "optimizer": {
    "enabled": true,
    "runs": 5000
  },
  "remappings": []
}