// SPDX-License-Identifier: MIT

pragma solidity ^0.7.0;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize, which returns 0 for contracts in
        // construction, since the code is only stored at the end of the
        // constructor execution.

        uint256 size;
        // solhint-disable-next-line no-inline-assembly
        assembly { size := extcodesize(account) }
        return size > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://diligence.consensys.net/posts/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.5.11/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        // solhint-disable-next-line avoid-low-level-calls, avoid-call-value
        (bool success, ) = recipient.call{ value: amount }("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain`call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
      return functionCall(target, data, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data, string memory errorMessage) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value, string memory errorMessage) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        require(isContract(target), "Address: call to non-contract");

        // solhint-disable-next-line avoid-low-level-calls
        (bool success, bytes memory returndata) = target.call{ value: value }(data);
        return _verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data, string memory errorMessage) internal view returns (bytes memory) {
        require(isContract(target), "Address: static call to non-contract");

        // solhint-disable-next-line avoid-low-level-calls
        (bool success, bytes memory returndata) = target.staticcall(data);
        return _verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionDelegateCall(target, data, "Address: low-level delegate call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data, string memory errorMessage) internal returns (bytes memory) {
        require(isContract(target), "Address: delegate call to non-contract");

        // solhint-disable-next-line avoid-low-level-calls
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return _verifyCallResult(success, returndata, errorMessage);
    }

    function _verifyCallResult(bool success, bytes memory returndata, string memory errorMessage) private pure returns(bytes memory) {
        if (success) {
            return returndata;
        } else {
            // Look for revert reason and bubble it up if present
            if (returndata.length > 0) {
                // The easiest way to bubble the revert reason is using memory via assembly

                // solhint-disable-next-line no-inline-assembly
                assembly {
                    let returndata_size := mload(returndata)
                    revert(add(32, returndata), returndata_size)
                }
            } else {
                revert(errorMessage);
            }
        }
    }
}

// SPDX-License-Identifier: MIT

pragma solidity >=0.6.0 <0.8.0;

/*
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with GSN meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address payable) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes memory) {
        this; // silence state mutability warning without generating bytecode - see https://github.com/ethereum/solidity/issues/2691
        return msg.data;
    }
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.7.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `recipient`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address recipient, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `sender` to `recipient` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address sender, address recipient, uint256 amount) external returns (bool);

    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.7.6;

interface IWETH {
  function deposit() external payable;

  function withdraw(uint256 wad) external;
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.7.6;

interface IZap {
  function zap(
    address _fromToken,
    uint256 _amountIn,
    address _toToken,
    uint256 _minOut
  ) external payable returns (uint256);

  function zapWithRoutes(
    address _fromToken,
    uint256 _amountIn,
    address _toToken,
    uint256[] calldata _routes,
    uint256 _minOut
  ) external payable returns (uint256);

  function zapFrom(
    address _fromToken,
    uint256 _amountIn,
    address _toToken,
    uint256 _minOut
  ) external payable returns (uint256);
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.7.0;

import "../utils/Context.sol";
/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor () {
        address msgSender = _msgSender();
        _owner = msgSender;
        emit OwnershipTransferred(address(0), msgSender);
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
        _;
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions anymore. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby removing any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        emit OwnershipTransferred(_owner, address(0));
        _owner = address(0);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        emit OwnershipTransferred(_owner, newOwner);
        _owner = newOwner;
    }
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.7.0;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant _NOT_ENTERED = 1;
    uint256 private constant _ENTERED = 2;

    uint256 private _status;

    constructor () {
        _status = _NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and make it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        // On the first call to nonReentrant, _notEntered will be true
        require(_status != _ENTERED, "ReentrancyGuard: reentrant call");

        // Any calls to nonReentrant after this point will fail
        _status = _ENTERED;

        _;

        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = _NOT_ENTERED;
    }
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.7.0;

import "./IERC20.sol";
import "../../math/SafeMath.sol";
import "../../utils/Address.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using SafeMath for uint256;
    using Address for address;

    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transfer.selector, to, value));
    }

    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transferFrom.selector, from, to, value));
    }

    /**
     * @dev Deprecated. This function has issues similar to the ones found in
     * {IERC20-approve}, and its usage is discouraged.
     *
     * Whenever possible, use {safeIncreaseAllowance} and
     * {safeDecreaseAllowance} instead.
     */
    function safeApprove(IERC20 token, address spender, uint256 value) internal {
        // safeApprove should only be called when setting an initial allowance,
        // or when resetting it to zero. To increase and decrease it, use
        // 'safeIncreaseAllowance' and 'safeDecreaseAllowance'
        // solhint-disable-next-line max-line-length
        require((value == 0) || (token.allowance(address(this), spender) == 0),
            "SafeERC20: approve from non-zero to non-zero allowance"
        );
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, value));
    }

    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 newAllowance = token.allowance(address(this), spender).add(value);
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, newAllowance));
    }

    function safeDecreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 newAllowance = token.allowance(address(this), spender).sub(value, "SafeERC20: decreased allowance below zero");
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, newAllowance));
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We use {Address.functionCall} to perform this call, which verifies that
        // the target address contains contract code and also asserts for success in the low-level call.

        bytes memory returndata = address(token).functionCall(data, "SafeERC20: low-level call failed");
        if (returndata.length > 0) { // Return data is optional
            // solhint-disable-next-line max-line-length
            require(abi.decode(returndata, (bool)), "SafeERC20: ERC20 operation did not succeed");
        }
    }
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.7.0;

