// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/ERC20.sol)

pragma solidity ^0.8.20;

import {IERC20} from "./IERC20.sol";
import {IERC20Metadata} from "./extensions/IERC20Metadata.sol";
import {Context} from "../../utils/Context.sol";
import {IERC20Errors} from "../../interfaces/draft-IERC6093.sol";

/**
 * @dev Implementation of the {IERC20} interface.
 *
 * This implementation is agnostic to the way tokens are created. This means
 * that a supply mechanism has to be added in a derived contract using {_mint}.
 *
 * TIP: For a detailed writeup see our guide
 * https://forum.openzeppelin.com/t/how-to-implement-erc20-supply-mechanisms/226[How
 * to implement supply mechanisms].
 *
 * The default value of {decimals} is 18. To change this, you should override
 * this function so it returns a different value.
 *
 * We have followed general OpenZeppelin Contracts guidelines: functions revert
 * instead returning `false` on failure. This behavior is nonetheless
 * conventional and does not conflict with the expectations of ERC20
 * applications.
 *
 * Additionally, an {Approval} event is emitted on calls to {transferFrom}.
 * This allows applications to reconstruct the allowance for all accounts just
 * by listening to said events. Other implementations of the EIP may not emit
 * these events, as it isn't required by the specification.
 */
abstract contract ERC20 is Context, IERC20, IERC20Metadata, IERC20Errors {
    mapping(address account => uint256) private _balances;

    mapping(address account => mapping(address spender => uint256)) private _allowances;

    uint256 private _totalSupply;

    string private _name;
    string private _symbol;

    /**
     * @dev Sets the values for {name} and {symbol}.
     *
     * All two of these values are immutable: they can only be set once during
     * construction.
     */
    constructor(string memory name_, string memory symbol_) {
        _name = name_;
        _symbol = symbol_;
    }

    /**
     * @dev Returns the name of the token.
     */
    function name() public view virtual returns (string memory) {
        return _name;
    }

    /**
     * @dev Returns the symbol of the token, usually a shorter version of the
     * name.
     */
    function symbol() public view virtual returns (string memory) {
        return _symbol;
    }

    /**
     * @dev Returns the number of decimals used to get its user representation.
     * For example, if `decimals` equals `2`, a balance of `505` tokens should
     * be displayed to a user as `5.05` (`505 / 10 ** 2`).
     *
     * Tokens usually opt for a value of 18, imitating the relationship between
     * Ether and Wei. This is the default value returned by this function, unless
     * it's overridden.
     *
     * NOTE: This information is only used for _display_ purposes: it in
     * no way affects any of the arithmetic of the contract, including
     * {IERC20-balanceOf} and {IERC20-transfer}.
     */
    function decimals() public view virtual returns (uint8) {
        return 18;
    }

    /**
     * @dev See {IERC20-totalSupply}.
     */
    function totalSupply() public view virtual returns (uint256) {
        return _totalSupply;
    }

    /**
     * @dev See {IERC20-balanceOf}.
     */
    function balanceOf(address account) public view virtual returns (uint256) {
        return _balances[account];
    }

    /**
     * @dev See {IERC20-transfer}.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     * - the caller must have a balance of at least `value`.
     */
    function transfer(address to, uint256 value) public virtual returns (bool) {
        address owner = _msgSender();
        _transfer(owner, to, value);
        return true;
    }

    /**
     * @dev See {IERC20-allowance}.
     */
    function allowance(address owner, address spender) public view virtual returns (uint256) {
        return _allowances[owner][spender];
    }

    /**
     * @dev See {IERC20-approve}.
     *
     * NOTE: If `value` is the maximum `uint256`, the allowance is not updated on
     * `transferFrom`. This is semantically equivalent to an infinite approval.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function approve(address spender, uint256 value) public virtual returns (bool) {
        address owner = _msgSender();
        _approve(owner, spender, value);
        return true;
    }

    /**
     * @dev See {IERC20-transferFrom}.
     *
     * Emits an {Approval} event indicating the updated allowance. This is not
     * required by the EIP. See the note at the beginning of {ERC20}.
     *
     * NOTE: Does not update the allowance if the current allowance
     * is the maximum `uint256`.
     *
     * Requirements:
     *
     * - `from` and `to` cannot be the zero address.
     * - `from` must have a balance of at least `value`.
     * - the caller must have allowance for ``from``'s tokens of at least
     * `value`.
     */
    function transferFrom(address from, address to, uint256 value) public virtual returns (bool) {
        address spender = _msgSender();
        _spendAllowance(from, spender, value);
        _transfer(from, to, value);
        return true;
    }

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to`.
     *
     * This internal function is equivalent to {transfer}, and can be used to
     * e.g. implement automatic token fees, slashing mechanisms, etc.
     *
     * Emits a {Transfer} event.
     *
     * NOTE: This function is not virtual, {_update} should be overridden instead.
     */
    function _transfer(address from, address to, uint256 value) internal {
        if (from == address(0)) {
            revert ERC20InvalidSender(address(0));
        }
        if (to == address(0)) {
            revert ERC20InvalidReceiver(address(0));
        }
        _update(from, to, value);
    }

    /**
     * @dev Transfers a `value` amount of tokens from `from` to `to`, or alternatively mints (or burns) if `from`
     * (or `to`) is the zero address. All customizations to transfers, mints, and burns should be done by overriding
     * this function.
     *
     * Emits a {Transfer} event.
     */
    function _update(address from, address to, uint256 value) internal virtual {
        if (from == address(0)) {
            // Overflow check required: The rest of the code assumes that totalSupply never overflows
            _totalSupply += value;
        } else {
            uint256 fromBalance = _balances[from];
            if (fromBalance < value) {
                revert ERC20InsufficientBalance(from, fromBalance, value);
            }
            unchecked {
                // Overflow not possible: value <= fromBalance <= totalSupply.
                _balances[from] = fromBalance - value;
            }
        }

        if (to == address(0)) {
            unchecked {
                // Overflow not possible: value <= totalSupply or value <= fromBalance <= totalSupply.
                _totalSupply -= value;
            }
        } else {
            unchecked {
                // Overflow not possible: balance + value is at most totalSupply, which we know fits into a uint256.
                _balances[to] += value;
            }
        }

        emit Transfer(from, to, value);
    }

    /**
     * @dev Creates a `value` amount of tokens and assigns them to `account`, by transferring it from address(0).
     * Relies on the `_update` mechanism
     *
     * Emits a {Transfer} event with `from` set to the zero address.
     *
     * NOTE: This function is not virtual, {_update} should be overridden instead.
     */
    function _mint(address account, uint256 value) internal {
        if (account == address(0)) {
            revert ERC20InvalidReceiver(address(0));
        }
        _update(address(0), account, value);
    }

    /**
     * @dev Destroys a `value` amount of tokens from `account`, lowering the total supply.
     * Relies on the `_update` mechanism.
     *
     * Emits a {Transfer} event with `to` set to the zero address.
     *
     * NOTE: This function is not virtual, {_update} should be overridden instead
     */
    function _burn(address account, uint256 value) internal {
        if (account == address(0)) {
            revert ERC20InvalidSender(address(0));
        }
        _update(account, address(0), value);
    }

    /**
     * @dev Sets `value` as the allowance of `spender` over the `owner` s tokens.
     *
     * This internal function is equivalent to `approve`, and can be used to
     * e.g. set automatic allowances for certain subsystems, etc.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `owner` cannot be the zero address.
     * - `spender` cannot be the zero address.
     *
     * Overrides to this logic should be done to the variant with an additional `bool emitEvent` argument.
     */
    function _approve(address owner, address spender, uint256 value) internal {
        _approve(owner, spender, value, true);
    }

    /**
     * @dev Variant of {_approve} with an optional flag to enable or disable the {Approval} event.
     *
     * By default (when calling {_approve}) the flag is set to true. On the other hand, approval changes made by
     * `_spendAllowance` during the `transferFrom` operation set the flag to false. This saves gas by not emitting any
     * `Approval` event during `transferFrom` operations.
     *
     * Anyone who wishes to continue emitting `Approval` events on the`transferFrom` operation can force the flag to
     * true using the following override:
     * ```
     * function _approve(address owner, address spender, uint256 value, bool) internal virtual override {
     *     super._approve(owner, spender, value, true);
     * }
     * ```
     *
     * Requirements are the same as {_approve}.
     */
    function _approve(address owner, address spender, uint256 value, bool emitEvent) internal virtual {
        if (owner == address(0)) {
            revert ERC20InvalidApprover(address(0));
        }
        if (spender == address(0)) {
            revert ERC20InvalidSpender(address(0));
        }
        _allowances[owner][spender] = value;
        if (emitEvent) {
            emit Approval(owner, spender, value);
        }
    }

    /**
     * @dev Updates `owner` s allowance for `spender` based on spent `value`.
     *
     * Does not update the allowance value in case of infinite allowance.
     * Revert if not enough allowance is available.
     *
     * Does not emit an {Approval} event.
     */
    function _spendAllowance(address owner, address spender, uint256 value) internal virtual {
        uint256 currentAllowance = allowance(owner, spender);
        if (currentAllowance != type(uint256).max) {
            if (currentAllowance < value) {
                revert ERC20InsufficientAllowance(spender, currentAllowance, value);
            }
            unchecked {
                _approve(owner, spender, currentAllowance - value, false);
            }
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/extensions/ERC20Burnable.sol)

pragma solidity ^0.8.20;

import {ERC20} from "../ERC20.sol";
import {Context} from "../../../utils/Context.sol";

/**
 * @dev Extension of {ERC20} that allows token holders to destroy both their own
 * tokens and those that they have an allowance for, in a way that can be
 * recognized off-chain (via event analysis).
 */
abstract contract ERC20Burnable is Context, ERC20 {
    /**
     * @dev Destroys a `value` amount of tokens from the caller.
     *
     * See {ERC20-_burn}.
     */
    function burn(uint256 value) public virtual {
        _burn(_msgSender(), value);
    }

    /**
     * @dev Destroys a `value` amount of tokens from `account`, deducting from
     * the caller's allowance.
     *
     * See {ERC20-_burn} and {ERC20-allowance}.
     *
     * Requirements:
     *
     * - the caller must have allowance for ``accounts``'s tokens of at least
     * `value`.
     */
    function burnFrom(address account, uint256 value) public virtual {
        _spendAllowance(account, _msgSender(), value);
        _burn(account, value);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/extensions/IERC20Metadata.sol)

pragma solidity ^0.8.20;

import {IERC20} from "../IERC20.sol";

/**
 * @dev Interface for the optional metadata functions from the ERC20 standard.
 */
interface IERC20Metadata is IERC20 {
    /**
     * @dev Returns the name of the token.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the symbol of the token.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the decimals places of the token.
     */
    function decimals() external view returns (uint8);
}

// SPDX-License-Identifier: MIT
pragma solidity =0.8.24;

import {IUniswapV2Router02} from "@uniswap/v2-periphery/contracts/interfaces/IUniswapV2Router02.sol";
import {IMedXTokenEvents} from "./IMedXTokenEvents.sol";
import {IMedXTokenErrors} from "./IMedXTokenErrors.sol";

/// @title Interface of the MedX token contract
/// @author PixelPlex Inc.
interface IMedXToken is IMedXTokenEvents, IMedXTokenErrors {
    // #region public constants
    // solhint-disable func-name-mixedcase
    // slither-disable-start naming-convention

    /// @notice Fee percent on buy
    function BUY_FEE_PERCENT() external pure returns (uint256);

    /// @notice Fee percent on sell
    function SELL_FEE_PERCENT() external pure returns (uint256);

    // slither-disable-end naming-convention
    // solhint-enable func-name-mixedcase
    // #endregion

    /// @dev When contract is deployed, trading on [MedX<=>USDT] and [MedX<=>WETH] Uniswap V2 pairs are disabled
    /// @dev This is used to prevent sniping on release
    /// @dev Trading is always enabled for whitelisted accounts
    /// @return tradingEnableTime Timestamp when trading becomes enabled
    function tradingEnableTime() external view returns (uint256);

    /// @return weth The address of the wrapped ETH contract
    function weth() external view returns (address);

    /// @return wethUniV2Pair The address of the [MEDX<=>WETH] Uniswap V2 pair
    function wethUniV2Pair() external view returns (address);

    /// @return uniV2Router The address of the Uniswap V2 router (Router02)
    function uniV2Router() external view returns (IUniswapV2Router02);

    /// @dev see: IMedXToken#tradingEnableTime
    /// @return tradingEnabled Equals `true` if trading is enabled
    function tradingEnabled() external view returns (bool);

    /// @return feeEnabled Equals `true` if the fee feature is enabled, `false` otherwise
    function feeEnabled() external view returns (bool);

    /// @return admin The address of the admin
    function admin() external view returns (address);

    /// @return feeReceiver The address of the fee receiver
    function feeReceiver() external view returns (address payable);

    /// @notice Checks if an account is whitelisted, meaning the trading fee is not applicable to it
    /// @param account The address of the account to check whitelisting for
    /// @return whitelisted_ Equals `true` if the account is whitelisted, `false` otherwise
    function whitelisted(address account) external view returns (bool whitelisted_);

    /// @notice Checks if an account is blacklisted and cannot send or receive MedX tokens
    /// @param account The address of the account to check blacklisting for
    /// @return blacklisted_ Equals `true` if the account is blacklisted, `false` otherwise
    function blacklisted(address account) external view returns (bool blacklisted_);

    /// @notice Checks if an account is a taxable DEX, to which a fee should be applied
    /// @dev When tokens are sent to the DEX, it is considered a buy operation and 3% of the sent tokens will be
    /// sent to the fee receiver.
    /// @dev When tokens are received from the DEX, it is considered a sell operation and 3% of the received
    /// tokens will be swapped to ETH and sent to the fee receiver.
    /// @param account The address of the account to check if it is a taxable DEX
    /// @return applyTax_ Equals `true` if the account is a taxable DEX, `false` otherwise
    function applyTax(address account) external view returns (bool applyTax_);

    /// @notice Checks if an account is in the burners list
    /// @param account The address of the account to check if it is in the burners list
    /// @return canBurn_ Equals `true` if the account can burn tokens
    function canBurn(address account) external view returns (bool canBurn_);

    // #region ADMIN & OWNER FUNCTIONS

    /// @notice Changes the address of the admin
    /// @dev Can only be called by the owner or the admin
    /// @dev Will succeed, but will not emit any event if the current admin equals `newAdmin`
    /// @param newAdmin The address of the new admin
    /// @return changed Equals `true` if the fee receiver is updated, `false` otherwise
    function updateAdmin(address newAdmin) external returns (bool changed);

    /// @notice Enables or disables the fee feature
    /// @dev Can only be called by the owner or the admin
    /// @dev Will succeed, but will not emit any event if the current fee feature state equals `enabled`
    /// @param enabled Should equal `true` if the fee feature should be enabled, `false` otherwise
    /// @return toggled Equals `true` if the fee feature was toggled, `false` otherwise
    function toggleFee(bool enabled) external returns (bool toggled);

    /// @notice Changes the address of the fee receiver
    /// @dev Can only be called by the owner or the admin
    /// @dev Will succeed, but will not emit any event if the current fee receiver equals `newFeeReceiver`
    /// @param newFeeReceiver The address of the new fee receiver
    /// @return changed Equals `true` if the fee receiver is updated, `false` otherwise
    function updateFeeReceiver(address payable newFeeReceiver) external returns (bool changed);

    /// @notice Updates the whitelist
    /// @dev Can only be called by the owner or the admin
    /// @dev The function will not check if the same address is in both parameters. In this case, the address
    /// will be whitelisted.
    /// @param removeFromWhitelist The list of addresses to be removed from the whitelist
    /// @param addToWhitelist The list of addresses to be added to the whitelist
    function updateWhitelist(address[] calldata removeFromWhitelist, address[] calldata addToWhitelist) external;

    /// @notice Updates the blacklist
    /// @dev Can only be called by the owner or the admin
    /// @dev The function will not check if the same address is in both parameters. In this case, the address
    /// will be blacklisted.
    /// @param removeFromBlacklist The list of addresses to be removed from the blacklist
    /// @param addToBlacklist The list of addresses to be added to the blacklist
    function updateBlacklist(address[] calldata removeFromBlacklist, address[] calldata addToBlacklist) external;

    /// @notice Updates the list of taxable DEX addresses
    /// @dev Can only be called by the owner or the admin
    /// @dev The function will not check if the same address is in both parameters. In this case, the address
    /// will be added to the list.
    /// @param removeFromTaxedList The list of addresses to be removed from the list of taxable DEX addresses
    /// @param addToTaxedList The list of addresses to be added to the list of taxable DEX addresses
    function updateTaxedAddresses(address[] calldata removeFromTaxedList, address[] calldata addToTaxedList) external;

    /// @notice Updates the list of addresses, that can burn tokens
    /// @dev Can only be called by the owner or the admin
    /// @dev The function will not check if the same address is in both parameters. In this case, the address
    /// will be added to the list.
    /// @param removeFromBurnersList The list of addresses to be removed from the burners list
    /// @param addToBurnersList The list of addresses to be added to the burners list
    function updateBurnersList(address[] calldata removeFromBurnersList, address[] calldata addToBurnersList) external;

    // #endregion
}

// SPDX-License-Identifier: MIT
pragma solidity =0.8.24;

/// @title Errors of the MedX token contract
/// @author PixelPlex Inc.
interface IMedXTokenErrors {
    /// @notice Indicates that trading currently is disabled for non-whitelisted accounts
    /// @param tradingEnableTime The timestamp of trading enable
    /// @param currentTime The current timestamp
    error TradingIsDisabled(uint256 tradingEnableTime, uint256 currentTime);

    /// @notice Indicates that provided address is taxed and can not be added to the whitelist
    /// @param account Address of the account to be whitelisted
    error InvalidWhitelistedAccount(address account);

    /// @notice Indicates that provided account can not be added to the blacklist
    /// @param account Address of the account to be blacklisted
    error InvalidBlacklistedAccount(address account);

    /// @notice Indicates that the sender or the receiver is blacklisted
    /// @param account Address of the blacklisted account
    error Blacklisted(address account);

    /// @notice Indicates that the fee receiver is zero address
    /// @dev Fee receiver can be zero address only if the fee feature is disable
    error InvalidFeeReceiver();

    /// @notice Indicates that the function was called by an account that is not the fee receiver
    /// @param account Address of the account that called the function
    error FeeReceiverUnauthorizedAccount(address account);

    /// @notice Indicates that the function was called by an account that is not the owner nor the admin
    /// @param account Address of the account that called the function
    error OwnerOrAdminUnauthorizedAccount(address account);

    /// @notice Indicates that the function was called by an account that is not a burner
    /// @param account Address of the account that called the function
    error BurnerUnauthorizedAccount(address account);
}

// SPDX-License-Identifier: MIT
pragma solidity =0.8.24;

/// @title Events of MedX token contract
/// @author PixelPlex Inc.
interface IMedXTokenEvents {
    /// @notice Emitted when the admin address is updated
    /// @param previousAdmin The address of previous admin
    /// @param newAdmin The address of the new admin
    event AdminUpdated(address indexed previousAdmin, address indexed newAdmin);

    /// @notice Emitted when trading by non-whitelisted accounts are enabled
    event TradingEnabled();

    // #region FEE EVENTS

    /// @notice Emitted when the fee feature is toggled
    /// @param enabled `true` if fee is enabled, `false` otherwise
    event FeeToggled(bool indexed enabled);

    /// @notice Emitted when the fee receiver is updated
    /// @param prevFeeReceiver Address of previous fee receiver
    /// @param newFeeReceiver Address of the new fee receiver
    event FeeReceiverUpdated(address indexed prevFeeReceiver, address indexed newFeeReceiver);

    /// @notice Emitted when fee is collected in MedX tokens
    /// @dev Whenever the user sells MedX tokens the contract charges the fee and sends it to the fee receiver
    /// @param transferFrom Address of the account that sent tokens
    /// @param transferTo Address of the account that received tokens
    /// @param feeReceiver Address of the account that received the fee (current fee receiver)
    /// @param feeValue Amount of tokens that were charged as a fee
    event FeeTokenCollected(
        address indexed transferFrom,
        address indexed transferTo,
        address indexed feeReceiver,
        uint256 feeValue
    );

    /// @notice Emitted when swapping MedX tokens to ETH is failed
    /// @dev Whenever the user buys MedX tokens the contract tries to swap the fee to ETH using UniswapV2
    /// @param amountIn Amount of tokens that were charged as a fee
    /// @param reason Reason of the swap's failure
    event FeeSwapFailed(uint256 amountIn, bytes reason);

    /// @notice Emitted when fee is collected in ETH
    /// @dev Whenever the user buys MedX tokens the contract swaps fee to ETH using UniswapV2.
    /// @dev Swapped ETH is sent to the fee receiver.
    /// @param transferFrom Address of the account that sent tokens
    /// @param transferTo Address of the account that received tokens
    /// @param feeReceiver Address of the account that received the fee (current fee receiver)
    /// @param tokenFeeValue Amount of tokens that were charged as a fee
    /// @param ethFeeValue Amount of ETH received from the swap
    event FeeEthCollected(
        address indexed transferFrom,
        address indexed transferTo,
        address indexed feeReceiver,
        uint256 tokenFeeValue,
        uint256 ethFeeValue
    );

    // #endregion

    /// @notice Emitted when an address is added to or removed from the whitelist
    /// @param account Address of the account that was added to or removed from the whitelist
    /// @param whitelisted `true` if account is added to whitelist, `false` if it was removed
    event WhitelistUpdated(address indexed account, bool indexed whitelisted);

    /// @notice Emitted when an address is added to or removed from the blacklist
    /// @param account Address of the account, that was added to or removed from the blacklist
    /// @param blacklisted `true` if account is added to blacklist, `false` if it was removed
    event BlacklistUpdated(address indexed account, bool indexed blacklisted);

    /// @notice Emitted when an address is added to or removed from the tax list
    /// @param account Address of the account, that was added to or removed from the tax list
    /// @param taxed `true` if account is added to tax list, `false` if it was removed
    event TaxedListUpdated(address indexed account, bool indexed taxed);

    /// @notice Emitted when an address is added to or removed from the burners list
    /// @param account Address of the account, that was added to or removed from the burners list
    /// @param canBurn `true` if account is added to the burners list, `false` if it was removed
    event BurnersListUpdated(address indexed account, bool indexed canBurn);
}

pragma solidity >=0.5.0;

interface IUniswapV2Factory {
    event PairCreated(address indexed token0, address indexed token1, address pair, uint);

    function feeTo() external view returns (address);
    function feeToSetter() external view returns (address);

    function getPair(address tokenA, address tokenB) external view returns (address pair);
    function allPairs(uint) external view returns (address pair);
    function allPairsLength() external view returns (uint);

    function createPair(address tokenA, address tokenB) external returns (address pair);

    function setFeeTo(address) external;
    function setFeeToSetter(address) external;
}

pragma solidity >=0.6.2;

interface IUniswapV2Router01 {
    function factory() external pure returns (address);
    function WETH() external pure returns (address);

    function addLiquidity(
        address tokenA,
        address tokenB,
        uint amountADesired,
        uint amountBDesired,
        uint amountAMin,
        uint amountBMin,
        address to,
        uint deadline
    ) external returns (uint amountA, uint amountB, uint liquidity);
    function addLiquidityETH(
        address token,
        uint amountTokenDesired,
        uint amountTokenMin,
        uint amountETHMin,
        address to,
        uint deadline
    ) external payable returns (uint amountToken, uint amountETH, uint liquidity);
    function removeLiquidity(
        address tokenA,
        address tokenB,
        uint liquidity,
        uint amountAMin,
        uint amountBMin,
        address to,
        uint deadline
    ) external returns (uint amountA, uint amountB);
    function removeLiquidityETH(
        address token,
        uint liquidity,
        uint amountTokenMin,
        uint amountETHMin,
        address to,
        uint deadline
    ) external returns (uint amountToken, uint amountETH);
    function removeLiquidityWithPermit(
        address tokenA,
        address tokenB,
        uint liquidity,
        uint amountAMin,
        uint amountBMin,
        address to,
        uint deadline,
        bool approveMax, uint8 v, bytes32 r, bytes32 s
    ) external returns (uint amountA, uint amountB);
    function removeLiquidityETHWithPermit(
        address token,
        uint liquidity,
        uint amountTokenMin,
        uint amountETHMin,
        address to,
        uint deadline,
        bool approveMax, uint8 v, bytes32 r, bytes32 s
    ) external returns (uint amountToken, uint amountETH);
    function swapExactTokensForTokens(
        uint amountIn,
        uint amountOutMin,
        address[] calldata path,
        address to,
        uint deadline
    ) external returns (uint[] memory amounts);
    function swapTokensForExactTokens(
        uint amountOut,
        uint amountInMax,
        address[] calldata path,
        address to,
        uint deadline
    ) external returns (uint[] memory amounts);
    function swapExactETHForTokens(uint amountOutMin, address[] calldata path, address to, uint deadline)
        external
        payable
        returns (uint[] memory amounts);
    function swapTokensForExactETH(uint amountOut, uint amountInMax, address[] calldata path, address to, uint deadline)
        external
        returns (uint[] memory amounts);
    function swapExactTokensForETH(uint amountIn, uint amountOutMin, address[] calldata path, address to, uint deadline)
        external
        returns (uint[] memory amounts);
    function swapETHForExactTokens(uint amountOut, address[] calldata path, address to, uint deadline)
        external
        payable
        returns (uint[] memory amounts);

    function quote(uint amountA, uint reserveA, uint reserveB) external pure returns (uint amountB);
    function getAmountOut(uint amountIn, uint reserveIn, uint reserveOut) external pure returns (uint amountOut);
    function getAmountIn(uint amountOut, uint reserveIn, uint reserveOut) external pure returns (uint amountIn);
    function getAmountsOut(uint amountIn, address[] calldata path) external view returns (uint[] memory amounts);
    function getAmountsIn(uint amountOut, address[] calldata path) external view returns (uint[] memory amounts);
}

pragma solidity >=0.6.2;

import './IUniswapV2Router01.sol';

interface IUniswapV2Router02 is IUniswapV2Router01 {
    function removeLiquidityETHSupportingFeeOnTransferTokens(
        address token,
        uint liquidity,
        uint amountTokenMin,
        uint amountETHMin,
        address to,
        uint deadline
    ) external returns (uint amountETH);
    function removeLiquidityETHWithPermitSupportingFeeOnTransferTokens(
        address token,
        uint liquidity,
        uint amountTokenMin,
        uint amountETHMin,
        address to,
        uint deadline,
        bool approveMax, uint8 v, bytes32 r, bytes32 s
    ) external returns (uint amountETH);

    function swapExactTokensForTokensSupportingFeeOnTransferTokens(
        uint amountIn,
        uint amountOutMin,
        address[] calldata path,
        address to,
        uint deadline
    ) external;
    function swapExactETHForTokensSupportingFeeOnTransferTokens(
        uint amountOutMin,
        address[] calldata path,
        address to,
        uint deadline
    ) external payable;
    function swapExactTokensForETHSupportingFeeOnTransferTokens(
        uint amountIn,
        uint amountOutMin,
        address[] calldata path,
        address to,
        uint deadline
    ) external;
}

// SPDX-License-Identifier: MIT
pragma solidity =0.8.24;

import {Ownable, Ownable2Step} from "@openzeppelin/contracts/access/Ownable2Step.sol";
import {ERC20, ERC20Burnable} from "@openzeppelin/contracts/token/ERC20/extensions/ERC20Burnable.sol";
import {ReentrancyGuard} from "@openzeppelin/contracts/utils/ReentrancyGuard.sol";

import {IUniswapV2Factory} from "@uniswap/v2-core/contracts/interfaces/IUniswapV2Factory.sol";
import {IUniswapV2Router02} from "@uniswap/v2-periphery/contracts/interfaces/IUniswapV2Router02.sol";

import {IMedXToken} from "./interfaces/MedXToken/IMedXToken.sol";
import {UnsafeMath} from "./libraries/UnsafeMath.sol";

/// @title MedX ERC20 Token
/// @author PixelPlex Inc.
contract MedXToken is IMedXToken, ERC20Burnable, Ownable2Step, ReentrancyGuard {
    using UnsafeMath for uint256;

    /// @inheritdoc IMedXToken
    uint256 public constant BUY_FEE_PERCENT = 3;

    /// @inheritdoc IMedXToken
    uint256 public constant SELL_FEE_PERCENT = 3;

    /// @inheritdoc IMedXToken
    uint256 public immutable tradingEnableTime;

    /// @inheritdoc IMedXToken
    address public immutable weth;

    /// @inheritdoc IMedXToken
    address public immutable wethUniV2Pair;

    /// @inheritdoc IMedXToken
    IUniswapV2Router02 public immutable uniV2Router;

    bool private _tradingEnabled;
    /// @inheritdoc IMedXToken
    function tradingEnabled() external view returns (bool) {
        return _tradingEnabled || tradingEnableTime <= block.timestamp;
    }

    /// @inheritdoc IMedXToken
    bool public feeEnabled;

    /// @inheritdoc IMedXToken
    address public admin;

    /// @inheritdoc IMedXToken
    address payable public feeReceiver;

    /// @inheritdoc IMedXToken
    mapping(address => bool) public whitelisted;

    /// @inheritdoc IMedXToken
    mapping(address => bool) public blacklisted;

    /// @inheritdoc IMedXToken
    mapping(address => bool) public applyTax;

    /// @inheritdoc IMedXToken
    mapping(address => bool) public canBurn;

    constructor(
        address _owner,
        address payable _feeReceiver,
        IUniswapV2Router02 _uniV2Router,
        address usdt,
        uint256 _tradingEnableTime
    ) ERC20("MedXT", "$MedXT") Ownable(_owner) {
        address admin_ = msg.sender;
        _mint(admin_, 25e9 * 1e18);
        _setAdmin(admin_);
        _setFeeReceiver(_feeReceiver);
        _toggleFee(true);
        uniV2Router = _uniV2Router;
        tradingEnableTime = _tradingEnableTime;

        // `_tradingIsEnabled()` is called to set `tradingEnabled` variable
        // and emit `TradingEnabled` event if `_tradingEnableTime` lte `block.number`
        _tradingIsEnabled();

        weth = _uniV2Router.WETH();
        IUniswapV2Factory factory = IUniswapV2Factory(_uniV2Router.factory());
        address self = address(this);
        address _wethUniV2Pair = factory.createPair(self, weth);
        wethUniV2Pair = _wethUniV2Pair;
        address usdtUniV2Pair = factory.createPair(self, usdt);
        _updateTaxedList(_wethUniV2Pair, true);
        _updateTaxedList(usdtUniV2Pair, true);
        _approve(self, address(_uniV2Router), type(uint256).max);
    }

    // #region PUBLIC OVERRIDES

    /// @inheritdoc ERC20Burnable
    function burn(uint256 value) public override(ERC20Burnable) onlyBurner {
        super.burn(value);
    }

    /// @inheritdoc ERC20Burnable
    function burnFrom(address account, uint256 value) public override(ERC20Burnable) onlyBurner {
        super.burnFrom(account, value);
    }

    // #endregion

    // #region ADMIN & OWNER FUNCTIONS

    /// @inheritdoc IMedXToken
    function updateAdmin(address newAdmin) external onlyOwnerOrAdmin returns (bool changed) {
        return _setAdmin(newAdmin);
    }

    /// @inheritdoc IMedXToken
    function toggleFee(bool enable) external onlyOwnerOrAdmin returns (bool toggled) {
        return _toggleFee(enable);
    }

    /// @inheritdoc IMedXToken
    function updateFeeReceiver(address payable newFeeReceiver) external onlyOwnerOrAdmin returns (bool changed) {
        return _setFeeReceiver(newFeeReceiver);
    }

    /// @inheritdoc IMedXToken
    function updateWhitelist(
        address[] calldata removeFromWhitelist,
        address[] calldata addToWhitelist
    ) external onlyOwnerOrAdmin {
        uint256 removeListLength = removeFromWhitelist.length;
        for (uint256 i = 0; i < removeListLength; i++) _updateWhitelist(removeFromWhitelist[i], false);
        uint256 addListLength = addToWhitelist.length;
        for (uint256 i = 0; i < addListLength; i++) _updateWhitelist(addToWhitelist[i], true);
    }

    /// @inheritdoc IMedXToken
    function updateBlacklist(
        address[] calldata removeFromBlacklist,
        address[] calldata addToBlacklist
    ) external onlyOwnerOrAdmin {
        uint256 removeListLength = removeFromBlacklist.length;
        for (uint256 i = 0; i < removeListLength; i++) _updateBlacklist(removeFromBlacklist[i], false);
        uint256 addListLength = addToBlacklist.length;
        for (uint256 i = 0; i < addListLength; i++) _updateBlacklist(addToBlacklist[i], true);
    }

    /// @inheritdoc IMedXToken
    function updateTaxedAddresses(
        address[] calldata removeFromTaxedList,
        address[] calldata addToTaxedList
    ) external onlyOwnerOrAdmin {
        uint256 removeListLength = removeFromTaxedList.length;
        for (uint256 i = 0; i < removeListLength; i++) _updateTaxedList(removeFromTaxedList[i], false);
        uint256 addListLength = addToTaxedList.length;
        for (uint256 i = 0; i < addListLength; i++) _updateTaxedList(addToTaxedList[i], true);
    }

    /// @inheritdoc IMedXToken
    function updateBurnersList(
        address[] calldata removeFromBurnersList,
        address[] calldata addToBurnersList
    ) external onlyOwnerOrAdmin {
        uint256 removeListLength = removeFromBurnersList.length;
        for (uint256 i = 0; i < removeListLength; i++) _updateBurnersList(removeFromBurnersList[i], false);
        uint256 addListLength = addToBurnersList.length;
        for (uint256 i = 0; i < addListLength; i++) _updateBurnersList(addToBurnersList[i], true);
    }

    // #endregion

    // #region PRIVATE OVERRIDES

    function _update(address from, address to, uint256 value) internal override(ERC20) {
        if (blacklisted[from]) revert Blacklisted(from);
        if (blacklisted[to]) revert Blacklisted(to);
        if (!feeEnabled || whitelisted[from] || whitelisted[to] || from == address(this)) {
            return super._update(from, to, value);
        }
        if (applyTax[to]) _updateWithSellFee(from, to, value);
        else if (applyTax[from]) _updateWithBuyFee(from, to, value);
        else super._update(from, to, value);
    }

    // emit Approval event on transferFrom and burnFrom operations
    function _approve(address owner, address spender, uint256 value, bool) internal virtual override(ERC20) {
        super._approve(owner, spender, value, true);
    }

    // #endregion

    function _collectFee(address transferFrom, address transferTo, address feeFrom, uint256 feeValue) private {
        address _feeReceiver = feeReceiver;
        super._update(feeFrom, _feeReceiver, feeValue);
        emit FeeTokenCollected(transferFrom, transferTo, _feeReceiver, feeValue);
    }

    function _updateWithSellFee(address from, address to, uint256 value) private onlyEnabledTrading {
        uint256 fee = (value * SELL_FEE_PERCENT) / 100;
        value = value.unsafeSub(fee);
        _collectFee(from, to, from, fee);
        super._update(from, to, value);
    }

    // has nonReentrant modifier
    // slither-disable-next-line reentrancy-no-eth
    function _updateWithBuyFee(address from, address to, uint256 value) private nonReentrant onlyEnabledTrading {
        uint256 tokenFee = (value * BUY_FEE_PERCENT) / 100;
        value = value.unsafeSub(tokenFee);
        address self = address(this);
        super._update(from, self, tokenFee);
        (bool swapSucceed, uint256 ethFee) = _trySwapFeeToEth(tokenFee);
        if (swapSucceed) emit FeeEthCollected(from, to, feeReceiver, tokenFee, ethFee);
        else _collectFee(from, to, self, tokenFee);
        super._update(from, to, value);
    }

    function _trySwapFeeToEth(uint256 value) private returns (bool success, uint256 amountOut) {
        address[] memory path = new address[](2);
        path[0] = address(this);
        path[1] = weth;
        try uniV2Router.swapExactTokensForETH(value, 1e-6 ether, path, feeReceiver, block.timestamp) returns (
            uint256[] memory amounts
        ) {
            return (true, amounts[1]);
        } catch (bytes memory reason) {
            // event is emitted if call reverted, so reentrancy is not possible here
            // slither-disable-next-line reentrancy-events
            emit FeeSwapFailed(value, reason);
            return (false, 0);
        }
    }

    function _toggleFee(bool enabled) private returns (bool toggled) {
        if (feeEnabled == enabled) return false;
        if (enabled && feeReceiver == address(0)) revert InvalidFeeReceiver();
        feeEnabled = enabled;
        emit FeeToggled(enabled);
        return true;
    }

    function _setFeeReceiver(address payable newFeeReceiver) private returns (bool changed) {
        address prevFeeReceiver = feeReceiver;
        if (prevFeeReceiver == newFeeReceiver) return false;
        if (newFeeReceiver == address(0) && feeEnabled) revert InvalidFeeReceiver();
        emit FeeReceiverUpdated(prevFeeReceiver, newFeeReceiver);
        feeReceiver = newFeeReceiver;
        return true;
    }

    function _updateWhitelist(address account, bool whitelist) private {
        if (whitelisted[account] == whitelist) return;
        if (applyTax[account]) revert InvalidWhitelistedAccount(account);
        whitelisted[account] = whitelist;
        emit WhitelistUpdated(account, whitelist);
    }

    function _updateBlacklist(address account, bool blacklist) private {
        if (blacklisted[account] == blacklist) return;
        if (account == address(this) || account == wethUniV2Pair) revert InvalidBlacklistedAccount(account);
        blacklisted[account] = blacklist;
        emit BlacklistUpdated(account, blacklist);
    }

    function _updateTaxedList(address account, bool taxed) private {
        if (applyTax[account] == taxed) return;
        if (taxed) _updateWhitelist(account, false);
        applyTax[account] = taxed;
        emit TaxedListUpdated(account, taxed);
    }

    function _updateBurnersList(address account, bool _canBurn) private {
        if (canBurn[account] == _canBurn) return;
        canBurn[account] = _canBurn;
        emit BurnersListUpdated(account, _canBurn);
    }

    function _setAdmin(address newAdmin) private returns (bool changed) {
        address prevAdmin = admin;
        if (prevAdmin == newAdmin) return false;
        emit AdminUpdated(prevAdmin, newAdmin);
        admin = newAdmin;
        return true;
    }

    /// @dev Is not a view function, because it enables fee using cache-variable `_tradingEnabled`
    function _tradingIsEnabled() private returns (bool) {
        if (_tradingEnabled) return true;
        if (tradingEnableTime > block.timestamp) return false;
        _tradingEnabled = true;
        emit TradingEnabled();
        return true;
    }

    modifier onlyOwnerOrAdmin() {
        address caller = msg.sender;
        if (caller != owner() && caller != admin) revert OwnerOrAdminUnauthorizedAccount(caller);
        _;
    }

    modifier onlyBurner() {
        address caller = msg.sender;
        if (!canBurn[caller]) revert BurnerUnauthorizedAccount(caller);
        _;
    }

    modifier onlyEnabledTrading() {
        if (!_tradingIsEnabled()) revert TradingIsDisabled(tradingEnableTime, block.timestamp);
        _;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable.sol)

pragma solidity ^0.8.20;

import {Context} from "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is set to the address provided by the deployer. This can
 * later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    /**
     * @dev The caller account is not authorized to perform an operation.
     */
    error OwnableUnauthorizedAccount(address account);

    /**
     * @dev The owner is not a valid owner account. (eg. `address(0)`)
     */
    error OwnableInvalidOwner(address owner);

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the address provided by the deployer as the initial owner.
     */
    constructor(address initialOwner) {
        if (initialOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(initialOwner);
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        if (owner() != _msgSender()) {
            revert OwnableUnauthorizedAccount(_msgSender());
        }
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        if (newOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable2Step.sol)

pragma solidity ^0.8.20;

import {Ownable} from "./Ownable.sol";

/**
 * @dev Contract module which provides access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is specified at deployment time in the constructor for `Ownable`. This
 * can later be changed with {transferOwnership} and {acceptOwnership}.
 *
 * This module is used through inheritance. It will make available all functions
 * from parent (Ownable).
 */
abstract contract Ownable2Step is Ownable {
    address private _pendingOwner;

    event OwnershipTransferStarted(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Returns the address of the pending owner.
     */
    function pendingOwner() public view virtual returns (address) {
        return _pendingOwner;
    }

    /**
     * @dev Starts the ownership transfer of the contract to a new account. Replaces the pending transfer if there is one.
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual override onlyOwner {
        _pendingOwner = newOwner;
        emit OwnershipTransferStarted(owner(), newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`) and deletes any pending owner.
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual override {
        delete _pendingOwner;
        super._transferOwnership(newOwner);
    }

    /**
     * @dev The new owner accepts the ownership transfer.
     */
    function acceptOwnership() public virtual {
        address sender = _msgSender();
        if (pendingOwner() != sender) {
            revert OwnableUnauthorizedAccount(sender);
        }
        _transferOwnership(sender);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/ReentrancyGuard.sol)

