// SPDX-License-Identifier: UNLICENSED
pragma solidity ^0.8.18;

import "./IManifoldERC1155.sol";
import "./IBurnExtension.sol";
import "@openzeppelin/contracts/access/Ownable.sol";

contract BalloonSave is Ownable {
    IManifoldERC1155 public balloonContract =
        IManifoldERC1155(0x1386f70A946Cf9F06E32190cFB2F4F4f18365b87);
    IBurnExtension public balloonBurn = IBurnExtension(0xfa1B15dF09c2944a91A2F9F10A6133090d4119BD);

    uint256 pinkBurnIndex = 561955056;
    uint256 blueBurnIndex = 547496176;
    uint256 greenBurnIndex = 547492080;

    uint256 public ticketTokenId = 2;
    uint256 public pinkBalloonTokenId = 3;
    uint256 public blackBalloonTokenId = 4;
    uint256 public blueBalloonTokenId = 5;
    uint256 public greenBalloonTokenId = 6;

    uint256[] public blackBalloonTokenIds;

    bool public enabled;
    uint256 public disableTime;

    constructor(uint256 _disableTime) {
        enabled = false;
        disableTime = _disableTime;

        blackBalloonTokenIds = new uint256[](1);
        blackBalloonTokenIds[0] = blackBalloonTokenId;
    }

    event BalloonSaved(
        address indexed user,
        uint32 pinkBalloons,
        uint32 blueBalloons,
        uint32 greenBalloons
    );

    function saveBalloons(
        uint32 pinkBalloons,
        uint32 blueBalloons,
        uint32 greenBalloons
    ) external {
        require(enabled, "BalloonBurn: Contract is not enabled");
        require(block.timestamp < disableTime, "BalloonBurn: Contract is disabled");
        require(
            pinkBalloons + blueBalloons + greenBalloons > 0,
            "BalloonBurn: You must burn at least one ticket"
        );

        uint256[] memory blackBalloonAmounts = new uint256[](1);
        blackBalloonAmounts[0] = pinkBalloons + blueBalloons + greenBalloons;
        balloonContract.burn(msg.sender, blackBalloonTokenIds, blackBalloonAmounts);

        address[] memory addresses = new address[](1);
        addresses[0] = msg.sender;
        if (pinkBalloons > 0) {
            uint32[] memory pinkBalloonsArr = new uint32[](1);
            pinkBalloonsArr[0] = pinkBalloons;
            balloonBurn.airdrop(
                address(balloonContract),
                pinkBurnIndex,
                addresses,
                pinkBalloonsArr
            );
        }
        if (blueBalloons > 0) {
            uint32[] memory blueBalloonsArr = new uint32[](1);
            blueBalloonsArr[0] = blueBalloons;
            balloonBurn.airdrop(
                address(balloonContract),
                blueBurnIndex,
                addresses,
                blueBalloonsArr
            );
        }
        if (greenBalloons > 0) {
            uint32[] memory greenBalloonsArr = new uint32[](1);
            greenBalloonsArr[0] = greenBalloons;
            balloonBurn.airdrop(
                address(balloonContract),
                greenBurnIndex,
                addresses,
                greenBalloonsArr
            );
        }

        emit BalloonSaved(msg.sender, pinkBalloons, blueBalloons, greenBalloons);
    }

    function setDisableTime(uint256 _disableTime) external onlyOwner {
        disableTime = _disableTime;
    }

    function setEnabled(bool newState) external onlyOwner {
        enabled = newState;
    }

    function getInfo(
        address user
    )
        public
        view
        returns (
            uint256 balance,
            bool hasApproved,
            bool isEnabled,
            uint256 endTime,
            uint256 pinkBalloonAmount,
            uint256 blackBalloonAmount,
            uint256 blueBalloonAmount,
            uint256 greenBalloonAmount,
            uint256 pinkBalloonTotalAmount,
            uint256 blackBalloonTotalAmount,
            uint256 blueBalloonTotalAmount,
            uint256 greenBalloonTotalAmount
        )
    {
        if (user == address(0)) {
            hasApproved = false;
            balance = 0;

            pinkBalloonAmount = 0;
            blackBalloonAmount = 0;
            blueBalloonAmount = 0;
            greenBalloonAmount = 0;
        } else {
            hasApproved = balloonContract.isApprovedForAll(user, address(this));
            balance = payable(user).balance;

            pinkBalloonAmount = balloonContract.balanceOf(user, pinkBalloonTokenId);
            blackBalloonAmount = balloonContract.balanceOf(user, blackBalloonTokenId);
            blueBalloonAmount = balloonContract.balanceOf(user, blueBalloonTokenId);
            greenBalloonAmount = balloonContract.balanceOf(user, greenBalloonTokenId);
        }

        isEnabled = enabled;
        endTime = disableTime;

        pinkBalloonTotalAmount = balloonContract.totalSupply(pinkBalloonTokenId);
        blackBalloonTotalAmount = balloonContract.totalSupply(blackBalloonTokenId);
        blueBalloonTotalAmount = balloonContract.totalSupply(blueBalloonTokenId);
        greenBalloonTotalAmount = balloonContract.totalSupply(greenBalloonTokenId);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Context.sol)

pragma solidity ^0.8.0;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}

