// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/Address.sol)

pragma solidity ^0.8.20;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev The ETH balance of the account is not enough to perform the operation.
     */
    error AddressInsufficientBalance(address account);

    /**
     * @dev There's no code at `target` (it is not a contract).
     */
    error AddressEmptyCode(address target);

    /**
     * @dev A call to an address target failed. The target may have reverted.
     */
    error FailedInnerCall();

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.8.20/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        if (address(this).balance < amount) {
            revert AddressInsufficientBalance(address(this));
        }

        (bool success, ) = recipient.call{value: amount}("");
        if (!success) {
            revert FailedInnerCall();
        }
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason or custom error, it is bubbled
     * up by this function (like regular Solidity function calls). However, if
     * the call reverted with no returned reason, this function reverts with a
     * {FailedInnerCall} error.
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        if (address(this).balance < value) {
            revert AddressInsufficientBalance(address(this));
        }
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and reverts if the target
     * was not a contract or bubbling up the revert reason (falling back to {FailedInnerCall}) in case of an
     * unsuccessful call.
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata
    ) internal view returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            // only check if target is a contract if the call was successful and the return data is empty
            // otherwise we already know that it was a contract
            if (returndata.length == 0 && target.code.length == 0) {
                revert AddressEmptyCode(target);
            }
            return returndata;
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and reverts if it wasn't, either by bubbling the
     * revert reason or with a default {FailedInnerCall} error.
     */
    function verifyCallResult(bool success, bytes memory returndata) internal pure returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            return returndata;
        }
    }

    /**
     * @dev Reverts with returndata if present. Otherwise reverts with {FailedInnerCall}.
     */
    function _revert(bytes memory returndata) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            /// @solidity memory-safe-assembly
            assembly {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert FailedInnerCall();
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}

// SPDX-License-Identifier: MIT
// Compatible with OpenZeppelin Contracts ^5.0.0
pragma solidity ^0.8.20;

import "@openzeppelin/contracts/utils/Address.sol";
import "@openzeppelin/contracts/access/Ownable.sol";
import "@openzeppelin/contracts/utils/ReentrancyGuard.sol";

// ::::::::::::::::         :::::::::::::::::::::    :::::::::::::::::::::
// ::::::::::::::::         :::::::::::::::::::::    :::::::::::::::::::::
// :::::::::::::::::::::    :::::::::::::::::::::    :::::::::::::::::::::
// :::::::::::    ::::::    :::::::::::    ::::::    ::::::::::::::::
// :::::::::::    ::::::    :::::::::::    ::::::    ::::::::::::::::
// :::::::::::    ::::::    :::::::::::    ::::::     :::::::::::::::
// :::::::::::    ::::::    :::::::::::    ::::::         :::::::::::
// :::::::::::    ::::::    :::::::::::    ::::::         :::::::::::
// :::::::::::    ::::::    :::::::::::    ::::::         :::::::::::
// :::::::::::    ::::::    :::::::::::    ::::::         :::::::::::
// :::::::::::::::::::::    :::::::::::::::::::::         :::::::::::
// ::::::::::::::::         :::::::::::::::::::::         :::::::::::
// ::::::::::::::::         :::::::::::::::::::::         :::::::::::

