pragma solidity ^0.6.0;
import "./Initializable.sol";

/*
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with GSN meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
contract ContextUpgradeSafe is Initializable {
    // Empty internal constructor, to prevent people from mistakenly deploying
    // an instance of this contract, which should be used via inheritance.

    function __Context_init() internal initializer {
        __Context_init_unchained();
    }

    function __Context_init_unchained() internal initializer {


    }


    function _msgSender() internal view virtual returns (address payable) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes memory) {
        this; // silence state mutability warning without generating bytecode - see https://github.com/ethereum/solidity/issues/2691
        return msg.data;
    }

    uint256[50] private __gap;
}

pragma solidity ^0.6.0;

/**
 * @dev Library for managing
 * https://en.wikipedia.org/wiki/Set_(abstract_data_type)[sets] of primitive
 * types.
 *
 * Sets have the following properties:
 *
 * - Elements are added, removed, and checked for existence in constant time
 * (O(1)).
 * - Elements are enumerated in O(n). No guarantees are made on the ordering.
 *
 * ```
 * contract Example {
 *     // Add the library methods
 *     using EnumerableSet for EnumerableSet.AddressSet;
 *
 *     // Declare a set state variable
 *     EnumerableSet.AddressSet private mySet;
 * }
 * ```
 *
 * As of v3.0.0, only sets of type `address` (`AddressSet`) and `uint256`
 * (`UintSet`) are supported.
 */