//SPDX-License-Identifier: UNLICENSED
pragma solidity ^0.8.18;

interface IBurnExtension {
    function airdrop(
        address creatorContractAddress,
        uint256 index,
        address[] calldata recipients,
        uint32[] calldata amounts
    ) external;
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/introspection/IERC165.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[EIP].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[EIP section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.7.0) (token/ERC1155/IERC1155.sol)

pragma solidity ^0.8.0;

import "@openzeppelin/contracts/utils/introspection/IERC165.sol";

/**
 * @dev Required interface of an ERC1155 compliant contract, as defined in the
 * https://eips.ethereum.org/EIPS/eip-1155[EIP].
 *
 * _Available since v3.1._
 */
interface IManifoldERC1155 is IERC165 {
    /**
     * @dev Emitted when `value` tokens of token type `id` are transferred from `from` to `to` by `operator`.
     */
    event TransferSingle(
        address indexed operator,
        address indexed from,
        address indexed to,
        uint256 id,
        uint256 value
    );

    /**
     * @dev Equivalent to multiple {TransferSingle} events, where `operator`, `from` and `to` are the same for all
     * transfers.
     */
    event TransferBatch(
        address indexed operator,
        address indexed from,
        address indexed to,
        uint256[] ids,
        uint256[] values
    );

    /**
     * @dev Emitted when `account` grants or revokes permission to `operator` to transfer their tokens, according to
     * `approved`.
     */
    event ApprovalForAll(address indexed account, address indexed operator, bool approved);

    /**
     * @dev Emitted when the URI for token type `id` changes to `value`, if it is a non-programmatic URI.
     *
     * If an {URI} event was emitted for `id`, the standard
     * https://eips.ethereum.org/EIPS/eip-1155#metadata-extensions[guarantees] that `value` will equal the value
     * returned by {IERC1155MetadataURI-uri}.
     */
    event URI(string value, uint256 indexed id);

    /**
     * @dev Returns the amount of tokens of token type `id` owned by `account`.
     *
     * Requirements:
     *
     * - `account` cannot be the zero address.
     */
    function balanceOf(address account, uint256 id) external view returns (uint256);

    /**
     * @dev xref:ROOT:erc1155.adoc#batch-operations[Batched] version of {balanceOf}.
     *
     * Requirements:
     *
     * - `accounts` and `ids` must have the same length.
     */
    function balanceOfBatch(
        address[] calldata accounts,
        uint256[] calldata ids
    ) external view returns (uint256[] memory);

    /**
     * @dev Grants or revokes permission to `operator` to transfer the caller's tokens, according to `approved`,
     *
     * Emits an {ApprovalForAll} event.
     *
     * Requirements:
     *
     * - `operator` cannot be the caller.
     */
    function setApprovalForAll(address operator, bool approved) external;

    /**
     * @dev Returns true if `operator` is approved to transfer ``account``'s tokens.
     *
     * See {setApprovalForAll}.
     */
    function isApprovedForAll(address account, address operator) external view returns (bool);

    /**
     * @dev Transfers `amount` tokens of token type `id` from `from` to `to`.
     *
     * Emits a {TransferSingle} event.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     * - If the caller is not `from`, it must have been approved to spend ``from``'s tokens via {setApprovalForAll}.
     * - `from` must have a balance of tokens of type `id` of at least `amount`.
     * - If `to` refers to a smart contract, it must implement {IERC1155Receiver-onERC1155Received} and return the
     * acceptance magic value.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 id,
        uint256 amount,
        bytes calldata data
    ) external;

    /**
     * @dev xref:ROOT:erc1155.adoc#batch-operations[Batched] version of {safeTransferFrom}.
     *
     * Emits a {TransferBatch} event.
     *
     * Requirements:
     *
     * - `ids` and `amounts` must have the same length.
     * - If `to` refers to a smart contract, it must implement {IERC1155Receiver-onERC1155BatchReceived} and return the
     * acceptance magic value.
     */
    function safeBatchTransferFrom(
        address from,
        address to,
        uint256[] calldata ids,
        uint256[] calldata amounts,
        bytes calldata data
    ) external;

    function totalSupply(uint256 id) external view returns (uint256);

    function mintBaseExisting(
        address[] calldata to,
        uint256[] calldata tokenIds,
        uint256[] calldata amounts
    ) external;

    function burn(address account, uint256[] memory tokenIds, uint256[] memory amounts) external;
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.7.0) (access/Ownable.sol)

pragma solidity ^0.8.0;

import "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _transferOwnership(_msgSender());
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions anymore. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby removing any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

{
  "compilationTarget": {
    "BalloonSave.sol": "BalloonSave"
  },
  "evmVersion": "paris",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": true,
    "runs": 200
  },
  "remappings": []
}