pragma solidity ^0.8.20;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant NOT_ENTERED = 1;
    uint256 private constant ENTERED = 2;

    uint256 private _status;

    /**
     * @dev Unauthorized reentrant call.
     */
    error ReentrancyGuardReentrantCall();

    constructor() {
        _status = NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be NOT_ENTERED
        if (_status == ENTERED) {
            revert ReentrancyGuardReentrantCall();
        }

        // Any calls to nonReentrant after this point will fail
        _status = ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = NOT_ENTERED;
    }

    /**
     * @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
     * `nonReentrant` function in the call stack.
     */
    function _reentrancyGuardEntered() internal view returns (bool) {
        return _status == ENTERED;
    }
}

// SPDX-License-Identifier: MIT
pragma solidity =0.8.24;

library UnsafeMath {
    function unsafeAdd(uint256 a, uint256 b) internal pure returns (uint256) {
        unchecked {
            return a + b;
        }
    }

    function unsafeSub(uint256 a, uint256 b) internal pure returns (uint256) {
        unchecked {
            return a - b;
        }
    }

    function unsafeMul(uint256 a, uint256 b) internal pure returns (uint256) {
        unchecked {
            return a * b;
        }
    }

    function unsafeDiv(uint256 a, uint256 b) internal pure returns (uint256) {
        unchecked {
            return a / b;
        }
    }

    function unsafeDivCeil(uint256 a, uint256 b) internal pure returns (uint256) {
        unchecked {
            uint256 result = a / b;
            return a % b > 0 ? result + 1 : result;
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (interfaces/draft-IERC6093.sol)
pragma solidity ^0.8.20;

/**
 * @dev Standard ERC20 Errors
 * Interface of the https://eips.ethereum.org/EIPS/eip-6093[ERC-6093] custom errors for ERC20 tokens.
 */
interface IERC20Errors {
    /**
     * @dev Indicates an error related to the current `balance` of a `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     * @param balance Current balance for the interacting account.
     * @param needed Minimum amount required to perform a transfer.
     */
    error ERC20InsufficientBalance(address sender, uint256 balance, uint256 needed);

    /**
     * @dev Indicates a failure with the token `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     */
    error ERC20InvalidSender(address sender);

    /**
     * @dev Indicates a failure with the token `receiver`. Used in transfers.
     * @param receiver Address to which tokens are being transferred.
     */
    error ERC20InvalidReceiver(address receiver);

    /**
     * @dev Indicates a failure with the `spender`’s `allowance`. Used in transfers.
     * @param spender Address that may be allowed to operate on tokens without being their owner.
     * @param allowance Amount of tokens a `spender` is allowed to operate with.
     * @param needed Minimum amount required to perform a transfer.
     */
    error ERC20InsufficientAllowance(address spender, uint256 allowance, uint256 needed);

    /**
     * @dev Indicates a failure with the `approver` of a token to be approved. Used in approvals.
     * @param approver Address initiating an approval operation.
     */
    error ERC20InvalidApprover(address approver);

    /**
     * @dev Indicates a failure with the `spender` to be approved. Used in approvals.
     * @param spender Address that may be allowed to operate on tokens without being their owner.
     */
    error ERC20InvalidSpender(address spender);
}

/**
 * @dev Standard ERC721 Errors
 * Interface of the https://eips.ethereum.org/EIPS/eip-6093[ERC-6093] custom errors for ERC721 tokens.
 */
interface IERC721Errors {
    /**
     * @dev Indicates that an address can't be an owner. For example, `address(0)` is a forbidden owner in EIP-20.
     * Used in balance queries.
     * @param owner Address of the current owner of a token.
     */
    error ERC721InvalidOwner(address owner);

    /**
     * @dev Indicates a `tokenId` whose `owner` is the zero address.
     * @param tokenId Identifier number of a token.
     */
    error ERC721NonexistentToken(uint256 tokenId);

    /**
     * @dev Indicates an error related to the ownership over a particular token. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     * @param tokenId Identifier number of a token.
     * @param owner Address of the current owner of a token.
     */
    error ERC721IncorrectOwner(address sender, uint256 tokenId, address owner);

    /**
     * @dev Indicates a failure with the token `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     */
    error ERC721InvalidSender(address sender);

    /**
     * @dev Indicates a failure with the token `receiver`. Used in transfers.
     * @param receiver Address to which tokens are being transferred.
     */
    error ERC721InvalidReceiver(address receiver);

    /**
     * @dev Indicates a failure with the `operator`’s approval. Used in transfers.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     * @param tokenId Identifier number of a token.
     */
    error ERC721InsufficientApproval(address operator, uint256 tokenId);

    /**
     * @dev Indicates a failure with the `approver` of a token to be approved. Used in approvals.
     * @param approver Address initiating an approval operation.
     */
    error ERC721InvalidApprover(address approver);

    /**
     * @dev Indicates a failure with the `operator` to be approved. Used in approvals.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     */
    error ERC721InvalidOperator(address operator);
}

/**
 * @dev Standard ERC1155 Errors
 * Interface of the https://eips.ethereum.org/EIPS/eip-6093[ERC-6093] custom errors for ERC1155 tokens.
 */
interface IERC1155Errors {
    /**
     * @dev Indicates an error related to the current `balance` of a `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     * @param balance Current balance for the interacting account.
     * @param needed Minimum amount required to perform a transfer.
     * @param tokenId Identifier number of a token.
     */
    error ERC1155InsufficientBalance(address sender, uint256 balance, uint256 needed, uint256 tokenId);

    /**
     * @dev Indicates a failure with the token `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     */
    error ERC1155InvalidSender(address sender);

    /**
     * @dev Indicates a failure with the token `receiver`. Used in transfers.
     * @param receiver Address to which tokens are being transferred.
     */
    error ERC1155InvalidReceiver(address receiver);

    /**
     * @dev Indicates a failure with the `operator`’s approval. Used in transfers.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     * @param owner Address of the current owner of a token.
     */
    error ERC1155MissingApprovalForAll(address operator, address owner);

    /**
     * @dev Indicates a failure with the `approver` of a token to be approved. Used in approvals.
     * @param approver Address initiating an approval operation.
     */
    error ERC1155InvalidApprover(address approver);

    /**
     * @dev Indicates a failure with the `operator` to be approved. Used in approvals.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     */
    error ERC1155InvalidOperator(address operator);

    /**
     * @dev Indicates an array length mismatch between ids and values in a safeBatchTransferFrom operation.
     * Used in batch transfers.
     * @param idsLength Length of the array of token identifiers
     * @param valuesLength Length of the array of token amounts
     */
    error ERC1155InvalidArrayLength(uint256 idsLength, uint256 valuesLength);
}

{
  "compilationTarget": {
    "contracts/MedXToken.sol": "MedXToken"
  },
  "evmVersion": "paris",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs",
    "useLiteralContent": true
  },
  "optimizer": {
    "enabled": true,
    "runs": 200
  },
  "remappings": []
}