/**
 * @dev Wrappers over Solidity's arithmetic operations with added overflow
 * checks.
 *
 * Arithmetic operations in Solidity wrap on overflow. This can easily result
 * in bugs, because programmers usually assume that an overflow raises an
 * error, which is the standard behavior in high level programming languages.
 * `SafeMath` restores this intuition by reverting the transaction when an
 * operation overflows.
 *
 * Using this library instead of the unchecked operations eliminates an entire
 * class of bugs, so it's recommended to use it always.
 */
library SafeMath {
    /**
     * @dev Returns the addition of two unsigned integers, with an overflow flag.
     *
     * _Available since v3.4._
     */
    function tryAdd(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        uint256 c = a + b;
        if (c < a) return (false, 0);
        return (true, c);
    }

    /**
     * @dev Returns the substraction of two unsigned integers, with an overflow flag.
     *
     * _Available since v3.4._
     */
    function trySub(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        if (b > a) return (false, 0);
        return (true, a - b);
    }

    /**
     * @dev Returns the multiplication of two unsigned integers, with an overflow flag.
     *
     * _Available since v3.4._
     */
    function tryMul(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        // Gas optimization: this is cheaper than requiring 'a' not being zero, but the
        // benefit is lost if 'b' is also tested.
        // See: https://github.com/OpenZeppelin/openzeppelin-contracts/pull/522
        if (a == 0) return (true, 0);
        uint256 c = a * b;
        if (c / a != b) return (false, 0);
        return (true, c);
    }

    /**
     * @dev Returns the division of two unsigned integers, with a division by zero flag.
     *
     * _Available since v3.4._
     */
    function tryDiv(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        if (b == 0) return (false, 0);
        return (true, a / b);
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers, with a division by zero flag.
     *
     * _Available since v3.4._
     */
    function tryMod(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        if (b == 0) return (false, 0);
        return (true, a % b);
    }

    /**
     * @dev Returns the addition of two unsigned integers, reverting on
     * overflow.
     *
     * Counterpart to Solidity's `+` operator.
     *
     * Requirements:
     *
     * - Addition cannot overflow.
     */
    function add(uint256 a, uint256 b) internal pure returns (uint256) {
        uint256 c = a + b;
        require(c >= a, "SafeMath: addition overflow");
        return c;
    }

    /**
     * @dev Returns the subtraction of two unsigned integers, reverting on
     * overflow (when the result is negative).
     *
     * Counterpart to Solidity's `-` operator.
     *
     * Requirements:
     *
     * - Subtraction cannot overflow.
     */
    function sub(uint256 a, uint256 b) internal pure returns (uint256) {
        require(b <= a, "SafeMath: subtraction overflow");
        return a - b;
    }

    /**
     * @dev Returns the multiplication of two unsigned integers, reverting on
     * overflow.
     *
     * Counterpart to Solidity's `*` operator.
     *
     * Requirements:
     *
     * - Multiplication cannot overflow.
     */
    function mul(uint256 a, uint256 b) internal pure returns (uint256) {
        if (a == 0) return 0;
        uint256 c = a * b;
        require(c / a == b, "SafeMath: multiplication overflow");
        return c;
    }

    /**
     * @dev Returns the integer division of two unsigned integers, reverting on
     * division by zero. The result is rounded towards zero.
     *
     * Counterpart to Solidity's `/` operator. Note: this function uses a
     * `revert` opcode (which leaves remaining gas untouched) while Solidity
     * uses an invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function div(uint256 a, uint256 b) internal pure returns (uint256) {
        require(b > 0, "SafeMath: division by zero");
        return a / b;
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers. (unsigned integer modulo),
     * reverting when dividing by zero.
     *
     * Counterpart to Solidity's `%` operator. This function uses a `revert`
     * opcode (which leaves remaining gas untouched) while Solidity uses an
     * invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function mod(uint256 a, uint256 b) internal pure returns (uint256) {
        require(b > 0, "SafeMath: modulo by zero");
        return a % b;
    }

    /**
     * @dev Returns the subtraction of two unsigned integers, reverting with custom message on
     * overflow (when the result is negative).
     *
     * CAUTION: This function is deprecated because it requires allocating memory for the error
     * message unnecessarily. For custom revert reasons use {trySub}.
     *
     * Counterpart to Solidity's `-` operator.
     *
     * Requirements:
     *
     * - Subtraction cannot overflow.
     */
    function sub(uint256 a, uint256 b, string memory errorMessage) internal pure returns (uint256) {
        require(b <= a, errorMessage);
        return a - b;
    }

    /**
     * @dev Returns the integer division of two unsigned integers, reverting with custom message on
     * division by zero. The result is rounded towards zero.
     *
     * CAUTION: This function is deprecated because it requires allocating memory for the error
     * message unnecessarily. For custom revert reasons use {tryDiv}.
     *
     * Counterpart to Solidity's `/` operator. Note: this function uses a
     * `revert` opcode (which leaves remaining gas untouched) while Solidity
     * uses an invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function div(uint256 a, uint256 b, string memory errorMessage) internal pure returns (uint256) {
        require(b > 0, errorMessage);
        return a / b;
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers. (unsigned integer modulo),
     * reverting with custom message when dividing by zero.
     *
     * CAUTION: This function is deprecated because it requires allocating memory for the error
     * message unnecessarily. For custom revert reasons use {tryMod}.
     *
     * Counterpart to Solidity's `%` operator. This function uses a `revert`
     * opcode (which leaves remaining gas untouched) while Solidity uses an
     * invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function mod(uint256 a, uint256 b, string memory errorMessage) internal pure returns (uint256) {
        require(b > 0, errorMessage);
        return a % b;
    }
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.7.6;

import "@openzeppelin/contracts/access/Ownable.sol";
import "@openzeppelin/contracts/math/SafeMath.sol";
import "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import "@openzeppelin/contracts/token/ERC20/SafeERC20.sol";
import "@openzeppelin/contracts/utils/ReentrancyGuard.sol";

import "../interfaces/IWETH.sol";
import "../interfaces/IZap.sol";

import "./Vesting.sol";

// solhint-disable reason-string, not-rely-on-time

contract TokenSale is Ownable, ReentrancyGuard {
  using SafeERC20 for IERC20;
  using SafeMath for uint256;

  event Buy(address indexed sender, address _token, uint256 _amountIn, uint256 _refundAmount, uint256 _amountOut);
  event Claim(address indexed _recipient, uint256 _vestingAmount, uint256 _claimAmount);
  event UpdatePrice(uint256 _initialPrice, uint256 _upRatio, uint256 _variation);
  event UpdateSaleTime(uint256 _whitelistSaleTime, uint256 _publicSaleTime, uint256 _publicSaleDuration);
  event UpdateVesting(address _vesting, uint256 _vestRatio, uint256 _duration);
  event UpdateWhitelistCap(address indexed _whitelist, uint256 _cap);
  event UpdateSupportedToken(address indexed _token, bool _status);
  event UpdateCap(uint128 _cap);

  uint256 private constant PRICE_PRECISION = 1e18;
  uint256 private constant RATIO_PRECISION = 1e9;

  address public immutable weth;
  address public immutable base;
  address public immutable zap;
  address public quota;

  struct PriceData {
    uint96 initialPrice;
    uint32 upRatio;
    uint128 variation;
  }

  struct SaleTimeData {
    uint64 whitelistSaleTime;
    uint64 publicSaleTime;
    uint64 saleDuration;
  }

  struct VestingData {
    address vesting;
    uint32 vestRatio;
    uint64 duration;
  }

  SaleTimeData public saleTimeData;
  PriceData public priceData;
  VestingData public vestingData;

  uint128 public cap;
  uint128 public totalSold;

  mapping(address => bool) public isSupported;
  mapping(address => uint256) public whitelistCap;
  mapping(address => uint256) public shares;
  mapping(address => bool) public claimed;

  constructor(
    address _weth,
    address _base,
    address _zap,
    uint128 _cap
  ) {
    weth = _weth;
    base = _base;
    zap = _zap;
    cap = _cap;
  }

  /********************************** View Functions **********************************/

  /// @notice Return current price (base/quota) of quota token.
  /// @dev                                                  / totalSold \
  ///      CurrenetPrice = InitPrice * (1 + UpRatio * floor|  ---------  |)
  ///                                                       \ Variation /
  function getPrice() public view returns (uint256) {
    PriceData memory _data = priceData;
    uint256 _totalSold = totalSold;
    uint256 _level = _totalSold / _data.variation;

    return RATIO_PRECISION.add(_level.mul(_data.upRatio)).mul(_data.initialPrice).div(RATIO_PRECISION);
  }

  /********************************** Mutated Functions **********************************/

  /// @notice Purchase some quota in contract using supported base token.
  ///
  /// @dev The contract will refund `_token` back to caller if the sale cap is not enough.
  ///
  /// @param _token The address of token used to buy quota token.
  /// @param _amountIn The amount of `_token` to use.
  /// @param _minOut The minimum recieved quota token.
  function buy(
    address _token,
    uint256 _amountIn,
    uint256 _minOut
  ) external payable nonReentrant returns (uint256) {
    require(_amountIn > 0, "TokenSale: zero input amount");

    // 1. check supported token
    require(isSupported[_token], "TokenSale: token not support");

    // 2. check sale time
    SaleTimeData memory _saleTime = saleTimeData;
    require(block.timestamp >= _saleTime.whitelistSaleTime, "TokenSale: sale not start");
    require(block.timestamp <= _saleTime.publicSaleTime + _saleTime.saleDuration, "TokenSale: sale ended");

    // 3. determine account sale cap
    uint256 _cap = cap;
    uint256 _totalSold = totalSold;
    uint256 _saleCap = _cap.sub(_totalSold);
    require(_saleCap > 0, "TokenSale: sold out");

    uint256 _userCap;
    if (block.timestamp < _saleTime.publicSaleTime) {
      _userCap = whitelistCap[msg.sender].sub(shares[msg.sender]);
      if (_userCap > _saleCap) {
        _userCap = _saleCap;
      }
    } else {
      _userCap = _saleCap;
    }
    require(_userCap > 0, "TokenSale: no cap to buy");

    // 4. transfer token in contract
    if (_token == address(0)) {
      require(_amountIn == msg.value, "TokenSale: msg.value mismatch");
      _token = weth;
      IWETH(_token).deposit{ value: _amountIn }();
    } else {
      require(0 == msg.value, "TokenSale: nonzero msg.value");
      uint256 _before = IERC20(_token).balanceOf(address(this));
      IERC20(_token).safeTransferFrom(msg.sender, address(this), _amountIn);
      _amountIn = IERC20(_token).balanceOf(address(this)) - _before;
    }

    // 5. zap input token to base token
    address _base = base;
    uint256 _baseAmountIn;
    if (_token != _base) {
      address _zap = zap;
      IERC20(_token).safeTransfer(_zap, _amountIn);
      _baseAmountIn = IZap(_zap).zap(_token, _amountIn, _base, 0);
    } else {
      _baseAmountIn = _amountIn;
    }

    // 6. buy and update storage
    uint256 _price = getPrice();
    uint256 _amountOut = _baseAmountIn.mul(PRICE_PRECISION).div(_price);
    uint256 _refundAmount;
    if (_userCap < _amountOut) {
      _refundAmount = (_amountOut - _userCap).mul(_price).div(PRICE_PRECISION);
      _amountOut = _userCap;
    }
    require(_amountOut >= _minOut, "TokenSale: insufficient output");
    shares[msg.sender] += _amountOut;

    _totalSold += _amountOut;
    require(_totalSold <= uint128(-1), "TokenSale: overflow");
    totalSold = uint128(_totalSold);

    // 7. refund extra token
    if (_refundAmount > 0) {
      _refundAmount = _refund(_token, _refundAmount);
    }

    emit Buy(msg.sender, msg.value > 0 ? address(0) : _token, _amountIn, _refundAmount, _amountOut);

    return _amountOut;
  }

  /// @notice Claim purchased quota token.
  function claim() external nonReentrant {
    // 1. check timestamp and claimed.
    SaleTimeData memory _saleTime = saleTimeData;
    require(block.timestamp > _saleTime.publicSaleTime + _saleTime.saleDuration, "TokenSale: sale not end");
    require(!claimed[msg.sender], "TokenSale: already claimed");

    // 2. check claiming amount
    VestingData memory _vesting = vestingData;
    uint256 _claimAmount = shares[msg.sender];
    require(_claimAmount > 0, "TokenSale: no share to claim");
    claimed[msg.sender] = true;

    address _quota = quota;

    // 3. vesting
    uint256 _vestingAmount = _claimAmount.mul(_vesting.vestRatio).div(RATIO_PRECISION);
    if (_vestingAmount > 0) {
      IERC20(_quota).safeApprove(_vesting.vesting, 0);
      IERC20(_quota).safeApprove(_vesting.vesting, _vestingAmount);
      Vesting(_vesting.vesting).newVesting(
        msg.sender,
        uint128(_vestingAmount),
        uint64(block.timestamp),
        uint64(block.timestamp + _vesting.duration)
      );
    }

    // 4. transfer
    _claimAmount = _claimAmount - _vestingAmount;
    if (_claimAmount > 0) {
      IERC20(_quota).safeTransfer(msg.sender, _claimAmount);
    }

    emit Claim(msg.sender, _vestingAmount, _claimAmount);
  }

  /********************************** Restricted Functions **********************************/

  function updateCap(uint128 _cap) external onlyOwner {
    cap = _cap;

    emit UpdateCap(_cap);
  }

  /// @notice Update supported tokens.
  /// @param _tokens The list of addresses of token to update.
  /// @param _status The status to update.
  function updateSupportedTokens(address[] memory _tokens, bool _status) external onlyOwner {
    for (uint256 i = 0; i < _tokens.length; i++) {
      isSupported[_tokens[i]] = _status;
      emit UpdateSupportedToken(_tokens[i], _status);
    }
  }

  /// @notice Update token cap for whitelists.
  /// @param _whitelist The list of whitelist to update.
  /// @param _caps The list of cap to update.
  function updateWhitelistCap(address[] memory _whitelist, uint256[] memory _caps) external onlyOwner {
    require(_whitelist.length == _caps.length, "TokenSale: length mismatch");

    for (uint256 i = 0; i < _whitelist.length; i++) {
      whitelistCap[_whitelist[i]] = _caps[i];
      emit UpdateWhitelistCap(_whitelist[i], _caps[i]);
    }
  }

  /// @notice Update sale start time, including whitelist/public sale start time and duration.
  ///
  /// @param _whitelistSaleTime The timestamp when whitelist sale started.
  /// @param _publicSaleTime The timestamp when public sale started.
  /// @param _publicSaleDuration The durarion of public sale in seconds.
  function updateSaleTime(
    uint64 _whitelistSaleTime,
    uint64 _publicSaleTime,
    uint64 _publicSaleDuration
  ) external onlyOwner {
    require(_whitelistSaleTime >= block.timestamp, "TokenSale: start time too small");
    require(_whitelistSaleTime <= _publicSaleTime, "TokenSale: whitelist after public");

    SaleTimeData memory _saleTime = saleTimeData;
    require(
      _saleTime.whitelistSaleTime == 0 || block.timestamp < _saleTime.whitelistSaleTime,
      "TokenSale: sale started"
    );

    saleTimeData = SaleTimeData(_whitelistSaleTime, _publicSaleTime, _publicSaleDuration);

    emit UpdateSaleTime(_whitelistSaleTime, _publicSaleTime, _publicSaleDuration);
  }

  /// @notice Update token sale price info.
  /// @dev See comments in function `getPrice()` for the usage of each parameters.
  ///
  /// @param _initialPrice The initial price for the sale, with precision 1e18.
  /// @param _upRatio The up ratio for the token sale, with precision 1e9.
  /// @param _variation The variation for price change base on the amount of quota token sold.
  function updatePrice(
    uint96 _initialPrice,
    uint32 _upRatio,
    uint128 _variation
  ) external onlyOwner {
    require(_upRatio <= RATIO_PRECISION, "TokenSale: ratio too large");
    require(_variation > 0, "TokenSale: zero variation");

    SaleTimeData memory _saleTime = saleTimeData;
    require(
      _saleTime.whitelistSaleTime == 0 || block.timestamp < _saleTime.whitelistSaleTime,
      "TokenSale: sale started"
    );

    priceData = PriceData(_initialPrice, _upRatio, _variation);

    emit UpdatePrice(_initialPrice, _upRatio, _variation);
  }

  /// @notice Update vesting information.
  /// @param _vesting The address of vesting contract.
  /// @param _vestRatio The percentage of quota token to vest.
  /// @param _duration The vesting duration, in seconds.
  function updateVesting(
    address _quota,
    address _vesting,
    uint32 _vestRatio,
    uint64 _duration
  ) external onlyOwner {
    require(_vestRatio <= RATIO_PRECISION, "TokenSale: ratio too large");
    require(_duration > 0, "TokenSale: zero duration");

    quota = _quota;
    vestingData = VestingData(_vesting, _vestRatio, _duration);

    emit UpdateVesting(_vesting, _vestRatio, _duration);
  }

  function withdrawFund(address[] memory _tokens, address _recipient) external onlyOwner {
    for (uint256 i = 0; i < _tokens.length; i++) {
      if (_tokens[i] == address(0)) {
        uint256 _balance = address(this).balance;
        // solhint-disable-next-line avoid-low-level-calls
        (bool success, ) = _recipient.call{ value: _balance }("");
        require(success, "TokenSale: failed to withdraw ETH");
      } else {
        uint256 _balance = IERC20(_tokens[i]).balanceOf(address(this));
        IERC20(_tokens[i]).safeTransfer(_recipient, _balance);
      }
    }
  }

  /********************************** Internal Functions **********************************/

  /// @dev Refund extra token back to sender, will call zap if needed.
  /// @param _token The address of token to refund.
  /// @param _amount The amount of base token to refund.
  function _refund(address _token, uint256 _amount) internal returns (uint256) {
    address _base = base;
    if (_token != _base) {
      address _zap = zap;
      IERC20(_base).safeTransfer(_zap, _amount);
      uint256 _before = IERC20(_token).balanceOf(address(this));
      IZap(_zap).zap(_base, _amount, _token, 0);
      _amount = IERC20(_token).balanceOf(address(this)) - _before;
    }
    if (msg.value > 0) {
      IWETH(_token).withdraw(_amount);
      // solhint-disable-next-line avoid-low-level-calls
      (bool success, ) = msg.sender.call{ value: _amount }("");
      require(success, "TokenSale: failed to refund ETH");
    } else {
      IERC20(_token).safeTransfer(msg.sender, _amount);
    }
    return _amount;
  }

  // solhint-disable-next-line no-empty-blocks
  receive() external payable {}
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.7.6;
pragma abicoder v2;

import "@openzeppelin/contracts/access/Ownable.sol";
import "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import "@openzeppelin/contracts/token/ERC20/SafeERC20.sol";

// solhint-disable not-rely-on-time

contract Vesting is Ownable {
  using SafeERC20 for IERC20;

  /// @notice Emitted when a token vest is added.
  /// @param _recipient The address of recipient who will receive the vest.
  /// @param _index The index of the vesting list.
  /// @param _amount The amount of token to vest.
  /// @param _startTime The timestamp in second when the vest starts.
  /// @param _endTime The timestamp in second when the vest ends.
  event Vest(address indexed _recipient, uint256 indexed _index, uint256 _amount, uint256 _startTime, uint256 _endTime);

  /// @notice Emitted when a vest is cancled.
  /// @param _recipient The address of recipient who will receive the vest.
  /// @param _index The index of the vesting list.
  /// @param _unvested The amount of unvested token.
  /// @param _cancleTime The timestamp in second when the vest is cancled.
  event Cancle(address indexed _recipient, uint256 indexed _index, uint256 _unvested, uint256 _cancleTime);

  /// @notice Emitted when a user claim his vest.
  /// @param _recipient The address of recipient who will receive the token.
  /// @param _amount The amount of token claimed.
  event Claim(address indexed _recipient, uint256 _amount);

  /// @notice The address of token to vest.
  address public immutable token;

  struct VestState {
    uint128 vestingAmount;
    uint128 claimedAmount;
    uint64 startTime;
    uint64 endTime;
    uint64 cancleTime;
  }

  /// @notice Mapping from user address to vesting list.
  mapping(address => VestState[]) public vesting;

  /// @notice The list of whilelist address.
  mapping(address => bool) public isWhitelist;

  constructor(address _token) {
    require(_token != address(0), "Vesting: zero address token");

    token = _token;
  }

  /// @notice Return the vesting list for some user.
  /// @param _recipient The address of user to query.
  function getUserVest(address _recipient) external view returns (VestState[] memory) {
    return vesting[_recipient];
  }

  /// @notice Return the total amount of vested tokens.
  /// @param _recipient The address of user to query.
  function vested(address _recipient) external view returns (uint256 _vested) {
    uint256 _length = vesting[_recipient].length;
    for (uint256 i = 0; i < _length; i++) {
      _vested += _getVested(vesting[_recipient][i], block.timestamp);
    }
    return _vested;
  }

  /// @notice Return the total amount of unvested tokens.
  /// @param _recipient The address of user to query.
  function locked(address _recipient) external view returns (uint256 _unvested) {
    uint256 _length = vesting[_recipient].length;
    for (uint256 i = 0; i < _length; i++) {
      VestState memory _state = vesting[_recipient][i];
      _unvested += _state.vestingAmount - _getVested(_state, block.timestamp);
    }
  }

  /// @notice Claim pending tokens
  /// @return _claimable The amount of token will receive in this claim.
  function claim() external returns (uint256 _claimable) {
    uint256 _length = vesting[msg.sender].length;
    for (uint256 i = 0; i < _length; i++) {
      VestState memory _state = vesting[msg.sender][i];

      uint256 _vested = _getVested(_state, block.timestamp);
      vesting[msg.sender][i].claimedAmount = uint128(_vested);

      _claimable += _vested - _state.claimedAmount;
    }

    IERC20(token).safeTransfer(msg.sender, _claimable);

    emit Claim(msg.sender, _claimable);
  }

  /// @notice Add a new token vesting
  /// @param _recipient The address of user who will receive the vesting.
  /// @param _amount The amount of token to vest.
  /// @param _startTime The timestamp in second when the vest starts.
  /// @param _endTime The timestamp in second when the vest ends.
  function newVesting(
    address _recipient,
    uint128 _amount,
    uint64 _startTime,
    uint64 _endTime
  ) external {
    require(_startTime < _endTime, "Vesting: invalid timestamp");
    require(isWhitelist[msg.sender], "Vesting: caller not whitelisted");

    IERC20(token).safeTransferFrom(msg.sender, address(this), _amount);

    uint256 _index = vesting[_recipient].length;
    vesting[_recipient].push(
      VestState({ vestingAmount: _amount, claimedAmount: 0, startTime: _startTime, endTime: _endTime, cancleTime: 0 })
    );

    emit Vest(_recipient, _index, _amount, _startTime, _endTime);
  }

  /// @notice Cancle a vest for some user. The unvested tokens will be transfered to owner.
  /// @param _user The address of the user to cancle.
  /// @param _index The index of the vest to cancle.
  function cancle(address _user, uint256 _index) external onlyOwner {
    VestState memory _state = vesting[_user][_index];
    require(_state.cancleTime == 0, "already cancled");

    uint256 _vestedAmount = _getVested(_state, block.timestamp);
    uint256 _unvested = _state.vestingAmount - _vestedAmount;
    IERC20(token).safeTransfer(msg.sender, _unvested);

    vesting[_user][_index].cancleTime = uint64(block.timestamp);

    emit Cancle(_user, _index, _unvested, block.timestamp);
  }

  /// @notice Update the whitelist status of given accounts.
  /// @param _accounts The list of accounts to update.
  /// @param _status The status to update.
  function updateWhitelist(address[] memory _accounts, bool _status) external onlyOwner {
    for (uint256 i = 0; i < _accounts.length; i++) {
      isWhitelist[_accounts[i]] = _status;
    }
  }

  /// @dev Internal function to calculate vested token amount for a single vest.
  /// @param _state The vest state.
  /// @param _claimTime The timestamp in second when someone claim vested token.
  function _getVested(VestState memory _state, uint256 _claimTime) internal pure returns (uint256) {
    // This vest is cancled before, so we take minimum between claimTime and cancleTime.
    if (_state.cancleTime != 0 && _state.cancleTime < _claimTime) {
      _claimTime = _state.cancleTime;
    }

    if (_claimTime < _state.startTime) {
      return 0;
    } else if (_claimTime >= _state.endTime) {
      return _state.vestingAmount;
    } else {
      // safe math is not needed, since all amounts are valid.
      return (uint256(_state.vestingAmount) * (_claimTime - _state.startTime)) / (_state.endTime - _state.startTime);
    }
  }
}

{
  "compilationTarget": {
    "contracts/misc/TokenSale.sol": "TokenSale"
  },
  "evmVersion": "istanbul",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": true,
    "runs": 200
  },
  "remappings": []
}