// SPDX-License-Identifier: BSD-3-Clause

// File: @openzeppelin/contracts/utils/Strings.sol
// OpenZeppelin Contracts v4.4.1 (utils/Strings.sol)

pragma solidity ^0.8.0;

/**
 * @dev String operations.
 */
library Strings {
    bytes16 private constant _HEX_SYMBOLS = "0123456789abcdef";

    /**
     * @dev Converts a `uint256` to its ASCII `string` decimal representation.
     */
    function toString(uint256 value) internal pure returns (string memory) {
        // Inspired by OraclizeAPI's implementation - MIT licence
        // https://github.com/oraclize/ethereum-api/blob/b42146b063c7d6ee1358846c198246239e9360e8/oraclizeAPI_0.4.25.sol

        if (value == 0) {
            return "0";
        }
        uint256 temp = value;
        uint256 digits;
        while (temp != 0) {
            digits++;
            temp /= 10;
        }
        bytes memory buffer = new bytes(digits);
        while (value != 0) {
            digits -= 1;
            buffer[digits] = bytes1(uint8(48 + uint256(value % 10)));
            value /= 10;
        }
        return string(buffer);
    }

    /**
     * @dev Converts a `uint256` to its ASCII `string` hexadecimal representation.
     */
    function toHexString(uint256 value) internal pure returns (string memory) {
        if (value == 0) {
            return "0x00";
        }
        uint256 temp = value;
        uint256 length = 0;
        while (temp != 0) {
            length++;
            temp >>= 8;
        }
        return toHexString(value, length);
    }

    /**
     * @dev Converts a `uint256` to its ASCII `string` hexadecimal representation with fixed length.
     */
    function toHexString(uint256 value, uint256 length) internal pure returns (string memory) {
        bytes memory buffer = new bytes(2 * length + 2);
        buffer[0] = "0";
        buffer[1] = "x";
        for (uint256 i = 2 * length + 1; i > 1; --i) {
            buffer[i] = _HEX_SYMBOLS[value & 0xf];
            value >>= 4;
        }
        require(value == 0, "Strings: hex length insufficient");
        return string(buffer);
    }
}

// File: @openzeppelin/contracts/utils/Address.sol
// OpenZeppelin Contracts v4.4.1 (utils/Address.sol)

pragma solidity ^0.8.0;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize, which returns 0 for contracts in
        // construction, since the code is only stored at the end of the
        // constructor execution.

        uint256 size;
        assembly {
            size := extcodesize(account)
        }
        return size > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://diligence.consensys.net/posts/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.5.11/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        (bool success, ) = recipient.call{value: amount}("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCall(target, data, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        require(isContract(target), "Address: call to non-contract");

        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        require(isContract(target), "Address: static call to non-contract");

        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionDelegateCall(target, data, "Address: low-level delegate call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(isContract(target), "Address: delegate call to non-contract");

        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Tool to verifies that a low level call was successful, and revert if it wasn't, either by bubbling the
     * revert reason using the provided one.
     *
     * _Available since v4.3._
     */
    function verifyCallResult(
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal pure returns (bytes memory) {
        if (success) {
            return returndata;
        } else {
            // Look for revert reason and bubble it up if present
            if (returndata.length > 0) {
                // The easiest way to bubble the revert reason is using memory via assembly

                assembly {
                    let returndata_size := mload(returndata)
                    revert(add(32, returndata), returndata_size)
                }
            } else {
                revert(errorMessage);
            }
        }
    }
}

// File: @openzeppelin/contracts/token/ERC721/IERC721Receiver.sol
// OpenZeppelin Contracts v4.4.1 (token/ERC721/IERC721Receiver.sol)

pragma solidity ^0.8.0;

/**
 * @title ERC721 token receiver interface
 * @dev Interface for any contract that wants to support safeTransfers
 * from ERC721 asset contracts.
 */
interface IERC721Receiver {
    /**
     * @dev Whenever an {IERC721} `tokenId` token is transferred to this contract via {IERC721-safeTransferFrom}
     * by `operator` from `from`, this function is called.
     *
     * It must return its Solidity selector to confirm the token transfer.
     * If any other value is returned or the interface is not implemented by the recipient, the transfer will be reverted.
     *
     * The selector can be obtained in Solidity with `IERC721.onERC721Received.selector`.
     */
    function onERC721Received(
        address operator,
        address from,
        uint256 tokenId,
        bytes calldata data
    ) external returns (bytes4);
}

// File: @openzeppelin/contracts/utils/introspection/IERC165.sol
// OpenZeppelin Contracts v4.4.1 (utils/introspection/IERC165.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[EIP].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[EIP section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}

// File: @openzeppelin/contracts/utils/introspection/ERC165.sol
// OpenZeppelin Contracts v4.4.1 (utils/introspection/ERC165.sol)

pragma solidity ^0.8.0;


/**
 * @dev Implementation of the {IERC165} interface.
 *
 * Contracts that want to implement ERC165 should inherit from this contract and override {supportsInterface} to check
 * for the additional interface id that will be supported. For example:
 *
 * ```solidity
 * function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
 *     return interfaceId == type(MyInterface).interfaceId || super.supportsInterface(interfaceId);
 * }
 * ```
 *
 * Alternatively, {ERC165Storage} provides an easier to use but more expensive implementation.
 */
abstract contract ERC165 is IERC165 {
    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
        return interfaceId == type(IERC165).interfaceId;
    }
}

