// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.27;

import {Ownable, Ownable2Step} from "@openzeppelin/contracts/access/Ownable2Step.sol";
import {IERC20} from "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import {SafeERC20} from "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
import {ReentrancyGuard} from "@openzeppelin/contracts/utils/ReentrancyGuard.sol";
import {IGuessHook} from "./IGuessHook.sol";

/**
 * @title GuessGame
 * @notice A game where players attempt to guess a secret phrase
 * @dev Players can make free attempts daily and buy additional attempts using tokens
 */
contract GuessGame is Ownable2Step, ReentrancyGuard {
    /* Constants */
    uint256 private constant ONE_DAY = 86400;

    /* Structs */
    /**
     * @notice Tracks a player's attempts in a specific game
     * @dev Used to manage both free and paid attempts per day
     */
    struct PlayerAttempts {
        /// @notice Timestamp of the last attempt update
        uint64 updateTimestamp;
        /// @notice Total number of attempts made in the current day
        uint32 attemptsCount;
        /// @notice Number of paid attempts purchased in the current day
        uint32 paidAttempts;
    }

    /* State variables */
    /// @notice The ERC20 token used for payments
    IERC20 private immutable i_token;

    /// @notice Price for purchasing a bunch of attempts
    uint256 private s_attemptsBunchPrice;
    /// @notice Number of attempts included in each purchased bunch
    uint32 private s_attemptsBunchSize;
    /// @notice Maximum number of paid attempts allowed per day
    uint32 private s_maxPaidAttemptsPerDay;
    /// @notice Number of free attempts allowed per day
    uint32 private s_freeAttemptsPerDay;

    /// @notice Address of the hook contract or address(0) if no hook is set
    address private s_guessHook;

    /// @notice Current game ID
    uint32 private s_gameId;

    /// @notice Mapping of game IDs to player addresses to their attempt data
    mapping(uint32 gameId => mapping(address player => PlayerAttempts)) private s_playerAttempts;

    /// @notice The secret phrase that players are trying to guess
    mapping(uint32 gameId => string secretPhrase) private s_secretPhrases;

    /// @notice The address of the winner of the current game
    mapping(uint32 gameId => address winner) private s_winners;

    /// @notice The total amount of contributions for each game
    mapping(uint32 gameId => uint256 totalContributions) private s_totalContributions;

    /* Events */
    event GameStarted(uint32 indexed gameId);
    event GameEnded(uint32 indexed gameId, address indexed winner, uint256 amount);
    event Guess(uint32 indexed gameId, address indexed player, bytes32 phraseHash);
    event BuyAttempts(uint32 indexed gameId, address indexed player);
    event ParametersChanged(
        uint32 indexed gameId,
        uint256 attemptsBunchPrice,
        uint32 attemptsBunchSize,
        uint32 maxPaidAttemptsPerDay,
        uint32 freeAttemptsPerDay,
        address guessHook
    );

    /* Errors */
    error GuessGame__ZeroAddress();
    error GuessGame__ZeroAmount();
    error GuessGame__NoAttemptsLeft();
    error GuessGame__MaxPaidAttemptsReached();
    error GuessGame__GameEnded();

    /**
     * @notice Initializes the game with the specified parameters
     * @param token The ERC20 token used for payments
     * @param attemptsBunchPrice The price for a bunch of attempts
     * @param attemptsBunchSize The number of attempts in a bunch
     * @param maxPaidAttemptsPerDay Maximum paid attempts allowed per day
     * @param freeAttemptsPerDay Number of free attempts allowed per day
     */
    constructor(
        IERC20 token,
        uint256 attemptsBunchPrice,
        uint32 attemptsBunchSize,
        uint32 maxPaidAttemptsPerDay,
        uint32 freeAttemptsPerDay,
        address guessHook
    ) Ownable(msg.sender) {
        if (address(token) == address(0)) revert GuessGame__ZeroAddress();
        i_token = token;
        _startNewGame(attemptsBunchPrice, attemptsBunchSize, maxPaidAttemptsPerDay, freeAttemptsPerDay, guessHook);
    }

    /**
     * @notice Allows a player to purchase additional guess attempts
     * @dev Transfers tokens from the player to the contract
     * @dev Reverts if the game has ended or the player has reached the max paid attempts for the day
     */
    function buyAttempts() external nonReentrant {
        uint32 gameId = s_gameId;
        if (_isEndedGame(gameId)) revert GuessGame__GameEnded();

        PlayerAttempts memory playerAttempts = s_playerAttempts[gameId][msg.sender];
        uint256 startOfDay = _getStartOfDay();
        uint32 bunchSize = s_attemptsBunchSize;

        if (playerAttempts.updateTimestamp >= startOfDay) {
            if (playerAttempts.paidAttempts + bunchSize > s_maxPaidAttemptsPerDay) {
                revert GuessGame__MaxPaidAttemptsReached();
            }

            playerAttempts.paidAttempts += bunchSize;
        } else {
            playerAttempts.updateTimestamp = uint64(block.timestamp);
            playerAttempts.attemptsCount = 0;
            playerAttempts.paidAttempts = bunchSize;
        }

        s_playerAttempts[gameId][msg.sender] = playerAttempts;

        uint256 attemptsBunchPrice = s_attemptsBunchPrice;
        s_totalContributions[gameId] += attemptsBunchPrice;

        emit BuyAttempts(gameId, msg.sender);

        SafeERC20.safeTransferFrom(i_token, msg.sender, address(this), attemptsBunchPrice);
    }

    /**
     * @notice Allows a player to make a guess by submitting a hash of their phrase
     * @param phraseHash The keccak256 hash of the player's guessed phrase
     * @dev Consumes one attempt and emits a Guess event
     * @dev Reverts if the game has ended or the player has no attempts left
     */
    function guess(bytes32 phraseHash) external {
        uint32 gameId = s_gameId;
        if (_isEndedGame(gameId)) revert GuessGame__GameEnded();

        uint256 startOfDay = _getStartOfDay();
        uint32 freeAttemptsPerDay = s_freeAttemptsPerDay;
        PlayerAttempts memory playerAttempts = s_playerAttempts[gameId][msg.sender];
        if (playerAttempts.updateTimestamp < startOfDay) {
            playerAttempts.attemptsCount = 0;
            playerAttempts.paidAttempts = 0;
        }

        if (playerAttempts.attemptsCount >= freeAttemptsPerDay + playerAttempts.paidAttempts) {
            revert GuessGame__NoAttemptsLeft();
        }

        address guessHook = s_guessHook;
        if (guessHook != address(0)) {
            IGuessHook(guessHook).onGuess(msg.sender, gameId, phraseHash);
        }

        playerAttempts.attemptsCount++;
        playerAttempts.updateTimestamp = uint64(block.timestamp);

        s_playerAttempts[gameId][msg.sender] = playerAttempts;
        emit Guess(gameId, msg.sender, phraseHash);
    }

    /**
     * @notice Sets the winner of the current game and transfers the prize
     * @param winner The address of the winning player
     * @param secretPhrase The correct secret phrase that was guessed
     * @dev Can only be called by the contract owner
     * @dev Transfers all tokens held by the contract to the winner
     */
    function setWinner(address winner, string memory secretPhrase) external onlyOwner {
        if (address(winner) == address(0)) revert GuessGame__ZeroAddress();

        uint32 gameId = s_gameId;
        if (_isEndedGame(gameId)) revert GuessGame__GameEnded();

        s_winners[gameId] = winner;
        s_secretPhrases[gameId] = secretPhrase;

        IERC20 token = i_token;
        uint256 balance = token.balanceOf(address(this));
        SafeERC20.safeTransfer(token, winner, balance);

        emit GameEnded(gameId, winner, balance);
    }

    /**
     * @notice Starts a new game with updated parameters
     * @param attemptsBunchPrice The price for a bunch of attempts
     * @param attemptsBunchSize The number of attempts in a bunch
     * @param maxPaidAttemptsPerDay Maximum paid attempts allowed per day
     * @param freeAttemptsPerDay Number of free attempts allowed per day
     * @param guessHook The address of the hook contract or address(0) if no hook is set
     * @dev Can only be called by the contract owner
     */
    function startNewGame(
        uint256 attemptsBunchPrice,
        uint32 attemptsBunchSize,
        uint32 maxPaidAttemptsPerDay,
        uint32 freeAttemptsPerDay,
        address guessHook
    ) external onlyOwner {
        _startNewGame(attemptsBunchPrice, attemptsBunchSize, maxPaidAttemptsPerDay, freeAttemptsPerDay, guessHook);
    }

    /**
     * @notice Changes the parameters of the game
     * @param attemptsBunchPrice The price for a bunch of attempts
     * @param attemptsBunchSize The number of attempts in a bunch
     * @param maxPaidAttemptsPerDay Maximum paid attempts allowed per day
     * @param freeAttemptsPerDay Number of free attempts allowed per day
     * @param guessHook The address of the hook contract or address(0) if no hook is set
     * @dev Can only be called by the contract owner
     */
    function changeParameters(
        uint256 attemptsBunchPrice,
        uint32 attemptsBunchSize,
        uint32 maxPaidAttemptsPerDay,
        uint32 freeAttemptsPerDay,
        address guessHook
    ) external onlyOwner {
        _changeParameters(attemptsBunchPrice, attemptsBunchSize, maxPaidAttemptsPerDay, freeAttemptsPerDay, guessHook);
    }

    /**
     * @notice Internal function to start a new game with specified parameters
     * @dev Increments the game ID and resets game state
     */
    function _startNewGame(
        uint256 attemptsBunchPrice,
        uint32 attemptsBunchSize,
        uint32 maxPaidAttemptsPerDay,
        uint32 freeAttemptsPerDay,
        address guessHook
    ) private {
        uint32 gameId = s_gameId + 1;
        s_gameId = gameId;

        _changeParameters(attemptsBunchPrice, attemptsBunchSize, maxPaidAttemptsPerDay, freeAttemptsPerDay, guessHook);

        emit GameStarted(gameId);
    }

    function _changeParameters(
        uint256 attemptsBunchPrice,
        uint32 attemptsBunchSize,
        uint32 maxPaidAttemptsPerDay,
        uint32 freeAttemptsPerDay,
        address guessHook
    ) private {
        if (attemptsBunchPrice == 0) revert GuessGame__ZeroAmount();
        if (attemptsBunchSize == 0) revert GuessGame__ZeroAmount();
        if (maxPaidAttemptsPerDay == 0) revert GuessGame__ZeroAmount();

        s_attemptsBunchPrice = attemptsBunchPrice;
        s_attemptsBunchSize = attemptsBunchSize;
        s_maxPaidAttemptsPerDay = maxPaidAttemptsPerDay;

        // if freeAttemptsPerDay is 0, it means that all attempts are paid
        s_freeAttemptsPerDay = freeAttemptsPerDay;
        s_guessHook = guessHook;

        emit ParametersChanged(
            s_gameId, attemptsBunchPrice, attemptsBunchSize, maxPaidAttemptsPerDay, freeAttemptsPerDay, guessHook
        );
    }

    /**
     * @notice Calculates the start of the current day (00:00 UTC)
     * @return The timestamp for the start of the current day
     */
    function _getStartOfDay() private view returns (uint64) {
        return uint64(block.timestamp - (block.timestamp % ONE_DAY)); // safe for block.timestamp
    }

    /**
     * @notice Checks if a game has ended
     * @param gameId The ID of the game to check
     * @return True if the game has ended, false otherwise
     */
    function _isEndedGame(uint32 gameId) private view returns (bool) {
        return s_winners[gameId] != address(0);
    }

    /**
     * @notice Returns the number of attempts left for a player in a current game
     * @param player The address of the player
     * @return The number of attempts left
     */
    function getLeftAttempts(address player) external view returns (uint32) {
        uint32 gameId = s_gameId;
        if (_isEndedGame(gameId)) return 0;

        uint32 freeAttemptsPerDay = s_freeAttemptsPerDay;
        uint256 startOfDay = _getStartOfDay();
        PlayerAttempts memory playerAttempts = s_playerAttempts[s_gameId][player];
        if (playerAttempts.updateTimestamp < startOfDay) {
            return freeAttemptsPerDay;
        } else {
            return freeAttemptsPerDay + playerAttempts.paidAttempts - playerAttempts.attemptsCount;
        }
    }

    /**
     * @notice Returns the token used for payments
     * @return The ERC20 token interface
     */
    function getToken() external view returns (IERC20) {
        return i_token;
    }

    /**
     * @notice Returns the current price for a bunch of attempts
     * @return The price in token units
     */
    function getAttemptsBunchPrice() external view returns (uint256) {
        return s_attemptsBunchPrice;
    }

    /**
     * @notice Returns the number of attempts in each purchased bunch
     * @return The number of attempts per bunch
     */
    function getAttemptsBunchSize() external view returns (uint32) {
        return s_attemptsBunchSize;
    }

    /**
     * @notice Returns the maximum number of paid attempts allowed per day
     * @return The maximum paid attempts limit
     */
    function getMaxPaidAttemptsPerDay() external view returns (uint32) {
        return s_maxPaidAttemptsPerDay;
    }

    /**
     * @notice Returns the number of free attempts allowed per day
     * @return The free attempts count
     */
    function getFreeAttemptsPerDay() external view returns (uint32) {
        return s_freeAttemptsPerDay;
    }

    /**
     * @notice Returns the address of the current game winner, if any
     * @return The winner's address or address(0) if no winner yet
     */
    function getWinner(uint32 gameId) external view returns (address) {
        return s_winners[gameId];
    }

    /**
     * @notice Returns the current game ID
     * @return The game ID
     */
    function getGameId() external view returns (uint32) {
        return s_gameId;
    }

    /**
     * @notice Returns the secret phrase after the game has ended
     * @return The secret phrase
     */
    function getSecretPhrase(uint32 gameId) external view returns (string memory) {
        return s_secretPhrases[gameId];
    }

    /**
     * @notice Returns a player's attempt data for a specific game
     * @param gameId The ID of the game
     * @param player The address of the player
     * @return The player's attempt data
     */
    function getPlayerAttempts(uint32 gameId, address player) external view returns (PlayerAttempts memory) {
        return s_playerAttempts[gameId][player];
    }

    /**
     * @notice Returns the address of the hook contract
     * @return The address of the hook contract
     */
    function getGuessHook() external view returns (address) {
        return s_guessHook;
    }

    /**
     * @notice Returns the total contributions for a specific game
     * @param gameId The ID of the game
     * @return The total contributions
     */
    function getTotalContributions(uint32 gameId) external view returns (uint256) {
        return s_totalContributions[gameId];
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (interfaces/IERC1363.sol)

pragma solidity ^0.8.20;

import {IERC20} from "./IERC20.sol";
import {IERC165} from "./IERC165.sol";

/**
 * @title IERC1363
 * @dev Interface of the ERC-1363 standard as defined in the https://eips.ethereum.org/EIPS/eip-1363[ERC-1363].
 *
 * Defines an extension interface for ERC-20 tokens that supports executing code on a recipient contract
 * after `transfer` or `transferFrom`, or code on a spender contract after `approve`, in a single transaction.
 */
interface IERC1363 is IERC20, IERC165 {
    /*
     * Note: the ERC-165 identifier for this interface is 0xb0202a11.
     * 0xb0202a11 ===
     *   bytes4(keccak256('transferAndCall(address,uint256)')) ^
     *   bytes4(keccak256('transferAndCall(address,uint256,bytes)')) ^
     *   bytes4(keccak256('transferFromAndCall(address,address,uint256)')) ^
     *   bytes4(keccak256('transferFromAndCall(address,address,uint256,bytes)')) ^
     *   bytes4(keccak256('approveAndCall(address,uint256)')) ^
     *   bytes4(keccak256('approveAndCall(address,uint256,bytes)'))
     */

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferAndCall(address to, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @param data Additional data with no specified format, sent in call to `to`.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferAndCall(address to, uint256 value, bytes calldata data) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the allowance mechanism
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param from The address which you want to send tokens from.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferFromAndCall(address from, address to, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the allowance mechanism
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param from The address which you want to send tokens from.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @param data Additional data with no specified format, sent in call to `to`.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferFromAndCall(address from, address to, uint256 value, bytes calldata data) external returns (bool);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens and then calls {IERC1363Spender-onApprovalReceived} on `spender`.
     * @param spender The address which will spend the funds.
     * @param value The amount of tokens to be spent.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function approveAndCall(address spender, uint256 value) external returns (bool);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens and then calls {IERC1363Spender-onApprovalReceived} on `spender`.
     * @param spender The address which will spend the funds.
     * @param value The amount of tokens to be spent.
     * @param data Additional data with no specified format, sent in call to `spender`.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function approveAndCall(address spender, uint256 value, bytes calldata data) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (interfaces/IERC165.sol)

pragma solidity ^0.8.20;

import {IERC165} from "../utils/introspection/IERC165.sol";

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC-20 standard as defined in the ERC.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.27;

interface IGuessHook {
    function onGuess(address player, uint32 gameId, bytes32 phraseHash) external;
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable.sol)

pragma solidity ^0.8.20;

import {Context} from "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is set to the address provided by the deployer. This can
 * later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    /**
     * @dev The caller account is not authorized to perform an operation.
     */
    error OwnableUnauthorizedAccount(address account);

    /**
     * @dev The owner is not a valid owner account. (eg. `address(0)`)
     */
    error OwnableInvalidOwner(address owner);

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the address provided by the deployer as the initial owner.
     */
    constructor(address initialOwner) {
        if (initialOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(initialOwner);
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        if (owner() != _msgSender()) {
            revert OwnableUnauthorizedAccount(_msgSender());
        }
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        if (newOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (access/Ownable2Step.sol)

pragma solidity ^0.8.20;

import {Ownable} from "./Ownable.sol";

/**
 * @dev Contract module which provides access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * This extension of the {Ownable} contract includes a two-step mechanism to transfer
 * ownership, where the new owner must call {acceptOwnership} in order to replace the
 * old one. This can help prevent common mistakes, such as transfers of ownership to
 * incorrect accounts, or to contracts that are unable to interact with the
 * permission system.
 *
 * The initial owner is specified at deployment time in the constructor for `Ownable`. This
 * can later be changed with {transferOwnership} and {acceptOwnership}.
 *
 * This module is used through inheritance. It will make available all functions
 * from parent (Ownable).
 */
abstract contract Ownable2Step is Ownable {
    address private _pendingOwner;

    event OwnershipTransferStarted(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Returns the address of the pending owner.
     */
    function pendingOwner() public view virtual returns (address) {
        return _pendingOwner;
    }

    /**
     * @dev Starts the ownership transfer of the contract to a new account. Replaces the pending transfer if there is one.
     * Can only be called by the current owner.
     *
     * Setting `newOwner` to the zero address is allowed; this can be used to cancel an initiated ownership transfer.
     */
    function transferOwnership(address newOwner) public virtual override onlyOwner {
        _pendingOwner = newOwner;
        emit OwnershipTransferStarted(owner(), newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`) and deletes any pending owner.
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual override {
        delete _pendingOwner;
        super._transferOwnership(newOwner);
    }

    /**
     * @dev The new owner accepts the ownership transfer.
     */
    function acceptOwnership() public virtual {
        address sender = _msgSender();
        if (pendingOwner() != sender) {
            revert OwnableUnauthorizedAccount(sender);
        }
        _transferOwnership(sender);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (utils/ReentrancyGuard.sol)

pragma solidity ^0.8.20;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If EIP-1153 (transient storage) is available on the chain you're deploying at,
 * consider using {ReentrancyGuardTransient} instead.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant NOT_ENTERED = 1;
    uint256 private constant ENTERED = 2;

    uint256 private _status;

    /**
     * @dev Unauthorized reentrant call.
     */
    error ReentrancyGuardReentrantCall();

    constructor() {
        _status = NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be NOT_ENTERED
        if (_status == ENTERED) {
            revert ReentrancyGuardReentrantCall();
        }

        // Any calls to nonReentrant after this point will fail
        _status = ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = NOT_ENTERED;
    }

    /**
     * @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
     * `nonReentrant` function in the call stack.
     */
    function _reentrancyGuardEntered() internal view returns (bool) {
        return _status == ENTERED;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.2.0) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.20;

import {IERC20} from "../IERC20.sol";
import {IERC1363} from "../../../interfaces/IERC1363.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC-20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    /**
     * @dev An operation with an ERC-20 token failed.
     */
    error SafeERC20FailedOperation(address token);

    /**
     * @dev Indicates a failed `decreaseAllowance` request.
     */
    error SafeERC20FailedDecreaseAllowance(address spender, uint256 currentAllowance, uint256 requestedDecrease);

    /**
     * @dev Transfer `value` amount of `token` from the calling contract to `to`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transfer, (to, value)));
    }

    /**
     * @dev Transfer `value` amount of `token` from `from` to `to`, spending the approval given by `from` to the
     * calling contract. If `token` returns no value, non-reverting calls are assumed to be successful.
     */
    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transferFrom, (from, to, value)));
    }

    /**
     * @dev Increase the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     *
     * IMPORTANT: If the token implements ERC-7674 (ERC-20 with temporary allowance), and if the "client"
     * smart contract uses ERC-7674 to set temporary allowances, then the "client" smart contract should avoid using
     * this function. Performing a {safeIncreaseAllowance} or {safeDecreaseAllowance} operation on a token contract
     * that has a non-zero temporary allowance (for that particular owner-spender) will result in unexpected behavior.
     */
    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 oldAllowance = token.allowance(address(this), spender);
        forceApprove(token, spender, oldAllowance + value);
    }

    /**
     * @dev Decrease the calling contract's allowance toward `spender` by `requestedDecrease`. If `token` returns no
     * value, non-reverting calls are assumed to be successful.
     *
     * IMPORTANT: If the token implements ERC-7674 (ERC-20 with temporary allowance), and if the "client"
     * smart contract uses ERC-7674 to set temporary allowances, then the "client" smart contract should avoid using
     * this function. Performing a {safeIncreaseAllowance} or {safeDecreaseAllowance} operation on a token contract
     * that has a non-zero temporary allowance (for that particular owner-spender) will result in unexpected behavior.
     */
    function safeDecreaseAllowance(IERC20 token, address spender, uint256 requestedDecrease) internal {
        unchecked {
            uint256 currentAllowance = token.allowance(address(this), spender);
            if (currentAllowance < requestedDecrease) {
                revert SafeERC20FailedDecreaseAllowance(spender, currentAllowance, requestedDecrease);
            }
            forceApprove(token, spender, currentAllowance - requestedDecrease);
        }
    }

    /**
     * @dev Set the calling contract's allowance toward `spender` to `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful. Meant to be used with tokens that require the approval
     * to be set to zero before setting it to a non-zero value, such as USDT.
     *
     * NOTE: If the token implements ERC-7674, this function will not modify any temporary allowance. This function
     * only sets the "standard" allowance. Any temporary allowance will remain active, in addition to the value being
     * set here.
     */
    function forceApprove(IERC20 token, address spender, uint256 value) internal {
        bytes memory approvalCall = abi.encodeCall(token.approve, (spender, value));

        if (!_callOptionalReturnBool(token, approvalCall)) {
            _callOptionalReturn(token, abi.encodeCall(token.approve, (spender, 0)));
            _callOptionalReturn(token, approvalCall);
        }
    }

    /**
     * @dev Performs an {ERC1363} transferAndCall, with a fallback to the simple {ERC20} transfer if the target has no
     * code. This can be used to implement an {ERC721}-like safe transfer that rely on {ERC1363} checks when
     * targeting contracts.
     *
     * Reverts if the returned value is other than `true`.
     */
    function transferAndCallRelaxed(IERC1363 token, address to, uint256 value, bytes memory data) internal {
        if (to.code.length == 0) {
            safeTransfer(token, to, value);
        } else if (!token.transferAndCall(to, value, data)) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Performs an {ERC1363} transferFromAndCall, with a fallback to the simple {ERC20} transferFrom if the target
     * has no code. This can be used to implement an {ERC721}-like safe transfer that rely on {ERC1363} checks when
     * targeting contracts.
     *
     * Reverts if the returned value is other than `true`.
     */
    function transferFromAndCallRelaxed(
        IERC1363 token,
        address from,
        address to,
        uint256 value,
        bytes memory data
    ) internal {
        if (to.code.length == 0) {
            safeTransferFrom(token, from, to, value);
        } else if (!token.transferFromAndCall(from, to, value, data)) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Performs an {ERC1363} approveAndCall, with a fallback to the simple {ERC20} approve if the target has no
     * code. This can be used to implement an {ERC721}-like safe transfer that rely on {ERC1363} checks when
     * targeting contracts.
     *
     * NOTE: When the recipient address (`to`) has no code (i.e. is an EOA), this function behaves as {forceApprove}.
     * Opposedly, when the recipient address (`to`) has code, this function only attempts to call {ERC1363-approveAndCall}
     * once without retrying, and relies on the returned value to be true.
     *
     * Reverts if the returned value is other than `true`.
     */
    function approveAndCallRelaxed(IERC1363 token, address to, uint256 value, bytes memory data) internal {
        if (to.code.length == 0) {
            forceApprove(token, to, value);
        } else if (!token.approveAndCall(to, value, data)) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturnBool} that reverts if call fails to meet the requirements.
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        uint256 returnSize;
        uint256 returnValue;
        assembly ("memory-safe") {
            let success := call(gas(), token, 0, add(data, 0x20), mload(data), 0, 0x20)
            // bubble errors
            if iszero(success) {
                let ptr := mload(0x40)
                returndatacopy(ptr, 0, returndatasize())
                revert(ptr, returndatasize())
            }
            returnSize := returndatasize()
            returnValue := mload(0)
        }

        if (returnSize == 0 ? address(token).code.length == 0 : returnValue != 1) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturn} that silently catches all reverts and returns a bool instead.
     */
    function _callOptionalReturnBool(IERC20 token, bytes memory data) private returns (bool) {
        bool success;
        uint256 returnSize;
        uint256 returnValue;
        assembly ("memory-safe") {
            success := call(gas(), token, 0, add(data, 0x20), mload(data), 0, 0x20)
            returnSize := returndatasize()
            returnValue := mload(0)
        }
        return success && (returnSize == 0 ? address(token).code.length > 0 : returnValue == 1);
    }
}

{
  "compilationTarget": {
    "src/GuessGame.sol": "GuessGame"
  },
  "evmVersion": "cancun",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": true,
    "runs": 10000000
  },
  "remappings": [
    ":@openzeppelin/=lib/openzeppelin-contracts/",
    ":erc4626-tests/=lib/openzeppelin-contracts/lib/erc4626-tests/",
    ":forge-std/=lib/forge-std/src/",
    ":halmos-cheatcodes/=lib/openzeppelin-contracts/lib/halmos-cheatcodes/src/",
    ":openzeppelin-contracts/=lib/openzeppelin-contracts/"
  ],
  "viaIR": true
}