pragma solidity ^0.4.23;

contract IERC20 {
  function totalSupply() public constant returns (uint);
  function balanceOf(address tokenOwner) public constant returns (uint balance);
  function allowance(address tokenOwner, address spender) public constant returns (uint remaining);
  function transfer(address to, uint tokens) public returns (bool success);
  function approve(address spender, uint tokens) public returns (bool success);
  function transferFrom(address from, address to, uint tokens) public returns (bool success);

  event Transfer(address indexed from, address indexed to, uint tokens);
  event Approval(address indexed tokenOwner, address indexed spender, uint tokens);
}

pragma solidity ^0.4.23;

import "./IERC20.sol";
import "./SafeERC20.sol";

contract MultiSend {
	using SafeERC20 for IERC20;

	bool private locked; // Re-entrancy protection
  mapping(address => bool) public admins;
	
	event AdminSet(address indexed newAdmin);
	event AdminRemoved(address indexed oldAdmin);
	event Transfer(address indexed from, address indexed to, address indexed tokenAddress, uint tokens);

	constructor() public {
		admins[msg.sender] = true;
		emit AdminSet(msg.sender);
	}

	modifier onlyAdmin() {
		require(admins[msg.sender], "Must be an admin");
		_;
	}

	 // Reentrancy guard modifier
	modifier reentrancyGuard() {
		require(!locked, "Reentrancy Guard: Reentrant call detected!");
		locked = true;
		_;
		locked = false;
	}

	function setAdmin(address admin) external onlyAdmin returns(bool success){
		admins[admin] = true;
		emit AdminSet(admin);
		return admins[admin];
	}

	function removeAdmin(address admin) external onlyAdmin returns(bool success){
		admins[admin] = false;
		emit AdminRemoved(admin);
		return !admins[admin];
	}

	// withdraw tokens stuck in the contract
	function withdraw(address returnee, address tokenAddress, uint256 amount)external onlyAdmin returns(bool success){
		IERC20 token = IERC20(tokenAddress);
		uint256 balance = token.balanceOf(address(this));
		require(balance > 0, "There are no tokens to withdraw");
		require(balance >= amount, "Attempting to withdraw more tokens than available");
		require(token.safeTransfer(returnee, amount) == true, "Failed to transfer tokens");
		emit Transfer(address(this), returnee, tokenAddress, amount);
		return true;
	}

	function sendEth(address[] memory recipients, uint256[] memory amounts) public payable reentrancyGuard returns (bool) {
		// input validation
		require(recipients.length == amounts.length, "Recipients array must have same length as amounts");

		// count values for refunding sender
		uint256 sentTotal = 0;

		// loop through recipients and send amount
		for (uint i = 0; i < recipients.length; i++) {
			sentTotal = sentTotal + amounts[i];
			require(sentTotal <= msg.value, "Ran out of funds. 'value' should be at least sum of amounts");
			require(recipients[i].call.value(amounts[i])(), "Failed to send");
			emit Transfer(msg.sender, recipients[i], address(0), amounts[i]);
		}
		// send back remaining value to sender
		uint256 remainingValue = msg.value - sentTotal;
		if (remainingValue > 0) {
			require(msg.sender.call.value(remainingValue)(), "Failed to send remaining back to self");
			emit Transfer(address(this), msg.sender, address(0), remainingValue);
		}
		return true;
	}

	function sendErc20(address tokenAddress, address[] memory recipients, uint256[] memory amounts) public returns (bool) {
		// input validation
		require(recipients.length == amounts.length, "Recipients array must have same length as amounts");

		// use the erc20 abi
		IERC20 token = IERC20(tokenAddress);

		// check if contract is allowed to send total amount
		uint256 total = 0;
		for (uint i = 0; i < recipients.length; i++) {
			total += amounts[i];
		}
		require(token.allowance(msg.sender, address(this)) >= total, "Insufficient token allowance");

		// loop through recipients and send amount
		for (i = 0; i < recipients.length; i++) {
			require(token.safeTransferFrom(msg.sender, recipients[i], amounts[i]) == true, "Failed to transfer");
			emit Transfer(msg.sender, recipients[i], tokenAddress, amounts[i]);
		}
		return true;
	}

}