library EnumerableSet {
    // To implement this library for multiple types with as little code
    // repetition as possible, we write it in terms of a generic Set type with
    // bytes32 values.
    // The Set implementation uses private functions, and user-facing
    // implementations (such as AddressSet) are just wrappers around the
    // underlying Set.
    // This means that we can only create new EnumerableSets for types that fit
    // in bytes32.

    struct Set {
        // Storage of set values
        bytes32[] _values;

        // Position of the value in the `values` array, plus 1 because index 0
        // means a value is not in the set.
        mapping (bytes32 => uint256) _indexes;
    }

    /**
     * @dev Add a value to a set. O(1).
     *
     * Returns true if the value was added to the set, that is if it was not
     * already present.
     */
    function _add(Set storage set, bytes32 value) private returns (bool) {
        if (!_contains(set, value)) {
            set._values.push(value);
            // The value is stored at length-1, but we add 1 to all indexes
            // and use 0 as a sentinel value
            set._indexes[value] = set._values.length;
            return true;
        } else {
            return false;
        }
    }

    /**
     * @dev Removes a value from a set. O(1).
     *
     * Returns true if the value was removed from the set, that is if it was
     * present.
     */
    function _remove(Set storage set, bytes32 value) private returns (bool) {
        // We read and store the value's index to prevent multiple reads from the same storage slot
        uint256 valueIndex = set._indexes[value];

        if (valueIndex != 0) { // Equivalent to contains(set, value)
            // To delete an element from the _values array in O(1), we swap the element to delete with the last one in
            // the array, and then remove the last element (sometimes called as 'swap and pop').
            // This modifies the order of the array, as noted in {at}.

            uint256 toDeleteIndex = valueIndex - 1;
            uint256 lastIndex = set._values.length - 1;

            // When the value to delete is the last one, the swap operation is unnecessary. However, since this occurs
            // so rarely, we still do the swap anyway to avoid the gas cost of adding an 'if' statement.

            bytes32 lastvalue = set._values[lastIndex];

            // Move the last value to the index where the value to delete is
            set._values[toDeleteIndex] = lastvalue;
            // Update the index for the moved value
            set._indexes[lastvalue] = toDeleteIndex + 1; // All indexes are 1-based

            // Delete the slot where the moved value was stored
            set._values.pop();

            // Delete the index for the deleted slot
            delete set._indexes[value];

            return true;
        } else {
            return false;
        }
    }

    /**
     * @dev Returns true if the value is in the set. O(1).
     */
    function _contains(Set storage set, bytes32 value) private view returns (bool) {
        return set._indexes[value] != 0;
    }

    /**
     * @dev Returns the number of values on the set. O(1).
     */
    function _length(Set storage set) private view returns (uint256) {
        return set._values.length;
    }

   /**
    * @dev Returns the value stored at position `index` in the set. O(1).
    *
    * Note that there are no guarantees on the ordering of values inside the
    * array, and it may change when more values are added or removed.
    *
    * Requirements:
    *
    * - `index` must be strictly less than {length}.
    */
    function _at(Set storage set, uint256 index) private view returns (bytes32) {
        require(set._values.length > index, "EnumerableSet: index out of bounds");
        return set._values[index];
    }

    // AddressSet

    struct AddressSet {
        Set _inner;
    }

    /**
     * @dev Add a value to a set. O(1).
     *
     * Returns true if the value was added to the set, that is if it was not
     * already present.
     */
    function add(AddressSet storage set, address value) internal returns (bool) {
        return _add(set._inner, bytes32(uint256(value)));
    }

    /**
     * @dev Removes a value from a set. O(1).
     *
     * Returns true if the value was removed from the set, that is if it was
     * present.
     */
    function remove(AddressSet storage set, address value) internal returns (bool) {
        return _remove(set._inner, bytes32(uint256(value)));
    }

    /**
     * @dev Returns true if the value is in the set. O(1).
     */
    function contains(AddressSet storage set, address value) internal view returns (bool) {
        return _contains(set._inner, bytes32(uint256(value)));
    }

    /**
     * @dev Returns the number of values in the set. O(1).
     */
    function length(AddressSet storage set) internal view returns (uint256) {
        return _length(set._inner);
    }

   /**
    * @dev Returns the value stored at position `index` in the set. O(1).
    *
    * Note that there are no guarantees on the ordering of values inside the
    * array, and it may change when more values are added or removed.
    *
    * Requirements:
    *
    * - `index` must be strictly less than {length}.
    */
    function at(AddressSet storage set, uint256 index) internal view returns (address) {
        return address(uint256(_at(set._inner, index)));
    }


    // UintSet

    struct UintSet {
        Set _inner;
    }

    /**
     * @dev Add a value to a set. O(1).
     *
     * Returns true if the value was added to the set, that is if it was not
     * already present.
     */
    function add(UintSet storage set, uint256 value) internal returns (bool) {
        return _add(set._inner, bytes32(value));
    }

    /**
     * @dev Removes a value from a set. O(1).
     *
     * Returns true if the value was removed from the set, that is if it was
     * present.
     */
    function remove(UintSet storage set, uint256 value) internal returns (bool) {
        return _remove(set._inner, bytes32(value));
    }

    /**
     * @dev Returns true if the value is in the set. O(1).
     */
    function contains(UintSet storage set, uint256 value) internal view returns (bool) {
        return _contains(set._inner, bytes32(value));
    }

    /**
     * @dev Returns the number of values on the set. O(1).
     */
    function length(UintSet storage set) internal view returns (uint256) {
        return _length(set._inner);
    }

   /**
    * @dev Returns the value stored at position `index` in the set. O(1).
    *
    * Note that there are no guarantees on the ordering of values inside the
    * array, and it may change when more values are added or removed.
    *
    * Requirements:
    *
    * - `index` must be strictly less than {length}.
    */
    function at(UintSet storage set, uint256 index) internal view returns (uint256) {
        return uint256(_at(set._inner, index));
    }
}

// "SPDX-License-Identifier: UNLICENSED"
pragma solidity 0.6.6;

/// @title Interface for ERC-20 Torro governing token.
/// @notice ERC-20 token.
/// @author ORayskiy - @robitnik_TorroDao
interface ITorro {

  // Initializer.

  /// @notice Initializes governing token.
  /// @param dao_ address of cloned DAO.
  /// @param factory_ address of factory.
  /// @param supply_ total supply of tokens.
  function initializeCustom(address dao_, address factory_, uint256 supply_) external;

