// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Context.sol)

pragma solidity ^0.8.0;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.19;
import "@openzeppelin/contracts/access/Ownable.sol";

contract FeeCollector is Ownable {
    // Variables
    uint public ownerFees;
    mapping(address => uint) public totalFees;
    mapping(address => uint) public totalClaimed;

    // Errors
    error CollectFail();
    error TransferFail();
    error ZeroTransfer();

    // Events
    event ReferrerCollect(address user, uint amount, uint id);
    event Collect(address user, uint amount);
    event Claim(address user, uint amount);

    /**
        @notice Collect protocol fees specifying referral address
        @param referrer the referrer address
        @param referrerAmount the amount that goes to referrer
        @return status
     */
    function collectWithReferral(
        address referrer,
        uint referrerAmount,
        uint id
    ) external payable returns (bool) {
        if (msg.value < referrerAmount) revert CollectFail();
        totalFees[referrer] = totalFees[referrer] + referrerAmount;
        emit ReferrerCollect(referrer, referrerAmount, id);
        ownerFees = ownerFees + msg.value - referrerAmount;
        emit Collect(owner(), msg.value - referrerAmount);
        return true;
    }

    /**
        @notice Collect protocol fees
        @return status
   */
    function collect() public payable returns (bool) {
        ownerFees = ownerFees + msg.value;
        emit Collect(owner(), msg.value);
        return true;
    }

    /**
        @notice Claim fees for msg.sender
   */
    function claim() public {
        claim(msg.sender);
    }

    /**
        @notice Claim fees for the specified user
        @param user the user address
   */
    function claim(address user) public {
        uint trfAmt;
        if (user == owner()) {
            trfAmt = ownerFees - 1;
            /// @dev it is cheaper to not zero balance
            ownerFees = 1;
        } else {
            trfAmt = totalFees[user] - totalClaimed[user];
            totalClaimed[user] = totalClaimed[user] + trfAmt;
        }
        _transfer(user, trfAmt);
        emit Claim(user, trfAmt);
    }

    /**
        @notice Internal function to transfer fees
        @param user the user address
        @param amt the amount of fees to transfer
   */
    function _transfer(address user, uint amt) internal {
        if (amt == 0) revert ZeroTransfer();
        (bool success, ) = payable(user).call{value: amt}("");
        if (!success) revert TransferFail();
    }

    /**
        @notice Transfer ownership of the contract
        @param newOwner the new owner address
   */
    function transferOwnership(address newOwner) public override onlyOwner {
        /// @dev only owner can transferOwnership so claim will claim owner's funds
        claim();
        _transferOwnership(newOwner);
    }

    // Fallback function
    fallback() external payable {
        collect();
    }

    // Receive function
    receive() external payable {
        collect();
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (access/Ownable.sol)

pragma solidity ^0.8.0;

import "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _transferOwnership(_msgSender());
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

{
  "compilationTarget": {
    "contracts/FeeCollector.sol": "FeeCollector"
  },
  "evmVersion": "paris",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": true,
    "runs": 10000
  },
  "remappings": []
}