// File: @openzeppelin/contracts/token/ERC721/IERC721.sol
// OpenZeppelin Contracts v4.4.1 (token/ERC721/IERC721.sol)

pragma solidity ^0.8.0;

/**
 * @dev Required interface of an ERC721 compliant contract.
 */
interface IERC721 is IERC165 {
    /**
     * @dev Emitted when `tokenId` token is transferred from `from` to `to`.
     */
    event Transfer(address indexed from, address indexed to, uint256 indexed tokenId);

    /**
     * @dev Emitted when `owner` enables `approved` to manage the `tokenId` token.
     */
    event Approval(address indexed owner, address indexed approved, uint256 indexed tokenId);

    /**
     * @dev Emitted when `owner` enables or disables (`approved`) `operator` to manage all of its assets.
     */
    event ApprovalForAll(address indexed owner, address indexed operator, bool approved);

    /**
     * @dev Returns the number of tokens in ``owner``'s account.
     */
    function balanceOf(address owner) external view returns (uint256 balance);

    /**
     * @dev Returns the owner of the `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function ownerOf(uint256 tokenId) external view returns (address owner);

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`, checking first that contract recipients
     * are aware of the ERC721 protocol to prevent tokens from being forever locked.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must be have been allowed to move this token by either {approve} or {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId
    ) external;

    /**
     * @dev Transfers `tokenId` token from `from` to `to`.
     *
     * WARNING: Usage of this method is discouraged, use {safeTransferFrom} whenever possible.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(
        address from,
        address to,
        uint256 tokenId
    ) external;

    /**
     * @dev Gives permission to `to` to transfer `tokenId` token to another account.
     * The approval is cleared when the token is transferred.
     *
     * Only a single account can be approved at a time, so approving the zero address clears previous approvals.
     *
     * Requirements:
     *
     * - The caller must own the token or be an approved operator.
     * - `tokenId` must exist.
     *
     * Emits an {Approval} event.
     */
    function approve(address to, uint256 tokenId) external;

    /**
     * @dev Returns the account approved for `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function getApproved(uint256 tokenId) external view returns (address operator);

    /**
     * @dev Approve or remove `operator` as an operator for the caller.
     * Operators can call {transferFrom} or {safeTransferFrom} for any token owned by the caller.
     *
     * Requirements:
     *
     * - The `operator` cannot be the caller.
     *
     * Emits an {ApprovalForAll} event.
     */
    function setApprovalForAll(address operator, bool _approved) external;

    /**
     * @dev Returns if the `operator` is allowed to manage all of the assets of `owner`.
     *
     * See {setApprovalForAll}
     */
    function isApprovedForAll(address owner, address operator) external view returns (bool);

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId,
        bytes calldata data
    ) external;
}

// File: @openzeppelin/contracts/token/ERC721/extensions/IERC721Metadata.sol
// OpenZeppelin Contracts v4.4.1 (token/ERC721/extensions/IERC721Metadata.sol)

pragma solidity ^0.8.0;


/**
 * @title ERC-721 Non-Fungible Token Standard, optional metadata extension
 * @dev See https://eips.ethereum.org/EIPS/eip-721
 */
interface IERC721Metadata is IERC721 {
    /**
     * @dev Returns the token collection name.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the token collection symbol.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the Uniform Resource Identifier (URI) for `tokenId` token.
     */
    function tokenURI(uint256 tokenId) external view returns (string memory);
}