  // Public calls.

  /// @notice Token's name.
  /// @return string name of the token.
  function name() external view returns (string memory);

  /// @notice Token's symbol.
  /// @return string symbol of the token.
  function symbol() external view returns (string memory);

  /// @notice Token's decimals.
  /// @return uint8 demials of the token.
  function decimals() external pure returns (uint8);

  /// @notice Token's total supply.
  /// @return uint256 total supply of the token.
  function totalSupply() external view returns (uint256);

  /// @notice Count of token holders.
  /// @return uint256 number of token holders.
  function holdersCount() external view returns (uint256);

  /// @notice All token holders.
  /// @return array of addresses of token holders.
  function holders() external view returns (address[] memory);

  /// @notice Available balance for address.
  /// @param sender_ address to get available balance for.
  /// @return uint256 amount of tokens available for given address.
  function balanceOf(address sender_) external view returns (uint256);

  /// @notice Staked balance for address.
  /// @param sender_ address to get staked balance for.
  /// @return uint256 amount of staked tokens for given address.
  function stakedOf(address sender_) external view returns (uint256);

  /// @notice Total balance for address = available + staked.
  /// @param sender_ address to get total balance for.
  /// @return uint256 total amount of tokens for given address.
  function totalOf(address sender_) external view returns (uint256);

  /// @notice Spending allowance.
  /// @param owner_ token owner address.
  /// @param spender_ token spender address.
  /// @return uint256 amount of owner's tokens that spender can use.
  function allowance(address owner_, address spender_) external view returns (uint256);

  /// @notice Unstaked supply of token.
  /// @return uint256 amount of tokens in circulation that are not staked.
  function unstakedSupply() external view returns (uint256);

  /// @notice Staked supply of token.
  /// @return uint256 amount of tokens in circulation that are staked.
  function stakedSupply() external view returns (uint256);

  // Public transactions.

  /// @notice Transfer tokens to recipient.
  /// @param recipient_ address of tokens' recipient.
  /// @param amount_ amount of tokens to transfer.
  /// @return bool true if successful.
  function transfer(address recipient_, uint256 amount_) external returns (bool);

  /// @notice Approve spender to spend an allowance.
  /// @param spender_ address that will be allowed to spend specified amount of tokens.
  /// @param amount_ amount of tokens that spender can spend.
  /// @return bool true if successful.
  function approve(address spender_, uint256 amount_) external returns (bool);

  /// @notice Approves DAO to spend tokens.
  /// @param owner_ address whose tokens DAO can spend.
  /// @param amount_ amount of tokens that DAO can spend.
  /// @return bool true if successful.
  function approveDao(address owner_, uint256 amount_) external returns (bool);

  /// @notice Transfers tokens from owner to recipient by approved spender.
  /// @param owner_ address of tokens' owner whose tokens will be spent.
  /// @param recipient_ address of recipient that will recieve tokens.
  /// @param amount_ amount of tokens to be spent.
  /// @return bool true if successful.
  function transferFrom(address owner_, address recipient_, uint256 amount_) external returns (bool);

  /// @notice Increases allowance for given spender.
  /// @param spender_ spender to increase allowance for.
  /// @param addedValue_ extra amount that spender can spend.
  /// @return bool true if successful.
  function increaseAllowance(address spender_, uint256 addedValue_) external returns (bool);

  /// @notice Decreases allowance for given spender.
  /// @param spender_ spender to decrease allowance for.
  /// @param subtractedValue_ removed amount that spender can spend.
  /// @return bool true if successful.
  function decreaseAllowance(address spender_, uint256 subtractedValue_) external returns (bool);

  /// @notice Stake tokens.
  /// @param amount_ amount of tokens to be staked.
  /// @return bool true if successful.
  function stake(uint256 amount_) external returns (bool);