contract DotGameChain is ReentrancyGuard, Ownable {
    bool private _initialized = false;
    uint256 private _reserved = 0;
    uint256 private _spellCardPrice = 400000000000000;
    uint256 private _moveCount = 0;
    uint256 private _spellCount = 0;
    uint256 private _initialPrize = 18000000000000000;
    uint256 private _prizeIncrement = 400000000000000;

    struct move {
        address player;
        uint256 moveTime;
        string team;
        string gameId;
        uint256 placement;
    }

    struct spell {
        address player;
        uint256 spellTime;
        string team;
        string gameId;
        uint256 placement;
        string spellType;
    }

    mapping(string => string) private _spellURIs;
    mapping(address => bool) public _flaggedPlayers;
    mapping(uint256 => move) private _moves;
    mapping(uint256 => spell) private _spells;
    mapping(address => uint256) private _sharePerWallet;

    constructor(address initialOwner) Ownable(initialOwner) {
        require(!_initialized, "Already initialized");
        _initialized = true;
    }

    receive() external payable {}

    /// Withdraw Reserved
    /// @dev Withdraws the reserved balance from the contract
    function withdraw() public nonReentrant() returns (uint256) {
        address payable player = payable(msg.sender);
        uint256 amount = _sharePerWallet[player];

        require(amount > 0, "No balance to withdraw");
        require(amount <= address(this).balance, "Insufficient balance");

        _sharePerWallet[player] = 0;
        _reserved -= amount;

        Address.sendValue(player, amount);

        return amount;
    }

    /// Withdraw For Player
    /// @param player player address
    /// @dev Withdraws the reserved balance for a player
    function withdrawForPlayer(
        address payable player
    ) public onlyOwner() nonReentrant() returns (uint256) {
        uint256 amount = _sharePerWallet[player];

        require(amount > 0, "No balance to withdraw");
        require(amount <= address(this).balance, "Insufficient balance");

        _sharePerWallet[player] = 0;
        _reserved -= amount;

        Address.sendValue(player, amount);

        return amount;
    }

    /// Withdraw
    /// @dev Withdraws the entire balance from the contract
    function withdrawDot() public onlyOwner() nonReentrant() returns (uint256) {
        uint256 amount = address(this).balance - _reserved;

        require(amount > 0, "Insufficient balance");

        Address.sendValue(payable(owner()), amount);

        return amount;
    }
    
    /// Withdraw Partial
    /// @param amount amount to withdraw
    /// @dev Withdraws a specific amount from the contract
    function withdrawDotPartial(
        uint256 amount
    ) public onlyOwner() nonReentrant() returns (uint256) {
        require(amount <= address(this).balance - _reserved, "Insufficient balance");

        Address.sendValue(payable(owner()), amount);

        return amount;
    }

    /// Set Spell URI
    /// @param spellId spell id
    /// @param uri spell uri
    /// @dev Set the URI of a spell card
    function setSpellURI(string memory spellId, string memory uri) public onlyOwner() nonReentrant() {
        _spellURIs[spellId] = uri;
    }

    /// Get Spell Card Price
    /// @return spell card price
    /// @dev Get the price of spell cards
    function getSpellCardPrice() public view returns (uint256) {
        return _spellCardPrice;
    }

    /// Set Initial Prize
    /// @param amount initial prize
    /// @dev Set the initial prize amount
    function setInitialPrize(uint256 amount) public onlyOwner() nonReentrant() {
        _initialPrize = amount;
    }

    /// Set Prize Increment
    /// @param amount prize increment
    /// @dev Set the prize increment amount
    function setPrizeIncrement(uint256 amount) public onlyOwner() nonReentrant() {
        _prizeIncrement = amount;
    }

    /// Get Initial Prize
    /// @return initial prize
    /// @dev Get the initial prize amount
    function getInitialPrize() public view returns (uint256) {
        return _initialPrize;
    }

    /// Get Prize Increment
    /// @return prize increment
    /// @dev Get the prize increment amount
    function getPrizeIncrement() public view returns (uint256) {
        return _prizeIncrement;
    }

    /// Flag Player
    /// @param player player address
    /// @dev Flag a player
    function flagPlayer(address player) public onlyOwner() nonReentrant() {
        _flaggedPlayers[player] = true;
    }

    /// Unflag Player
    /// @param player player address
    /// @dev Unflag a player
    function unflagPlayer(address player) public onlyOwner() nonReentrant() {
        _flaggedPlayers[player] = false;
    }

    /// Create move
    /// @param gameId game id
    /// @param moveTime move time
    /// @param team team slug
    /// @param placement placement on the board
    /// @param player player address
    /// @dev Store a move
    function storeMove(
        string memory gameId,
        uint256 moveTime,
        string memory team,
        uint256 placement,
        address player) public onlyOwner() nonReentrant()
    {
        _moves[_moveCount].team = team;
        _moves[_moveCount].moveTime = moveTime;
        _moves[_moveCount].gameId = gameId;
        _moves[_moveCount].player = player;
        _moves[_moveCount].placement = placement;
        _moveCount++;
    }

    /// Create move
    /// @param gameId game id
    /// @param spellTime spell time
    /// @param team team slug
    /// @param placement placement on the board
    /// @param spellType spell type
    /// @param player player address
    /// @dev Store a move
    function storeSpell(
        string memory gameId,
        uint256 spellTime,
        string memory team,
        uint256 placement,
        string memory spellType,
        address player) public onlyOwner() nonReentrant()
    {
        _spells[_spellCount].team = team;
        _spells[_spellCount].spellTime = spellTime;
        _spells[_spellCount].gameId = gameId;
        _spells[_spellCount].player = player;
        _spells[_spellCount].placement = placement;
        _spells[_spellCount].spellType = spellType;
        _spellCount++;
    }

    // Reserve an amount for player
    /// @param player player address
    /// @param amount amount to pay
    /// @dev Reserve an amount for a player
    function reserveForPlayer(address player, uint256 amount) public onlyOwner() nonReentrant() {
        require(amount > 0, "Amount must be greater than 0");
        require(!_flaggedPlayers[player], "Player is flagged");
        
        if(_sharePerWallet[player] > 0) {
            _sharePerWallet[player] += amount;
        } else {
            _sharePerWallet[player] = amount;
        }

        _reserved += amount;
    }

    /// Get Reserved Balance 
    /// @return reserved balance
    /// @dev Get the reserved balance
    function reservedForDot() public view returns (uint256) {
        return address(this).balance - _reserved;
    }

    /// Get Reserved Balance for Players
    /// @return reserved balance for players
    /// @dev Get the reserved balance for players
    function reservedForPlayers() public view returns (uint256) {
        return _reserved;
    }

    /// Get Reserved Balance for Player
    /// @param player player address
    /// @return reserved balance for player
    /// @dev Get the reserved balance for a player
    function reservedForPlayer(
        address player
    ) public view returns (uint256) {
        return _sharePerWallet[player];
    }

    /// Get Move Count
    /// @return move count
    /// @dev Get the total number of moves
    function getMoveCount() public view returns (uint256) {
        return _moveCount;
    }

    /// Get Spell Count
    /// @return spell count
    /// @dev Get the total number of spells
    function getSpellCount() public view returns (uint256) {
        return _spellCount;
    }

    /// Get All Moves
    /// @return all moves
    /// @dev Get all moves
    function getAllMoves() public view returns (move[] memory) {
        move[] memory result = new move[](_moveCount);
        uint256 count = 0;

        for(uint256 i = 0; i < _moveCount; i++) {
            result[count] = _moves[i];
            count++;
        }

        return result;
    }

    /// Get All Spells
    /// @return all spells
    /// @dev Get all spells
    function getAllSpells() public view returns (spell[] memory) {
        spell[] memory result = new spell[](_spellCount);
        uint256 count = 0;

        for(uint256 i = 0; i < _spellCount; i++) {
            result[count] = _spells[i];
            count++;
        }

        return result;
    }

    /// Get Moves by player
    /// @param player player address
    /// @return moves by player
    /// @dev Get moves by player
    function getMovesByPlayer(address player) public view returns (move[] memory) {
        move[] memory getMoves = new move[](_moveCount);
        uint256 count = 0;

        for(uint256 i = 0; i < _moveCount; i++) {
            if(_moves[i].player == player) {
                getMoves[count] = _moves[i];
                count++;
            }
        }

        move[] memory result = new move[](count);

        for (uint256 i = 0; i < count; i++) {
            result[i] = getMoves[i];
        }

        return result;
    }

    /// Get Spells by player
    /// @param player player address
    /// @return spells by player
    /// @dev Get spells by player
    function getSpellsByPlayer(address player) public view returns (spell[] memory) {
        spell[] memory getSpells = new spell[](_spellCount);
        uint256 count = 0;

        for(uint256 i = 0; i < _spellCount; i++) {
            if(_spells[i].player == player) {
                getSpells[count] = _spells[i];
                count++;
            }
        }

        spell[] memory result = new spell[](count);

        for (uint256 i = 0; i < count; i++) {
            result[i] = getSpells[i];
        }

        return result;
    }

    /// Get Moves by game
    /// @param gameId game id
    /// @return moves by game
    /// @dev Get moves by game
    function getMovesByGame(string memory gameId) public view returns (move[] memory) {
        move[] memory getMoves = new move[](_moveCount);
        uint256 count = 0;

        for(uint256 i = 0; i < _moveCount; i++){
            if(compareStrings(_moves[i].gameId, gameId)) {
                getMoves[count] = _moves[i];
                count++;
            }
        }

        move[] memory result = new move[](count);

        for (uint256 i = 0; i < count; i++) {
            result[i] = getMoves[i];
        }

        return result;
    }

    /// Get Spells by game
    /// @param gameId game id
    /// @return spells by game
    /// @dev Get spells by game
    function getSpellsByGame(string memory gameId) public view returns (spell[] memory) {
        spell[] memory getSpells = new spell[](_spellCount);
        uint256 count = 0;

        for(uint256 i = 0; i < _spellCount; i++){
            if(compareStrings(_spells[i].gameId, gameId)) {
                getSpells[count] = _spells[i];
                count++;
            }
        }

        spell[] memory result = new spell[](count);

        for (uint256 i = 0; i < count; i++) {
            result[i] = getSpells[i];
        }

        return result;
    }

    /// Get Player Moves by game
    /// @param player player address
    /// @param gameId game id
    /// @return moves by game and player
    /// @dev Get player moves by game
    function getUserMovesByGame(address player, string memory gameId) public view returns (move[] memory) {
        move[] memory getMoves = new move[](_moveCount);
        uint256 count = 0;

        for(uint256 i = 0; i < _moveCount; i++){
            if(compareStrings(_moves[i].gameId, gameId) && _moves[i].player == player) {
                getMoves[count] = _moves[i];
                count++;
            }
        }

        move[] memory result = new move[](count);

        for (uint256 i = 0; i < count; i++) {
            result[i] = getMoves[i];
        }

        return result;
    }

    /// Get Player Spells by game
    /// @param player player address
    /// @param gameId game id
    /// @return spells by game and player
    /// @dev Get player spells by game
    function getUserSpellsByGame(address player, string memory gameId) public view returns (spell[] memory) {
        spell[] memory getSpells = new spell[](_spellCount);
        uint256 count = 0;

        for(uint256 i = 0; i < _spellCount; i++){
            if(compareStrings(_spells[i].gameId, gameId) && _spells[i].player == player) {
                getSpells[count] = _spells[i];
                count++;
            }
        }

        spell[] memory result = new spell[](count);

        for (uint256 i = 0; i < count; i++) {
            result[i] = getSpells[i];
        }

        return result;
    }

    /// Compare Strings
    function compareStrings(string memory a, string memory b) internal pure returns (bool) {
        return (keccak256(abi.encodePacked((a))) == keccak256(abi.encodePacked((b))));
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable.sol)

pragma solidity ^0.8.20;

import {Context} from "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is set to the address provided by the deployer. This can
 * later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    /**
     * @dev The caller account is not authorized to perform an operation.
     */
    error OwnableUnauthorizedAccount(address account);

    /**
     * @dev The owner is not a valid owner account. (eg. `address(0)`)
     */
    error OwnableInvalidOwner(address owner);

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the address provided by the deployer as the initial owner.
     */
    constructor(address initialOwner) {
        if (initialOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(initialOwner);
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        if (owner() != _msgSender()) {
            revert OwnableUnauthorizedAccount(_msgSender());
        }
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        if (newOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/ReentrancyGuard.sol)

pragma solidity ^0.8.20;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant NOT_ENTERED = 1;
    uint256 private constant ENTERED = 2;

    uint256 private _status;

    /**
     * @dev Unauthorized reentrant call.
     */
    error ReentrancyGuardReentrantCall();

    constructor() {
        _status = NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be NOT_ENTERED
        if (_status == ENTERED) {
            revert ReentrancyGuardReentrantCall();
        }

        // Any calls to nonReentrant after this point will fail
        _status = ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = NOT_ENTERED;
    }

    /**
     * @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
     * `nonReentrant` function in the call stack.
     */
    function _reentrancyGuardEntered() internal view returns (bool) {
        return _status == ENTERED;
    }
}

{
  "compilationTarget": {
    "contracts/DotGameChain.sol": "DotGameChain"
  },
  "evmVersion": "paris",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": false,
    "runs": 200
  },
  "remappings": []
}