// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}

// SPDX-License-Identifier: UNLICENSED
pragma solidity ^0.8.24;

interface IManager {
    event WithdrawalRequested(uint256 indexed id, address indexed recipient, uint256 amount);
    event WithdrawalApproved(uint256 indexed id, address indexed approver);
    event WithdrawalExecuted(uint256 indexed id, address indexed recipient, uint256 amount);

    function setBuyFeePercentage(uint256 _newBuyFeePercentage) external;
    function setSellFeePercentage(uint256 _newSellFeePercentage) external;
    function addToWhitelist(address _account) external;
    function removeFromWhitelist(address _account) external;
    function requestWithdrawal(uint256 _amount, address payable _recipient) external;
    function approveWithdrawal(uint256 _requestId) external;
}

// SPDX-License-Identifier: UNLICENSED
pragma solidity ^0.8.24;

interface ITokenERC20 {
    event ManagerChanged(address indexed _manager);
    event BuyFeePercentageChanged(uint256 _previousBuyFee, uint256 _newBuyFee);
    event SellFeePercentageChanged(uint256 _previousSellFee, uint256 _newSellFee);
    event Whitelisted(address indexed _account);
    event RemovedFromWhitelist(address indexed _account);

    function isWhitelisted(address _account) external view returns (bool);
    function setManager(address payable _management) external;
    function renounceOwnership() external;
    function addToWhitelist(address _account) external;
    function removeFromWhitelist(address _account) external;
    function setBuyFeePercentage(uint256 _newBuyFeePercentage) external;
    function setSellFeePercentage(uint256 _newSellFeePercentage) external;
}

// SPDX-License-Identifier: UNLICENSED
pragma solidity ^0.8.24;

import "@openzeppelin/contracts/access/Ownable.sol";
import "./ITokenERC20.sol";
import {IManager} from "./IManager.sol";

contract Manager is IManager, Ownable {
    struct WithdrawalRequest {
        uint256 id;
        uint256 amount;
        address payable recipient;
        bool executed;
        uint256 approvals;
    }

    ITokenERC20 public tokenContract;
    uint256 public requestCount = 0;
    uint256 public constant requiredApprovals = 2;

    mapping(uint256 => WithdrawalRequest) public withdrawalRequests;
    mapping(uint256 => mapping(address => bool)) public approvals;
    mapping(address => bool) public approvers;

    constructor(address _tokenContract) Ownable(msg.sender) {
        require(_tokenContract != address(0), "Invalid token contract address");
        tokenContract = ITokenERC20(_tokenContract);
    }

    modifier onlyApprover() {
        require(approvers[msg.sender], "Not an approver");
        _;
    }

    function setApprover(address _approver, bool _status) external onlyOwner {
        approvers[_approver] = _status;
    }

    function setBuyFeePercentage(uint256 _newBuyFeePercentage) external onlyOwner {
        tokenContract.setBuyFeePercentage(_newBuyFeePercentage);
    }

    function setSellFeePercentage(uint256 _newSellFeePercentage) external onlyOwner {
        tokenContract.setSellFeePercentage(_newSellFeePercentage);
    }

    function addToWhitelist(address _account) external onlyOwner {
        tokenContract.addToWhitelist(_account);
    }

    function removeFromWhitelist(address _account) external onlyOwner {
        tokenContract.removeFromWhitelist(_account);
    }

    function requestWithdrawal(uint256 _amount, address payable _recipient) external onlyOwner {
        require(_recipient != address(0), "Invalid recipient address");
        (bool success, bytes memory result) = address(tokenContract).staticcall(
            abi.encodeWithSelector(bytes4(keccak256("balanceOf(address)")), address(this))
        );
        require(success, "Failed to get contract balance");
        require(_amount <= abi.decode(result, (uint256)), "Insufficient balance");

        uint256 requestId = ++requestCount;
        withdrawalRequests[requestId] = WithdrawalRequest({
            id: requestId,
            amount: _amount,
            recipient: _recipient,
            executed: false,
            approvals: 0
        });

        emit WithdrawalRequested(requestId, _recipient, _amount);
    }

    function approveWithdrawal(uint256 _requestId) external onlyApprover {
        WithdrawalRequest storage request = withdrawalRequests[_requestId];

        require(request.id == _requestId, "Invalid request id");
        require(!request.executed, "Request already executed");
        require(!approvals[_requestId][msg.sender], "Already approved");

        approvals[_requestId][msg.sender] = true;
        request.approvals++;

        emit WithdrawalApproved(_requestId, msg.sender);

        if (request.approvals >= requiredApprovals) {
            executeWithdrawal(_requestId);
        }
    }

    function executeWithdrawal(uint256 _requestId) internal {
        WithdrawalRequest storage request = withdrawalRequests[_requestId];

        require(request.id == _requestId, "Invalid request id");
        require(!request.executed, "Request already executed");
        require(request.approvals >= requiredApprovals, "Not enough approvals");

        request.executed = true;
        bytes memory data = abi.encodeWithSignature("transfer(address,uint256)", request.recipient, request.amount);
        (bool success,) = address(tokenContract).call(data);
        
        require(success, "Failed to transfer tokens");

        emit WithdrawalExecuted(_requestId, request.recipient, request.amount);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable.sol)

pragma solidity ^0.8.20;

import {Context} from "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is set to the address provided by the deployer. This can
 * later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    /**
     * @dev The caller account is not authorized to perform an operation.
     */
    error OwnableUnauthorizedAccount(address account);

    /**
     * @dev The owner is not a valid owner account. (eg. `address(0)`)
     */
    error OwnableInvalidOwner(address owner);

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the address provided by the deployer as the initial owner.
     */
    constructor(address initialOwner) {
        if (initialOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(initialOwner);
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        if (owner() != _msgSender()) {
            revert OwnableUnauthorizedAccount(_msgSender());
        }
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        if (newOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

{
  "compilationTarget": {
    "contracts/Manager.sol": "Manager"
  },
  "evmVersion": "paris",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": false,
    "runs": 200
  },
  "remappings": []
}