  /// @notice Unstake tokens.
  /// @param amount_ amount of tokens to be unstaked.
  /// @return bool true if successful.
  function unstake(uint256 amount_) external returns (bool);

  /// @notice Functionality for DAO to add benefits for all stakers.
  /// @param amount_ amount of wei to be shared among stakers.
  function addBenefits(uint256 amount_) external;

  /// @notice Sets DAO and Factory addresses.
  /// @param dao_ DAO address that this token governs.
  /// @param factory_ Factory address.
  function setDaoFactoryAddresses(address dao_, address factory_) external;

  /// @notice Pauses token functionality.
  /// @param paused_ whether token functionality is paused.
  function setPause(bool paused_) external;

  /// @notice Sets whitelist address allowing it to make token operations when paused.
  /// @param whitelistAddress_ address to whitelist.
  function setWhitelistAddress(address whitelistAddress_) external;

  /// @notice Functionality for owner to burn tokens.
  /// @param amount_ amount of tokens to burn.
  function burn(uint256 amount_) external;
}

// "SPDX-License-Identifier: UNLICENSED"
pragma solidity 0.6.6;

/// @title Factory interface with benefits related methods exposed.
/// @notice Interface for claiming, adding and depositing benefits.
/// @author ORayskiy - @robitnik_TorroDao
interface ITorroFactory {

  /// @notice Address of the main token.
  /// @return address of the main token.  
  function mainToken() external view returns (address);

  /// @notice Address of the main DAO.
  /// @return address of the main DAO.
  function mainDao() external view returns (address);

  /// @notice Checks whether provided address is a valid DAO.
  /// @param dao_ address to check.
  /// @return bool true if address is a valid DAO.
  function isDao(address dao_) external view returns (bool);

  /// @notice Claim available benefits for holder.
  /// @param amount_ of wei to claim.
  function claimBenefits(uint256 amount_) external;

  /// @notice Adds withdrawal benefits for holder.
  /// @param recipient_ holder that's getting benefits.
  /// @param amount_ benefits amount to be added to holder's existing benefits.
  function addBenefits(address recipient_, uint256 amount_) external;
  
  /// @notice Depositis withdrawal benefits.
  /// @param token_ governing token for DAO that's depositing benefits.
  function depositBenefits(address token_) external payable;
}

pragma solidity >=0.4.24 <0.7.0;


/**
 * @title Initializable
 *
 * @dev Helper contract to support initializer functions. To use it, replace
 * the constructor with a function that has the `initializer` modifier.
 * WARNING: Unlike constructors, initializer functions must be manually
 * invoked. This applies both to deploying an Initializable contract, as well
 * as extending an Initializable contract via inheritance.
 * WARNING: When used with inheritance, manual care must be taken to not invoke
 * a parent initializer twice, or ensure that all initializers are idempotent,
 * because this is not dealt with automatically as with constructors.
 */
contract Initializable {

  /**
   * @dev Indicates that the contract has been initialized.
   */
  bool private initialized;

  /**
   * @dev Indicates that the contract is in the process of being initialized.
   */
  bool private initializing;

  /**
   * @dev Modifier to use in the initializer function of a contract.
   */
  modifier initializer() {
    require(initializing || isConstructor() || !initialized, "Contract instance has already been initialized");

    bool isTopLevelCall = !initializing;
    if (isTopLevelCall) {
      initializing = true;
      initialized = true;
    }

    _;

    if (isTopLevelCall) {
      initializing = false;
    }
  }

  /// @dev Returns true if and only if the function is running in the constructor
  function isConstructor() private view returns (bool) {
    // extcodesize checks the size of the code stored in an address, and
    // address returns the current address. Since the code is still not
    // deployed when running a constructor, any checks on its code size will
    // yield zero, making it an effective way to detect if a contract is
    // under construction or not.
    address self = address(this);
    uint256 cs;
    assembly { cs := extcodesize(self) }
    return cs == 0;
  }

  // Reserved storage space to allow for layout changes in the future.
  uint256[50] private ______gap;
}

