// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC-20 standard as defined in the ERC.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable.sol)

pragma solidity ^0.8.20;

import {Context} from "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is set to the address provided by the deployer. This can
 * later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    /**
     * @dev The caller account is not authorized to perform an operation.
     */
    error OwnableUnauthorizedAccount(address account);

    /**
     * @dev The owner is not a valid owner account. (eg. `address(0)`)
     */
    error OwnableInvalidOwner(address owner);

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the address provided by the deployer as the initial owner.
     */
    constructor(address initialOwner) {
        if (initialOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(initialOwner);
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        if (owner() != _msgSender()) {
            revert OwnableUnauthorizedAccount(_msgSender());
        }
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        if (newOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (access/Ownable2Step.sol)

pragma solidity ^0.8.20;

import {Ownable} from "./Ownable.sol";

/**
 * @dev Contract module which provides access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * This extension of the {Ownable} contract includes a two-step mechanism to transfer
 * ownership, where the new owner must call {acceptOwnership} in order to replace the
 * old one. This can help prevent common mistakes, such as transfers of ownership to
 * incorrect accounts, or to contracts that are unable to interact with the
 * permission system.
 *
 * The initial owner is specified at deployment time in the constructor for `Ownable`. This
 * can later be changed with {transferOwnership} and {acceptOwnership}.
 *
 * This module is used through inheritance. It will make available all functions
 * from parent (Ownable).
 */
abstract contract Ownable2Step is Ownable {
    address private _pendingOwner;

    event OwnershipTransferStarted(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Returns the address of the pending owner.
     */
    function pendingOwner() public view virtual returns (address) {
        return _pendingOwner;
    }

    /**
     * @dev Starts the ownership transfer of the contract to a new account. Replaces the pending transfer if there is one.
     * Can only be called by the current owner.
     *
     * Setting `newOwner` to the zero address is allowed; this can be used to cancel an initiated ownership transfer.
     */
    function transferOwnership(address newOwner) public virtual override onlyOwner {
        _pendingOwner = newOwner;
        emit OwnershipTransferStarted(owner(), newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`) and deletes any pending owner.
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual override {
        delete _pendingOwner;
        super._transferOwnership(newOwner);
    }

    /**
     * @dev The new owner accepts the ownership transfer.
     */
    function acceptOwnership() public virtual {
        address sender = _msgSender();
        if (pendingOwner() != sender) {
            revert OwnableUnauthorizedAccount(sender);
        }
        _transferOwnership(sender);
    }
}

//SPDX-License-Identifier: MIT
pragma solidity ^0.8.22;

import {Ownable, Ownable2Step} from '@openzeppelin/contracts/access/Ownable2Step.sol';
import {IERC20} from '@openzeppelin/contracts/token/ERC20/IERC20.sol';

interface IERC20Mintable {
  function mint(address to, uint256 amount) external;
}

/// @title Token minter contract
/// @author EqLab
/// @notice Contract that allows to mint tokens according to a specified schedule.
contract TokenMinter is Ownable2Step {
  /* Type declarations */
  struct MintConfig {
    /// @dev Before the start time minting is not available
    uint64 startTime;
    /// @dev Period length in seconds. Should be greater than zero, should be greater than periodShift
    uint64 periodLength;
    /// @dev Period shift in seconds for making beginning of period more flexible. Should be less than periodLength
    uint64 periodShift;
    /// @dev Maximum count of mints
    uint64 maxCountOfMints;
    /// @dev Amount of tokens to mint for each period
    uint256 mintAmount;
  }

  struct Allocation {
    /// @dev Recipient of the minted tokens
    address recipient;
    ///@dev Share of the minted tokens
    uint96 share;
  }

  /* State variables */
  /// @dev Represents 100%
  uint96 private constant ONE = 10 ** 18;

  /// @dev Address of a token to mint
  address private immutable i_token;

  /// @dev Operators who can perform minting
  mapping(address => bool) private s_operators;

  /// @dev Minting configuration
  MintConfig private s_mintConfig;

  /// @dev Time of the last mint in seconds
  uint128 private s_lastMintTime;

  /// @dev Counter of the mint operations
  uint32 private s_mintCount;

  /// @dev List of allocations
  Allocation[] private s_allocations;

  /* Events */
  event OperatorChanged(address indexed operator, bool added);
  event Mint(uint256 amount, uint256 mintCount);

  /* Errors */
  error TokenMinter__InvalidAddress();
  error TokenMinter__Unauthorized();
  error TokenMinter__InvalidShares();
  error TokenMinter__MintNotAvailable();
  error TokenMinter__InvalidMintConfig();

  /* Modifiers */
  modifier onlyOperator() {
    _ensureOperator(msg.sender);
    _;
  }

  /// Contract constructor
  /// @param token IERC20 token address, should be mintable, should transfer ownership or mint rights to this contract
  /// @param initialOwner Initial owner of the contract
  /// @param mintConfig Initial minting configuration
  /// @param allocations Initial list of allocations
  /// @param operators Initial list of operators
  constructor(
    address token,
    address initialOwner,
    MintConfig memory mintConfig,
    Allocation[] memory allocations,
    address[] memory operators
  ) Ownable(initialOwner) {
    if (token == address(0)) {
      revert TokenMinter__InvalidAddress();
    }

    i_token = token;
    _updateMintConfig(mintConfig);
    _updateAllocations(allocations);

    uint256 length = operators.length;
    for (uint256 i; i < length; ) {
      _addOperator(operators[i], true);

      unchecked {
        ++i;
      }
    }
  }

  /// @notice Mint tokens according to the schedule
  /// @dev Available only for operators
  function mint() external onlyOperator {
    MintConfig memory mintConfig = s_mintConfig;
    if (!_canMint(mintConfig)) {
      revert TokenMinter__MintNotAvailable();
    }

    s_lastMintTime = uint128(block.timestamp); // safe
    uint32 newMintCount = s_mintCount + 1;
    s_mintCount = newMintCount;

    emit Mint(mintConfig.mintAmount, newMintCount);

    IERC20Mintable token = IERC20Mintable(i_token);
    uint256 restAmount = mintConfig.mintAmount;
    uint256 length = s_allocations.length;

    for (uint256 i = 0; i < length; ) {
      Allocation memory allocation = s_allocations[i];
      uint256 mintAmount = (i == length - 1) ? restAmount : (mintConfig.mintAmount * allocation.share) / ONE;

      token.mint(allocation.recipient, mintAmount);
      restAmount -= mintAmount;

      unchecked {
        ++i;
      }
    }
  }

  /// @dev Transfer ownership of the token to another address
  /// @param newTokenOwner new token owner address
  function transferTokenOwnership(address newTokenOwner) external onlyOwner {
    if (newTokenOwner == address(0)) {
      revert TokenMinter__InvalidAddress();
    }

    Ownable(i_token).transferOwnership(newTokenOwner);
  }

  /// Adds new operator
  /// @dev Only owner can add operator
  /// @param operator Address of the operator
  /// @param add True to add operator, false to remove
  function addOperator(address operator, bool add) external onlyOwner {
    _addOperator(operator, add);
  }

  /// Updates allocations
  /// @dev Only owner can update allocations
  /// @param allocations List of allocations
  function updateAllocations(Allocation[] calldata allocations) external onlyOwner {
    _updateAllocations(allocations);
  }

  /// Updates minting configuration
  /// @dev Only owner can update minting configuration
  /// @param mintConfig New minting configuration
  function updateMintConfig(MintConfig calldata mintConfig) external onlyOwner {
    _updateMintConfig(mintConfig);
  }

  /// Checks if minting is available
  function canMint() external view returns (bool) {
    return _canMint(s_mintConfig);
  }

  function getToken() public view returns (address) {
    return i_token;
  }

  function getMintConfig() public view returns (MintConfig memory) {
    return s_mintConfig;
  }

  function getAllocations() public view returns (Allocation[] memory) {
    return s_allocations;
  }

  function getLastMintTime() public view returns (uint256) {
    return s_lastMintTime;
  }

  function getMintCount() public view returns (uint32) {
    return s_mintCount;
  }

  function isOperator(address operator) public view returns (bool) {
    return s_operators[operator];
  }

  function _addOperator(address operator, bool add) private {
    if (operator == address(0)) {
      revert TokenMinter__InvalidAddress();
    }

    s_operators[operator] = add;
    emit OperatorChanged(operator, add);
  }

  function _updateMintConfig(MintConfig memory mintConfig) private {
    if (mintConfig.periodShift >= mintConfig.periodLength) revert TokenMinter__InvalidMintConfig();

    s_mintConfig = mintConfig;
  }

  function _updateAllocations(Allocation[] memory allocations) private {
    uint256 totalShare = 0;
    for (uint256 i; i < allocations.length; ) {
      if (allocations[i].recipient == address(0)) revert TokenMinter__InvalidAddress();

      totalShare += allocations[i].share;

      unchecked {
        ++i;
      }
    }

    if (totalShare != ONE) revert TokenMinter__InvalidShares();

    s_allocations = allocations;
  }

  function _ensureOperator(address _operator) private view {
    if (!s_operators[_operator]) revert TokenMinter__Unauthorized();
  }

  function _canMint(MintConfig memory mintConfig) private view returns (bool) {
    if (s_mintCount >= mintConfig.maxCountOfMints) return false;
    if (block.timestamp < mintConfig.startTime) return false;

    /*
     * ts - current block timestamp
     * N  - number of period starting from zero timestamp
     * periodLength - period length in seconds
     * periodShift - period shift in seconds
     *
     * ts >= N * periodLength + periodShift
     * N = floor[(ts - periodShift) / periodLength]
     * curPeriodBegin = N * periodLength + periodShift =
     *  = floor[(ts - periodShift) / periodLength] * periodLength + periodShift =
     *  = ts - ((ts - periodShift) % periodLength)
     */
    uint256 curPeriodBegin = block.timestamp - ((block.timestamp - mintConfig.periodShift) % mintConfig.periodLength);
    if (s_lastMintTime >= curPeriodBegin) return false;

    return true;
  }
}

{
  "compilationTarget": {
    "contracts/TokenMinter.sol": "TokenMinter"
  },
  "evmVersion": "paris",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": true,
    "runs": 1000000
  },
  "remappings": [],
  "viaIR": true
}