// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize, which returns 0 for contracts in
        // construction, since the code is only stored at the end of the
        // constructor execution.

        uint256 size;
        // solhint-disable-next-line no-inline-assembly
        assembly { size := extcodesize(account) }
        return size > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://diligence.consensys.net/posts/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.5.11/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        // solhint-disable-next-line avoid-low-level-calls, avoid-call-value
        (bool success, ) = recipient.call{ value: amount }("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain`call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
      return functionCall(target, data, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data, string memory errorMessage) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value, string memory errorMessage) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        require(isContract(target), "Address: call to non-contract");

        // solhint-disable-next-line avoid-low-level-calls
        (bool success, bytes memory returndata) = target.call{ value: value }(data);
        return _verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data, string memory errorMessage) internal view returns (bytes memory) {
        require(isContract(target), "Address: static call to non-contract");

        // solhint-disable-next-line avoid-low-level-calls
        (bool success, bytes memory returndata) = target.staticcall(data);
        return _verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionDelegateCall(target, data, "Address: low-level delegate call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data, string memory errorMessage) internal returns (bytes memory) {
        require(isContract(target), "Address: delegate call to non-contract");

        // solhint-disable-next-line avoid-low-level-calls
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return _verifyCallResult(success, returndata, errorMessage);
    }

    function _verifyCallResult(bool success, bytes memory returndata, string memory errorMessage) private pure returns(bytes memory) {
        if (success) {
            return returndata;
        } else {
            // Look for revert reason and bubble it up if present
            if (returndata.length > 0) {
                // The easiest way to bubble the revert reason is using memory via assembly

                // solhint-disable-next-line no-inline-assembly
                assembly {
                    let returndata_size := mload(returndata)
                    revert(add(32, returndata), returndata_size)
                }
            } else {
                revert(errorMessage);
            }
        }
    }
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.9;

import "SafeERC20.sol";
import "IVaultRewardHandler.sol";
import "ICurvePool.sol";
import "ICurveTriCrypto.sol";
import "ICurveV2Pool.sol";
import "ICvxCrvDeposit.sol";
import "ICurveFactoryPool.sol";
import "StrategyBase.sol";

contract stkCvxPrismaHarvester is stkCvxPrismaStrategyBase {
    using SafeERC20 for IERC20;
    address public owner;
    address public immutable strategy;
    uint256 public allowedSlippage = 9700;
    uint256 public constant DECIMALS = 10000;
    address public pendingOwner;

    bool public useOracle = true;
    bool public forceLock;

    constructor(address _strategy) {
        strategy = _strategy;
        owner = msg.sender;
    }

    /// @notice Set approvals for the contracts used when swapping & staking
    function setApprovals() external {
        IERC20(CVX_TOKEN).safeApprove(CURVE_CVX_ETH_POOL, 0);
        IERC20(CVX_TOKEN).safeApprove(CURVE_CVX_ETH_POOL, type(uint256).max);

        IERC20(MKUSD_TOKEN).safeApprove(CURVE_PRISMA_MKUSD_POOL, 0);
        IERC20(MKUSD_TOKEN).safeApprove(
            CURVE_PRISMA_MKUSD_POOL,
            type(uint256).max
        );

        IERC20(PRISMA_TOKEN).safeApprove(PRISMA_DEPOSIT, 0);
        IERC20(PRISMA_TOKEN).safeApprove(PRISMA_DEPOSIT, type(uint256).max);

        IERC20(PRISMA_TOKEN).safeApprove(CURVE_CVXPRISMA_PRISMA_POOL, 0);
        IERC20(PRISMA_TOKEN).safeApprove(
            CURVE_CVXPRISMA_PRISMA_POOL,
            type(uint256).max
        );
    }

    /// @notice Turns oracle on or off for swap
    function switchOracle() external onlyOwner {
        useOracle = !useOracle;
    }

    /// @notice Sets the contract's future owner
    /// @param _po - pending owner's address
    function setPendingOwner(address _po) external onlyOwner {
        pendingOwner = _po;
    }

    /// @notice Allows a pending owner to accept ownership
    function acceptOwnership() external {
        require(pendingOwner == msg.sender, "only new owner");
        owner = pendingOwner;
        pendingOwner = address(0);
    }

    /// @notice switch the forceLock option to force harvester to lock
    /// @dev the harvester will lock even if there is a discount if forceLock is true
    function setForceLock() external onlyOwner {
        forceLock = !forceLock;
    }

    /// @notice Rescue tokens wrongly sent to the contracts or claimed extra
    /// rewards that the contract is not equipped to handle
    /// @dev Unhandled rewards can be redirected to new harvester contract
    function rescueToken(address _token, address _to) external onlyOwner {
        /// Only allow to rescue non-supported tokens
        require(
            _token != MKUSD_TOKEN &&
                _token != PRISMA_TOKEN &&
                _token != CVX_TOKEN,
            "not allowed"
        );
        IERC20 _t = IERC20(_token);
        uint256 _balance = _t.balanceOf(address(this));
        _t.safeTransfer(_to, _balance);
    }

    /// @notice Sets the range of acceptable slippage & price impact
    function setSlippage(uint256 _slippage) external onlyOwner {
        allowedSlippage = _slippage;
    }

    /// @notice Compute a min amount of Prisma bought for CVX sold based on pool oracle for cvx/eth & prisma/eth
    /// @param _amount - amount to swap
    /// @return min acceptable amount of Prisma
    function _calcMinAmountOutCvxPrisma(
        uint256 _amount
    ) internal returns (uint256) {
        uint256 _cvxEthPrice = cvxEthSwap.price_oracle();
        uint256 _ethPrismaPrice = prismaEthSwap.price_oracle();
        uint256 _amountEthPrice = (_amount * _cvxEthPrice) / 1e18;
        uint256 _amountPrismaPrice = (_amountEthPrice * 1e18) / _ethPrismaPrice;
        return ((_amountPrismaPrice * allowedSlippage) / DECIMALS);
    }

    /// @notice Compute a min amount of Prisma bought for mkUSD sold based on pool oracle for mkusd/Prisma
    /// @param _amount - amount to swap
    /// @return min acceptable amount of Prisma
    function _calcMinAmountOutMkUsdPrisma(
        uint256 _amount
    ) internal returns (uint256) {
        uint256 _prismaMkUsdPrice = mkUsdPrismaSwap.price_oracle();
        uint256 _amountPrismaPrice = (_amount * 1e18) / _prismaMkUsdPrice;
        return ((_amountPrismaPrice * allowedSlippage) / DECIMALS);
    }

    function processRewards()
        external
        onlyStrategy
        returns (uint256 _harvested)
    {
        // swap cvx to eth
        uint256 _cvxBalance = IERC20(CVX_TOKEN).balanceOf(address(this));
        if (_cvxBalance > 0) {
            _swapEthCvx(_cvxBalance, 0, false);
        }
        uint256 _ethBalance = address(this).balance;
        _harvested = 0;

        // swap eth to prisma
        if (_ethBalance > 0) {
            _swapEthPrisma(
                _ethBalance,
                useOracle ? _calcMinAmountOutCvxPrisma(_cvxBalance) : 0,
                true
            );
        }
        // handle mkusd rewards
        uint256 _mkUsdBalance = IERC20(MKUSD_TOKEN).balanceOf(address(this));
        // swap to prisma
        if (_mkUsdBalance > 0) {
            _swapMkUsdPrisma(
                _mkUsdBalance,
                useOracle ? _calcMinAmountOutMkUsdPrisma(_mkUsdBalance) : 0,
                true
            );
        }

        uint256 _prismaBalance = IERC20(PRISMA_TOKEN).balanceOf(address(this));
        if (_prismaBalance > 0) {
            uint256 _oraclePrice = cvxPrismaPrismaSwap.price_oracle();
            // check if there is a premium on cvxPrisma or if we want to lock
            if (_oraclePrice > 1 ether || forceLock) {
                // lock and deposit as cvxPrisma
                cvxPrismaDeposit.deposit(_prismaBalance, true);
                _harvested = _prismaBalance;
            }
            // If not swap on Curve
            else {
                uint256 _minCvxPrismaAmountOut = 0;
                if (useOracle) {
                    _minCvxPrismaAmountOut =
                        (_prismaBalance * 1e18) /
                        _oraclePrice;
                    _minCvxPrismaAmountOut = ((_minCvxPrismaAmountOut *
                        allowedSlippage) / DECIMALS);
                }
                _harvested = _swapCvxPrismaPrisma(
                    _prismaBalance,
                    _minCvxPrismaAmountOut,
                    false
                );
            }
            IERC20(CVXPRISMA_TOKEN).safeTransfer(msg.sender, _harvested);
        }
        return _harvested;
    }

    modifier onlyOwner() {
        require((msg.sender == owner), "owner only");
        _;
    }

    modifier onlyStrategy() {
        require((msg.sender == strategy), "strategy only");
        _;
    }
}

// SPDX-License-Identifier: UNLICENSED
pragma solidity 0.8.9;

interface IBasicRewards {
    function stakeFor(address, uint256) external returns (bool);

    function balanceOf(address) external view returns (uint256);

    function earned(address) external view returns (uint256);

    function withdrawAll(bool) external returns (bool);

    function withdraw(uint256, bool) external returns (bool);

    function withdrawAndUnwrap(uint256 amount, bool claim)
        external
        returns (bool);

    function getReward() external returns (bool);

    function stake(uint256) external returns (bool);

    function extraRewards(uint256) external view returns (address);

    function exit() external returns (bool);
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.9;

interface ICurveFactoryPool {
    function get_dy(
        int128 i,
        int128 j,
        uint256 dx
    ) external view returns (uint256);

    function get_balances() external view returns (uint256[2] memory);

    function add_liquidity(
        uint256[2] memory _amounts,
        uint256 _min_mint_amount,
        address _receiver
    ) external returns (uint256);

    function exchange(
        int128 i,
        int128 j,
        uint256 _dx,
        uint256 _min_dy,
        address _receiver
    ) external returns (uint256);
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.9;

interface ICurvePool {
    function remove_liquidity_one_coin(
        uint256 token_amount,
        int128 i,
        uint256 min_amount
    ) external;

    function calc_withdraw_one_coin(uint256 _token_amount, int128 i)
        external
        view
        returns (uint256);

    function exchange(
        int128 i,
        int128 j,
        uint256 dx,
        uint256 min_dy
    ) external returns (uint256);

    function exchange(
        int128 i,
        int128 j,
        uint256 dx,
        uint256 min_dy,
        address receiver
    ) external returns (uint256);

    function get_dy(
        int128 i,
        int128 j,
        uint256 dx
    ) external view returns (uint256);

    function get_virtual_price() external view returns (uint256);

    function price_oracle() external view returns (uint256);
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.9;

interface ICurveTriCrypto {
    function exchange(
        uint256 i,
        uint256 j,
        uint256 dx,
        uint256 min_dy,
        bool use_eth
    ) external payable;

    function get_dy(
        uint256 i,
        uint256 j,
        uint256 dx
    ) external view returns (uint256);

    function price_oracle(uint256 k) external view returns (uint256);
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.9;

interface ICurveV2Pool {
    function get_dy(
        uint256 i,
        uint256 j,
        uint256 dx
    ) external view returns (uint256);

    function calc_token_amount(uint256[2] calldata amounts)
        external
        view
        returns (uint256);

    function exchange_underlying(
        uint256 i,
        uint256 j,
        uint256 dx,
        uint256 min_dy
    ) external payable returns (uint256);

    function add_liquidity(uint256[2] calldata amounts, uint256 min_mint_amount)
        external
        returns (uint256);

    function lp_price() external view returns (uint256);

    function exchange(
        uint256 i,
        uint256 j,
        uint256 dx,
        uint256 min_dy
    ) external payable returns (uint256);

    function exchange(
        uint256 i,
        uint256 j,
        uint256 dx,
        uint256 min_dy,
        bool use_eth
    ) external payable returns (uint256);

    function exchange(
        uint256 i,
        uint256 j,
        uint256 dx,
        uint256 min_dy,
        bool use_eth,
        address receiver
    ) external payable returns (uint256);

    function price_oracle() external view returns (uint256);

    function remove_liquidity_one_coin(
        uint256 token_amount,
        uint256 i,
        uint256 min_amount,
        bool use_eth,
        address receiver
    ) external returns (uint256);
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.9;

interface ICvxCrvDeposit {
    function deposit(uint256, bool) external;
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `recipient`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address recipient, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `sender` to `recipient` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address sender, address recipient, uint256 amount) external returns (bool);

    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.9;

interface IVaultRewardHandler {
    function sell(uint256 _amount) external;

    function setPendingOwner(address _po) external;

    function applyPendingOwner() external;

    function rescueToken(address _token, address _to) external;
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.9;

interface IWETH {
    function deposit() external payable;

    function transfer(address to, uint256 value) external returns (bool);

    function withdraw(uint256) external;
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

import "IERC20.sol";
import "Address.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using Address for address;

    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transfer.selector, to, value));
    }

    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transferFrom.selector, from, to, value));
    }

    /**
     * @dev Deprecated. This function has issues similar to the ones found in
     * {IERC20-approve}, and its usage is discouraged.
     *
     * Whenever possible, use {safeIncreaseAllowance} and
     * {safeDecreaseAllowance} instead.
     */
    function safeApprove(IERC20 token, address spender, uint256 value) internal {
        // safeApprove should only be called when setting an initial allowance,
        // or when resetting it to zero. To increase and decrease it, use
        // 'safeIncreaseAllowance' and 'safeDecreaseAllowance'
        // solhint-disable-next-line max-line-length
        require((value == 0) || (token.allowance(address(this), spender) == 0),
            "SafeERC20: approve from non-zero to non-zero allowance"
        );
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, value));
    }

    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 newAllowance = token.allowance(address(this), spender) + value;
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, newAllowance));
    }

    function safeDecreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        unchecked {
            uint256 oldAllowance = token.allowance(address(this), spender);
            require(oldAllowance >= value, "SafeERC20: decreased allowance below zero");
            uint256 newAllowance = oldAllowance - value;
            _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, newAllowance));
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We use {Address.functionCall} to perform this call, which verifies that
        // the target address contains contract code and also asserts for success in the low-level call.

        bytes memory returndata = address(token).functionCall(data, "SafeERC20: low-level call failed");
        if (returndata.length > 0) { // Return data is optional
            // solhint-disable-next-line max-line-length
            require(abi.decode(returndata, (bool)), "SafeERC20: ERC20 operation did not succeed");
        }
    }
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.9;