pragma solidity ^0.6.0;

import "./Context.sol";
import "./Initializable.sol";
/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
contract OwnableUpgradeSafe is Initializable, ContextUpgradeSafe {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */

    function __Ownable_init() internal initializer {
        __Context_init_unchained();
        __Ownable_init_unchained();
    }

    function __Ownable_init_unchained() internal initializer {


        address msgSender = _msgSender();
        _owner = msgSender;
        emit OwnershipTransferred(address(0), msgSender);

    }


    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        require(_owner == _msgSender(), "Ownable: caller is not the owner");
        _;
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions anymore. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby removing any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        emit OwnershipTransferred(_owner, address(0));
        _owner = address(0);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        emit OwnershipTransferred(_owner, newOwner);
        _owner = newOwner;
    }

    uint256[49] private __gap;
}

pragma solidity =0.6.6;

// a library for performing overflow-safe math, courtesy of DappHub (https://github.com/dapphub/ds-math)

library SafeMath {
    function add(uint x, uint y) internal pure returns (uint z) {
        require((z = x + y) >= x, 'ds-math-add-overflow');
    }

    function sub(uint x, uint y) internal pure returns (uint z) {
        require((z = x - y) <= x, 'ds-math-sub-underflow');
    }

    function mul(uint x, uint y) internal pure returns (uint z) {
        require(y == 0 || (z = x * y) / y == x, 'ds-math-mul-overflow');
    }
}

// "SPDX-License-Identifier: UNLICENSED"
pragma solidity 0.6.6;

import "./Ownable.sol";
import "./EnumerableSet.sol";

import "./SafeMath.sol";

import "./ITorro.sol";
import "./ITorroFactory.sol";

