// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/Address.sol)

pragma solidity ^0.8.1;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     *
     * Furthermore, `isContract` will also return true if the target contract within
     * the same transaction is already scheduled for destruction by `SELFDESTRUCT`,
     * which only has an effect at the end of a transaction.
     * ====
     *
     * [IMPORTANT]
     * ====
     * You shouldn't rely on `isContract` to protect against flash loan attacks!
     *
     * Preventing calls from contracts is highly discouraged. It breaks composability, breaks support for smart wallets
     * like Gnosis Safe, and does not provide security since it can be circumvented by calling from a contract
     * constructor.
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize/address.code.length, which returns 0
        // for contracts in construction, since the code is only stored at the end
        // of the constructor execution.

        return account.code.length > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.8.0/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        (bool success, ) = recipient.call{value: amount}("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionDelegateCall(target, data, "Address: low-level delegate call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and revert (either by bubbling
     * the revert reason or using the provided one) in case of unsuccessful call or if target was not a contract.
     *
     * _Available since v4.8._
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        if (success) {
            if (returndata.length == 0) {
                // only check isContract if the call was successful and the return data is empty
                // otherwise we already know that it was a contract
                require(isContract(target), "Address: call to non-contract");
            }
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and revert if it wasn't, either by bubbling the
     * revert reason or using the provided one.
     *
     * _Available since v4.3._
     */
    function verifyCallResult(
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal pure returns (bytes memory) {
        if (success) {
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    function _revert(bytes memory returndata, string memory errorMessage) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            /// @solidity memory-safe-assembly
            assembly {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert(errorMessage);
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.7.0) (utils/Base64.sol)

pragma solidity ^0.8.0;

/**
 * @dev Provides a set of functions to operate with Base64 strings.
 *
 * _Available since v4.5._
 */
library Base64 {
    /**
     * @dev Base64 Encoding/Decoding Table
     */
    string internal constant _TABLE = "ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789+/";

    /**
     * @dev Converts a `bytes` to its Bytes64 `string` representation.
     */
    function encode(bytes memory data) internal pure returns (string memory) {
        /**
         * Inspired by Brecht Devos (Brechtpd) implementation - MIT licence
         * https://github.com/Brechtpd/base64/blob/e78d9fd951e7b0977ddca77d92dc85183770daf4/base64.sol
         */
        if (data.length == 0) return "";

        // Loads the table into memory
        string memory table = _TABLE;

        // Encoding takes 3 bytes chunks of binary data from `bytes` data parameter
        // and split into 4 numbers of 6 bits.
        // The final Base64 length should be `bytes` data length multiplied by 4/3 rounded up
        // - `data.length + 2`  -> Round up
        // - `/ 3`              -> Number of 3-bytes chunks
        // - `4 *`              -> 4 characters for each chunk
        string memory result = new string(4 * ((data.length + 2) / 3));

        /// @solidity memory-safe-assembly
        assembly {
            // Prepare the lookup table (skip the first "length" byte)
            let tablePtr := add(table, 1)

            // Prepare result pointer, jump over length
            let resultPtr := add(result, 32)

            // Run over the input, 3 bytes at a time
            for {
                let dataPtr := data
                let endPtr := add(data, mload(data))
            } lt(dataPtr, endPtr) {

            } {
                // Advance 3 bytes
                dataPtr := add(dataPtr, 3)
                let input := mload(dataPtr)

                // To write each character, shift the 3 bytes (18 bits) chunk
                // 4 times in blocks of 6 bits for each character (18, 12, 6, 0)
                // and apply logical AND with 0x3F which is the number of
                // the previous character in the ASCII table prior to the Base64 Table
                // The result is then added to the table to get the character to write,
                // and finally write it in the result pointer but with a left shift
                // of 256 (1 byte) - 8 (1 ASCII char) = 248 bits

                mstore8(resultPtr, mload(add(tablePtr, and(shr(18, input), 0x3F))))
                resultPtr := add(resultPtr, 1) // Advance

                mstore8(resultPtr, mload(add(tablePtr, and(shr(12, input), 0x3F))))
                resultPtr := add(resultPtr, 1) // Advance

                mstore8(resultPtr, mload(add(tablePtr, and(shr(6, input), 0x3F))))
                resultPtr := add(resultPtr, 1) // Advance

                mstore8(resultPtr, mload(add(tablePtr, and(input, 0x3F))))
                resultPtr := add(resultPtr, 1) // Advance
            }

            // When data `bytes` is not exactly 3 bytes long
            // it is padded with `=` characters at the end
            switch mod(mload(data), 3)
            case 1 {
                mstore8(sub(resultPtr, 1), 0x3d)
                mstore8(sub(resultPtr, 2), 0x3d)
            }
            case 2 {
                mstore8(sub(resultPtr, 1), 0x3d)
            }
        }

        return result;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Context.sol)

pragma solidity ^0.8.0;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/introspection/ERC165.sol)

pragma solidity ^0.8.0;

import "./IERC165.sol";

/**
 * @dev Implementation of the {IERC165} interface.
 *
 * Contracts that want to implement ERC165 should inherit from this contract and override {supportsInterface} to check
 * for the additional interface id that will be supported. For example:
 *
 * ```solidity
 * function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
 *     return interfaceId == type(MyInterface).interfaceId || super.supportsInterface(interfaceId);
 * }
 * ```
 *
 * Alternatively, {ERC165Storage} provides an easier to use but more expensive implementation.
 */
abstract contract ERC165 is IERC165 {
    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
        return interfaceId == type(IERC165).interfaceId;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/introspection/IERC165.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[EIP].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[EIP section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `from` to `to` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 amount) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (token/ERC721/WARPS721.sol)

pragma solidity ^0.8.0;

import "lib/openzeppelin-contracts/contracts/token/ERC721/IERC721.sol";
import "lib/openzeppelin-contracts/contracts/utils/introspection/IERC165.sol";

/// @title EIP-721 Metadata Update Extension
interface IERC4906 is IERC165, IERC721 {
    /// @dev This event emits when the metadata of a token is changed.
    /// Third-party platforms such as NFT marketplaces can listen to
    /// the event and auto-update the tokens in their apps.
    event MetadataUpdate(uint256 _tokenId);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC721/IERC721.sol)

pragma solidity ^0.8.0;

import "../../utils/introspection/IERC165.sol";

/**
 * @dev Required interface of an ERC721 compliant contract.
 */
interface IERC721 is IERC165 {
    /**
     * @dev Emitted when `tokenId` token is transferred from `from` to `to`.
     */
    event Transfer(address indexed from, address indexed to, uint256 indexed tokenId);

    /**
     * @dev Emitted when `owner` enables `approved` to manage the `tokenId` token.
     */
    event Approval(address indexed owner, address indexed approved, uint256 indexed tokenId);

    /**
     * @dev Emitted when `owner` enables or disables (`approved`) `operator` to manage all of its assets.
     */
    event ApprovalForAll(address indexed owner, address indexed operator, bool approved);

    /**
     * @dev Returns the number of tokens in ``owner``'s account.
     */
    function balanceOf(address owner) external view returns (uint256 balance);

    /**
     * @dev Returns the owner of the `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function ownerOf(uint256 tokenId) external view returns (address owner);

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(address from, address to, uint256 tokenId, bytes calldata data) external;

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`, checking first that contract recipients
     * are aware of the ERC721 protocol to prevent tokens from being forever locked.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must have been allowed to move this token by either {approve} or {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(address from, address to, uint256 tokenId) external;

    /**
     * @dev Transfers `tokenId` token from `from` to `to`.
     *
     * WARNING: Note that the caller is responsible to confirm that the recipient is capable of receiving ERC721
     * or else they may be permanently lost. Usage of {safeTransferFrom} prevents loss, though the caller must
     * understand this adds an external call which potentially creates a reentrancy vulnerability.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 tokenId) external;

    /**
     * @dev Gives permission to `to` to transfer `tokenId` token to another account.
     * The approval is cleared when the token is transferred.
     *
     * Only a single account can be approved at a time, so approving the zero address clears previous approvals.
     *
     * Requirements:
     *
     * - The caller must own the token or be an approved operator.
     * - `tokenId` must exist.
     *
     * Emits an {Approval} event.
     */
    function approve(address to, uint256 tokenId) external;

    /**
     * @dev Approve or remove `operator` as an operator for the caller.
     * Operators can call {transferFrom} or {safeTransferFrom} for any token owned by the caller.
     *
     * Requirements:
     *
     * - The `operator` cannot be the caller.
     *
     * Emits an {ApprovalForAll} event.
     */
    function setApprovalForAll(address operator, bool approved) external;

    /**
     * @dev Returns the account approved for `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function getApproved(uint256 tokenId) external view returns (address operator);

    /**
     * @dev Returns if the `operator` is allowed to manage all of the assets of `owner`.
     *
     * See {setApprovalForAll}
     */
    function isApprovedForAll(address owner, address operator) external view returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.5.0) (token/ERC721/extensions/IERC721Enumerable.sol)

pragma solidity ^0.8.0;

import "../IERC721.sol";

/**
 * @title ERC-721 Non-Fungible Token Standard, optional enumeration extension
 * @dev See https://eips.ethereum.org/EIPS/eip-721
 */
interface IERC721Enumerable is IERC721 {
    /**
     * @dev Returns the total amount of tokens stored by the contract.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns a token ID owned by `owner` at a given `index` of its token list.
     * Use along with {balanceOf} to enumerate all of ``owner``'s tokens.
     */
    function tokenOfOwnerByIndex(address owner, uint256 index) external view returns (uint256);

    /**
     * @dev Returns a token ID at a given `index` of all the tokens stored by the contract.
     * Use along with {totalSupply} to enumerate all tokens.
     */
    function tokenByIndex(uint256 index) external view returns (uint256);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (token/ERC721/extensions/IERC721Metadata.sol)

pragma solidity ^0.8.0;

import "../IERC721.sol";

/**
 * @title ERC-721 Non-Fungible Token Standard, optional metadata extension
 * @dev See https://eips.ethereum.org/EIPS/eip-721
 */
interface IERC721Metadata is IERC721 {
    /**
     * @dev Returns the token collection name.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the token collection symbol.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the Uniform Resource Identifier (URI) for `tokenId` token.
     */
    function tokenURI(uint256 tokenId) external view returns (string memory);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.6.0) (token/ERC721/IERC721Receiver.sol)

pragma solidity ^0.8.0;

/**
 * @title ERC721 token receiver interface
 * @dev Interface for any contract that wants to support safeTransfers
 * from ERC721 asset contracts.
 */
interface IERC721Receiver {
    /**
     * @dev Whenever an {IERC721} `tokenId` token is transferred to this contract via {IERC721-safeTransferFrom}
     * by `operator` from `from`, this function is called.
     *
     * It must return its Solidity selector to confirm the token transfer.
     * If any other value is returned or the interface is not implemented by the recipient, the transfer will be reverted.
     *
     * The selector can be obtained in Solidity with `IERC721Receiver.onERC721Received.selector`.
     */
    function onERC721Received(
        address operator,
        address from,
        uint256 tokenId,
        bytes calldata data
    ) external returns (bytes4);
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.17;

interface IWarps {
    struct StoredWarp {
        uint16[6] composites; // The tokenIds that were composited into this one
        uint8[5] colorBands; // The length of the used color band in percent
        uint8[5] gradients; // Gradient settings for each generation
        uint8 divisorIndex; // Easy access to next / previous divisor
        uint16 seed; // A unique identifier to enable swapping
    }

    struct Warp {
        StoredWarp stored; // We carry over the warp from storage
        uint256 seed; // The instantiated seed for pseudo-randomisation
        uint8 warpsCount; // How many warps this token has
        bool hasManyWarps; // Whether the warp has many warps
        uint16 composite; // The parent tokenId that was composited into this one
        bool isRoot; // Whether it has no parents (80 warps)
        uint8 colorBand; // 100%, 50%, 25%, 12.5%, 6.25%, 5%, 1.25%
        uint8 gradient; // Linearly through the colorBand [1, 2, 3]
    }

    struct Epoch {
        bool committed;
        bool revealed;
        uint64 revealBlock;
        uint128 randomness;
    }

    struct Warps {
        mapping(uint256 => StoredWarp) all; // All warps
        mapping(uint256 => Epoch) epochs; // Epoch data for randomness
        uint32 minted; // The number of warps editions that have been migrated
        uint32 burned; // The number of tokens that have been burned
        uint32 currentEpoch; // Current epoch number
    }

    event Sacrifice(uint256 indexed burnedId, uint256 indexed tokenId);

    event Composite(uint256 indexed tokenId, uint256 indexed burnedId, uint8 indexed warps);

    error NotAllowed();
    error InvalidTokenCount();
    error BlackWarp__InvalidWarp();
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/math/Math.sol)

pragma solidity ^0.8.0;

/**
 * @dev Standard math utilities missing in the Solidity language.
 */
library Math {
    enum Rounding {
        Down, // Toward negative infinity
        Up, // Toward infinity
        Zero // Toward zero
    }

    /**
     * @dev Returns the largest of two numbers.
     */
    function max(uint256 a, uint256 b) internal pure returns (uint256) {
        return a > b ? a : b;
    }

    /**
     * @dev Returns the smallest of two numbers.
     */
    function min(uint256 a, uint256 b) internal pure returns (uint256) {
        return a < b ? a : b;
    }

    /**
     * @dev Returns the average of two numbers. The result is rounded towards
     * zero.
     */
    function average(uint256 a, uint256 b) internal pure returns (uint256) {
        // (a + b) / 2 can overflow.
        return (a & b) + (a ^ b) / 2;
    }

    /**
     * @dev Returns the ceiling of the division of two numbers.
     *
     * This differs from standard division with `/` in that it rounds up instead
     * of rounding down.
     */
    function ceilDiv(uint256 a, uint256 b) internal pure returns (uint256) {
        // (a + b - 1) / b can overflow on addition, so we distribute.
        return a == 0 ? 0 : (a - 1) / b + 1;
    }

    /**
     * @notice Calculates floor(x * y / denominator) with full precision. Throws if result overflows a uint256 or denominator == 0
     * @dev Original credit to Remco Bloemen under MIT license (https://xn--2-umb.com/21/muldiv)
     * with further edits by Uniswap Labs also under MIT license.
     */
    function mulDiv(uint256 x, uint256 y, uint256 denominator) internal pure returns (uint256 result) {
        unchecked {
            // 512-bit multiply [prod1 prod0] = x * y. Compute the product mod 2^256 and mod 2^256 - 1, then use
            // use the Chinese Remainder Theorem to reconstruct the 512 bit result. The result is stored in two 256
            // variables such that product = prod1 * 2^256 + prod0.
            uint256 prod0; // Least significant 256 bits of the product
            uint256 prod1; // Most significant 256 bits of the product
            assembly {
                let mm := mulmod(x, y, not(0))
                prod0 := mul(x, y)
                prod1 := sub(sub(mm, prod0), lt(mm, prod0))
            }

            // Handle non-overflow cases, 256 by 256 division.
            if (prod1 == 0) {
                // Solidity will revert if denominator == 0, unlike the div opcode on its own.
                // The surrounding unchecked block does not change this fact.
                // See https://docs.soliditylang.org/en/latest/control-structures.html#checked-or-unchecked-arithmetic.
                return prod0 / denominator;
            }

            // Make sure the result is less than 2^256. Also prevents denominator == 0.
            require(denominator > prod1, "Math: mulDiv overflow");

            ///////////////////////////////////////////////
            // 512 by 256 division.
            ///////////////////////////////////////////////

            // Make division exact by subtracting the remainder from [prod1 prod0].
            uint256 remainder;
            assembly {
                // Compute remainder using mulmod.
                remainder := mulmod(x, y, denominator)

                // Subtract 256 bit number from 512 bit number.
                prod1 := sub(prod1, gt(remainder, prod0))
                prod0 := sub(prod0, remainder)
            }

            // Factor powers of two out of denominator and compute largest power of two divisor of denominator. Always >= 1.
            // See https://cs.stackexchange.com/q/138556/92363.

            // Does not overflow because the denominator cannot be zero at this stage in the function.
            uint256 twos = denominator & (~denominator + 1);
            assembly {
                // Divide denominator by twos.
                denominator := div(denominator, twos)

                // Divide [prod1 prod0] by twos.
                prod0 := div(prod0, twos)

                // Flip twos such that it is 2^256 / twos. If twos is zero, then it becomes one.
                twos := add(div(sub(0, twos), twos), 1)
            }

            // Shift in bits from prod1 into prod0.
            prod0 |= prod1 * twos;

            // Invert denominator mod 2^256. Now that denominator is an odd number, it has an inverse modulo 2^256 such
            // that denominator * inv = 1 mod 2^256. Compute the inverse by starting with a seed that is correct for
            // four bits. That is, denominator * inv = 1 mod 2^4.
            uint256 inverse = (3 * denominator) ^ 2;

            // Use the Newton-Raphson iteration to improve the precision. Thanks to Hensel's lifting lemma, this also works
            // in modular arithmetic, doubling the correct bits in each step.
            inverse *= 2 - denominator * inverse; // inverse mod 2^8
            inverse *= 2 - denominator * inverse; // inverse mod 2^16
            inverse *= 2 - denominator * inverse; // inverse mod 2^32
            inverse *= 2 - denominator * inverse; // inverse mod 2^64
            inverse *= 2 - denominator * inverse; // inverse mod 2^128
            inverse *= 2 - denominator * inverse; // inverse mod 2^256

            // Because the division is now exact we can divide by multiplying with the modular inverse of denominator.
            // This will give us the correct result modulo 2^256. Since the preconditions guarantee that the outcome is
            // less than 2^256, this is the final result. We don't need to compute the high bits of the result and prod1
            // is no longer required.
            result = prod0 * inverse;
            return result;
        }
    }

    /**
     * @notice Calculates x * y / denominator with full precision, following the selected rounding direction.
     */
    function mulDiv(uint256 x, uint256 y, uint256 denominator, Rounding rounding) internal pure returns (uint256) {
        uint256 result = mulDiv(x, y, denominator);
        if (rounding == Rounding.Up && mulmod(x, y, denominator) > 0) {
            result += 1;
        }
        return result;
    }

    /**
     * @dev Returns the square root of a number. If the number is not a perfect square, the value is rounded down.
     *
     * Inspired by Henry S. Warren, Jr.'s "Hacker's Delight" (Chapter 11).
     */
    function sqrt(uint256 a) internal pure returns (uint256) {
        if (a == 0) {
            return 0;
        }

        // For our first guess, we get the biggest power of 2 which is smaller than the square root of the target.
        //
        // We know that the "msb" (most significant bit) of our target number `a` is a power of 2 such that we have
        // `msb(a) <= a < 2*msb(a)`. This value can be written `msb(a)=2**k` with `k=log2(a)`.
        //
        // This can be rewritten `2**log2(a) <= a < 2**(log2(a) + 1)`
        // → `sqrt(2**k) <= sqrt(a) < sqrt(2**(k+1))`
        // → `2**(k/2) <= sqrt(a) < 2**((k+1)/2) <= 2**(k/2 + 1)`
        //
        // Consequently, `2**(log2(a) / 2)` is a good first approximation of `sqrt(a)` with at least 1 correct bit.
        uint256 result = 1 << (log2(a) >> 1);

        // At this point `result` is an estimation with one bit of precision. We know the true value is a uint128,
        // since it is the square root of a uint256. Newton's method converges quadratically (precision doubles at
        // every iteration). We thus need at most 7 iteration to turn our partial result with one bit of precision
        // into the expected uint128 result.
        unchecked {
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            return min(result, a / result);
        }
    }

    /**
     * @notice Calculates sqrt(a), following the selected rounding direction.
     */
    function sqrt(uint256 a, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = sqrt(a);
            return result + (rounding == Rounding.Up && result * result < a ? 1 : 0);
        }
    }

    /**
     * @dev Return the log in base 2, rounded down, of a positive value.
     * Returns 0 if given 0.
     */
    function log2(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >> 128 > 0) {
                value >>= 128;
                result += 128;
            }
            if (value >> 64 > 0) {
                value >>= 64;
                result += 64;
            }
            if (value >> 32 > 0) {
                value >>= 32;
                result += 32;
            }
            if (value >> 16 > 0) {
                value >>= 16;
                result += 16;
            }
            if (value >> 8 > 0) {
                value >>= 8;
                result += 8;
            }
            if (value >> 4 > 0) {
                value >>= 4;
                result += 4;
            }
            if (value >> 2 > 0) {
                value >>= 2;
                result += 2;
            }
            if (value >> 1 > 0) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 2, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log2(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log2(value);
            return result + (rounding == Rounding.Up && 1 << result < value ? 1 : 0);
        }
    }

    /**
     * @dev Return the log in base 10, rounded down, of a positive value.
     * Returns 0 if given 0.
     */
    function log10(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >= 10 ** 64) {
                value /= 10 ** 64;
                result += 64;
            }
            if (value >= 10 ** 32) {
                value /= 10 ** 32;
                result += 32;
            }
            if (value >= 10 ** 16) {
                value /= 10 ** 16;
                result += 16;
            }
            if (value >= 10 ** 8) {
                value /= 10 ** 8;
                result += 8;
            }
            if (value >= 10 ** 4) {
                value /= 10 ** 4;
                result += 4;
            }
            if (value >= 10 ** 2) {
                value /= 10 ** 2;
                result += 2;
            }
            if (value >= 10 ** 1) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 10, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log10(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log10(value);
            return result + (rounding == Rounding.Up && 10 ** result < value ? 1 : 0);
        }
    }

    /**
     * @dev Return the log in base 256, rounded down, of a positive value.
     * Returns 0 if given 0.
     *
     * Adding one to the result gives the number of pairs of hex symbols needed to represent `value` as a hex string.
     */
    function log256(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >> 128 > 0) {
                value >>= 128;
                result += 16;
            }
            if (value >> 64 > 0) {
                value >>= 64;
                result += 8;
            }
            if (value >> 32 > 0) {
                value >>= 32;
                result += 4;
            }
            if (value >> 16 > 0) {
                value >>= 16;
                result += 2;
            }
            if (value >> 8 > 0) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 256, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log256(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log256(value);
            return result + (rounding == Rounding.Up && 1 << (result << 3) < value ? 1 : 0);
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (access/Ownable.sol)

pragma solidity ^0.8.0;

import "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _transferOwnership(_msgSender());
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.7.0) (security/Pausable.sol)

pragma solidity ^0.8.0;

import "../utils/Context.sol";

/**
 * @dev Contract module which allows children to implement an emergency stop
 * mechanism that can be triggered by an authorized account.
 *
 * This module is used through inheritance. It will make available the
 * modifiers `whenNotPaused` and `whenPaused`, which can be applied to
 * the functions of your contract. Note that they will not be pausable by
 * simply including this module, only once the modifiers are put in place.
 */
abstract contract Pausable is Context {
    /**
     * @dev Emitted when the pause is triggered by `account`.
     */
    event Paused(address account);

    /**
     * @dev Emitted when the pause is lifted by `account`.
     */
    event Unpaused(address account);

    bool private _paused;

    /**
     * @dev Initializes the contract in unpaused state.
     */
    constructor() {
        _paused = false;
    }

    /**
     * @dev Modifier to make a function callable only when the contract is not paused.
     *
     * Requirements:
     *
     * - The contract must not be paused.
     */
    modifier whenNotPaused() {
        _requireNotPaused();
        _;
    }

    /**
     * @dev Modifier to make a function callable only when the contract is paused.
     *
     * Requirements:
     *
     * - The contract must be paused.
     */
    modifier whenPaused() {
        _requirePaused();
        _;
    }

    /**
     * @dev Returns true if the contract is paused, and false otherwise.
     */
    function paused() public view virtual returns (bool) {
        return _paused;
    }

    /**
     * @dev Throws if the contract is paused.
     */
    function _requireNotPaused() internal view virtual {
        require(!paused(), "Pausable: paused");
    }

    /**
     * @dev Throws if the contract is not paused.
     */
    function _requirePaused() internal view virtual {
        require(paused(), "Pausable: not paused");
    }

    /**
     * @dev Triggers stopped state.
     *
     * Requirements:
     *
     * - The contract must not be paused.
     */
    function _pause() internal virtual whenNotPaused {
        _paused = true;
        emit Paused(_msgSender());
    }

    /**
     * @dev Returns to normal state.
     *
     * Requirements:
     *
     * - The contract must be paused.
     */
    function _unpause() internal virtual whenPaused {
        _paused = false;
        emit Unpaused(_msgSender());
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (utils/math/SignedMath.sol)

pragma solidity ^0.8.0;

/**
 * @dev Standard signed math utilities missing in the Solidity language.
 */
library SignedMath {
    /**
     * @dev Returns the largest of two signed numbers.
     */
    function max(int256 a, int256 b) internal pure returns (int256) {
        return a > b ? a : b;
    }

    /**
     * @dev Returns the smallest of two signed numbers.
     */
    function min(int256 a, int256 b) internal pure returns (int256) {
        return a < b ? a : b;
    }

    /**
     * @dev Returns the average of two signed numbers without overflow.
     * The result is rounded towards zero.
     */
    function average(int256 a, int256 b) internal pure returns (int256) {
        // Formula from the book "Hacker's Delight"
        int256 x = (a & b) + ((a ^ b) >> 1);
        return x + (int256(uint256(x) >> 255) & (a ^ b));
    }

    /**
     * @dev Returns the absolute unsigned value of a signed value.
     */
    function abs(int256 n) internal pure returns (uint256) {
        unchecked {
            // must be unchecked in order to support `n = type(int256).min`
            return uint256(n >= 0 ? n : -n);
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/Strings.sol)

pragma solidity ^0.8.0;

import "./math/Math.sol";
import "./math/SignedMath.sol";

/**
 * @dev String operations.
 */
library Strings {
    bytes16 private constant _SYMBOLS = "0123456789abcdef";
    uint8 private constant _ADDRESS_LENGTH = 20;

    /**
     * @dev Converts a `uint256` to its ASCII `string` decimal representation.
     */
    function toString(uint256 value) internal pure returns (string memory) {
        unchecked {
            uint256 length = Math.log10(value) + 1;
            string memory buffer = new string(length);
            uint256 ptr;
            /// @solidity memory-safe-assembly
            assembly {
                ptr := add(buffer, add(32, length))
            }
            while (true) {
                ptr--;
                /// @solidity memory-safe-assembly
                assembly {
                    mstore8(ptr, byte(mod(value, 10), _SYMBOLS))
                }
                value /= 10;
                if (value == 0) break;
            }
            return buffer;
        }
    }

    /**
     * @dev Converts a `int256` to its ASCII `string` decimal representation.
     */
    function toString(int256 value) internal pure returns (string memory) {
        return string(abi.encodePacked(value < 0 ? "-" : "", toString(SignedMath.abs(value))));
    }

    /**
     * @dev Converts a `uint256` to its ASCII `string` hexadecimal representation.
     */
    function toHexString(uint256 value) internal pure returns (string memory) {
        unchecked {
            return toHexString(value, Math.log256(value) + 1);
        }
    }

    /**
     * @dev Converts a `uint256` to its ASCII `string` hexadecimal representation with fixed length.
     */
    function toHexString(uint256 value, uint256 length) internal pure returns (string memory) {
        bytes memory buffer = new bytes(2 * length + 2);
        buffer[0] = "0";
        buffer[1] = "x";
        for (uint256 i = 2 * length + 1; i > 1; --i) {
            buffer[i] = _SYMBOLS[value & 0xf];
            value >>= 4;
        }
        require(value == 0, "Strings: hex length insufficient");
        return string(buffer);
    }

    /**
     * @dev Converts an `address` with fixed length of 20 bytes to its not checksummed ASCII `string` hexadecimal representation.
     */
    function toHexString(address addr) internal pure returns (string memory) {
        return toHexString(uint256(uint160(addr)), _ADDRESS_LENGTH);
    }

    /**
     * @dev Returns true if the two strings are equal.
     */
    function equal(string memory a, string memory b) internal pure returns (bool) {
        return keccak256(bytes(a)) == keccak256(bytes(b));
    }
}

//SPDX-License-Identifier: MIT
pragma solidity ^0.8.17;

library Utilities {
    /// @dev Zero-index based pseudorandom number based on one input and max bound
    function random(uint256 input, uint256 _max) internal pure returns (uint256) {
        return (uint256(keccak256(abi.encodePacked(input))) % _max);
    }

    /// @dev Zero-index based salted pseudorandom number based on two inputs and max bound
    function random(uint256 input, string memory salt, uint256 _max) internal pure returns (uint256) {
        return (uint256(keccak256(abi.encodePacked(input, salt))) % _max);
    }

    /// @dev Convert an integer to a string
    function uint2str(uint256 _i) internal pure returns (string memory _uintAsString) {
        if (_i == 0) {
            return "0";
        }
        uint256 j = _i;
        uint256 len;
        while (j != 0) {
            ++len;
            j /= 10;
        }
        bytes memory bstr = new bytes(len);
        uint256 k = len;
        while (_i != 0) {
            k = k - 1;
            uint8 temp = (48 + uint8(_i - (_i / 10) * 10));
            bytes1 b1 = bytes1(temp);
            bstr[k] = b1;
            _i /= 10;
        }
        return string(bstr);
    }

    /// @dev Get the smallest non zero number
    function minGt0(uint8 one, uint8 two) internal pure returns (uint8) {
        return one > two ? two > 0 ? two : one : one;
    }

    /// @dev Get the smaller number
    function min(uint8 one, uint8 two) internal pure returns (uint8) {
        return one < two ? one : two;
    }

    /// @dev Get the larger number
    function max(uint8 one, uint8 two) internal pure returns (uint8) {
        return one > two ? one : two;
    }

    /// @dev Get the average between two numbers
    function avg(uint8 one, uint8 two) internal pure returns (uint8 result) {
        unchecked {
            result = (one >> 1) + (two >> 1) + (one & two & 1);
        }
    }

    /// @dev Get the days since another date (input is seconds)
    function day(uint256 from, uint256 to) internal pure returns (uint24) {
        return uint24((to - from) / 24 hours + 1);
    }
}

// OpenZeppelin Contracts (last updated v4.8.0) (token/ERC721/WARPS721.sol)

pragma solidity ^0.8.0;

import "lib/openzeppelin-contracts/contracts/token/ERC721/IERC721.sol";
import "lib/openzeppelin-contracts/contracts/token/ERC721/IERC721Receiver.sol";
import "lib/openzeppelin-contracts/contracts/token/ERC721/extensions/IERC721Metadata.sol";
import "lib/openzeppelin-contracts/contracts/token/ERC721/extensions/IERC721Enumerable.sol";
import "lib/openzeppelin-contracts/contracts/utils/Address.sol";
import "lib/openzeppelin-contracts/contracts/utils/Context.sol";
import "lib/openzeppelin-contracts/contracts/utils/Strings.sol";
import "lib/openzeppelin-contracts/contracts/utils/introspection/ERC165.sol";
import "../interfaces/IERC4906.sol";

/**
 * @dev Implementation of https://eips.ethereum.org/EIPS/eip-721[ERC721] Non-Fungible Token Standard, including
 * the Metadata extension and the Enumerable extension.
 */
contract WARPS721 is Context, ERC165, IERC721, IERC721Metadata, IERC721Enumerable, IERC4906 {
    error ERC721__InvalidApproval();
    error ERC721__InvalidOwner();
    error ERC721__InvalidToken();
    error ERC721__NotAllowed();
    error ERC721__TokenExists();
    error ERC721__TransferToNonReceiver();
    error ERC721__TransferToZero();

    using Address for address;
    using Strings for uint256;

    // Token name
    string private _name;

    // Token symbol
    string private _symbol;

    // Mapping from token ID to owner address
    mapping(uint256 => address) private _owners;

    // Mapping owner address to token count
    mapping(address => uint256) private _balances;

    // Mapping from token ID to approved address
    mapping(uint256 => address) private _tokenApprovals;

    // Mapping from owner to operator approvals
    mapping(address => mapping(address => bool)) private _operatorApprovals;

    // Enumerable mappings
    // Mapping from owner to list of owned token IDs
    mapping(address => mapping(uint256 => uint256)) private _ownedTokens;

    // Mapping from token ID to index of the owner tokens list
    mapping(uint256 => uint256) private _ownedTokensIndex;

    // Array with all token ids, used for enumeration
    uint256[] private _allTokens;

    // Mapping from token id to position in the allTokens array
    mapping(uint256 => uint256) private _allTokensIndex;

    /**
     * @dev Initializes the contract by setting a `name` and a `symbol` to the token collection.
     */
    constructor() {
        _name = "Warps";
        _symbol = "WARPS";
    }

    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override(ERC165, IERC165) returns (bool) {
        return interfaceId == type(IERC721).interfaceId || interfaceId == type(IERC721Metadata).interfaceId
            || interfaceId == type(IERC721Enumerable).interfaceId || super.supportsInterface(interfaceId);
    }

    /**
     * @dev See {IERC721-balanceOf}.
     */
    function balanceOf(address owner) public view virtual override returns (uint256) {
        if (owner == address(0)) {
            revert ERC721__InvalidOwner();
        }
        return _balances[owner];
    }

    /**
     * @dev See {IERC721-ownerOf}.
     */
    function ownerOf(uint256 tokenId) public view virtual override returns (address) {
        address owner = _ownerOf(tokenId);
        if (owner == address(0)) {
            revert ERC721__InvalidToken();
        }
        return owner;
    }

    /**
     * @dev See {IERC721Metadata-name}.
     */
    function name() public view virtual override returns (string memory) {
        return _name;
    }

    /**
     * @dev See {IERC721Metadata-symbol}.
     */
    function symbol() public view virtual override returns (string memory) {
        return _symbol;
    }

    /**
     * @dev See {IERC721Metadata-tokenURI}.
     */
    function tokenURI(uint256 tokenId) public view virtual override returns (string memory) {
        _requireMinted(tokenId);

        return "";
    }

    /**
     * @dev See {IERC721-approve}.
     */
    function approve(address to, uint256 tokenId) public virtual override {
        address owner = WARPS721.ownerOf(tokenId);

        if (to == owner || (_msgSender() != owner && !isApprovedForAll(owner, _msgSender()))) {
            revert ERC721__InvalidApproval();
        }

        _approve(to, tokenId);
    }

    /**
     * @dev See {IERC721-getApproved}.
     */
    function getApproved(uint256 tokenId) public view virtual override returns (address) {
        _requireMinted(tokenId);

        return _tokenApprovals[tokenId];
    }

    /**
     * @dev See {IERC721-setApprovalForAll}.
     */
    function setApprovalForAll(address operator, bool approved) public virtual override {
        _setApprovalForAll(_msgSender(), operator, approved);
    }

    /**
     * @dev See {IERC721-isApprovedForAll}.
     */
    function isApprovedForAll(address owner, address operator) public view virtual override returns (bool) {
        return _operatorApprovals[owner][operator];
    }

    /**
     * @dev See {IERC721-transferFrom}.
     */
    function transferFrom(address from, address to, uint256 tokenId) public virtual override {
        if (!_isApprovedOrOwner(_msgSender(), tokenId)) {
            revert ERC721__NotAllowed();
        }

        _transfer(from, to, tokenId);
    }

    /**
     * @dev See {IERC721-safeTransferFrom}.
     */
    function safeTransferFrom(address from, address to, uint256 tokenId) public virtual override {
        safeTransferFrom(from, to, tokenId, "");
    }

    /**
     * @dev See {IERC721-safeTransferFrom}.
     */
    function safeTransferFrom(address from, address to, uint256 tokenId, bytes memory data) public virtual override {
        if (!_isApprovedOrOwner(_msgSender(), tokenId)) {
            revert ERC721__NotAllowed();
        }
        _safeTransfer(from, to, tokenId, data);
    }

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`, checking first that contract recipients
     * are aware of the ERC721 protocol to prevent tokens from being forever locked.
     *
     * `data` is additional data, it has no specified format and it is sent in call to `to`.
     *
     * This internal function is equivalent to {safeTransferFrom}, and can be used to e.g.
     * implement alternative mechanisms to perform token transfer, such as signature-based.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function _safeTransfer(address from, address to, uint256 tokenId, bytes memory data) internal virtual {
        _transfer(from, to, tokenId);
        if (!_checkOnERC721Received(from, to, tokenId, data)) {
            revert ERC721__TransferToNonReceiver();
        }
    }

    /**
     * @dev Returns the owner of the `tokenId`. Does NOT revert if token doesn't exist
     */
    function _ownerOf(uint256 tokenId) internal view virtual returns (address) {
        return _owners[tokenId];
    }

    /**
     * @dev Returns whether `tokenId` exists.
     *
     * Tokens can be managed by their owner or approved accounts via {approve} or {setApprovalForAll}.
     *
     * Tokens start existing when they are minted (`_mint`),
     * and stop existing when they are burned (`_burn`).
     */
    function _exists(uint256 tokenId) internal view virtual returns (bool) {
        return _ownerOf(tokenId) != address(0);
    }

    /**
     * @dev Returns whether `spender` is allowed to manage `tokenId`.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function _isApprovedOrOwner(address spender, uint256 tokenId) internal view virtual returns (bool) {
        address owner = WARPS721.ownerOf(tokenId);
        return (spender == owner || isApprovedForAll(owner, spender) || getApproved(tokenId) == spender);
    }

    /**
     * @dev Safely mints `tokenId` and transfers it to `to`.
     *
     * Requirements:
     *
     * - `tokenId` must not exist.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function _safeMint(address to, uint256 tokenId) internal virtual {
        _safeMint(to, tokenId, "");
    }

    /**
     * @dev Same as {xref-ERC721-_safeMint-address-uint256-}[`_safeMint`], with an additional `data` parameter which is
     * forwarded in {IERC721Receiver-onERC721Received} to contract recipients.
     */
    function _safeMint(address to, uint256 tokenId, bytes memory data) internal virtual {
        _mint(to, tokenId);
        if (!_checkOnERC721Received(address(0), to, tokenId, data)) {
            revert ERC721__TransferToNonReceiver();
        }
    }

    /**
     * @dev Safely mints `tokenId` and transfers it to `to` after an inital transfer to `via`.
     *
     * Requirements:
     *
     * - `tokenId` must not exist.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function _safeMintVia(address to, address via, uint256 tokenId) internal virtual {
        _safeMintVia(to, via, tokenId, "");
    }

    /**
     * @dev Same as {xref-ERC721-_safeMint-address-uint256-}[`_safeMint`], with an additional `data` parameter which is
     * forwarded in {IERC721Receiver-onERC721Received} to contract recipients.
     */
    function _safeMintVia(address to, address via, uint256 tokenId, bytes memory data) internal virtual {
        _mintVia(to, via, tokenId);
        if (!_checkOnERC721Received(address(0), to, tokenId, data)) {
            revert ERC721__TransferToNonReceiver();
        }
    }

    /**
     * @dev Mints `tokenId` and transfers it to `to`.
     *
     * WARNING: Usage of this method is discouraged, use {_safeMint} whenever possible
     *
     * Requirements:
     *
     * - `tokenId` must not exist.
     * - `to` cannot be the zero address.
     *
     * Emits a {Transfer} event.
     */
    function _mint(address to, uint256 tokenId) internal virtual {
        _mintState(to, tokenId);

        emit Transfer(address(0), to, tokenId);

        _afterTokenTransfer(address(0), to, tokenId, 1);
    }

    /**
     * @dev Mints `tokenId` and transfers it to `to` after a transfer to `via`
     *
     * WARNING: Usage of this method is discouraged, use {_safeMint} whenever possible
     *
     * Requirements:
     *
     * - `tokenId` must not exist.
     * - `to` cannot be the zero address.
     *
     * Emits a {Transfer} event.
     */
    function _mintVia(address to, address via, uint256 tokenId) internal virtual {
        _mintState(to, tokenId);

        emit Transfer(address(0), via, tokenId);
        emit Transfer(via, to, tokenId);

        _afterTokenTransfer(address(0), to, tokenId, 1);
    }

    /**
     * @dev Mints `tokenId` and transfers it to `to`.
     *
     * WARNING: Usage of this method is discouraged, use {_safeMint} whenever possible
     *
     * Requirements:
     *
     * - `tokenId` must not exist.
     * - `to` cannot be the zero address.
     */
    function _mintState(address to, uint256 tokenId) internal virtual {
        if (to == address(0)) {
            revert ERC721__TransferToZero();
        }
        if (_exists(tokenId)) {
            revert ERC721__TokenExists();
        }

        _beforeTokenTransfer(address(0), to, tokenId, 1);

        // Check that tokenId was not minted by `_beforeTokenTransfer` hook
        if (_exists(tokenId)) {
            revert ERC721__TokenExists();
        }

        unchecked {
            // Will not overflow unless all 2**256 token ids are minted to the same owner.
            // Given that tokens are minted one by one, it is impossible in practice that
            // this ever happens. Might change if we allow batch minting.
            // The ERC fails to describe this case.
            _balances[to] += 1;
        }

        _owners[tokenId] = to;
    }

    /**
     * @dev Destroys `tokenId`.
     * The approval is cleared when the token is burned.
     * This is an internal function that does not check if the sender is authorized to operate on the token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     *
     * Emits a {Transfer} event.
     */
    function _burn(uint256 tokenId) internal virtual {
        address owner = WARPS721.ownerOf(tokenId);

        _beforeTokenTransfer(owner, address(0), tokenId, 1);

        // Update ownership in case tokenId was transferred by `_beforeTokenTransfer` hook
        owner = WARPS721.ownerOf(tokenId);

        // Clear approvals
        delete _tokenApprovals[tokenId];

        unchecked {
            // Cannot overflow, as that would require more tokens to be burned/transferred
            // out than the owner initially received through minting and transferring in.
            _balances[owner] -= 1;
        }
        delete _owners[tokenId];

        emit Transfer(owner, address(0), tokenId);

        _afterTokenTransfer(owner, address(0), tokenId, 1);
    }

    /**
     * @dev Transfers `tokenId` from `from` to `to`.
     *  As opposed to {transferFrom}, this imposes no restrictions on msg.sender.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     * - `tokenId` token must be owned by `from`.
     *
     * Emits a {Transfer} event.
     */
    function _transfer(address from, address to, uint256 tokenId) internal virtual {
        if (WARPS721.ownerOf(tokenId) != from) {
            revert ERC721__InvalidOwner();
        }
        if (to == address(0)) {
            revert ERC721__TransferToZero();
        }

        _beforeTokenTransfer(from, to, tokenId, 1);

        // Check that tokenId was not transferred by `_beforeTokenTransfer` hook
        if (WARPS721.ownerOf(tokenId) != from) {
            revert ERC721__InvalidOwner();
        }

        // Clear approvals from the previous owner
        delete _tokenApprovals[tokenId];

        unchecked {
            // `_balances[from]` cannot overflow for the same reason as described in `_burn`:
            // `from`'s balance is the number of token held, which is at least one before the current
            // transfer.
            // `_balances[to]` could overflow in the conditions described in `_mint`. That would require
            // all 2**256 token ids to be minted, which in practice is impossible.
            _balances[from] -= 1;
            _balances[to] += 1;
        }
        _owners[tokenId] = to;

        emit Transfer(from, to, tokenId);

        _afterTokenTransfer(from, to, tokenId, 1);
    }

    /**
     * @dev Approve `to` to operate on `tokenId`
     *
     * Emits an {Approval} event.
     */
    function _approve(address to, uint256 tokenId) internal virtual {
        _tokenApprovals[tokenId] = to;
        emit Approval(WARPS721.ownerOf(tokenId), to, tokenId);
    }

    /**
     * @dev Approve `operator` to operate on all of `owner` tokens
     *
     * Emits an {ApprovalForAll} event.
     */
    function _setApprovalForAll(address owner, address operator, bool approved) internal virtual {
        if (owner == operator) {
            revert ERC721__InvalidApproval();
        }
        _operatorApprovals[owner][operator] = approved;
        emit ApprovalForAll(owner, operator, approved);
    }

    /**
     * @dev Reverts if the `tokenId` has not been minted yet.
     */
    function _requireMinted(uint256 tokenId) internal view virtual {
        if (!_exists(tokenId)) {
            revert ERC721__InvalidToken();
        }
    }

    /**
     * @dev Internal function to invoke {IERC721Receiver-onERC721Received} on a target address.
     * The call is not executed if the target address is not a contract.
     *
     * @param from address representing the previous owner of the given token ID
     * @param to target address that will receive the tokens
     * @param tokenId uint256 ID of the token to be transferred
     * @param data bytes optional data to send along with the call
     * @return bool whether the call correctly returned the expected magic value
     */
    function _checkOnERC721Received(address from, address to, uint256 tokenId, bytes memory data)
        private
        returns (bool)
    {
        if (_isContract(to)) {
            try IERC721Receiver(to).onERC721Received(_msgSender(), from, tokenId, data) returns (bytes4 retval) {
                return retval == IERC721Receiver.onERC721Received.selector;
            } catch (bytes memory reason) {
                if (reason.length == 0) {
                    revert ERC721__TransferToNonReceiver();
                } else {
                    /// @solidity memory-safe-assembly
                    assembly {
                        revert(add(32, reason), mload(reason))
                    }
                }
            }
        } else {
            return true;
        }
    }

    /**
     * @dev Hook that is called before any token transfer. This includes minting and burning.
     */
    function _beforeTokenTransfer(address from, address to, uint256 firstTokenId, uint256 batchSize) internal virtual {
        if (batchSize > 1) {
            if (from != address(0)) {
                _balances[from] -= batchSize;
            }
            if (to != address(0)) {
                _balances[to] += batchSize;
            }
        }

        if (from == address(0)) {
            _addTokenToAllTokensEnumeration(firstTokenId);
        } else if (from != to) {
            _removeTokenFromOwnerEnumeration(from, firstTokenId);
        }
        if (to == address(0)) {
            _removeTokenFromAllTokensEnumeration(firstTokenId);
        } else if (to != from) {
            _addTokenToOwnerEnumeration(to, firstTokenId);
        }
    }

    /**
     * @dev Hook that is called after any token transfer. This includes minting and burning.
     */
    function _afterTokenTransfer(address from, address to, uint256 firstTokenId, uint256 batchSize) internal virtual {}

    /**
     * @dev Returns true if `account` is a contract.
     *
     * This function is a direct replacement for the Address.isContract function
     * from OpenZeppelin's Address utility.
     */
    function _isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize/address.code.length, which returns 0
        // for contracts in construction, since the code is only stored at the end
        // of the constructor execution.
        return account.code.length > 0;
    }

    /**
     * @dev See {IERC721Enumerable-totalSupply}.
     */
    function totalSupply() public view virtual override returns (uint256) {
        return _allTokens.length;
    }

    /**
     * @dev See {IERC721Enumerable-tokenByIndex}.
     */
    function tokenByIndex(uint256 index) public view virtual override returns (uint256) {
        if (index >= totalSupply()) {
            revert ERC721__InvalidToken();
        }
        return _allTokens[index];
    }

    /**
     * @dev See {IERC721Enumerable-tokenOfOwnerByIndex}.
     */
    function tokenOfOwnerByIndex(address owner, uint256 index) public view virtual override returns (uint256) {
        if (index >= balanceOf(owner)) {
            revert ERC721__InvalidToken();
        }
        return _ownedTokens[owner][index];
    }

    /**
     * @dev Private function to add a token to this extension's ownership-tracking data structures.
     * @param to address representing the new owner of the given token ID
     * @param tokenId uint256 ID of the token to be added to the tokens list of the given address
     */
    function _addTokenToOwnerEnumeration(address to, uint256 tokenId) private {
        uint256 length = balanceOf(to);
        _ownedTokens[to][length] = tokenId;
        _ownedTokensIndex[tokenId] = length;
    }

    /**
     * @dev Private function to add a token to this extension's token tracking data structures.
     * @param tokenId uint256 ID of the token to be added to the tokens list
     */
    function _addTokenToAllTokensEnumeration(uint256 tokenId) private {
        _allTokensIndex[tokenId] = _allTokens.length;
        _allTokens.push(tokenId);
    }

    /**
     * @dev Private function to remove a token from this extension's ownership-tracking data structures.
     * @param from address representing the previous owner of the given token ID
     * @param tokenId uint256 ID of the token to be removed from the tokens list of the given address
     */
    function _removeTokenFromOwnerEnumeration(address from, uint256 tokenId) private {
        // To prevent a gap in from's tokens array, we store the last token in the index of the token to delete, and
        // then delete the last slot (swap and pop).

        uint256 lastTokenIndex = balanceOf(from) - 1;
        uint256 tokenIndex = _ownedTokensIndex[tokenId];

        // When the token to delete is the last token, the swap operation is unnecessary
        if (tokenIndex != lastTokenIndex) {
            uint256 lastTokenId = _ownedTokens[from][lastTokenIndex];

            _ownedTokens[from][tokenIndex] = lastTokenId; // Move the last token to the slot of the to-delete token
            _ownedTokensIndex[lastTokenId] = tokenIndex; // Update the moved token's index
        }

        // This also deletes the contents at the last position of the array
        delete _ownedTokens[from][lastTokenIndex];
        delete _ownedTokensIndex[tokenId];
    }

    /**
     * @dev Private function to remove a token from this extension's token tracking data structures.
     * @param tokenId uint256 ID of the token to be removed from the tokens list
     */
    function _removeTokenFromAllTokensEnumeration(uint256 tokenId) private {
        // To prevent a gap in the tokens array, we store the last token in the index of the token to delete, and
        // then delete the last slot (swap and pop).

        uint256 lastTokenIndex = _allTokens.length - 1;
        uint256 tokenIndex = _allTokensIndex[tokenId];

        // When the token to delete is the last token, the swap operation is unnecessary. However, since this occurs so
        // rarely (when the last minted token is burnt) that we still do the swap here to avoid the gas cost of adding
        // an 'if' statement (like in _removeTokenFromOwnerEnumeration)
        uint256 lastTokenId = _allTokens[lastTokenIndex];

        _allTokens[tokenIndex] = lastTokenId; // Move the last token to the slot of the to-delete token
        _allTokensIndex[lastTokenId] = tokenIndex; // Update the moved token's index

        // This also deletes the contents at the last position of the array
        _allTokens.pop();
        delete _allTokensIndex[tokenId];
    }
}

//SPDX-License-Identifier: MIT
pragma solidity ^0.8.17;

/**
 * @title  WarpColors
 * @author Hurls
 * @notice The ten colors of Warps.
 */
library WarpColors {
    /// @dev These are sorted by brand.
    function colors() public pure returns (string[5] memory) {
        return [
            "FF007A", // Uniswap
            "855DCD", // Farcaster
            "FF9900", // Bitcoin
            "52b043", // XBOX
            "1da1f2" // Twitter
        ];
    }

    /**
     * @notice Get the color string at a specific index.
     * @param _index The index (0-4) of the color to retrieve.
     * @return The hex string of the color at the specified index.
     * @dev Reverts if the index is out of bounds.
     */
    function getColorByIndex(uint8 _index) public pure returns (string memory) {
        require(_index < 5, "Index out of bounds");
        return colors()[_index];
    }

    /**
     * @notice Get the index of a specific color string.
     * @param _color The hex string of the color to find.
     * @return The index (0-4) of the color.
     * @dev Reverts if the color is not found in the list.
     */
    function getIndexByColor(string memory _color) public pure returns (uint8) {
        string[5] memory _colors = colors();
        bytes32 colorHash = keccak256(abi.encodePacked(_color));

        for (uint8 i = 0; i < 5; i++) {
            if (keccak256(abi.encodePacked(_colors[i])) == colorHash) {
                return i;
            }
        }
        revert("Color not found");
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.17;

import "./interfaces/IWarps.sol";
import "./libraries/WarpsArt.sol";
import "./libraries/WarpsMetadata.sol";
import "./libraries/WarpColors.sol";
import "./libraries/Utilities.sol";
import "./standards/WARPS721.sol";
import "lib/openzeppelin-contracts/contracts/access/Ownable.sol";
import "lib/openzeppelin-contracts/contracts/token/ERC20/IERC20.sol";
import "lib/openzeppelin-contracts/contracts/security/Pausable.sol";

/**
 * @title  Warps
 * @author Hurls
 * @notice Up and to the right.
 */
contract Warps is IWarps, WARPS721, Ownable, Pausable {
    event MintPriceUpdated(uint256 newPrice);
    event MintLimitUpdated(uint8 newLimit);
    event PrizeClaimed(uint256 tokenId, address winner, uint256 amount);
    event PrizePoolUpdated(uint256 totalDeposited);
    event EmergencyWithdrawn(uint256 amount);
    event TokensMinted(address indexed recipient, uint256 startTokenId, uint256 count);
    event TokensComposited(uint256 indexed keptTokenId, uint256 indexed burnedTokenId);
    event TokenBurned(uint256 indexed tokenId, address indexed burner);
    event WinningColorIndexUpdated(uint8 newIndex);
    event PaymentTokenSet(address indexed tokenAddress, uint256 mintPrice);
    event OwnerMintSharePercentageUpdated(uint8 newPercentage);
    event WinnerClaimPercentageUpdated(uint8 newPercentage);
    event WinningColorSet(string colorHex, uint8 colorIndex);
    event FreeMintUsed(address indexed recipient);
    event TokensDeposited(address indexed sender, uint256 amount);
    event ContractPaused(address indexed pauser);
    event ContractUnpaused(address indexed unpauser);

    uint8 public mintLimit = 4;
    uint256 public constant MAX_COMPOSITE_LEVEL = 5;
    uint256 public mintPrice;
    uint256 public tokenMintId = 0;
    IERC20 public paymentToken;

    /// @dev We use this database for persistent storage.
    Warps _warpsData;

    // Prize pool state
    struct PrizePool {
        uint32 lastWinnerClaim;
        uint256 totalDeposited;
        uint256 actualAvailable; // Tracks the real available amount after owner shares
    }

    PrizePool public prizePool;
    uint8 public winningColorIndex;
    uint8 public ownerMintSharePercentage;
    uint8 public winnerClaimPercentage;

    // Track addresses that have already used their free mint
    mapping(address => bool) public hasUsedFreeMint;

    // Store token metadata directly instead of using epochs
    struct TokenMetadata {
        uint256 seed; // The final seed used for randomization
        uint8[5] colorBands; // Color band values - Note: These seem unused now, consider removal?
        uint8[5] gradients; // Gradient values - Note: These seem unused now, consider removal?
    }

    mapping(uint256 => TokenMetadata) private _tokenMetadata;

    // Add on-chain palette storage per token
    struct Palette {
        uint8 len; // 3 → 2 → 1
        uint24[3] colors; // unused slots stay 0
    }

    mapping(uint256 => Palette) private _palette;

    /// @notice Get the total amount deposited in the prize pool
    /// @return The total amount deposited
    function getTotalDeposited() public view returns (uint256) {
        return prizePool.totalDeposited;
    }

    /// @notice Get the actual available amount in the prize pool for prizes
    /// @return The actual available amount for prizes
    function getActualAvailable() public view returns (uint256) {
        return prizePool.actualAvailable;
    }

    /// @dev Initializes the Warps contract and links the Edition contract.
    constructor() Ownable() {
        _warpsData.minted = 0;
        _warpsData.burned = 0;
        prizePool.lastWinnerClaim = 0;
        prizePool.actualAvailable = 0;
        winningColorIndex = 2; // Set to Bitcoin (FF9900) at index 2
        ownerMintSharePercentage = 40;
        winnerClaimPercentage = 5;
    }

    /// @notice Pauses the contract, preventing certain operations
    /// @dev Can only be called by the contract owner
    function pause() external onlyOwner {
        _pause();
        emit ContractPaused(msg.sender);
    }

    /// @notice Unpauses the contract, allowing operations to resume
    /// @dev Can only be called by the contract owner
    function unpause() external onlyOwner {
        _unpause();
        emit ContractUnpaused(msg.sender);
    }

    /// @notice Allow users to deposit tokens to the contract for minting
    /// @param amount The amount of tokens to deposit
    function depositTokens(uint256 amount) external whenNotPaused {
        require(address(paymentToken) != address(0), "Payment token not set");
        require(amount > 0, "Amount must be greater than 0");

        // Check if user has approved the contract to spend their tokens
        uint256 allowance = paymentToken.allowance(msg.sender, address(this));
        require(allowance >= amount, "Check allowance");

        // Transfer tokens from the user to this contract
        bool success = paymentToken.transferFrom(msg.sender, address(this), amount);
        require(success, "ERC20 transfer failed");

        // Add the full amount to both prize pool trackers
        prizePool.totalDeposited += amount;
        prizePool.actualAvailable += amount;

        emit TokensDeposited(msg.sender, amount);
        emit PrizePoolUpdated(prizePool.totalDeposited);
    }

    /// @notice Update the mint price (in terms of the payment token)
    /// @param newPrice The new price in the smallest unit of the payment token
    function updateMintPrice(uint256 newPrice) external onlyOwner {
        require(address(paymentToken) != address(0), "Payment token not set");
        mintPrice = newPrice;
        emit MintPriceUpdated(newPrice);
    }

    /// @notice Sets the ERC20 token used for payments and its mint price.
    /// @param _tokenAddress The address of the ERC20 token contract.
    /// @param _mintPrice The price to mint tokens, in the smallest unit of the ERC20 token.
    function setPaymentToken(address _tokenAddress, uint256 _mintPrice) external onlyOwner {
        require(_tokenAddress != address(0), "Invalid token address");
        paymentToken = IERC20(_tokenAddress);
        mintPrice = _mintPrice;
        emit PaymentTokenSet(_tokenAddress, _mintPrice);
        emit MintPriceUpdated(_mintPrice);
    }

    /// @notice Update the mint limit
    /// @param newLimit The new limit of tokens per mint
    function updateMintLimit(uint8 newLimit) external onlyOwner {
        require(newLimit > 0 && newLimit <= 100, "Invalid limit");
        mintLimit = newLimit;
        emit MintLimitUpdated(newLimit);
    }

    /// @notice Update the owner's percentage share received on each mint
    /// @param newPercentage The new percentage (0-99)
    function updateOwnerMintSharePercentage(uint8 newPercentage) external onlyOwner {
        require(newPercentage < 100, "Percentage must be < 100");
        ownerMintSharePercentage = newPercentage;
        emit OwnerMintSharePercentageUpdated(newPercentage);
    }

    /// @notice Update the winner's percentage share of the current prize pool upon claim
    /// @param newPercentage The new percentage (1-100)
    function updateWinnerClaimPercentage(uint8 newPercentage) external onlyOwner {
        require(newPercentage > 0 && newPercentage <= 100, "Percentage must be 1-100");
        winnerClaimPercentage = newPercentage;
        emit WinnerClaimPercentageUpdated(newPercentage);
    }

    /// @notice Generate randomness for a token at mint time
    /// @param tokenId The token ID to generate randomness for
    function _generateTokenRandomness(uint256 tokenId) internal {
        uint256 seed = uint256(
            keccak256(abi.encodePacked(block.timestamp, block.prevrandao, tokenId, msg.sender, _warpsData.minted))
        ) % type(uint128).max;

        // Store the seed for this token
        _tokenMetadata[tokenId].seed = seed;

        // Extract non-contiguous bytes to reduce correlation
        uint8 n1 = uint8(seed & 0xFF); // byte 0
        uint8 n2 = uint8((seed >> 56) & 0xFF); // byte 7

        // Scale to maintain original rarity distributions
        uint8 scaledN1 = uint8((uint256(n1) * 120) / 255);
        uint8 scaledN2 = uint8((uint256(n2) * 100) / 255);

        // Apply thresholds using scaled values
        uint8 colorBand = scaledN1 > 20
            ? 0
            : scaledN1 > 10 ? 1 : scaledN1 > 5 ? 2 : scaledN1 > 2 ? 3 : scaledN1 > 1 ? 4 : scaledN1 > 0 ? 5 : 6;

        uint8 gradient = scaledN2 < 20 ? uint8(1 + (scaledN2 % 6)) : 0;

        // Store the initial values
        _warpsData.all[tokenId].colorBands[0] = colorBand;
        _warpsData.all[tokenId].gradients[0] = gradient;
    }

    /// @notice Mint new Warps tokens using the specified ERC20 payment token
    /// @param recipient The address to receive the tokens
    function mint(address recipient) external whenNotPaused {
        require(address(paymentToken) != address(0), "Payment token not set");
        require(recipient != address(0), "Invalid recipient");

        uint256 requiredAmount = mintPrice;
        require(requiredAmount > 0, "Mint price cannot be zero");

        // Process payment by default
        uint256 allowance = paymentToken.allowance(msg.sender, address(this));
        require(allowance >= requiredAmount, "Check allowance");
        bool success = paymentToken.transferFrom(msg.sender, address(this), requiredAmount);
        require(success, "ERC20 transfer failed (minter -> contract)");

        uint256 ownerShareAmount = (requiredAmount * ownerMintSharePercentage) / 100;
        uint256 prizePoolAmount = requiredAmount - ownerShareAmount;

        if (ownerShareAmount > 0) {
            bool ownerTransferSuccess = paymentToken.transfer(owner(), ownerShareAmount);
            require(ownerTransferSuccess, "ERC20 transfer failed (contract -> owner)");
        }

        // Add total amount to totalDeposited (for test compatibility)
        prizePool.totalDeposited += requiredAmount;
        // Track the actual available amount separately
        prizePool.actualAvailable += prizePoolAmount;
        emit PrizePoolUpdated(prizePool.totalDeposited);

        uint256 startTokenId = tokenMintId;

        for (uint256 i; i < mintLimit;) {
            uint256 id = tokenMintId++;

            StoredWarp storage warp = _warpsData.all[id];
            warp.seed = uint16(id);
            warp.divisorIndex = 0;

            _generateTokenRandomness(id);

            _safeMint(recipient, id);
            _initPalette(id, recipient);

            unchecked {
                ++i;
            }
        }

        unchecked {
            _warpsData.minted += uint32(mintLimit);
        }

        emit TokensMinted(recipient, startTokenId, mintLimit);
    }

    /// @notice Mint new Warps tokens with a free mint if available
    /// @param recipient The address to receive the tokens
    function freeMint(address recipient) external whenNotPaused {
        require(address(paymentToken) != address(0), "Payment token not set");
        require(recipient != address(0), "Invalid recipient");
        require(!hasUsedFreeMint[msg.sender], "Free mint already used");

        // Mark that this address has used its free mint
        hasUsedFreeMint[msg.sender] = true;
        emit FreeMintUsed(msg.sender);

        uint256 startTokenId = tokenMintId;

        for (uint256 i; i < mintLimit;) {
            uint256 id = tokenMintId++;

            StoredWarp storage warp = _warpsData.all[id];
            warp.seed = uint16(id);
            warp.divisorIndex = 0;

            _generateTokenRandomness(id);

            _safeMint(recipient, id);
            _initPalette(id, recipient);

            unchecked {
                ++i;
            }
        }

        unchecked {
            _warpsData.minted += uint32(mintLimit);
        }

        emit TokensMinted(recipient, startTokenId, mintLimit);
    }

    /// @notice Composite one token into another, mixing visuals and reducing warp count
    /// @param tokenId The token ID to keep alive (its visual will change)
    /// @param burnId The token ID to composite into the kept token
    function composite(uint256 tokenId, uint256 burnId) external whenNotPaused {
        _composite(tokenId, burnId);
        unchecked {
            ++_warpsData.burned;
        }
        emit TokensComposited(tokenId, burnId);
    }

    /// @notice Burn a single warp token without compositing
    /// @param tokenId The token ID to burn
    /// @dev This is a common purpose burn method that does not affect other tokens
    function burn(uint256 tokenId) external whenNotPaused {
        if (!_isApprovedOrOwner(msg.sender, tokenId)) {
            revert NotAllowed();
        }

        _burn(tokenId);
        unchecked {
            ++_warpsData.burned;
        }
        emit TokenBurned(tokenId, msg.sender);
    }

    /// @notice Get the metadata URI for a token
    /// @param tokenId The token ID to get metadata for
    /// @return The metadata URI string
    function tokenURI(uint256 tokenId) public view override returns (string memory) {
        _requireMinted(tokenId);

        // Build warp object
        IWarps.Warp memory warp = WarpsArt.getWarp(tokenId, _warpsData);

        // Load palette
        Palette storage palStore = _palette[tokenId];
        uint24[] memory pal = new uint24[](palStore.len);
        for (uint8 i; i < palStore.len; ++i) {
            pal[i] = palStore.colors[i];
        }

        // Generate SVG based on palette (fallback to default if none)
        bytes memory staticSvg = pal.length > 0
            ? WarpsArt.generateSVGWithPalette(warp, _warpsData, pal)
            : WarpsArt.generateSVG(warp, _warpsData);

        // Prepare JSON metadata
        bytes memory metadata = abi.encodePacked(
            "{",
            '"name": "Warps ',
            Utilities.uint2str(tokenId),
            '",',
            '"description": "Up and to the right.",',
            '"image": ',
            '"data:image/svg+xml;base64,',
            Base64.encode(staticSvg),
            '",',
            '"attributes": [',
            WarpsMetadata.attributes(warp),
            "]",
            "}"
        );

        return string(abi.encodePacked("data:application/json;base64,", Base64.encode(metadata)));
    }

    /// @dev Get warp with the stored seed instead of epoch-based randomness
    function _getWarpWithSeed(uint256 tokenId) internal view returns (IWarps.Warp memory) {
        IWarps.Warp memory warp = WarpsArt.getWarp(tokenId, _warpsData);

        // Override the seed with our stored seed
        if (_tokenMetadata[tokenId].seed != 0) {
            warp.seed = _tokenMetadata[tokenId].seed;
        }

        return warp;
    }

    /// @dev Composite one token into to another and burn it.
    /// @param tokenId The token ID to keep. Its art and warp-count will change.
    /// @param burnId The token ID to burn in the process.
    function _composite(uint256 tokenId, uint256 burnId) internal {
        (StoredWarp storage toKeep,, uint8 divisorIndex) = _tokenOperation(tokenId, burnId);

        uint8 nextDivisor = divisorIndex + 1;

        // Declare gradient and colorBand outside the conditional block
        uint8 gradient = 0;
        uint8 colorBand = 0;

        // We only need to breed band + gradient up until 4-Warps.
        if (divisorIndex < 5) {
            // Assign values from _compositeGenes
            (gradient, colorBand) = _compositeGenes(tokenId, burnId);

            toKeep.colorBands[divisorIndex] = colorBand;
            toKeep.gradients[divisorIndex] = gradient;
        }

        // Update on-chain palette before finalizing composite
        _updatePaletteOnComposite(tokenId, burnId, divisorIndex);

        // Composite our warp
        toKeep.composites[divisorIndex] = uint16(burnId);
        toKeep.divisorIndex = nextDivisor;

        // Generate new seed based on parents' seeds and resulting genes
        uint256 newSeed = uint256(
            keccak256(
                abi.encodePacked(
                    _tokenMetadata[tokenId].seed,
                    _tokenMetadata[burnId].seed,
                    gradient, // Use resulting gradient
                    colorBand // Use resulting colorBand
                )
            )
        ) % type(uint128).max;

        _tokenMetadata[tokenId].seed = newSeed;

        // Perform the burn.
        _burn(burnId);

        // Notify DAPPs about the Composite.
        emit Composite(tokenId, burnId, WarpsArt.divisors()[toKeep.divisorIndex]);
        emit MetadataUpdate(tokenId);
    }

    /// @dev Composite the gradient and colorBand settings.
    /// @param tokenId The token ID to keep.
    /// @param burnId The token ID to burn.
    function _compositeGenes(uint256 tokenId, uint256 burnId) internal view returns (uint8 gradient, uint8 colorBand) {
        Warp memory keeper = _getWarpWithSeed(tokenId);
        Warp memory burner = _getWarpWithSeed(burnId);

        // Pseudorandom gene manipulation.
        uint256 randomizer = uint256(keccak256(abi.encodePacked(keeper.seed, burner.seed)));

        // If at least one token has a gradient, we force it in ~20% of cases.
        gradient = Utilities.random(randomizer, 100) > 80
            ? randomizer % 2 == 0
                ? Utilities.minGt0(keeper.gradient, burner.gradient)
                : Utilities.max(keeper.gradient, burner.gradient)
            : Utilities.min(keeper.gradient, burner.gradient);

        // We breed the lower end average color band when breeding.
        colorBand = Utilities.avg(keeper.colorBand, burner.colorBand);
    }

    /// @dev Make sure this is a valid request to composite/switch a token pair.
    /// @param tokenId The token ID to keep.
    /// @param burnId The token ID to burn.
    function _tokenOperation(uint256 tokenId, uint256 burnId)
        internal
        view
        returns (StoredWarp storage toKeep, StoredWarp storage toBurn, uint8 divisorIndex)
    {
        toKeep = _warpsData.all[tokenId];
        toBurn = _warpsData.all[burnId];
        divisorIndex = toKeep.divisorIndex;

        require(
            _isApprovedOrOwner(msg.sender, tokenId) && _isApprovedOrOwner(msg.sender, burnId)
                && divisorIndex == toBurn.divisorIndex && tokenId != burnId && divisorIndex <= MAX_COMPOSITE_LEVEL,
            "Invalid composite operation"
        );
    }

    /// @notice Emergency withdrawal of all contract balance
    /// @dev Only callable by the contract owner
    /// @dev Used in case of emergency to recover all funds (ERC20)
    function emergencyWithdraw() external onlyOwner {
        require(address(paymentToken) != address(0), "Payment token not set");
        uint256 balance = paymentToken.balanceOf(address(this));
        require(balance > 0, "No funds to withdraw");

        bool success = paymentToken.transfer(owner(), balance);
        require(success, "ERC20 transfer failed");

        // Reset both accounting values since all funds are withdrawn
        prizePool.totalDeposited = 0;
        prizePool.actualAvailable = 0;

        emit EmergencyWithdrawn(balance);
        emit PrizePoolUpdated(0);
    }

    /// @notice Get the current available prize pool balance (ERC20)
    /// @return The current contract balance of the payment token
    function getAvailablePrizePool() public view returns (uint256) {
        if (address(paymentToken) == address(0)) {
            return 0;
        }
        return paymentToken.balanceOf(address(this));
    }

    /// @notice Check if a token is a winning token
    /// @param tokenId The token ID to check
    /// @return bool True if the token is a winner, false otherwise
    /// @dev A token is considered a winner if it has exactly 1 warp and its first palette colour matches
    ///      the current `winningColorIndex` from `WarpColors`.
    function isWinningToken(uint256 tokenId) public view returns (bool) {
        // Ensure token exists
        if (!_exists(tokenId)) return false;

        // Winning rule still requires a single–warp token
        Warp memory warp = _getWarpWithSeed(tokenId);
        if (warp.warpsCount != 1) return false;

        // Fetch palette and ensure it is initialised
        Palette storage p = _palette[tokenId];
        if (p.len == 0) return false;

        // Compare first palette colour with the canonical winning colour code
        return p.colors[0] == _warpColorCode(winningColorIndex);
    }

    /**
     * @notice Get the current winning color string
     * @return The hex string of the current winning color
     */
    function getCurrentWinningColor() public view returns (string memory) {
        return WarpColors.colors()[winningColorIndex];
    }

    /**
     * @notice Get the color string for a given index.
     * @param _index The index (0-6) of the color to retrieve.
     * @return The hex string of the color at the specified index.
     */
    function getColorFromIndex(uint8 _index) public pure returns (string memory) {
        // Calls the function in the library
        return WarpColors.getColorByIndex(_index);
    }

    /**
     * @notice Get the index for a given color string.
     * @param _color The hex string of the color to find (must be one of the 7 colors).
     * @return The index (0-6) of the color.
     * @dev Reverts if the color is not found in the list.
     */
    function getIndexFromColor(string memory _color) public pure returns (uint8) {
        // Calls the function in the library
        return WarpColors.getIndexByColor(_color);
    }

    /// @notice Update the winning color index
    /// @param newIndex The new index (0-4) for the winning color
    function updateWinningColorIndex(uint8 newIndex) external onlyOwner {
        require(newIndex < 5, "Index must be < 5");
        winningColorIndex = newIndex;
        emit WinningColorIndexUpdated(newIndex);
    }

    /// @notice Set the winning color by providing a hex color code
    /// @param colorHex The hex string of the color (e.g., "FFA000")
    /// @dev The color must be one of the 5 predefined colors in WarpColors
    function setWinningColor(string memory colorHex) external onlyOwner {
        uint8 colorIndex = WarpColors.getIndexByColor(colorHex);
        winningColorIndex = colorIndex;
        emit WinningColorSet(colorHex, colorIndex);
        emit WinningColorIndexUpdated(colorIndex);
    }

    /// @notice Claim a prize for a winning token
    /// @param tokenId The winning token ID to burn and claim prize for
    /// @dev The token must be a winning token (have exactly 1 warp and the winning color)
    function claimPrize(uint256 tokenId) external whenNotPaused {
        require(_isApprovedOrOwner(msg.sender, tokenId), "Not token owner");
        require(isWinningToken(tokenId), "Not a winning token");
        require(address(paymentToken) != address(0), "Payment token not set");
        require(prizePool.totalDeposited > 0, "Prize pool empty");
        require(prizePool.actualAvailable > 0, "Actual prize pool is empty");

        // Check actual contract balance first to ensure we have tokens
        uint256 contractBalance = paymentToken.balanceOf(address(this));
        require(contractBalance > 0, "No tokens in contract");

        // Calculate prize amount (winnerClaimPercentage% of the total deposited)
        uint256 claimAmount = (prizePool.totalDeposited * winnerClaimPercentage) / 100;

        // Ensure claim amount doesn't exceed actual available funds
        if (claimAmount > prizePool.actualAvailable) {
            claimAmount = prizePool.actualAvailable;
        }

        // Ensure we have enough balance for the specific claim amount
        require(contractBalance >= claimAmount, "Insufficient tokens for prize claim");

        // Update prize pool state
        prizePool.lastWinnerClaim = uint32(block.timestamp);
        prizePool.totalDeposited -= claimAmount;
        prizePool.actualAvailable -= claimAmount;

        // Burn the token first (to prevent reentrancy)
        _burn(tokenId);
        unchecked {
            ++_warpsData.burned;
        }

        // Transfer the prize to the winner
        bool success = paymentToken.transfer(msg.sender, claimAmount);
        require(success, "ERC20 transfer failed");

        // Randomly select a new winning color
        uint8 oldColorIndex = winningColorIndex;
        uint8 newColorIndex;

        // Generate random index and make sure it's different from the current one
        do {
            // Use keccak256 to generate pseudorandom number
            uint256 randomSeed = uint256(
                keccak256(
                    abi.encodePacked(block.timestamp, block.prevrandao, msg.sender, tokenId, prizePool.lastWinnerClaim)
                )
            );
            newColorIndex = uint8(randomSeed % 5); // There are 5 colors in WarpColors
        } while (newColorIndex == oldColorIndex);

        // Update the winning color index
        winningColorIndex = newColorIndex;

        // Emit events
        emit PrizeClaimed(tokenId, msg.sender, claimAmount);
        emit TokenBurned(tokenId, msg.sender);
        emit PrizePoolUpdated(prizePool.totalDeposited);
        emit WinningColorIndexUpdated(newColorIndex);
        emit WinningColorSet(WarpColors.getColorByIndex(newColorIndex), newColorIndex);
    }

    // ====================== Palette Logic ======================

    /// @dev Initialize a palette of 3 random colors for a newly minted token.
    ///      Uses packed uint24 RGB values for gas efficiency.
    function _initPalette(uint256 tokenId, address minter) internal {
        Palette storage p = _palette[tokenId];
        if (p.len != 0) return; // already initialised
        p.len = 3;

        uint256 s = uint256(keccak256(abi.encodePacked(block.prevrandao, tokenId, minter)));
        // Map random bytes to WarpColors indices (0-4) and then to uint24 values
        p.colors[0] = _warpColorCode(uint8(s & 0xFF) % 5);
        p.colors[1] = _warpColorCode(uint8((s >> 8) & 0xFF) % 5);
        p.colors[2] = _warpColorCode(uint8((s >> 16) & 0xFF) % 5);
    }

    /// @dev Return the uint24 RGB code for the 5 canonical WarpColors.
    function _warpColorCode(uint8 index) internal pure returns (uint24) {
        if (index == 0) return 0xFF007A; // Uniswap
        if (index == 1) return 0x855DCD; // Farcaster
        if (index == 2) return 0xFF9900; // Bitcoin
        if (index == 3) return 0x52b043; // XBOX
        if (index == 4) return 0x1da1f2; // Twitter
        revert("Index out of bounds");
    }

    /// @dev Update the palette when compositing two tokens.
    ///      Shrinks from 3 → 2 → 1 colours across the first two composites.
    function _updatePaletteOnComposite(uint256 keepId, uint256 burnId, uint8 divisorIdx) internal {
        Palette storage a = _palette[keepId];
        Palette storage b = _palette[burnId];
        uint256 r = uint256(keccak256(abi.encodePacked(a.colors[0], b.colors[0], block.prevrandao)));

        if (divisorIdx == 0 && a.len == 3 && b.len == 3) {
            // First composite → 2 colours (one from each parent)
            a.colors[0] = a.colors[uint8(r) % 3];
            a.colors[1] = b.colors[uint8(r >> 8) % 3];
            a.colors[2] = 0;
            a.len = 2;
        } else if (divisorIdx == 1 && a.len == 2 && b.len == 2) {
            // Second composite → 1 colour (picked from either parent)
            a.colors[0] = (r & 1) == 0 ? a.colors[uint8(r) % 2] : b.colors[uint8(r >> 8) % 2];
            a.colors[1] = 0;
            a.len = 1;
        }
    }

    /// @notice Return this token's current palette as a dynamic array.
    function tokenColors(uint256 id) external view returns (uint24[] memory) {
        Palette storage p = _palette[id];
        uint24[] memory out = new uint24[](p.len);
        for (uint8 i; i < p.len; ++i) {
            out[i] = p.colors[i];
        }
        return out;
    }
}

//SPDX-License-Identifier: MIT
pragma solidity ^0.8.17;

import "../interfaces/IWarps.sol";
import "./WarpColors.sol";
import "./Utilities.sol";

/**
 * @title  WarpsArt
 * @author Hurls
 * @notice Renders the Warps visuals.
 */
library WarpsArt {
    /// @dev The semiperfect divisors of the 20 warps.
    function divisors() public pure returns (uint8[8] memory) {
        return [20, 4, 1, 0, 0, 0, 0, 0];
    }

    /// @dev The different color band sizes that we use for the art.
    function colorBands() public pure returns (uint8[7] memory) {
        return [10, 8, 6, 4, 2, 1, 0];
    }

    /// @dev The gradient increment steps.
    function gradients() public pure returns (uint8[7] memory) {
        return [0, 1, 2, 5, 8, 9, 10];
    }

    /// @dev Load a warp from storage and fill its current state settings.
    /// @param tokenId The id of the warp to fetch.
    /// @param warps The DB containing all warps.
    function getWarp(uint256 tokenId, IWarps.Warps storage warps) public view returns (IWarps.Warp memory warp) {
        IWarps.StoredWarp memory stored = warps.all[tokenId];

        return getWarp(tokenId, stored.divisorIndex, warps);
    }

    /// @dev Load a warp from storage and fill its current state settings.
    /// @param tokenId The id of the warp to fetch.
    /// @param divisorIndex The divisorindex to get.
    /// @param warps The DB containing all warps.
    function getWarp(uint256 tokenId, uint8 divisorIndex, IWarps.Warps storage warps)
        public
        view
        returns (IWarps.Warp memory warp)
    {
        IWarps.StoredWarp memory stored = warps.all[tokenId];
        stored.divisorIndex = divisorIndex; // Override in case we're fetching specific state.
        warp.stored = stored;

        // Set up the source of randomness + seed for this Warp.
        warp.seed = stored.seed;

        // Helpers
        warp.isRoot = divisorIndex == 0;
        warp.hasManyWarps = divisorIndex < 6;
        warp.composite = !warp.isRoot && divisorIndex < 7 ? stored.composites[divisorIndex - 1] : 0;

        // Token properties
        warp.colorBand = colorBandIndex(warp, divisorIndex);
        warp.gradient = gradientIndex(warp, divisorIndex);
        warp.warpsCount = divisors()[divisorIndex];
    }

    /// @dev Query the gradient of a given warp at a certain warp count.
    /// @param warp The warp we want to get the gradient for.
    /// @param divisorIndex The warp divisor in question.
    function gradientIndex(IWarps.Warp memory warp, uint8 divisorIndex) public pure returns (uint8) {
        uint256 n = Utilities.random(warp.seed, "gradient", 100);

        return divisorIndex == 0
            ? n < 20 ? uint8(1 + (n % 6)) : 0
            : divisorIndex < 6 ? warp.stored.gradients[divisorIndex - 1] : 0;
    }

    /// @dev Query the color band of a given warp at a certain warp count.
    /// @param warp The warp we want to get the color band for.
    /// @param divisorIndex The warp divisor in question.
    function colorBandIndex(IWarps.Warp memory warp, uint8 divisorIndex) public pure returns (uint8) {
        uint256 n = Utilities.random(warp.seed, "band", 10);

        return divisorIndex == 0
            ? (n > 5 ? 2 : 3) // Return either index 2 (6 colors) or 3 (4 colors)
            : divisorIndex < 6 ? warp.stored.colorBands[divisorIndex - 1] : 4;
    }

    /// @dev Generate indexes for the color slots of warp parents (up to the WarpColors.COLORS themselves).
    /// @param divisorIndex The current divisorIndex to query.
    /// @param warp The current warp to investigate.
    /// @param warps The DB containing all warps.
    function colorIndexes(uint8 divisorIndex, IWarps.Warp memory warp, IWarps.Warps storage warps)
        public
        view
        returns (uint256[] memory)
    {
        uint8[8] memory divisors_ = divisors();
        uint256 warpsCount = divisors_[divisorIndex];
        uint256 seed = warp.seed;
        uint8 colorBand = colorBands()[colorBandIndex(warp, divisorIndex)];
        uint8 gradient = gradients()[gradientIndex(warp, divisorIndex)];

        // If we're a composited warp, we choose colors only based on
        // the slots available in our parents. Otherwise,
        // we choose based on our available spectrum.
        uint256 possibleColorChoices = divisorIndex > 0 ? divisors_[divisorIndex - 1] * 2 : 5;

        // We initialize our index and select the first color
        uint256[] memory indexes = new uint256[](warpsCount);
        indexes[0] = Utilities.random(seed, possibleColorChoices);

        // If we have more than one warp, continue selecting colors
        if (warp.hasManyWarps) {
            if (gradient > 0) {
                // If we're a gradient warp, we select based on the color band looping around
                // the 5 possible colors
                for (uint256 i = 1; i < warpsCount;) {
                    indexes[i] = (indexes[0] + (i * gradient * colorBand / warpsCount) % colorBand) % 5;
                    unchecked {
                        ++i;
                    }
                }
            } else if (divisorIndex == 0) {
                // If we select initial non gradient colors, we just take random ones
                // available in our color band
                for (uint256 i = 1; i < warpsCount;) {
                    indexes[i] = (indexes[0] + Utilities.random(seed + i, colorBand)) % 5;
                    unchecked {
                        ++i;
                    }
                }
            } else {
                // If we have parent warps, we select our colors from their set
                for (uint256 i = 1; i < warpsCount;) {
                    indexes[i] = Utilities.random(seed + i, possibleColorChoices);
                    unchecked {
                        ++i;
                    }
                }
            }
        }

        // We resolve our color indexes through our parent tree until we reach the root warps
        if (divisorIndex > 0) {
            uint8 previousDivisor = divisorIndex - 1;

            // We already have our current warp, but need the our parent state color indices
            uint256[] memory parentIndexes = colorIndexes(previousDivisor, warp, warps);

            // We also need to fetch the colors of the warp that was composited into us
            IWarps.Warp memory composited = getWarp(warp.composite, previousDivisor, warps);
            uint256[] memory compositedIndexes = colorIndexes(previousDivisor, composited, warps);

            // Replace random indices with parent / root color indices
            uint8 count = divisors_[previousDivisor];

            // We always select the first color from our parent
            uint256 initialBranchIndex = indexes[0] % count;
            indexes[0] = indexes[0] < count ? parentIndexes[initialBranchIndex] : compositedIndexes[initialBranchIndex];

            // If we don't have a gradient, we continue resolving from our parent for the remaining warps
            if (gradient == 0) {
                for (uint256 i; i < warpsCount;) {
                    uint256 branchIndex = indexes[i] % count;
                    indexes[i] = indexes[i] < count ? parentIndexes[branchIndex] : compositedIndexes[branchIndex];

                    unchecked {
                        ++i;
                    }
                }
            } else {
                // If we have a gradient we base the remaining colors off our initial selection
                for (uint256 i = 1; i < warpsCount;) {
                    indexes[i] = (indexes[0] + (i * gradient * colorBand / warpsCount) % colorBand) % 5;

                    unchecked {
                        ++i;
                    }
                }
            }
        }

        return indexes;
    }

    /// @dev Fetch all colors of a given Warp.
    /// @param warp The warp to get colors for.
    /// @param warps The DB containing all warps.
    function colors(IWarps.Warp memory warp, IWarps.Warps storage warps)
        public
        view
        returns (string[] memory, uint256[] memory)
    {
        // A fully composited warp has no color.
        if (warp.stored.divisorIndex == 7) {
            string[] memory zeroColors = new string[](1);
            uint256[] memory zeroIndexes = new uint256[](1);
            zeroColors[0] = "000";
            zeroIndexes[0] = 999;
            return (zeroColors, zeroIndexes);
        }

        // Fetch the indices on the original color mapping.
        uint256[] memory indexes = colorIndexes(warp.stored.divisorIndex, warp, warps);

        // Map over to get the colors.
        string[] memory warpColors = new string[](indexes.length);
        string[5] memory allColors = WarpColors.colors();

        // Always set the first color.
        warpColors[0] = allColors[indexes[0]];

        // Resolve each additional check color via their index in WarpColors.COLORS.
        for (uint256 i = 1; i < indexes.length; i++) {
            warpColors[i] = allColors[indexes[i]];
        }

        return (warpColors, indexes);
    }

    /// @dev Get the number of warps we should display per row.
    /// @param warps The number of warps in the piece.
    function perRow(uint8 warps) public pure returns (uint8) {
        return warps == 80 ? 8 : warps >= 20 ? 4 : warps == 10 || warps == 4 ? 2 : 1;
    }

    /// @dev Get the X-offset for positioning warp horizontally.
    /// @param warps The number of warps in the piece.
    function rowX(uint8 warps) public pure returns (uint16) {
        if (warps == 2) {
            return 310; // Adjusted value to center two warps horizontally
        }
        return warps <= 1 ? 286 : warps == 5 ? 304 : warps == 10 || warps == 4 ? 268 : 196;
    }

    /// @dev Get the Y-offset for positioning warp vertically.
    /// @param warps The number of warps in the piece.
    function rowY(uint8 warps) public pure returns (uint16) {
        if (warps == 2) {
            return 270; // Adjusted value to center two warps vertically
        }
        return warps > 4 ? 160 : warps == 4 ? 268 : warps > 1 ? 304 : 286;
    }

    /// @dev Generate the SVG code for all warps in a given token.
    /// @param data The data object containing rendering settings.
    function generateWarps(WarpRenderData memory data) public pure returns (bytes memory) {
        bytes memory warpsBytes;

        uint8 warpsCount = data.count;
        for (uint8 i; i < warpsCount; i++) {
            // Compute row settings.
            data.indexInRow = i % data.perRow;
            data.isNewRow = data.indexInRow == 0 && i > 0;

            // Compute offsets.
            if (data.isNewRow) data.rowY += data.spaceY;
            if (data.isNewRow && data.indent) {
                if (i == 0) {
                    data.rowX += data.spaceX / 2;
                }

                if (i % (data.perRow * 2) == 0) {
                    data.rowX -= data.spaceX / 2;
                } else {
                    data.rowX += data.spaceX / 2;
                }
            }
            string memory translateX = Utilities.uint2str(data.rowX + data.indexInRow * data.spaceX);
            string memory translateY = Utilities.uint2str(data.rowY);
            string memory color = data.colors[i];

            // Render the current   .
            warpsBytes = abi.encodePacked(
                warpsBytes,
                abi.encodePacked(
                    '<g transform="translate(',
                    translateX,
                    ", ",
                    translateY,
                    ')">',
                    '<g transform="translate(3, 3) scale(',
                    data.scale,
                    ')">',
                    // Outer layer (color)
                    '<path d="M15 26.264c1.271 0 4.012 4.144 5.207 3.703 1.194-.441.668-5.403 1.643-6.233.974-.83 5.698.558 6.334-.56.636-1.117-2.91-4.576-2.69-5.847.221-1.27 4.72-3.29 4.498-4.56-.22-1.271-5.127-1.607-5.763-2.725-.636-1.117 1.53-5.597.556-6.427-.974-.83-4.945 2.114-6.14 1.672C17.45 4.846 16.272 0 15 0c-1.272 0-2.45 4.846-3.645 5.287-1.195.442-5.166-2.502-6.14-1.672-.974.83 1.192 5.31.556 6.427C5.136 11.16.23 11.496.008 12.767c-.22 1.27 4.277 3.29 4.497 4.56.221 1.271-3.325 4.73-2.689 5.847.636 1.118 5.36-.27 6.334.56.974.83.448 5.791 1.643 6.233 1.196.441 3.936-3.703 5.207-3.703Z" fill="#',
                    color,
                    '"/>',
                    // First black layer
                    '<path d="M14.999 24.216c1.04 0 3.283 3.39 4.26 3.03.978-.361.547-4.421 1.345-5.1.797-.679 4.662.456 5.182-.458.52-.915-2.381-3.744-2.2-4.784.18-1.04 3.86-2.691 3.68-3.731-.181-1.04-4.196-1.315-4.716-2.23-.52-.913 1.253-4.58.456-5.258-.797-.679-4.047 1.73-5.025 1.368-.977-.361-1.941-4.326-2.982-4.326-1.04 0-2.004 3.965-2.982 4.326-.977.361-4.227-2.047-5.024-1.368-.797.678.976 4.345.456 5.259-.52.914-4.535 1.19-4.716 2.229-.18 1.04 3.5 2.691 3.68 3.731.18 1.04-2.72 3.87-2.2 4.784.52.914 4.385-.22 5.182.458.797.678.367 4.738 1.344 5.1.978.36 3.22-3.03 4.26-3.03Z" fill="#000"/>',
                    // Middle layer (color)
                    '<path d="M14.998 22.168c.81 0 2.553 2.637 3.314 2.357.76-.281.425-3.44 1.046-3.967.62-.528 3.625.355 4.03-.356.405-.712-1.852-2.912-1.711-3.72.14-.81 3.003-2.094 2.862-2.903-.14-.809-3.263-1.023-3.668-1.734-.404-.711.975-3.562.355-4.09S18.078 9.1 17.318 8.819c-.76-.28-1.51-3.364-2.32-3.364-.809 0-1.558 3.083-2.319 3.364-.76.281-3.288-1.592-3.907-1.064-.62.528.758 3.379.354 4.09-.405.711-3.527.925-3.668 1.734-.14.809 2.722 2.093 2.862 2.902.14.809-2.116 3.01-1.711 3.72.404.712 3.41-.171 4.03.357.62.528.286 3.685 1.046 3.966.76.281 2.505-2.356 3.314-2.356Z" fill="#',
                    color,
                    '"/>',
                    // Inner black layer
                    '<path d="M15.005 20.12c.579 0 1.824 1.884 2.367 1.683.543-.2.304-2.456.747-2.833.443-.377 2.59.254 2.88-.255.288-.508-1.323-2.08-1.223-2.657.1-.578 2.145-1.495 2.044-2.073-.1-.578-2.33-.73-2.62-1.238-.288-.508.696-2.545.254-2.922-.443-.377-2.248.96-2.792.76-.543-.2-1.078-2.403-1.656-2.403-.578 0-1.114 2.202-1.657 2.403-.543.2-2.348-1.137-2.791-.76-.443.377.542 2.414.253 2.922-.29.508-2.52.66-2.62 1.238-.1.578 1.944 1.495 2.044 2.073.1.578-1.511 2.15-1.222 2.657.289.509 2.437-.122 2.88.255.442.377.203 2.632.746 2.833.543.2 1.789-1.683 2.367-1.683Z" fill="#000"/>',
                    // Inner layer (color)
                    '<path d="M15 18.584c.404 0 1.276 1.319 1.656 1.178.38-.14.213-1.719.523-1.983.31-.264 1.813.177 2.015-.178.202-.356-.926-1.456-.855-1.86.07-.405 1.5-1.047 1.43-1.451-.07-.405-1.63-.512-1.833-.867-.203-.356.487-1.782.177-2.046-.31-.264-1.574.673-1.954.532-.38-.14-.755-1.682-1.16-1.682-.404 0-.78 1.542-1.16 1.682-.38.141-1.643-.796-1.953-.532-.31.264.38 1.69.177 2.046-.202.355-1.764.462-1.834.867-.07.404 1.36 1.046 1.431 1.45.07.405-1.058 1.505-.856 1.86.203.356 1.706-.085 2.016.179.31.264.142 1.843.523 1.983.38.14 1.252-1.178 1.656-1.178Z" fill="#',
                    color,
                    '"/>',
                    "</g>",
                    "</g>"
                )
            );
        }

        return warpsBytes;
    }

    /// @dev Collect relevant rendering data for easy access across functions.
    /// @param warp Our current warp loaded from storage.
    /// @param warps The DB containing all warps.
    function collectRenderData(IWarps.Warp memory warp, IWarps.Warps storage warps)
        public
        view
        returns (WarpRenderData memory data)
    {
        // Carry through base settings.
        data.warp = warp;
        data.isBlack = warp.stored.divisorIndex == 7;
        data.count = data.isBlack ? 1 : divisors()[warp.stored.divisorIndex];

        // Compute colors and indexes.
        (string[] memory colors_, uint256[] memory colorIndexes_) = colors(warp, warps);
        data.gridColor = "#000000";
        data.canvasColor = "#000000";
        data.colorIndexes = colorIndexes_;
        data.colors = colors_;

        // Compute positioning data.
        data.scale = data.count > 20 ? "1.2" : data.count > 1 ? "2" : "3";
        data.spaceX = data.count == 80 ? 36 : 72;
        data.spaceY = data.count > 20 ? 36 : 72;
        data.perRow = perRow(data.count);
        data.indent = data.count == 40;
        data.rowX = rowX(data.count);
        data.rowY = rowY(data.count);
    }

    /// @dev Generate the SVG code for rows in the 8x10 Warps grid.
    function generateGridRow() public pure returns (bytes memory) {
        bytes memory row;
        for (uint256 i; i < 8; i++) {
            row = abi.encodePacked(row, '<use href="#square" x="', Utilities.uint2str(196 + i * 36), '" y="160"/>');
        }
        return row;
    }

    /// @dev Generate the SVG code for the entire 8x10 Warps grid.
    function generateGrid() public pure returns (bytes memory) {
        bytes memory grid;
        for (uint256 i; i < 10; i++) {
            grid = abi.encodePacked(grid, '<use href="#row" y="', Utilities.uint2str(i * 36), '"/>');
        }

        return abi.encodePacked('<g id="grid" x="196" y="160">', grid, "</g>");
    }

    /// @dev Generate the complete SVG code for a given Warp.
    /// @param warp The warp to render.
    /// @param warps The DB containing all warps.
    function generateSVG(IWarps.Warp memory warp, IWarps.Warps storage warps) public view returns (bytes memory) {
        WarpRenderData memory data = collectRenderData(warp, warps);

        return abi.encodePacked(
            "<svg ",
            'viewBox="0 0 680 680" ',
            'fill="none" xmlns="http://www.w3.org/2000/svg" ',
            'style="width:100%;background:black;"',
            ">",
            "<defs>",
            '<rect id="square" width="36" height="36" stroke="',
            data.gridColor,
            '"></rect>',
            '<g id="row">',
            generateGridRow(),
            "</g>" "</defs>",
            '<rect width="680" height="680" fill="black"/>',
            '<rect x="188" y="152" width="304" height="376" fill="',
            data.canvasColor,
            '"/>',
            generateGrid(),
            generateWarps(data),
            "</svg>"
        );
    }

    /*────────────────────────── Palette Support ─────────────────────────*/

    /// @dev Convert a packed uint24 RGB into 6-character hex string (no prefix).
    function _uint24ToHex(uint24 value) internal pure returns (string memory) {
        bytes16 symbols = "0123456789abcdef";
        bytes memory buffer = new bytes(6);
        for (uint256 i; i < 6; ++i) {
            buffer[5 - i] = symbols[value & 0xF];
            value >>= 4;
        }
        return string(buffer);
    }

    /// @notice Generate SVG strictly using provided palette colours.
    /// @param warp The warp to render.
    /// @param warps Global warps storage.
    /// @param palette Array of packed uint24 RGB colours.
    function generateSVGWithPalette(IWarps.Warp memory warp, IWarps.Warps storage warps, uint24[] memory palette)
        public
        view
        returns (bytes memory)
    {
        WarpRenderData memory data = collectRenderData(warp, warps);

        // Build colour strings cycling through palette.
        uint256 len = data.count;
        string[] memory custom = new string[](len);
        for (uint256 i; i < len; ++i) {
            custom[i] = _uint24ToHex(palette[i % palette.length]);
        }
        data.colors = custom;

        return abi.encodePacked(
            "<svg ",
            'viewBox="0 0 680 680" ',
            'fill="none" xmlns="http://www.w3.org/2000/svg" ',
            'style="width:100%;background:black;"',
            ">",
            "<defs>",
            '<rect id="square" width="36" height="36" stroke="',
            data.gridColor,
            '"></rect>',
            '<g id="row">',
            generateGridRow(),
            "</g>" "</defs>",
            '<rect width="680" height="680" fill="black"/>',
            '<rect x="188" y="152" width="304" height="376" fill="',
            data.canvasColor,
            '"/>',
            generateGrid(),
            generateWarps(data),
            "</svg>"
        );
    }
}

/// @dev Bag holding all data relevant for rendering.
struct WarpRenderData {
    IWarps.Warp warp;
    uint256[] colorIndexes;
    string[] colors;
    string canvasColor;
    string gridColor;
    string duration;
    string scale;
    uint32 seed;
    uint16 rowX;
    uint16 rowY;
    uint8 count;
    uint8 spaceX;
    uint8 spaceY;
    uint8 perRow;
    uint8 indexInRow;
    uint8 isIndented;
    bool isNewRow;
    bool isBlack;
    bool indent;
    bool isStatic;
}

//SPDX-License-Identifier: MIT
pragma solidity ^0.8.17;

import "lib/openzeppelin-contracts/contracts/utils/Base64.sol";

import "./WarpsArt.sol";
import "../interfaces/IWarps.sol";
import "./Utilities.sol";

/**
 * @title  WarpsMetadata
 * @author Hurls
 * @notice Renders ERC721 compatible metadata for Warps.
 */
library WarpsMetadata {
    /// @dev Render the JSON Metadata for a given Warps token.
    /// @param tokenId The id of the token to render.
    /// @param warps The DB containing all warps.
    function tokenURI(uint256 tokenId, IWarps.Warps storage warps) public view returns (string memory) {
        IWarps.Warp memory warp = WarpsArt.getWarp(tokenId, warps);

        // Generate both static and animated versions
        bytes memory staticSvg = WarpsArt.generateSVG(warp, warps);

        bytes memory metadata = abi.encodePacked(
            "{",
            '"name": "Warps ',
            Utilities.uint2str(tokenId),
            '",',
            '"description": "Up and to the right.",',
            '"image": ',
            '"data:image/svg+xml;base64,',
            Base64.encode(staticSvg),
            '",',
            '"attributes": [',
            attributes(warp),
            "]",
            "}"
        );

        return string(abi.encodePacked("data:application/json;base64,", Base64.encode(metadata)));
    }

    /// @dev Render the JSON atributes for a given Warps token.
    /// @param warp The warp to render.
    function attributes(IWarps.Warp memory warp) public pure returns (bytes memory) {
        bool showVisualAttributes = warp.hasManyWarps;

        return abi.encodePacked(
            showVisualAttributes
                ? trait("Color Band", colorBand(WarpsArt.colorBandIndex(warp, warp.stored.divisorIndex)), ",")
                : "",
            showVisualAttributes
                ? trait("Gradient", gradients(WarpsArt.gradientIndex(warp, warp.stored.divisorIndex)), ",")
                : "",
            trait("Warps", Utilities.uint2str(warp.warpsCount), "")
        );
    }

    /// @dev Get the names for different gradients. Compare WarpsArt.GRADIENTS.
    /// @param gradientIndex The index of the gradient.
    function gradients(uint8 gradientIndex) public pure returns (string memory) {
        return ["None", "Linear", "Double Linear", "Reflected", "Double Angled", "Angled", "Linear Z"][gradientIndex];
    }

    /// @dev Get the percentage values for different color bands. Compare WarpsArt.COLOR_BANDS.
    /// @param bandIndex The index of the color band.
    function colorBand(uint8 bandIndex) public pure returns (string memory) {
        return ["Eighty", "Sixty", "Forty", "Twenty", "Ten", "Five", "One"][bandIndex];
    }

    /// @dev Generate the SVG snipped for a single attribute.
    /// @param traitType The `trait_type` for this trait.
    /// @param traitValue The `value` for this trait.
    /// @param append Helper to append a comma.
    function trait(string memory traitType, string memory traitValue, string memory append)
        public
        pure
        returns (string memory)
    {
        return
            string(abi.encodePacked("{", '"trait_type": "', traitType, '",' '"value": "', traitValue, '"' "}", append));
    }

    /// @dev Generate the HTML for the animation_url in the metadata.
    /// @param tokenId The id of the token to generate the embed for.
    /// @param svg The rendered SVG code to embed in the HTML.
    function generateHTML(uint256 tokenId, bytes memory svg) public pure returns (bytes memory) {
        return abi.encodePacked(
            "<!DOCTYPE html>",
            '<html lang="en">',
            "<head>",
            '<meta charset="UTF-8">',
            '<meta http-equiv="X-UA-Compatible" content="IE=edge">',
            '<meta name="viewport" content="width=device-width, initial-scale=1.0">',
            "<title>Warp #",
            Utilities.uint2str(tokenId),
            "</title>",
            "<style>",
            "html,",
            "body {",
            "margin: 0;",
            "background: #EFEFEF;",
            "overflow: hidden;",
            "}",
            "svg {",
            "max-width: 100vw;",
            "max-height: 100vh;",
            "}",
            "</style>",
            "</head>",
            "<body>",
            svg,
            "</body>",
            "</html>"
        );
    }
}

{
  "compilationTarget": {
    "src/Warps.sol": "Warps"
  },
  "evmVersion": "shanghai",
  "libraries": {
    "src/libraries/WarpColors.sol:WarpColors": "0xb3b22aaa28badc8b954add722e0da56fff329530",
    "src/libraries/WarpsArt.sol:WarpsArt": "0x717073089d146665f68188a7096c2efd41143889",
    "src/libraries/WarpsMetadata.sol:WarpsMetadata": "0x6b217d26f7c319be29d393825bc90563a608839a"
  },
  "metadata": {
    "appendCBOR": false,
    "bytecodeHash": "none"
  },
  "optimizer": {
    "enabled": true,
    "runs": 99999999
  },
  "remappings": [
    ":ds-test/=lib/forge-std/lib/ds-test/src/",
    ":erc4626-tests/=lib/openzeppelin-contracts/lib/erc4626-tests/",
    ":forge-std/=lib/forge-std/src/",
    ":openzeppelin-contracts/=lib/openzeppelin-contracts/contracts/",
    ":openzeppelin/contracts/=lib/openzeppelin-contracts/contracts/",
    ":solady-test/=lib/solady/test/",
    ":solady/=lib/solady/src/",
    ":uniswap-v2-core/=lib/uniswap/v2-core/contracts/",
    ":uniswap-v3-core/=lib/uniswap/v3-core/contracts/",
    ":uniswap-v3-periphery/=lib/uniswap/v3-periphery/contracts/",
    ":uniswap-v4-core/=lib/uniswap/v4-core/src/",
    ":uniswap-v4-periphery/=lib/uniswap/v4-periphery/src/",
    ":uniswap/=lib/uniswap/"
  ],
  "viaIR": true
}