import "ICurveV2Pool.sol";
import "ICurvePool.sol";
import "ICurveFactoryPool.sol";
import "IBasicRewards.sol";
import "IWETH.sol";

interface ICvxPrismaDeposit {
    function deposit(uint256, bool) external;
}

contract stkCvxPrismaStrategyBase {
    address public constant PRISMA_DEPOSIT =
        0x61404F7c2d8b1F3373eb3c6e8C4b8d8332c2D5B8;

    address public constant CURVE_CVX_ETH_POOL =
        0xB576491F1E6e5E62f1d8F26062Ee822B40B0E0d4;
    address public constant CURVE_PRISMA_ETH_POOL =
        0x322135Dd9cBAE8Afa84727d9aE1434b5B3EBA44B;

    address public constant CURVE_CVXPRISMA_PRISMA_POOL =
        0x3b21C2868B6028CfB38Ff86127eF22E68d16d53B;
    address public constant CURVE_PRISMA_MKUSD_POOL =
        0x9D8108DDD8aD1Ee89d527C0C9e928Cb9D2BBa2d3;

    address public constant CVXPRISMA_TOKEN =
        0x34635280737b5BFe6c7DC2FC3065D60d66e78185;
    address public constant PRISMA_TOKEN =
        0xdA47862a83dac0c112BA89c6abC2159b95afd71C;
    address public constant CVX_TOKEN =
        0x4e3FBD56CD56c3e72c1403e103b45Db9da5B9D2B;
    address public constant MKUSD_TOKEN =
        0x4591DBfF62656E7859Afe5e45f6f47D3669fBB28;

    uint256 public constant PRISMAETH_ETH_INDEX = 0;
    uint256 public constant PRISMAETH_PRISMA_INDEX = 1;
    uint256 public constant CVXETH_ETH_INDEX = 0;
    uint256 public constant CVXETH_CVX_INDEX = 1;
    uint256 public constant PRISMAMKUSD_MKUSD_INDEX = 0;
    uint256 public constant PRISMAMKUSD_PRISMA_INDEX = 1;
    int128 public constant PRISMACVXPRISMA_CVXPRISMA_INDEX = 1;
    int128 public constant PRISMACVXPRISMA_PRISMA_INDEX = 0;

    ICvxPrismaDeposit cvxPrismaDeposit = ICvxPrismaDeposit(PRISMA_DEPOSIT);
    ICurveV2Pool cvxEthSwap = ICurveV2Pool(CURVE_CVX_ETH_POOL);
    ICurveV2Pool prismaEthSwap = ICurveV2Pool(CURVE_PRISMA_ETH_POOL);
    ICurvePool cvxPrismaPrismaSwap = ICurvePool(CURVE_CVXPRISMA_PRISMA_POOL);
    ICurveV2Pool mkUsdPrismaSwap = ICurveV2Pool(CURVE_PRISMA_MKUSD_POOL);

    /// @notice Swap native ETH <-> CVX on Curve
    /// @param amount - amount to swap
    /// @param minAmountOut - minimum expected amount of output tokens
    /// @param ethToCvx - whether to swap from eth to cvx or the inverse
    /// @return amount of CVX obtained after the swap
    function _swapEthCvx(
        uint256 amount,
        uint256 minAmountOut,
        bool ethToCvx
    ) internal returns (uint256) {
        return
            cvxEthSwap.exchange_underlying{value: ethToCvx ? amount : 0}(
                ethToCvx ? CVXETH_ETH_INDEX : CVXETH_CVX_INDEX,
                ethToCvx ? CVXETH_CVX_INDEX : CVXETH_ETH_INDEX,
                amount,
                minAmountOut
            );
    }

    /// @notice Swap ETH<->Prisma on Curve
    /// @param amount - amount to swap
    /// @param minAmountOut - minimum expected amount of output tokens
    /// @param ethToPrisma - whether to swap from eth to prisma or the inverse
    /// @return amount of token obtained after the swap
    function _swapEthPrisma(
        uint256 amount,
        uint256 minAmountOut,
        bool ethToPrisma
    ) internal returns (uint256) {
        return
            prismaEthSwap.exchange_underlying{value: ethToPrisma ? amount : 0}(
                ethToPrisma ? PRISMAETH_ETH_INDEX : PRISMAETH_PRISMA_INDEX,
                ethToPrisma ? PRISMAETH_PRISMA_INDEX : PRISMAETH_ETH_INDEX,
                amount,
                minAmountOut
            );
    }

    /// @notice Swap mkUSD<->Prisma on Curve
    /// @param amount - amount to swap
    /// @param minAmountOut - minimum expected amount of output tokens
    /// @param mkUsdToPrisma - whether to swap from mkUsd to prisma or the inverse
    /// @return amount of token obtained after the swap
    function _swapMkUsdPrisma(
        uint256 amount,
        uint256 minAmountOut,
        bool mkUsdToPrisma
    ) internal returns (uint256) {
        return
            mkUsdPrismaSwap.exchange_underlying(
                mkUsdToPrisma
                    ? PRISMAMKUSD_MKUSD_INDEX
                    : PRISMAMKUSD_PRISMA_INDEX,
                mkUsdToPrisma
                    ? PRISMAMKUSD_PRISMA_INDEX
                    : PRISMAMKUSD_MKUSD_INDEX,
                amount,
                minAmountOut
            );
    }

    /// @notice Swap cvxPrisma<->Prisma on Curve
    /// @param amount - amount to swap
    /// @param minAmountOut - minimum expected amount of output tokens
    /// @param cvxPrismaToPrisma - whether to swap from cvxPrisma to prisma or the inverse
    /// @return amount of token obtained after the swap
    function _swapCvxPrismaPrisma(
        uint256 amount,
        uint256 minAmountOut,
        bool cvxPrismaToPrisma
    ) internal returns (uint256) {
        return
            cvxPrismaPrismaSwap.exchange(
                cvxPrismaToPrisma
                    ? PRISMACVXPRISMA_CVXPRISMA_INDEX
                    : PRISMACVXPRISMA_PRISMA_INDEX,
                cvxPrismaToPrisma
                    ? PRISMACVXPRISMA_PRISMA_INDEX
                    : PRISMACVXPRISMA_CVXPRISMA_INDEX,
                amount,
                minAmountOut
            );
    }

    receive() external payable {}
}

{
  "compilationTarget": {
    "Harvester.sol": "stkCvxPrismaHarvester"
  },
  "evmVersion": "istanbul",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": true,
    "runs": 200
  },
  "remappings": []
}