/// @title ERC-20 Torro governing token.
/// @notice Contract for ERC-20 governing token.
/// @author ORayskiy - @robitnik_TorroDao
contract Torro is ITorro, OwnableUpgradeSafe {
  using SafeMath for uint256;
  using EnumerableSet for EnumerableSet.AddressSet;

  // Structs.

  /// @notice structure to hold holder's information.
  struct Holder {
    uint256 balance;
    uint256 staked;
    mapping(address => uint256) allowances;
  }

  // Private data.

  uint8 constant private _decimals = 18;

  string private _name;
  string private _symbol;
  uint256 private _totalSupply;
  address private _dao;
  address private _factory;
  bool private _isMain;
  bool private _paused;

  mapping(address => Holder) private _holders;
  EnumerableSet.AddressSet private _holderAddresses;

  address private _whitelist;

  // Events.

  /// @notice Event for dispatching when token transfer occurs.
  /// @param from address of tokens' sender.
  /// @param to address of tokens' reciever.
  /// @param amount amount of tokens sent.
	event Transfer(address indexed from, address indexed to, uint256 amount);

  /// @notice Event for dispatching when tokens allowance has been approved.
  /// @param owner address of tokens' owner.
  /// @param spender address of tokens; spender.
  /// @param value amount of tokens approved for use.
  event Approval(address indexed owner, address indexed spender, uint256 value);

  /// @notice Event for dispatching when tokens have been staked.
  /// @param owner address of tokens' owner that have been staked.
  /// @param amount amount of tokens that have been staked.
	event Stake(address indexed owner, uint256 amount);

  /// @notice Event for dispatching when tokens have been unstaked.
  /// @param owner address of tokens' owner that have been unstaked.
  /// @param amount amount of tokens that have been unstaked.
	event Unstake(address indexed owner, uint256 amount);
  
  /// @notice Event for dispatching when benefits have been added.
  event AddBenefits();

  // Constructor.

  constructor() public {
    __Ownable_init();

    _name = "Torro DAO Token";
    _symbol = "TORRO";
    _totalSupply = 1e23;
    _dao = address(0x0);
    _factory = address(0x0);
    _isMain = true;
    _paused = true;
    _whitelist = address(0x0);

    _holders[msg.sender].balance = _totalSupply;
    _holderAddresses.add(msg.sender);

	emit Transfer(address(0x0), msg.sender, _totalSupply);
  }

  /// @notice Initializes governing token.
  /// @param dao_ address of cloned DAO.
  /// @param factory_ address of factory.
  /// @param supply_ total supply of tokens.
  function initializeCustom(address dao_, address factory_, uint256 supply_) public override initializer {
    __Ownable_init();

    _name = "Torro DAO Pool Token";
    _symbol = "TORRO_POOL";
    _totalSupply = supply_;
    _dao = dao_;
    _factory = factory_;
    _isMain = false;
    _paused = false;
    _whitelist = address(0x0);

    _holders[dao_].balance = _totalSupply;
    _holderAddresses.add(dao_);

    emit Transfer(address(0x0), dao_, _totalSupply);
  }

  // Modifiers.

  /// @notice Modifier to check that token functionality is not paused.
  modifier notPaused() {
    require(_paused == false || msg.sender == owner() || msg.sender == _whitelist);
    _;
  }

  // Public calls.

  /// @notice Token's name.
  /// @return string name of the token.
  function name() public override view returns (string memory) {
    return _name;
  }

  /// @notice Token's symbol.
  /// @return string symbol of the token.
  function symbol() public override view returns (string memory) {
    return _symbol;
  }

  /// @notice Token's decimals.
  /// @return uint8 demials of the token.
  function decimals() public override pure returns (uint8) {
    return _decimals;
  }

  /// @notice Token's total supply.
  /// @return uint256 total supply of the token.
	function totalSupply() public override view returns (uint256) {
		return _totalSupply;
	}

  /// @notice Count of token holders.
  /// @return uint256 number of token holders.
  function holdersCount() public override view returns (uint256) {
    return _holderAddresses.length();
  }

  /// @notice All token holders.
  /// @return array of addresses of token holders.
  function holders() public override view returns (address[] memory) {
    uint256 length = _holderAddresses.length();
    address[] memory holderAddresses = new address[](length);
    for (uint256 i = 0; i < length; i++) {
      holderAddresses[i] = _holderAddresses.at(i);
    }
    return holderAddresses;
  }

  /// @notice Available balance for address.
  /// @param sender_ address to get available balance for.
  /// @return uint256 amount of tokens available for given address.
  function balanceOf(address sender_) public override view returns (uint256) {
    return _holders[sender_].balance;
  }

  /// @notice Staked balance for address.
  /// @param sender_ address to get staked balance for.
  /// @return uint256 amount of staked tokens for given address.
  function stakedOf(address sender_) public override view returns (uint256) {
    return _holders[sender_].staked;
  }

  /// @notice Total balance for address = available + staked.
  /// @param sender_ address to get total balance for.
  /// @return uint256 total amount of tokens for given address.
  function totalOf(address sender_) public override view returns (uint256) {
    return _holders[sender_].balance.add(_holders[sender_].staked);
  }

  /// @notice Spending allowance.
  /// @param owner_ token owner address.
  /// @param spender_ token spender address.
  /// @return uint256 amount of owner's tokens that spender can use.
  function allowance(address owner_, address spender_) public override view returns (uint256) {
    return _holders[owner_].allowances[spender_];
  }

  /// @notice Unstaked supply of token.
  /// @return uint256 amount of tokens in circulation that are not staked.
  function unstakedSupply() public override view returns (uint256) {
    uint256 supply = 0;
    for (uint256 i = 0; i < _holderAddresses.length(); i++) {
      supply = supply.add(_holders[_holderAddresses.at(i)].balance);
    }
    return supply;
  }

  /// @notice Staked supply of token.
  /// @return uint256 amount of tokens in circulation that are staked.
  function stakedSupply() public override view returns (uint256) {
    uint256 supply = 0;
    for (uint256 i = 0; i < _holderAddresses.length(); i++) {
      supply = supply.add(_holders[_holderAddresses.at(i)].staked);
    }
    return supply;
  }

  // Public transactions.

  /// @notice Transfer tokens to recipient.
  /// @param recipient_ address of tokens' recipient.
  /// @param amount_ amount of tokens to transfer.
  /// @return bool true if successful.
  function transfer(address recipient_, uint256 amount_) public override notPaused returns (bool) {
    _transfer(msg.sender, recipient_, amount_);
    return true;
  }

  /// @notice Approve spender to spend an allowance.
  /// @param spender_ address that will be allowed to spend specified amount of tokens.
  /// @param amount_ amount of tokens that spender can spend.
  /// @return bool true if successful.
  function approve(address spender_, uint256 amount_) public override notPaused returns (bool) {
    _approve(msg.sender, spender_, amount_);
    return true;
  }

  /// @notice Approves DAO to spend tokens.
  /// @param owner_ address whose tokens DAO can spend.
  /// @param amount_ amount of tokens that DAO can spend.
  /// @return bool true if successful.
  function approveDao(address owner_, uint256 amount_) public override notPaused returns (bool) {
    require(msg.sender == _dao);
    _approve(owner_, _dao, amount_);
    return true;
  }

  /// @notice Transfers tokens from owner to recipient by approved spender.
  /// @param owner_ address of tokens' owner whose tokens will be spent.
  /// @param recipient_ address of recipient that will recieve tokens.
  /// @param amount_ amount of tokens to be spent.
  /// @return bool true if successful.
  function transferFrom(address owner_, address recipient_, uint256 amount_) public override notPaused returns (bool) {
    require(_holders[owner_].allowances[msg.sender] >= amount_);
    _transfer(owner_, recipient_, amount_);
    _approve(owner_, msg.sender, _holders[owner_].allowances[msg.sender].sub(amount_));
    return true;
  }

  /// @notice Increases allowance for given spender.
  /// @param spender_ spender to increase allowance for.
  /// @param addedValue_ extra amount that spender can spend.
  /// @return bool true if successful.
  function increaseAllowance(address spender_, uint256 addedValue_) public override notPaused returns (bool) {
    _approve(msg.sender, spender_, _holders[msg.sender].allowances[spender_].add(addedValue_));
    return true;
  }

  /// @notice Decreases allowance for given spender.
  /// @param spender_ spender to decrease allowance for.
  /// @param subtractedValue_ removed amount that spender can spend.
  /// @return bool true if successful.
  function decreaseAllowance(address spender_, uint256 subtractedValue_) public override notPaused returns (bool) {
    _approve(msg.sender, spender_, _holders[msg.sender].allowances[spender_].sub(subtractedValue_));
    return true;
  }

  /// @notice Stake tokens.
  /// @param amount_ amount of tokens to be staked.
  /// @return bool true if successful.
	function stake(uint256 amount_) public override notPaused returns (bool) {
    require(amount_ >= 1e18);
    require(balanceOf(msg.sender) >= amount_);
    Holder storage holder = _holders[msg.sender];
    holder.balance = holder.balance.sub(amount_);
    holder.staked = holder.staked.add(amount_);
		emit Transfer(msg.sender, address(this), amount_);
		emit Stake(msg.sender, amount_);
    return true;
	}

  /// @notice Unstake tokens.
  /// @param amount_ amount of tokens to be unstaked.
  /// @return bool true if successful.
  function unstake(uint256 amount_) public override notPaused returns (bool) {
    require(stakedOf(msg.sender) >= amount_);
    Holder storage holder = _holders[msg.sender];
    uint256 amount;
    if (_isMain) {
      uint256 burn = amount_ / 200;
      uint256 tempTotalSupply = _totalSupply.sub(burn);
      if (tempTotalSupply < 1e22) {
        burn = _totalSupply.sub(tempTotalSupply);
      }
      if (burn > 0) {
        amount = amount_.sub(burn);
        _totalSupply = _totalSupply.sub(burn);
        emit Transfer(msg.sender, address(0x0), burn);
      }
    } else {
      amount = amount_;
    }
    holder.staked = holder.staked.sub(amount_);
    holder.balance = holder.balance.add(amount);
    emit Transfer(address(this), msg.sender, amount);
    emit Unstake(msg.sender, amount_);
    return true;
  }

  /// @notice Functionality for DAO to add benefits for all stakers.
  /// @param amount_ amount of wei to be shared among stakers.
  function addBenefits(uint256 amount_) public override {
    require(msg.sender == _dao || ITorroFactory(_factory).isDao(msg.sender));
    for (uint256 i = 0; i < _holderAddresses.length(); i++) {
      address holder = _holderAddresses.at(i);
      uint256 staked = stakedOf(holder);
      if (staked > 0) {
        uint256 amount = staked.mul(amount_) / stakedSupply();
        if (amount > 0) {
          ITorroFactory(_factory).addBenefits(holder, amount);
        }
      }
    }

    // Emit event that benefits have been added for token.
    emit AddBenefits();
  }
  
  /// @notice Functionality to burn tokens.
  /// @param amount_ amount of tokens to burn.
  function burn(uint256 amount_) public override {
    Holder storage burner = _holders[msg.sender];
    require(burner.balance >= amount_);
    burner.balance = burner.balance.sub(amount_);
    _totalSupply = _totalSupply.sub(amount_);

    emit Transfer(msg.sender, address(0x0), amount_);
  }

  // Private transactions.

  /// @notice Main functionality for token trnasfer.
  /// @param sender_ address that sends tokens.
  /// @param recipient_ address that will recieve tokens.
  /// @param amount_ amount of tokens to be sent.
  function _transfer(address sender_, address recipient_, uint256 amount_) private {
    require(sender_ != address(0x0));
    require(recipient_ != address(0x0));

    Holder storage sender = _holders[sender_];
    Holder storage recipient = _holders[recipient_];

    require(sender.balance >= amount_);

    if (_holderAddresses.contains(recipient_)) {
      recipient.balance = recipient.balance.add(amount_);
    } else {
      recipient.balance = amount_;
      _holderAddresses.add(recipient_);
    }
    sender.balance = sender.balance.sub(amount_);
    if (totalOf(sender_) == 0) {
      _holderAddresses.remove(sender_);
    }

    emit Transfer(sender_, recipient_, amount_);
  }

  /// @notice Main functionality for token allowance approval.
  /// @param owner_ address whose tokens will be spent.
  /// @param spender_ address that will be able to spend tokens.
  /// @param amount_ amount of tokens that can be spent.
  function _approve(address owner_, address spender_, uint256 amount_) private {
    require(owner_ != address(0x0));
    require(spender_ != address(0x0));

    _holders[owner_].allowances[spender_] = amount_;

    emit Approval(owner_, spender_, amount_);
  }

  // Owner transactions.

  /// @notice Sets DAO and Factory addresses.
  /// @param dao_ DAO address that this token governs.
  /// @param factory_ Factory address.
  function setDaoFactoryAddresses(address dao_, address factory_) public override onlyOwner {
    _dao = dao_;
    _factory = factory_;
  }

  /// @notice Pauses token functionality.
  /// @param paused_ whether token functionality is paused.
  function setPause(bool paused_) public override onlyOwner {
    _paused = paused_;
  }

  /// @notice Sets whitelist address allowing it to make token operations when paused.
  /// @param whitelistAddress_ address to whitelist.
  function setWhitelistAddress(address whitelistAddress_) public override onlyOwner {
    _whitelist = whitelistAddress_;
  }
}

{
  "compilationTarget": {
    "Torro.sol": "Torro"
  },
  "evmVersion": "istanbul",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": true,
    "runs": 200
  },
  "remappings": []
}