pragma solidity ^0.4.23;

import "./IERC20.sol";
/**
* @dev Library to perform safe calls to standard method for ERC20 tokens.
*
* Why Transfers: transfer methods could have a return value (bool), throw or revert for insufficient funds or
* unathorized value.
*
* Why Approve: approve method could has a return value (bool) or does not accept 0 as a valid value (BNB token).
* The common strategy used to clean approvals.
*
* We use the Solidity call instead of interface methods because in the case of transfer, it will fail
* for tokens with an implementation without returning a value.
* Since versions of Solidity 0.4.22 the EVM has a new opcode, called RETURNDATASIZE.
* This opcode stores the size of the returned data of an external call. The code checks the size of the return value
* after an external call and reverts the transaction in case the return data is shorter than expected
*/
library SafeERC20 {
    /**
    * @dev Transfer token for a specified address
    * @param _token erc20 The address of the ERC20 contract
    * @param _to address The address which you want to transfer to
    * @param _value uint256 the _value of tokens to be transferred
    * @return bool whether the transfer was successful or not
    */
    function safeTransfer(IERC20 _token, address _to, uint256 _value) internal returns (bool) {
        uint256 prevBalance = _token.balanceOf(address(this));

        if (prevBalance < _value) {
            // Insufficient funds
            return false;
        }

        address(_token).call(
            abi.encodeWithSignature("transfer(address,uint256)", _to, _value)
        );

        // Fail if the new balance its not equal than previous balance sub _value
        return prevBalance - _value == _token.balanceOf(address(this));
    }

    /**
    * @dev Transfer tokens from one address to another
    * @param _token erc20 The address of the ERC20 contract
    * @param _from address The address which you want to send tokens from
    * @param _to address The address which you want to transfer to
    * @param _value uint256 the _value of tokens to be transferred
    * @return bool whether the transfer was successful or not
    */
    function safeTransferFrom(
        IERC20 _token,
        address _from,
        address _to,
        uint256 _value
    ) internal returns (bool)
    {
        uint256 prevBalance = _token.balanceOf(_from);

        if (
          prevBalance < _value || // Insufficient funds
          _token.allowance(_from, address(this)) < _value // Insufficient allowance
        ) {
            return false;
        }

        address(_token).call(
            abi.encodeWithSignature("transferFrom(address,address,uint256)", _from, _to, _value)
        );

        // Fail if the new balance its not equal than previous balance sub _value
        return prevBalance - _value == _token.balanceOf(_from);
    }

   /**
   * @dev Approve the passed address to spend the specified amount of tokens on behalf of msg.sender.
   *
   * Beware that changing an allowance with this method brings the risk that someone may use both the old
   * and the new allowance by unfortunate transaction ordering. One possible solution to mitigate this
   * race condition is to first reduce the spender's allowance to 0 and set the desired value afterwards:
   * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
   *
   * @param _token erc20 The address of the ERC20 contract
   * @param _spender The address which will spend the funds.
   * @param _value The amount of tokens to be spent.
   * @return bool whether the approve was successful or not
   */
    function safeApprove(IERC20 _token, address _spender, uint256 _value) internal returns (bool) {
        address(_token).call(
            abi.encodeWithSignature("approve(address,uint256)",_spender, _value)
        );

        // Fail if the new allowance its not equal than _value
        return _token.allowance(address(this), _spender) == _value;
    }

   /**
   * @dev Clear approval
   * Note that if 0 is not a valid value it will be set to 1.
   * @param _token erc20 The address of the ERC20 contract
   * @param _spender The address which will spend the funds.
   */
    function clearApprove(IERC20 _token, address _spender) internal returns (bool) {
        bool success = safeApprove(_token, _spender, 0);

        if (!success) {
            success = safeApprove(_token, _spender, 1);
        }

        return success;
    }
}

{
  "compilationTarget": {
    "MultiSend.sol": "MultiSend"
  },
  "evmVersion": "byzantium",
  "libraries": {},
  "optimizer": {
    "enabled": false,
    "runs": 200
  },
  "remappings": []
}