// File: @openzeppelin/contracts/utils/Context.sol


// OpenZeppelin Contracts v4.4.1 (utils/Context.sol)

pragma solidity ^0.8.0;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}

// File: contracts/ERC721B.sol

pragma solidity ^0.8.0;

abstract contract ERC721B is Context, ERC165, IERC721, IERC721Metadata {
    using Address for address;

    // Token name
    string private _name;

    // Token symbol
    string private _symbol;

    // Mapping from token ID to owner address
    address[] internal _owners;

    // Mapping from token ID to approved address
    mapping(uint256 => address) private _tokenApprovals;

    // Mapping from owner to operator approvals
    mapping(address => mapping(address => bool)) private _operatorApprovals;

    /**
     * @dev Initializes the contract by setting a `name` and a `symbol` to the token collection.
     */
    constructor(string memory name_, string memory symbol_) {
        _name = name_;
        _symbol = symbol_;
    }

    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override(ERC165, IERC165) returns (bool) {
        return
            interfaceId == type(IERC721).interfaceId ||
            interfaceId == type(IERC721Metadata).interfaceId ||
            super.supportsInterface(interfaceId);
    }

    /**
     * @dev See {IERC721-balanceOf}.
     */
    function balanceOf(address owner) public view virtual override returns (uint256) {
        require(owner != address(0), "ERC721: balance query for the zero address");

        uint count = 0;
        uint length = _owners.length;
        for( uint i = 0; i < length; ++i ){
          if( owner == _owners[i] ){
            ++count;
          }
        }

        delete length;
        return count;
    }

    /**
     * @dev See {IERC721-ownerOf}.
     */
    function ownerOf(uint256 tokenId) public view virtual override returns (address) {
        address owner = _owners[tokenId];
        require(owner != address(0), "ERC721: owner query for nonexistent token");
        return owner;
    }

    /**
     * @dev See {IERC721Metadata-name}.
     */
    function name() public view virtual override returns (string memory) {
        return _name;
    }

    /**
     * @dev See {IERC721Metadata-symbol}.
     */
    function symbol() public view virtual override returns (string memory) {
        return _symbol;
    }

    /**
     * @dev See {IERC721-approve}.
     */
    function approve(address to, uint256 tokenId) public virtual override {
        address owner = ERC721B.ownerOf(tokenId);
        require(to != owner, "ERC721: approval to current owner");

        require(
            _msgSender() == owner || isApprovedForAll(owner, _msgSender()),
            "ERC721: approve caller is not owner nor approved for all"
        );

        _approve(to, tokenId);
    }

    /**
     * @dev See {IERC721-getApproved}.
     */
    function getApproved(uint256 tokenId) public view virtual override returns (address) {
        require(_exists(tokenId), "ERC721: approved query for nonexistent token");

        return _tokenApprovals[tokenId];
    }

    /**
     * @dev See {IERC721-setApprovalForAll}.
     */
    function setApprovalForAll(address operator, bool approved) public virtual override {
        require(operator != _msgSender(), "ERC721: approve to caller");

        _operatorApprovals[_msgSender()][operator] = approved;
        emit ApprovalForAll(_msgSender(), operator, approved);
    }

    /**
     * @dev See {IERC721-isApprovedForAll}.
     */
    function isApprovedForAll(address owner, address operator) public view virtual override returns (bool) {
        return _operatorApprovals[owner][operator];
    }


    /**
     * @dev See {IERC721-transferFrom}.
     */
    function transferFrom(
        address from,
        address to,
        uint256 tokenId
    ) public virtual override {
        //solhint-disable-next-line max-line-length
        require(_isApprovedOrOwner(_msgSender(), tokenId), "ERC721: transfer caller is not owner nor approved");

        _transfer(from, to, tokenId);
    }

    /**
     * @dev See {IERC721-safeTransferFrom}.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId
    ) public virtual override {
        safeTransferFrom(from, to, tokenId, "");
    }

    /**
     * @dev See {IERC721-safeTransferFrom}.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId,
        bytes memory _data
    ) public virtual override {
        require(_isApprovedOrOwner(_msgSender(), tokenId), "ERC721: transfer caller is not owner nor approved");
        _safeTransfer(from, to, tokenId, _data);
    }

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`, checking first that contract recipients
     * are aware of the ERC721 protocol to prevent tokens from being forever locked.
     *
     * `_data` is additional data, it has no specified format and it is sent in call to `to`.
     *
     * This internal function is equivalent to {safeTransferFrom}, and can be used to e.g.
     * implement alternative mechanisms to perform token transfer, such as signature-based.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function _safeTransfer(
        address from,
        address to,
        uint256 tokenId,
        bytes memory _data
    ) internal virtual {
        _transfer(from, to, tokenId);
        require(_checkOnERC721Received(from, to, tokenId, _data), "ERC721: transfer to non ERC721Receiver implementer");
    }

    /**
     * @dev Returns whether `tokenId` exists.
     *
     * Tokens can be managed by their owner or approved accounts via {approve} or {setApprovalForAll}.
     *
     * Tokens start existing when they are minted (`_mint`),
     * and stop existing when they are burned (`_burn`).
     */
    function _exists(uint256 tokenId) internal view virtual returns (bool) {
        return tokenId < _owners.length && _owners[tokenId] != address(0);
    }

    /**
     * @dev Returns whether `spender` is allowed to manage `tokenId`.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function _isApprovedOrOwner(address spender, uint256 tokenId) internal view virtual returns (bool) {
        require(_exists(tokenId), "ERC721: operator query for nonexistent token");
        address owner = ERC721B.ownerOf(tokenId);
        return (spender == owner || getApproved(tokenId) == spender || isApprovedForAll(owner, spender));
    }

    /**
     * @dev Safely mints `tokenId` and transfers it to `to`.
     *
     * Requirements:
     *
     * - `tokenId` must not exist.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function _safeMint(address to, uint256 tokenId) internal virtual {
        _safeMint(to, tokenId, "");
    }


    /**
     * @dev Same as {xref-ERC721-_safeMint-address-uint256-}[`_safeMint`], with an additional `data` parameter which is
     * forwarded in {IERC721Receiver-onERC721Received} to contract recipients.
     */
    function _safeMint(
        address to,
        uint256 tokenId,
        bytes memory _data
    ) internal virtual {
        _mint(to, tokenId);
        require(
            _checkOnERC721Received(address(0), to, tokenId, _data),
            "ERC721: transfer to non ERC721Receiver implementer"
        );
    }

    /**
     * @dev Mints `tokenId` and transfers it to `to`.
     *
     * WARNING: Usage of this method is discouraged, use {_safeMint} whenever possible
     *
     * Requirements:
     *
     * - `tokenId` must not exist.
     * - `to` cannot be the zero address.
     *
     * Emits a {Transfer} event.
     */
    function _mint(address to, uint256 tokenId) internal virtual {
        require(to != address(0), "ERC721: mint to the zero address");
        require(!_exists(tokenId), "ERC721: token already minted");

        _beforeTokenTransfer(address(0), to, tokenId);
        _owners.push(to);

        emit Transfer(address(0), to, tokenId);
    }

    /**
     * @dev Destroys `tokenId`.
     * The approval is cleared when the token is burned.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     *
     * Emits a {Transfer} event.
     */
    function _burn(uint256 tokenId) internal virtual {
        address owner = ERC721B.ownerOf(tokenId);

        _beforeTokenTransfer(owner, address(0), tokenId);

        // Clear approvals
        _approve(address(0), tokenId);
        _owners[tokenId] = address(0);

        emit Transfer(owner, address(0), tokenId);
    }

    /**
     * @dev Transfers `tokenId` from `from` to `to`.
     *  As opposed to {transferFrom}, this imposes no restrictions on msg.sender.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     * - `tokenId` token must be owned by `from`.
     *
     * Emits a {Transfer} event.
     */
    function _transfer(
        address from,
        address to,
        uint256 tokenId
    ) internal virtual {
        require(ERC721B.ownerOf(tokenId) == from, "ERC721: transfer of token that is not own");
        require(to != address(0), "ERC721: transfer to the zero address");

        _beforeTokenTransfer(from, to, tokenId);

        // Clear approvals from the previous owner
        _approve(address(0), tokenId);
        _owners[tokenId] = to;

        emit Transfer(from, to, tokenId);
    }

    /**
     * @dev Approve `to` to operate on `tokenId`
     *
     * Emits a {Approval} event.
     */
    function _approve(address to, uint256 tokenId) internal virtual {
        _tokenApprovals[tokenId] = to;
        emit Approval(ERC721B.ownerOf(tokenId), to, tokenId);
    }

    /**
     * @dev Internal function to invoke {IERC721Receiver-onERC721Received} on a target address.
     * The call is not executed if the target address is not a contract.
     *
     * @param from address representing the previous owner of the given token ID
     * @param to target address that will receive the tokens
     * @param tokenId uint256 ID of the token to be transferred
     * @param _data bytes optional data to send along with the call
     * @return bool whether the call correctly returned the expected magic value
     */
    function _checkOnERC721Received(
        address from,
        address to,
        uint256 tokenId,
        bytes memory _data
    ) private returns (bool) {
        if (to.isContract()) {
            try IERC721Receiver(to).onERC721Received(_msgSender(), from, tokenId, _data) returns (bytes4 retval) {
                return retval == IERC721Receiver.onERC721Received.selector;
            } catch (bytes memory reason) {
                if (reason.length == 0) {
                    revert("ERC721: transfer to non ERC721Receiver implementer");
                } else {
                    assembly {
                        revert(add(32, reason), mload(reason))
                    }
                }
            }
        } else {
            return true;
        }
    }

    /**
     * @dev Hook that is called before any token transfer. This includes minting
     * and burning.
     *
     * Calling conditions:
     *
     * - When `from` and `to` are both non-zero, ``from``'s `tokenId` will be
     * transferred to `to`.
     * - When `from` is zero, `tokenId` will be minted for `to`.
     * - When `to` is zero, ``from``'s `tokenId` will be burned.
     * - `from` and `to` are never both zero.
     *
     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
     */
    function _beforeTokenTransfer(
        address from,
        address to,
        uint256 tokenId
    ) internal virtual {}
}

