// SPDX-License-Identifier: MIT
pragma solidity ^0.8.7;
import "./Token.sol";

contract Cloudwork is Ownable {
    mapping(address => bool) public allowedCoins;

    uint256 public totalPaid;
    uint256 public totalWithdrawn;

    address public tokenAddressForDiscount;

    uint256 public discountPercentage = 10; // 1%
    uint256 public constant PERCENTAGE_DIVIDER = 1000; // 100%

    uint256 public tokenHoldingForDiscount = 5000 ether; // 5000 tokens

    uint256 public currentPaymentId;

    mapping(address => uint256) public totalPaidPerCoin;

    struct Payment {
        uint256 id;
        address sender;
        address coin;
        uint256 amount;
        uint256 dicount;
        uint256 amountAfterDiscount;
        string message;
    }

    mapping(uint256 => Payment) public payments;

    event PaymentReceived(
        uint256 id,
        address sender,
        address coin,
        uint256 amount,
        string message
    );

    constructor(address[] memory coins, address _discountToken) Ownable() {
        allowedCoins[address(0)] = true;
        for (uint256 i = 0; i < coins.length; i++) {
            allowedCoins[coins[i]] = true;
        }
        tokenAddressForDiscount = _discountToken;
    }

    function setDiscountToken(address tokenAddress) external onlyOwner {
        tokenAddressForDiscount = tokenAddress;
    }

    function setDiscountPercentage(uint256 percentage) external onlyOwner {
        discountPercentage = percentage;
    }

    function setTokenHoldingForDiscount(uint256 amount) external onlyOwner {
        tokenHoldingForDiscount = amount;
    }

    function addAllowedCoin(address coin) external onlyOwner {
        allowedCoins[coin] = true;
    }

    function removeAllowedCoin(address coin) external onlyOwner {
        allowedCoins[coin] = false;
    }

    function pay(
        address coin,
        uint256 amount,
        string calldata message
    ) external payable {
        require(allowedCoins[coin], "Coin not allowed");

        uint256 finalAmount = amount;

        uint256 discount = 0;

        if (tokenAddressForDiscount != address(0)) {
            uint256 tokenBalance = ERC20(tokenAddressForDiscount).balanceOf(
                msg.sender
            );

            if (tokenBalance >= tokenHoldingForDiscount) {
                discount = (amount * discountPercentage) / PERCENTAGE_DIVIDER;

                finalAmount -= discount;
            }
        }

        if (coin == address(0)) {
            require(msg.value == finalAmount, "Invalid amount");
        } else {
            ERC20(coin).transferFrom(msg.sender, address(this), finalAmount);
        }

        totalPaid += finalAmount;

        totalPaidPerCoin[coin] += finalAmount;

        currentPaymentId++;

        uint256 id = currentPaymentId;

        payments[id] = Payment(
            id,
            msg.sender,
            coin,
            amount,
            discount,
            finalAmount,
            message
        );

        emit PaymentReceived(id, msg.sender, coin, amount, message);
    }

    fallback() external payable {}

    receive() external payable {}

    function withdraw(address coin, uint256 amount) external onlyOwner {
        if (coin == address(0)) {
            payable(owner).transfer(amount);
        } else {
            ERC20(coin).transfer(owner, amount);
        }
    }
}

/**
 *Submitted for verification at Etherscan.io on 2017-11-28
 */

pragma solidity ^0.8.7;

/**
 * @title SafeMath
 * @dev Math operations with safety checks that throw on error
 */
library SafeMath {
    function mul(uint256 a, uint256 b) internal pure returns (uint256) {
        if (a == 0) {
            return 0;
        }
        uint256 c = a * b;
        assert(c / a == b);
        return c;
    }

    function div(uint256 a, uint256 b) internal pure returns (uint256) {
        // assert(b > 0); // Solidity automatically throws when dividing by 0
        uint256 c = a / b;
        // assert(a == b * c + a % b); // There is no case in which this doesn't hold
        return c;
    }

    function sub(uint256 a, uint256 b) internal pure returns (uint256) {
        assert(b <= a);
        return a - b;
    }

    function add(uint256 a, uint256 b) internal pure returns (uint256) {
        uint256 c = a + b;
        assert(c >= a);
        return c;
    }
}

/**
 * @title Ownable
 * @dev The Ownable contract has an owner address, and provides basic authorization control
 * functions, this simplifies the implementation of "user permissions".
 */
contract Ownable {
    address public owner;

    /**
     * @dev The Ownable constructor sets the original `owner` of the contract to the sender
     * account.
     */
    constructor() {
        owner = msg.sender;
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        require(msg.sender == owner);
        _;
    }

    /**
     * @dev Allows the current owner to transfer control of the contract to a newOwner.
     * @param newOwner The address to transfer ownership to.
     */
    function transferOwnership(address newOwner) public onlyOwner {
        if (newOwner != address(0)) {
            owner = newOwner;
        }
    }
}

/**
 * @title ERC20Basic
 * @dev Simpler version of ERC20 interface
 * @dev see https://github.com/ethereum/EIPs/issues/20
 */
abstract contract ERC20Basic {
    uint public _totalSupply;

    function totalSupply() public virtual returns (uint);

    function balanceOf(address who) public virtual returns (uint);

    function transfer(address to, uint value) public virtual;

    event Transfer(address indexed from, address indexed to, uint value);
}

/**
 * @title ERC20 interface
 * @dev see https://github.com/ethereum/EIPs/issues/20
 */
abstract contract ERC20 is ERC20Basic {
    function allowance(
        address owner,
        address spender
    ) public virtual returns (uint);

    function transferFrom(address from, address to, uint value) public virtual;

    function approve(address spender, uint value) public virtual;

    event Approval(address indexed owner, address indexed spender, uint value);
}

{
  "compilationTarget": {
    "contracts/Cloudwork.sol": "Cloudwork"
  },
  "evmVersion": "london",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": false,
    "runs": 200
  },
  "remappings": []
}