// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize, which returns 0 for contracts in
        // construction, since the code is only stored at the end of the
        // constructor execution.

        uint256 size;
        assembly {
            size := extcodesize(account)
        }
        return size > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://diligence.consensys.net/posts/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.5.11/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        (bool success, ) = recipient.call{value: amount}("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCall(target, data, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        require(isContract(target), "Address: call to non-contract");

        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return _verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        require(isContract(target), "Address: static call to non-contract");

        (bool success, bytes memory returndata) = target.staticcall(data);
        return _verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionDelegateCall(target, data, "Address: low-level delegate call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(isContract(target), "Address: delegate call to non-contract");

        (bool success, bytes memory returndata) = target.delegatecall(data);
        return _verifyCallResult(success, returndata, errorMessage);
    }

    function _verifyCallResult(
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) private pure returns (bytes memory) {
        if (success) {
            return returndata;
        } else {
            // Look for revert reason and bubble it up if present
            if (returndata.length > 0) {
                // The easiest way to bubble the revert reason is using memory via assembly

                assembly {
                    let returndata_size := mload(returndata)
                    revert(add(32, returndata), returndata_size)
                }
            } else {
                revert(errorMessage);
            }
        }
    }
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

/*
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}

// SPDX-License-Identifier: GPL-2.0
pragma solidity >=0.5.0;

interface IERC20 {
    event Approval(address indexed owner, address indexed spender, uint value);
    event Transfer(address indexed from, address indexed to, uint value);

    function name() external view returns (string memory);
    function symbol() external view returns (string memory);
    function decimals() external view returns (uint8);
    function totalSupply() external view returns (uint);
    function balanceOf(address owner) external view returns (uint);
    function allowance(address owner, address spender) external view returns (uint);

    function approve(address spender, uint value) external returns (bool);
    function transfer(address to, uint value) external returns (bool);
    function transferFrom(address from, address to, uint value) external returns (bool);
}

// SPDX-License-Identifier: GPL-2.0
pragma solidity ^0.8.0;

interface IUniswapV2Pair {
    event Approval(address indexed owner, address indexed spender, uint value);
    event Transfer(address indexed from, address indexed to, uint value);

    function name() external pure returns (string memory);
    function symbol() external pure returns (string memory);
    function decimals() external pure returns (uint8);
    function totalSupply() external view returns (uint);
    function balanceOf(address owner) external view returns (uint);
    function allowance(address owner, address spender) external view returns (uint);

    function approve(address spender, uint value) external returns (bool);
    function transfer(address to, uint value) external returns (bool);
    function transferFrom(address from, address to, uint value) external returns (bool);

    function DOMAIN_SEPARATOR() external view returns (bytes32);
    function PERMIT_TYPEHASH() external pure returns (bytes32);
    function nonces(address owner) external view returns (uint);

    function permit(address owner, address spender, uint value, uint deadline, uint8 v, bytes32 r, bytes32 s) external;

    event Mint(address indexed sender, uint amount0, uint amount1);
    event Burn(address indexed sender, uint amount0, uint amount1, address indexed to);
    event Swap(
        address indexed sender,
        uint amount0In,
        uint amount1In,
        uint amount0Out,
        uint amount1Out,
        address indexed to
    );
    event Sync(uint112 reserve0, uint112 reserve1);

    function MINIMUM_LIQUIDITY() external pure returns (uint);
    function factory() external view returns (address);
    function token0() external view returns (address);
    function token1() external view returns (address);
    function getReserves() external view returns (uint112 reserve0, uint112 reserve1, uint32 blockTimestampLast);
    function price0CumulativeLast() external view returns (uint);
    function price1CumulativeLast() external view returns (uint);
    function kLast() external view returns (uint);

    function mint(address to) external returns (uint liquidity);
    function burn(address to) external returns (uint amount0, uint amount1);
    function swap(uint amount0Out, uint amount1Out, address to, bytes calldata data) external;
    function skim(address to) external;
    function sync() external;

    function initialize(address, address) external;
}

interface IUniswapV2Factory {
    event PairCreated(address indexed token0, address indexed token1, address pair, uint);

    function feeTo() external view returns (address);
    function feeToSetter() external view returns (address);

    function getPair(address tokenA, address tokenB) external view returns (address pair);
    function allPairs(uint) external view returns (address pair);
    function allPairsLength() external view returns (uint);

    function createPair(address tokenA, address tokenB) external returns (address pair);

    function setFeeTo(address) external;
    function setFeeToSetter(address) external;
}

interface IUniswapV2Router01 {
    function factory() external pure returns (address);
    function WETH() external pure returns (address);

    function addLiquidity(
        address tokenA,
        address tokenB,
        uint amountADesired,
        uint amountBDesired,
        uint amountAMin,
        uint amountBMin,
        address to,
        uint deadline
    ) external returns (uint amountA, uint amountB, uint liquidity);
    function addLiquidityETH(
        address token,
        uint amountTokenDesired,
        uint amountTokenMin,
        uint amountETHMin,
        address to,
        uint deadline
    ) external payable returns (uint amountToken, uint amountETH, uint liquidity);
    function removeLiquidity(
        address tokenA,
        address tokenB,
        uint liquidity,
        uint amountAMin,
        uint amountBMin,
        address to,
        uint deadline
    ) external returns (uint amountA, uint amountB);
    function removeLiquidityETH(
        address token,
        uint liquidity,
        uint amountTokenMin,
        uint amountETHMin,
        address to,
        uint deadline
    ) external returns (uint amountToken, uint amountETH);
    function removeLiquidityWithPermit(
        address tokenA,
        address tokenB,
        uint liquidity,
        uint amountAMin,
        uint amountBMin,
        address to,
        uint deadline,
        bool approveMax, uint8 v, bytes32 r, bytes32 s
    ) external returns (uint amountA, uint amountB);
    function removeLiquidityETHWithPermit(
        address token,
        uint liquidity,
        uint amountTokenMin,
        uint amountETHMin,
        address to,
        uint deadline,
        bool approveMax, uint8 v, bytes32 r, bytes32 s
    ) external returns (uint amountToken, uint amountETH);
    function swapExactTokensForTokens(
        uint amountIn,
        uint amountOutMin,
        address[] calldata path,
        address to,
        uint deadline
    ) external returns (uint[] memory amounts);
    function swapTokensForExactTokens(
        uint amountOut,
        uint amountInMax,
        address[] calldata path,
        address to,
        uint deadline
    ) external returns (uint[] memory amounts);
    function swapExactETHForTokens(uint amountOutMin, address[] calldata path, address to, uint deadline)
        external
        payable
        returns (uint[] memory amounts);
    function swapTokensForExactETH(uint amountOut, uint amountInMax, address[] calldata path, address to, uint deadline)
        external
        returns (uint[] memory amounts);
    function swapExactTokensForETH(uint amountIn, uint amountOutMin, address[] calldata path, address to, uint deadline)
        external
        returns (uint[] memory amounts);
    function swapETHForExactTokens(uint amountOut, address[] calldata path, address to, uint deadline)
        external
        payable
        returns (uint[] memory amounts);

    function quote(uint amountA, uint reserveA, uint reserveB) external pure returns (uint amountB);
    function getAmountOut(uint amountIn, uint reserveIn, uint reserveOut) external pure returns (uint amountOut);
    function getAmountIn(uint amountOut, uint reserveIn, uint reserveOut) external pure returns (uint amountIn);
    function getAmountsOut(uint amountIn, address[] calldata path) external view returns (uint[] memory amounts);
    function getAmountsIn(uint amountOut, address[] calldata path) external view returns (uint[] memory amounts);
}

interface IUniswapV2Router02 is IUniswapV2Router01 {
    function removeLiquidityETHSupportingFeeOnTransferTokens(
        address token,
        uint liquidity,
        uint amountTokenMin,
        uint amountETHMin,
        address to,
        uint deadline
    ) external returns (uint amountETH);
    function removeLiquidityETHWithPermitSupportingFeeOnTransferTokens(
        address token,
        uint liquidity,
        uint amountTokenMin,
        uint amountETHMin,
        address to,
        uint deadline,
        bool approveMax, uint8 v, bytes32 r, bytes32 s
    ) external returns (uint amountETH);

    function swapExactTokensForTokensSupportingFeeOnTransferTokens(
        uint amountIn,
        uint amountOutMin,
        address[] calldata path,
        address to,
        uint deadline
    ) external;
    function swapExactETHForTokensSupportingFeeOnTransferTokens(
        uint amountOutMin,
        address[] calldata path,
        address to,
        uint deadline
    ) external payable;
    function swapExactTokensForETHSupportingFeeOnTransferTokens(
        uint amountIn,
        uint amountOutMin,
        address[] calldata path,
        address to,
        uint deadline
    ) external;
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

import "./Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _setOwner(_msgSender());
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
        _;
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions anymore. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby removing any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _setOwner(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _setOwner(newOwner);
    }

    function _setOwner(address newOwner) private {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

import "./IERC20.sol";
import "./Address.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using Address for address;

    function safeTransfer(
        IERC20 token,
        address to,
        uint256 value
    ) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transfer.selector, to, value));
    }

    function safeTransferFrom(
        IERC20 token,
        address from,
        address to,
        uint256 value
    ) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transferFrom.selector, from, to, value));
    }

    /**
     * @dev Deprecated. This function has issues similar to the ones found in
     * {IERC20-approve}, and its usage is discouraged.
     *
     * Whenever possible, use {safeIncreaseAllowance} and
     * {safeDecreaseAllowance} instead.
     */
    function safeApprove(
        IERC20 token,
        address spender,
        uint256 value
    ) internal {
        // safeApprove should only be called when setting an initial allowance,
        // or when resetting it to zero. To increase and decrease it, use
        // 'safeIncreaseAllowance' and 'safeDecreaseAllowance'
        require(
            (value == 0) || (token.allowance(address(this), spender) == 0),
            "SafeERC20: approve from non-zero to non-zero allowance"
        );
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, value));
    }

    function safeIncreaseAllowance(
        IERC20 token,
        address spender,
        uint256 value
    ) internal {
        uint256 newAllowance = token.allowance(address(this), spender) + value;
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, newAllowance));
    }

    function safeDecreaseAllowance(
        IERC20 token,
        address spender,
        uint256 value
    ) internal {
        unchecked {
            uint256 oldAllowance = token.allowance(address(this), spender);
            require(oldAllowance >= value, "SafeERC20: decreased allowance below zero");
            uint256 newAllowance = oldAllowance - value;
            _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, newAllowance));
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We use {Address.functionCall} to perform this call, which verifies that
        // the target address contains contract code and also asserts for success in the low-level call.

        bytes memory returndata = address(token).functionCall(data, "SafeERC20: low-level call failed");
        if (returndata.length > 0) {
            // Return data is optional
            require(abi.decode(returndata, (bool)), "SafeERC20: ERC20 operation did not succeed");
        }
    }
}