// File: @openzeppelin/contracts/access/Ownable.sol
// OpenZeppelin Contracts v4.4.1 (access/Ownable.sol)

pragma solidity ^0.8.0;

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _transferOwnership(_msgSender());
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
        _;
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions anymore. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby removing any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

/*@@((#@&#((((((((/(((((((((((((((((((((((((((((((((((((((((((((((((((((((((((((((#############%%%%%%%%%%%%&&%%%%%%%%%%%%%%%##(((((%
%%(((((((((((((((((((((((((((((((((((((((((((((((((((((((((((((((((((((((#(((((((((((((((((/(((((((((((((((((((((((((((((((((((((@
%%#((((((((((((((((((((((((((((((((((((((((((((((((((((( ((((((((((((((((.((((((((((((((((((((((((((((((((((((((((((((((((((((((((
%#(((((((((((((((((((((((((((((((((((((((((((((((((((((# ((((((((((((((((,*((/((((((((((((((((((((((((((((((((((((((((((((((((((((
%((((((((((((((((((((((((((((((((((((((((((((((((((((((. (((((((((((((/(/. (((((((((((((((((((((((((((((((((((((((((((((((((((((((
&(((((((((((((((((((((((((((((((((((((((((((((((((((((#  #(((((//((((((((. /((((((((((((((((((((((((((((((((((((((((((((((((((((((
&(((((((((((((((((((((((((((((((((((((((((((((((((((((*  /.,***@@@&&(/##&, .((((((((((((((((((((((((((((((((((((((((((((((((((((((
&((((((((((((((((((((((((((((((((((((((((((((((((////(, .%@@@@#@@@@@@@@@&, .#(((((((((((((((((((((((((((((((((((((((((((((((((((((
&((((((((((((((((((((((((((((((((((((((((((//////((((&,  *@@@@@@@@@@@@@@%. .%&((((((((((((((((((((((((((((((((((((((((((((((/(((/(
&(((((((((((((((((((((((((((((((((((///////(((((((((#/.  *&(#%&#%&&&#((%(. .%%%(((((((((((((((((((((((((((((((((((((((((((((((((/(
&(((((((((((((((((((((((((((((///////(((((((((((((((%,,  .(&&@&@&@@&@&%&*...%&&(((((((((((((((((((((((((((((((((/(((((((((((((((((
&((((((((((((((((((((((//////////(((((((((((((((((((&%*. .&@@&#@&&@@&@@@*  ,&&@(((((((((((((((((((((((((((((((((((((((((((((((////
&((((((((((((((((//////////(((((((((((((((((((((((#&&&/,,&&&%/*&&&&@&&&&&&*,@@&&((((((((((((((((/(((((((/(((((((/((((/////((((((((
&((((((((((//////////(((((((((((((((((((((((((((((@@@&%&&&&#/&&&&&&&&&&&&&&@&@%(((((((((((((((/(((((((((((//////((((((((((((((((
&((((///////////(((((((((((((((((((((((((((((((((#@@&&#///,,,^/#%%(#(////(/(/&@@@(((((((((((((((/(((///////(((((((((((((((((((((((
&////////((((((((((((((((((((((((((((((((((((((((#@@&&&&&*(^/^/&#%%%%&%&&%&&&&&@@/((((((((((////////((((((((((((((((((((((((//////
&///((((((((((((((((((((((((((((((((((((((((((((((@&&&&&&/(***(&&&&&&&&@&&&&&&&@%(///////////(/(((((((((((((((((((((//////////////
&(((((((((((((((((((((((((((((((((((((((((((((*(. #@@@&&&/////%&&&&&&&&/&&&&&&&%.,*(.#///((((((((((((((((((((/////////////////////
##((((((((((((((((((((((((((((((((((((((((((((#.**(@&@...*@@@/.(%&&&&@@@&,.,&@@&**..((((((((((((((((((////(((#(///////////////////
#((((((((((((((((((((((((((((((((((((((((((((((/*.,@&&/*,....*,/...^/*....,/&&@(..//(((((((((((//////////((%%%(%&/////////////////
&(((((((((((((((((((((((((((((((((((((((((((((((#,.@%/..^^/*,.,.......,//*..*%@/.#/((((/////////////(((###%%%%%#%%%%//////////////
&(((((((((((((((((((((((((((((((((((((((((((//////(@#/.    ............     .(&&(*//////////////////%#(#%%%&##&%#/////////////////
/*((((((((((((((((((((((((((((((((((((////////(///(#&%(..........*./..........%&&#//////////////////#(#//%(((%(.#%%%&//////////////
&(((((((((((((((((((((((((((((/////((((((//////////(&%(,.........,/(,......%/%&&///////////////////(##%%#(##%&#/#/////////////////
&(((((((((((((((((((((((///(/(((((((////////////////@%((#%...%%%#(###.../@@@/#%@///////////////////%%(*(#%*,%(%#(/////////////((((
&((((((((((((((((/(((((((((((((////////////////((///&%/((#@@@...,*,,.(@@@@@@(/%&///////////////////&(#%%(%(##(#/////////(((((((///
&(((((((((((((((((((((((((//////////////////////////(&///#@@@@(*(/(*(@@@@@@&#/%#////////////////////#%&%(%.(#/(////(((((//////////
&(((((((((((((((((((((///////////////////////////////&(/((@@@%&*****,&#%@@@%&/#(/////////////////////((##/*#%%(((/////////////////
&(((((((/(((((((/////////////////////////////////////#(/#/%&&&,/&%.&%#(%@@@&@(((&&&&&(/////////(((////(%###%*#////////////////////
&((((((((((((/////////////////////////////////////////(/#(%@,....,(,..,/(##&&&#&&&&&#&&((((((/////////(###%/%/////////////////////
%(((((((///////////////////////////////////////%&&&&&&&&&&&#  ..,(,^/..,&&&&&&&&&&&&&&&&(//////////////#(#%%//////////////////////
/*(((///////////////////////////////////////(&&((&&&&&&&%#(/#&&&&(%&%*&&&&&&&&&&&&&&&&&&&&/////////////(,##%(//////////////////////
%///////////////////////////////////////(&&&&&&&&&&&&&&&&&&&&&&(%&&&&%(&&&&//&&&&%&&&&&&&#////////////&%#%&///////////////////////
%/////////////(///////////////////////&&&&&&&&&&&&&&&&&&&&&&&&(%&&&&&&&&&%&&&&&&@@&&&&&%%&(//////////#%&#%#///////////////////////
%(////////((///////////////////////(&//#&&&&&&&&&&&(&&&&&&&&&/&&&&&&&&&&&&%//%&&&@&&&&&&/(&/////////(&&&###///////////////////////
%(///((((////////////////////////&&/%&&&&&&&&&&&@@&@&&&&&&&#&&&&&&&&&&&&&&&&&%#&&&@&&&&&&/(&///////(&&&&##%///////////////////////
%((((/////////////////////////(&&(&&&&&&&&&&&@(////&&&&&&&(%&&&&&&&&&&&(/&&&&&/%#&&&@&&&&&%(&//////&(&&&(#%///////////////////////
%#//////((//////////////////&&&&&&&&&&&&&&&(//////%&&&&&(&&&&&&&&&&&&&&&&&&&&&////##&&&&&&&%%&////(%%&&&&#%///////////////////////
%#/(((///////////////////#&&%&&&&&&&&&&%////////((&&&/%%/&&&&&&&&&&&&&&&&&&&&&&&&&&&&%&#&&&&%&&///&/&&&&&&%///////////////////////
%#////////////////////(&&%%&&&&&&&&&%///////(((((&#%&&%((&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&/(&&&&&&&&#(//////////////////////
#%//////////////////&&&&&&&&#&&&&(//////(((//////&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&@&&&&&&&&%&#&&&&&&&#(//////////////////////
#%///////////////(&&&&&&&&&&&&(/////(((//////////#&&&&&&&&&&&%///(.......(*^/(#&&&&&&&&&&&&&&&&&@&&%&&&&&&##//////////////////////
#%///////////////(&&&&&%#&&(/////((////////////////&&#**,,****^//..........,*(##(#%////(@&&&&&%&&&&%&&&&&%&#//////////////////////
#%////////////////&&&&&//&%//((///////////////////////%(///((**...................#//////%&&&&&&%%&&&&&&&%&(//////////////////////
#%////////////////(&&&&&#/&%///////////////////////////(*((/***...................(////////&&&&&%#&&&&&%#&&///////////////////////
#&/////////////////%&&&&&%#&(/////////////////////////////^/.*.***..............*%///////////%&&&#&&&&&%&%////////////////////////
#&//////////////////%&&&&&%&&///////////////////////////#,&/.*,...**...........(%//////////////#((#&&&&%//////////////////////////
(&///////////////////%&&&&&&&&////////////////////////////.,,.............*(./,(%////////////////%%###////////////////////////////
(%////////////////////(&&&&&&&#//////////////////////////% ............*,.(..**(#/////////////////#%//////////////////////////////
(%//////////////////////%&&&&&&////////////////////////#*. ...........(*..//././#/////////////////(///////////////////////////////
(%///////////////////////(&&&&&&////////////////////(/.   .....................*%/////////////////(///////////////////////////////
(%/////////////////////////%&&&&&/////////////////#.@&........................,*(/////////////////#///////////////////////////////
(%//////////////////////////(&&&&&////(%/..,(,.#.   .&%...............*.......,**(////////////////////////////////////////////////
(%////////////////////////////@&@//(...*#(#&&@%.*  ...#&............ *,.......,*.&////////////////////////////////////////////////
(%//////////////////////////////*... .,,... .*&@&%,....#@.....................*.@%*///////////////////////////////////////////////
/*//////////////////////////////^**....,,***.,,&&&&&&,..&@%..................,%%....#////////////////////////////////////////////(
/#///////////////////////////////#%#/**,,#&@#&/&&&,.&&&&%@@@&...............&&.... ..%(//////////////////////////////////////////(
/(//////////////////////////////&@&&&%%@%.@&&%,&%&&&&&&&&*&&&@@&,.......*&@@,.../&&&&&&&&////////////////////////////////////////(
/(////////////////////////////(%&&&&///#@*%&&&&*&@@@@@&%&&&&&&###&&&&&&(#%&&#&&&&&(.&&&##(,./////////////////////////////////////(
/////////////////////////////(&%&&#///%&&&&&&&&&&&&&&&&@@@@@@@##&(#&%%&##&&&&##&&&&&&(&@@%////////////////////////////////////////
/////////////////////////////&&#&(///&&&&&&&&&&&&&&&&&&&&&&&&&&&&%&&@#@@&@@@@@@@&@@&@&&&&&#///////////////////////////////////////
////////////////////////////%&@&(//#&&&&&&&&&&&&%&&&&&&&&&&&&&&%/%&&&/&&&&&&&@&&&&&&&&&&&&&%//////////////////////////////////////
////////////////////////////&&&&(#/&&&&&&&&&&&&&&&&&&&&&&&&&*#&&%&&&@@%#&%&&&&&&&&&&&&&&&&&&%////////////////////////////////////(
///////////////////////////%&&&//%@%#&&&&&&&&&&&&&&&&&&&(&&@@&&%&&&&&&@&%#&&&&&&&&&&&&&(/&&&&#///////////////////////////////////(
///////////////////////////@&&(//&&&&&&&(*@&&&&&&&,%&#&&@@@&&&&&&&&@&&&&@&%/&&&&&&&&&&&///&&&&///////////////////////////////////(
//////////////////////////(&&&//%&&&&&&&&&&&&@@@@@@@@@&&&@//(%&%&&&&&&&&&&@@&%&&&&&&&&#////&&&&//////////////////////////////////#
//////////////////////////#&&&//&&&&&&&&&&&&&&&&&&&&&&&&&&//////&&&&&&&&&&&&&@&#*&&&&&&/////&&&%/////////////////////////////////#
(/////////////////////////%&&&//&&&&&&&&&&&&&&&&&&&&&&&&&&///////&&&&&&&&&&&&&&&@&%&&&&&////&&&&/////////////////////////////////#
#/////////////////////////&&&&/#&&&&&&&&&&&&&&&&&&&&&&&&&(///////%&&&&&&&&&&&&&&&&&@&%%#*///(&&&&////////////////////////////////%
/*/////////////////////////&&&&(%&&&&&&&&&&&&&&&&&&&&&&&&&/////////&&&&&&&&&&&&&&&&&&&&&&&%(##&@@&@@@@@@&&&&&&&%#///////////////#&%*/