// SPDX-License-Identifier: GPL-2.0
pragma solidity ^0.8.0;

import "./oz-0.8.0/Ownable.sol";
import "./oz-0.8.0/SafeERC20.sol";

import "./IUniswapV2.sol";


contract UniswapV2Migrator is Ownable {
    using SafeERC20 for IERC20;

    // Incoming router selector
    enum RouterVersion {
        UniswapV2, 
        Sushiswap
    }

    // Router addresses
    IUniswapV2Router02 private constant uniswapV2Router = IUniswapV2Router02(0x7a250d5630B4cF539739dF2C5dAcb4c659F2488D);
    IUniswapV2Router02 private constant sushiswapRouter = IUniswapV2Router02(0x1b02dA8Cb0d097eB8D57A175b88c7D8b47997506);
    IUniswapV2Router02 private constant nowswapRouter = IUniswapV2Router02(0x34E1F74e0786d18C08061B3C99b5D416060c55b4);

    // canonical WETH address (obtained from Uniswap router)
    address private immutable wethTokenAddress;
    
    // token holdings of each user: user => token => amount
    mapping(address => mapping(address => uint256)) public userBalance;
    // total tokens held by all users: token => amount
    mapping(address => uint256) public totalUserBalance;

    // stop certain functionality in emergencies   
    bool public stopped = false;

    // modifier for stopping in emergencies
    modifier stoppable {
        if (stopped) {
            revert("Temporarily stopped");
        } else {
            _;
        }
    }

    event migratedOut(
        address indexed sender,
        address indexed token,
        uint256 tokenAmt
    );

    event migratedIn(
        address indexed sender,
        address indexed token,
        uint256 tokenAmt
    );
    
    constructor()
    {
        wethTokenAddress = uniswapV2Router.WETH();        
    }

    function toggleContractActivity() 
        external 
        onlyOwner
    {
        stopped = !stopped;
    }


// ---------------------------------------------------------------------------------------------------------------------------
// Liquidity migrate function
// ---------------------------------------------------------------------------------------------------------------------------

    /**
        @notice Migrate liquidity in both tokens from an existing pair
        @param fromTokenPair Token pair from which to remove liquidity
        @param incomingLP Amount of liquidity (LP token) to remove from pair, type(uint256).max to remove all
        @param deadline Unix timestamp after which the transaction will revert
        @return sentAmountA Amount of tokenA provided as new liquidity
        @return sentAmountB Amount of tokenB provided as new liquidity
        @return outgoingLP Amount of new liquidity token received
    */
    function migrateTokenPair(
        RouterVersion fromRouterVer,
        address fromTokenPair,
        uint256 incomingLP,
        uint256 deadline
    ) 
        external
        payable
        stoppable 
        returns (uint256 sentAmountA, uint256 sentAmountB, uint256 outgoingLP) 
    {
        require(fromTokenPair != address(0), "Invalid token pair");
        
        address tokenA;
        address tokenB;
        uint256 recdAmountA;
        uint256 recdAmountB;

        // remove liquidity from Uniswap
        {
            IERC20 tokenLP = IERC20(fromTokenPair);
            if (incomingLP == type(uint256).max)
                incomingLP = tokenLP.balanceOf(msg.sender);
            require(tokenLP.allowance(msg.sender, address(this)) >= incomingLP, "Insufficient LP allowance");
            require(incomingLP > 0, "Incoming LP must be > 0");
    
            IUniswapV2Pair pair = IUniswapV2Pair(fromTokenPair);
            tokenA = pair.token0();
            tokenB = pair.token1();
            require(fromTokenPair == IUniswapV2Factory(_getRouter(fromRouterVer).factory()).getPair(tokenA, tokenB), "Invalid token pair for this router");
    
            tokenLP.safeTransferFrom(msg.sender, address(this), incomingLP);
            (recdAmountA, recdAmountB) = _removeLiquidity(_getRouter(fromRouterVer), fromTokenPair, tokenA, tokenB, incomingLP, deadline);
    
            emit migratedOut(msg.sender, tokenA, recdAmountA);
            emit migratedOut(msg.sender, tokenB, recdAmountB);
        }

        require(recdAmountA > 0 && recdAmountB > 0, "Token amounts must not be zero");

        // add liquidity (as much as possible) to nowswap (Note: ratio determined by nowswap)
        (sentAmountA, sentAmountB, outgoingLP) = _addNowswapLiquidity(tokenA, tokenB, recdAmountA, recdAmountB, deadline);

        emit migratedIn(msg.sender, tokenA, sentAmountA);
        emit migratedIn(msg.sender, tokenB, sentAmountB);

        // keep any remaining token safe for later use by the sender. Can be withdrawn using withdrawUserTokens()
        if (recdAmountA > sentAmountA) {
            userBalance[msg.sender][tokenA] += (recdAmountA - sentAmountA);
            totalUserBalance[tokenA] += (recdAmountA - sentAmountA);
        }
        if (recdAmountB > sentAmountB) {
            userBalance[msg.sender][tokenB] += (recdAmountB - sentAmountB);
            totalUserBalance[tokenB] +=(recdAmountB - sentAmountB);
        }
    }
    
    // convenience function for debugging
    function getPairs(
        RouterVersion fromRouter,
        address tokenA,
        address tokenB
    )
        external
        view
        returns (address uniPair, uint uniReserveA, uint uniReserveB, address nowPair, uint nowReserveA, uint nowReserveB)
    {
        uniPair = IUniswapV2Factory(_getRouter(fromRouter).factory()).getPair(tokenA, tokenB);
        if (uniPair != address(0))
            (uniReserveA, uniReserveB, ) = IUniswapV2Pair(uniPair).getReserves();
        nowPair = IUniswapV2Factory(nowswapRouter.factory()).getPair(tokenA, tokenB);
        if (nowPair != address(0))
            (nowReserveA, nowReserveB, ) = IUniswapV2Pair(nowPair).getReserves();
    }

// ---------------------------------------------------------------------------------------------------------------------------
// Token / ETH withdrawal functions
// ---------------------------------------------------------------------------------------------------------------------------

    function getUserBalance(address token)
        external
        view
        returns (uint256)
    {
        require(token != address(0), "Zero token address");
        return userBalance[msg.sender][token];
    }

    function withdrawUserTokens(address[] calldata tokens) 
        external 
    {
        for (uint256 i = 0; i < tokens.length; i++) {
            uint256 amount;
            require(tokens[i] != address(0), "Zero token address");

            amount = userBalance[msg.sender][tokens[i]];
            if (amount > 0) {
                userBalance[msg.sender][tokens[i]] = 0;
                totalUserBalance[tokens[i]] -= amount;

                if (tokens[i] == wethTokenAddress) {
                    Address.sendValue(payable(msg.sender), amount);
                } else {
                    IERC20(tokens[i]).safeTransfer(msg.sender, amount);
                }
            }
        }
    }

    function withdrawOwnerTokens(address[] calldata tokens) 
        external 
        onlyOwner
    {
        for (uint256 i = 0; i < tokens.length; i++) {
            uint256 amount;
            require(tokens[i] != address(0), "Zero token address");

            if ((tokens[i] == wethTokenAddress) && (address(this).balance > totalUserBalance[wethTokenAddress])) {
                amount = address(this).balance - totalUserBalance[wethTokenAddress];
                Address.sendValue(payable(owner()), amount);
            } else if (IERC20(tokens[i]).balanceOf(address(this)) > totalUserBalance[tokens[i]]) {
                amount = IERC20(tokens[i]).balanceOf(address(this)) - totalUserBalance[tokens[i]];
                IERC20(tokens[i]).safeTransfer(owner(), amount);
            }
        }
    }

    receive() external payable {
        require(msg.sender != tx.origin, "Do not send ETH directly");
    }


// ---------------------------------------------------------------------------------------------------------------------------
// Internal functions
// ---------------------------------------------------------------------------------------------------------------------------

    function _getRouter(RouterVersion routerVer) internal pure returns (IUniswapV2Router02) {
        if (routerVer == RouterVersion.Sushiswap)
            return sushiswapRouter;
        else
            return uniswapV2Router;
    }
    
    function _approveToken(
        address token, 
        address spender
    ) 
        internal 
    {
        require(token != address(0), "Zero token address");
        IERC20 _token = IERC20(token);
        if (_token.allowance(address(this), spender) > 0) 
            return;
        else {
            _token.safeApprove(spender, type(uint256).max);
        }
    }

    function _approveToken(
        address token,
        address spender,
        uint256 amount
    ) 
        internal 
    {
        require(token != address(0), "Zero token address");
        IERC20 _token = IERC20(token);
        if (_token.allowance(address(this), spender) != 0)
            _token.safeApprove(spender, 0);
        _token.safeApprove(spender, amount);
    }

    function _removeLiquidity(
        IUniswapV2Router02 fromRouter,
        address fromTokenPair,
        address tokenA,
        address tokenB,
        uint256 incomingLP,
        uint256 deadline
    )
        internal
        returns (uint256 recdAmountA, uint256 recdAmountB)
    {
        _approveToken(fromTokenPair, address(fromRouter), incomingLP);

        if (tokenA == wethTokenAddress)
            (recdAmountB, recdAmountA) = fromRouter.removeLiquidityETH(tokenB, incomingLP, 1, 1, address(this), deadline);
        else if (tokenB == wethTokenAddress)
            (recdAmountA, recdAmountB) = fromRouter.removeLiquidityETH(tokenA, incomingLP, 1, 1, address(this), deadline);
        else
            (recdAmountA, recdAmountB) = fromRouter.removeLiquidity(tokenA, tokenB, incomingLP, 1, 1, address(this), deadline);
    }
    
    function _addNowswapLiquidity(
        address tokenA,
        address tokenB,
        uint256 desiredAmountA,
        uint256 desiredAmountB,
        uint256 deadline
    )
        internal
        returns (uint256 sentAmountA, uint256 sentAmountB, uint256 outgoingLP)
    {
        _approveToken(tokenA, address(nowswapRouter), desiredAmountA);
        _approveToken(tokenB, address(nowswapRouter), desiredAmountB);

        if (tokenA == wethTokenAddress)
            (sentAmountB, sentAmountA, outgoingLP) = nowswapRouter.addLiquidityETH{ value: desiredAmountA }(tokenB, desiredAmountB, 1, 1, msg.sender, deadline);
        else if (tokenB == wethTokenAddress)
            (sentAmountA, sentAmountB, outgoingLP) = nowswapRouter.addLiquidityETH{ value: desiredAmountB }(tokenA, desiredAmountA, 1, 1, msg.sender, deadline);
        else
            (sentAmountA, sentAmountB, outgoingLP) = nowswapRouter.addLiquidity(tokenA, tokenB, desiredAmountA, desiredAmountB, 1, 1, msg.sender, deadline);
    }
}

{
  "compilationTarget": {
    "contracts/UniswapV2Migrator.sol": "UniswapV2Migrator"
  },
  "evmVersion": "istanbul",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": true,
    "runs": 200
  },
  "remappings": []
}