// ******** DEVIL CHICKS *********

pragma solidity ^0.8.10;

contract DevilChicks is Ownable, ERC721B {
    using Strings for uint256;

    uint256 private constant MAX_MINT = 2666;
    uint256 private constant MINT_PRICE = 0.02 ether;
    uint256 private constant T_MINT = 10;
    uint256 private _available;
    
    string private _contractURI;
    string private _baseURI;
    string private _notRevealedURI = "ipfs://QmUvCeboAPHDj5magQddFj9Z5mKb4yEzwBb8Q5qpkX84jj";
    string private _baseExtension = ".json";
    
    address private _vaultAddress = 0x94FAeC8839C37dA88b495243b85A75d06bdD6dab;

    bool private saleActive;
    bool private revealed;
   
    constructor() ERC721B("Devil Chicks", "DVLCKS") {
        _owners.push(address(0));
    }
    
    function mint(uint256 _amount) external payable {
        require(saleActive, "SALE_CLOSED");
        require(_amount * MINT_PRICE <= msg.value, "INSUFFICIENT_ETH");
        require(_amount <= T_MINT, "MAX_AMOUNT_PER_MINT");
        require(_amount <= _available, "MAX_SALE_SUPPLY");

        for(uint256 i = 0; i < _amount; i++) {
            _safeMint(msg.sender, _owners.length);
        }

        _available -= _amount;
    } 

    function setVaultAddress(address addr) external onlyOwner {
        _vaultAddress = addr;
    }

    function setBaseURI(string memory URI) external onlyOwner {
        _baseURI = URI;
    }

    function setNotRevealURI(string memory URI) external onlyOwner {
        _notRevealedURI = URI;
    }

    function setBaseExtension(string memory extension) external onlyOwner { 
        _baseExtension = extension;
    }

    function setReserve(uint256 reserve) external onlyOwner {
        _available = MAX_MINT - reserve - _owners.length + 1;
    }
    
    function setContractURI(string calldata URI) external onlyOwner {
        _contractURI = URI;
    }
    
    function totalSupply() external view returns (uint256) {
        return _owners.length - 1;
    }

    function contractURI() external view returns (string memory) {
        return _contractURI;
    } 

    function tokenURI(uint256 tokenId) external view virtual override returns (string memory) {
        require(_exists(tokenId), "ERC721Metadata: URI query for nonexistent token");

        if (!revealed) {
            return _notRevealedURI;
        }
        
        return string(abi.encodePacked(_baseURI, tokenId.toString(), _baseExtension));    
    }

// admin commands
    function gift(address[] calldata receivers) external onlyOwner {
        require(receivers.length + _owners.length - 1 <= MAX_MINT, "MAX_MINT");
        
        for (uint256 i = 0; i < receivers.length; i++) {
            _safeMint(receivers[i], _owners.length);
        }

        _available = _available < receivers.length ? 0 : _available - receivers.length;
    }

    function switchSale() external onlyOwner {
        saleActive = !saleActive;
    }

    function reveal() external onlyOwner {
        revealed = !revealed;
    }

    function withdraw() external onlyOwner {
        (bool success, ) = payable(_vaultAddress).call{value: address(this).balance}("");
        require(success);
    }
}

{
  "compilationTarget": {
    "contracts/DevilChicks.sol": "DevilChicks"
  },
  "evmVersion": "london",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": true,
    "runs": 200
  },
  "remappings": []
}