// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/Address.sol)

pragma solidity ^0.8.20;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev The ETH balance of the account is not enough to perform the operation.
     */
    error AddressInsufficientBalance(address account);

    /**
     * @dev There's no code at `target` (it is not a contract).
     */
    error AddressEmptyCode(address target);

    /**
     * @dev A call to an address target failed. The target may have reverted.
     */
    error FailedInnerCall();

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.8.20/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        if (address(this).balance < amount) {
            revert AddressInsufficientBalance(address(this));
        }

        (bool success, ) = recipient.call{value: amount}("");
        if (!success) {
            revert FailedInnerCall();
        }
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason or custom error, it is bubbled
     * up by this function (like regular Solidity function calls). However, if
     * the call reverted with no returned reason, this function reverts with a
     * {FailedInnerCall} error.
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        if (address(this).balance < value) {
            revert AddressInsufficientBalance(address(this));
        }
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and reverts if the target
     * was not a contract or bubbling up the revert reason (falling back to {FailedInnerCall}) in case of an
     * unsuccessful call.
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata
    ) internal view returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            // only check if target is a contract if the call was successful and the return data is empty
            // otherwise we already know that it was a contract
            if (returndata.length == 0 && target.code.length == 0) {
                revert AddressEmptyCode(target);
            }
            return returndata;
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and reverts if it wasn't, either by bubbling the
     * revert reason or with a default {FailedInnerCall} error.
     */
    function verifyCallResult(bool success, bytes memory returndata) internal pure returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            return returndata;
        }
    }

    /**
     * @dev Reverts with returndata if present. Otherwise reverts with {FailedInnerCall}.
     */
    function _revert(bytes memory returndata) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            /// @solidity memory-safe-assembly
            assembly {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert FailedInnerCall();
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/introspection/ERC165Checker.sol)

pragma solidity ^0.8.20;

import {IERC165} from "./IERC165.sol";

/**
 * @dev Library used to query support of an interface declared via {IERC165}.
 *
 * Note that these functions return the actual result of the query: they do not
 * `revert` if an interface is not supported. It is up to the caller to decide
 * what to do in these cases.
 */
library ERC165Checker {
    // As per the EIP-165 spec, no interface should ever match 0xffffffff
    bytes4 private constant INTERFACE_ID_INVALID = 0xffffffff;

    /**
     * @dev Returns true if `account` supports the {IERC165} interface.
     */
    function supportsERC165(address account) internal view returns (bool) {
        // Any contract that implements ERC165 must explicitly indicate support of
        // InterfaceId_ERC165 and explicitly indicate non-support of InterfaceId_Invalid
        return
            supportsERC165InterfaceUnchecked(account, type(IERC165).interfaceId) &&
            !supportsERC165InterfaceUnchecked(account, INTERFACE_ID_INVALID);
    }

    /**
     * @dev Returns true if `account` supports the interface defined by
     * `interfaceId`. Support for {IERC165} itself is queried automatically.
     *
     * See {IERC165-supportsInterface}.
     */
    function supportsInterface(address account, bytes4 interfaceId) internal view returns (bool) {
        // query support of both ERC165 as per the spec and support of _interfaceId
        return supportsERC165(account) && supportsERC165InterfaceUnchecked(account, interfaceId);
    }

    /**
     * @dev Returns a boolean array where each value corresponds to the
     * interfaces passed in and whether they're supported or not. This allows
     * you to batch check interfaces for a contract where your expectation
     * is that some interfaces may not be supported.
     *
     * See {IERC165-supportsInterface}.
     */
    function getSupportedInterfaces(
        address account,
        bytes4[] memory interfaceIds
    ) internal view returns (bool[] memory) {
        // an array of booleans corresponding to interfaceIds and whether they're supported or not
        bool[] memory interfaceIdsSupported = new bool[](interfaceIds.length);

        // query support of ERC165 itself
        if (supportsERC165(account)) {
            // query support of each interface in interfaceIds
            for (uint256 i = 0; i < interfaceIds.length; i++) {
                interfaceIdsSupported[i] = supportsERC165InterfaceUnchecked(account, interfaceIds[i]);
            }
        }

        return interfaceIdsSupported;
    }

    /**
     * @dev Returns true if `account` supports all the interfaces defined in
     * `interfaceIds`. Support for {IERC165} itself is queried automatically.
     *
     * Batch-querying can lead to gas savings by skipping repeated checks for
     * {IERC165} support.
     *
     * See {IERC165-supportsInterface}.
     */
    function supportsAllInterfaces(address account, bytes4[] memory interfaceIds) internal view returns (bool) {
        // query support of ERC165 itself
        if (!supportsERC165(account)) {
            return false;
        }

        // query support of each interface in interfaceIds
        for (uint256 i = 0; i < interfaceIds.length; i++) {
            if (!supportsERC165InterfaceUnchecked(account, interfaceIds[i])) {
                return false;
            }
        }

        // all interfaces supported
        return true;
    }

    /**
     * @notice Query if a contract implements an interface, does not check ERC165 support
     * @param account The address of the contract to query for support of an interface
     * @param interfaceId The interface identifier, as specified in ERC-165
     * @return true if the contract at account indicates support of the interface with
     * identifier interfaceId, false otherwise
     * @dev Assumes that account contains a contract that supports ERC165, otherwise
     * the behavior of this method is undefined. This precondition can be checked
     * with {supportsERC165}.
     *
     * Some precompiled contracts will falsely indicate support for a given interface, so caution
     * should be exercised when using this function.
     *
     * Interface identification is specified in ERC-165.
     */
    function supportsERC165InterfaceUnchecked(address account, bytes4 interfaceId) internal view returns (bool) {
        // prepare call
        bytes memory encodedParams = abi.encodeCall(IERC165.supportsInterface, (interfaceId));

        // perform static call
        bool success;
        uint256 returnSize;
        uint256 returnValue;
        assembly {
            success := staticcall(30000, account, add(encodedParams, 0x20), mload(encodedParams), 0x00, 0x20)
            returnSize := returndatasize()
            returnValue := mload(0x00)
        }

        return success && returnSize >= 0x20 && returnValue > 0;
    }
}

// SPDX-License-Identifier: GPL-2.0-or-later
pragma solidity >=0.8.20;

interface ICurve {
  function curveMath(uint256 base, uint256 add) external pure returns (uint256);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/introspection/IERC165.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[EIP].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[EIP section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/extensions/IERC20Permit.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC20 Permit extension allowing approvals to be made via signatures, as defined in
 * https://eips.ethereum.org/EIPS/eip-2612[EIP-2612].
 *
 * Adds the {permit} method, which can be used to change an account's ERC20 allowance (see {IERC20-allowance}) by
 * presenting a message signed by the account. By not relying on {IERC20-approve}, the token holder account doesn't
 * need to send a transaction, and thus is not required to hold Ether at all.
 *
 * ==== Security Considerations
 *
 * There are two important considerations concerning the use of `permit`. The first is that a valid permit signature
 * expresses an allowance, and it should not be assumed to convey additional meaning. In particular, it should not be
 * considered as an intention to spend the allowance in any specific way. The second is that because permits have
 * built-in replay protection and can be submitted by anyone, they can be frontrun. A protocol that uses permits should
 * take this into consideration and allow a `permit` call to fail. Combining these two aspects, a pattern that may be
 * generally recommended is:
 *
 * ```solidity
 * function doThingWithPermit(..., uint256 value, uint256 deadline, uint8 v, bytes32 r, bytes32 s) public {
 *     try token.permit(msg.sender, address(this), value, deadline, v, r, s) {} catch {}
 *     doThing(..., value);
 * }
 *
 * function doThing(..., uint256 value) public {
 *     token.safeTransferFrom(msg.sender, address(this), value);
 *     ...
 * }
 * ```
 *
 * Observe that: 1) `msg.sender` is used as the owner, leaving no ambiguity as to the signer intent, and 2) the use of
 * `try/catch` allows the permit to fail and makes the code tolerant to frontrunning. (See also
 * {SafeERC20-safeTransferFrom}).
 *
 * Additionally, note that smart contract wallets (such as Argent or Safe) are not able to produce permit signatures, so
 * contracts should have entry points that don't rely on permit.
 */
interface IERC20Permit {
    /**
     * @dev Sets `value` as the allowance of `spender` over ``owner``'s tokens,
     * given ``owner``'s signed approval.
     *
     * IMPORTANT: The same issues {IERC20-approve} has related to transaction
     * ordering also apply here.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `deadline` must be a timestamp in the future.
     * - `v`, `r` and `s` must be a valid `secp256k1` signature from `owner`
     * over the EIP712-formatted function arguments.
     * - the signature must use ``owner``'s current nonce (see {nonces}).
     *
     * For more information on the signature format, see the
     * https://eips.ethereum.org/EIPS/eip-2612#specification[relevant EIP
     * section].
     *
     * CAUTION: See Security Considerations above.
     */
    function permit(
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external;

    /**
     * @dev Returns the current nonce for `owner`. This value must be
     * included whenever a signature is generated for {permit}.
     *
     * Every successful call to {permit} increases ``owner``'s nonce by one. This
     * prevents a signature from being used multiple times.
     */
    function nonces(address owner) external view returns (uint256);

    /**
     * @dev Returns the domain separator used in the encoding of the signature for {permit}, as defined by {EIP712}.
     */
    // solhint-disable-next-line func-name-mixedcase
    function DOMAIN_SEPARATOR() external view returns (bytes32);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC721/IERC721.sol)

pragma solidity ^0.8.20;

import {IERC165} from "../../utils/introspection/IERC165.sol";

/**
 * @dev Required interface of an ERC721 compliant contract.
 */
interface IERC721 is IERC165 {
    /**
     * @dev Emitted when `tokenId` token is transferred from `from` to `to`.
     */
    event Transfer(address indexed from, address indexed to, uint256 indexed tokenId);

    /**
     * @dev Emitted when `owner` enables `approved` to manage the `tokenId` token.
     */
    event Approval(address indexed owner, address indexed approved, uint256 indexed tokenId);

    /**
     * @dev Emitted when `owner` enables or disables (`approved`) `operator` to manage all of its assets.
     */
    event ApprovalForAll(address indexed owner, address indexed operator, bool approved);

    /**
     * @dev Returns the number of tokens in ``owner``'s account.
     */
    function balanceOf(address owner) external view returns (uint256 balance);

    /**
     * @dev Returns the owner of the `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function ownerOf(uint256 tokenId) external view returns (address owner);

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon
     *   a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(address from, address to, uint256 tokenId, bytes calldata data) external;

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`, checking first that contract recipients
     * are aware of the ERC721 protocol to prevent tokens from being forever locked.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must have been allowed to move this token by either {approve} or
     *   {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon
     *   a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(address from, address to, uint256 tokenId) external;

    /**
     * @dev Transfers `tokenId` token from `from` to `to`.
     *
     * WARNING: Note that the caller is responsible to confirm that the recipient is capable of receiving ERC721
     * or else they may be permanently lost. Usage of {safeTransferFrom} prevents loss, though the caller must
     * understand this adds an external call which potentially creates a reentrancy vulnerability.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 tokenId) external;

    /**
     * @dev Gives permission to `to` to transfer `tokenId` token to another account.
     * The approval is cleared when the token is transferred.
     *
     * Only a single account can be approved at a time, so approving the zero address clears previous approvals.
     *
     * Requirements:
     *
     * - The caller must own the token or be an approved operator.
     * - `tokenId` must exist.
     *
     * Emits an {Approval} event.
     */
    function approve(address to, uint256 tokenId) external;

    /**
     * @dev Approve or remove `operator` as an operator for the caller.
     * Operators can call {transferFrom} or {safeTransferFrom} for any token owned by the caller.
     *
     * Requirements:
     *
     * - The `operator` cannot be the address zero.
     *
     * Emits an {ApprovalForAll} event.
     */
    function setApprovalForAll(address operator, bool approved) external;

    /**
     * @dev Returns the account approved for `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function getApproved(uint256 tokenId) external view returns (address operator);

    /**
     * @dev Returns if the `operator` is allowed to manage all of the assets of `owner`.
     *
     * See {setApprovalForAll}
     */
    function isApprovedForAll(address owner, address operator) external view returns (bool);
}

// SPDX-License-Identifier: GPL-2.0-or-later
pragma solidity >=0.8.20;

interface IFoundry {
  struct App {
    string name;
    address owner;
    address operator;
    address publicNFT;
    address mortgageNFT;
    address market;
    address payToken;
  }

  event CreateApp(
    uint256 appId,
    string name,
    address owner,
    address operator,
    address curve,
    address payToken,
    uint256 buyFee,
    uint256 sellFee,
    address publicNFT,
    address mortgageNFT,
    address market,
    address sender
  );

  event CreateToken(
    uint256 appId,
    string tid,
    bytes tData,
    uint256[] nftTokenIds,
    uint256[] nftPercents,
    address[] nftOwners,
    bytes[] nftData,
    address sender
  );

  event SetAppOwner(uint256 appId, address newOwner, address sender);

  event SetMortgageFee(uint256 appId, uint256 newMortgageFee, address sender);

  event SetMortgageFeeRecipient(uint256 appId, address newMortgageFeeOwner, address sender);

  function FEE_DENOMINATOR() external view returns (uint256);

  function TOTAL_PERCENT() external view returns (uint256);

  function publicNFTFactory() external view returns (address);

  function mortgageNFTFactory() external view returns (address);

  function marketFactory() external view returns (address);

  function nextAppId() external view returns (uint256);

  function defaultMortgageFee() external view returns (uint256);

  function defaultMortgageFeeRecipient() external view returns (address);

  function mortgageFee(uint256 appId) external view returns (uint256);

  function mortgageFeeRecipient(uint256 appId) external view returns (address);

  function apps(uint256 appId) external view returns (App memory app);

  function tokenExist(uint256 appId, string memory tid) external view returns (bool);

  function tokenData(uint256 appId, string memory tid) external view returns (bytes memory);

  function createApp(
    string memory name,
    address owner,
    address operator,
    address curve,
    address payToken,
    uint256 buyFee,
    uint256 sellFee
  ) external;

  function createToken(
    uint256 appId,
    string memory tid,
    bytes memory tData,
    uint256[] memory nftPercents,
    address[] memory nftOwners,
    bytes[] memory nftData
  ) external returns (uint256[] memory tokenIds);

  function setAppOwner(uint256 appId, address newOwner) external;

  function setMortgageFee(uint256 appId, uint256 newMortgageFee) external;

  function setMortgageFeeRecipient(uint256 appId, address newMortgageFeeRecipient) external;
}

// SPDX-License-Identifier: GPL-2.0-or-later
pragma solidity >=0.8.20;

interface IMarket {
  event Initialize(address publicNFT, address mortgageNFT);

  event Buy(
    string tid,
    uint256 tokenAmount,
    uint256 payTokenAmount,
    address sender,
    address user,
    uint256[] feeTokenIds,
    address[] feeOwners,
    uint256[] feeAmounts
  );

  event Sell(
    string tid,
    uint256 tokenAmount,
    uint256 payTokenAmount,
    address sender,
    address user,
    uint256[] feeTokenIds,
    address[] feeOwners,
    uint256[] feeAmounts
  );

  event Mortgage(
    uint256 tokenId,
    string tid,
    uint256 tokenAmount,
    uint256 payTokenAmount,
    uint256 feeAmount,
    address sender
  );

  event Redeem(uint256 tokenId, string tid, uint256 tokenAmount, uint256 payTokenAmount, address sender);

  event Multiply(
    uint256 tokenId,
    string tid,
    uint256 multiplyAmount,
    uint256 payTokenAmount,
    uint256 feeAmount,
    address sender,
    uint256[] feeTokenIds,
    address[] feeOwners,
    uint256[] feeAmounts
  );

  event Cash(
    uint256 tokenId,
    string tid,
    uint256 tokenAmount,
    uint256 payTokenAmount,
    address sender,
    uint256[] feeTokenIds,
    address[] feeOwners,
    uint256[] feeAmounts
  );

  event Merge(
    uint256 tokenId,
    string tid,
    uint256 otherTokenId,
    uint256 payTokenAmount,
    uint256 feeAmount,
    address sender
  );

  event Split(
    uint256 tokenId,
    uint256 newTokenId,
    string tid,
    uint256 splitAmount,
    uint256 payTokenAmount,
    address sender
  );

  function feeDenominator() external view returns (uint256);

  function totalPercent() external view returns (uint256);

  function foundry() external view returns (address);

  function appId() external view returns (uint256);

  function curve() external view returns (address);

  function payToken() external view returns (address);

  function buyFee() external view returns (uint256);

  function sellFee() external view returns (uint256);

  function publicNFT() external view returns (address);

  function mortgageNFT() external view returns (address);

  function initialize(address publicNFT, address mortgageNFT) external;

  function totalSupply(string memory tid) external view returns (uint256);

  function balanceOf(string memory tid, address account) external view returns (uint256);

  function getBuyPayTokenAmount(string memory tid, uint256 tokenAmount) external view returns (uint256 payTokenAmount);

  function getSellPayTokenAmount(string memory tid, uint256 tokenAmount) external view returns (uint256 payTokenAmount);

  function getPayTokenAmount(uint256 base, uint256 add) external view returns (uint256 payTokenAmount);

  function buy(string memory tid, uint256 tokenAmount) external payable returns (uint256 payTokenAmount);
  function buyProxy(
    string memory tid,
    uint256 tokenAmount,
    address user
  ) external payable returns (uint256 payTokenAmount);

  function sell(string memory tid, uint256 tokenAmount) external returns (uint256 payTokenAmount);
  function sellProxy(string memory tid, uint256 tokenAmount, address user) external returns (uint256 payTokenAmount);

  function mortgage(
    string memory tid,
    uint256 tokenAmount
  ) external returns (uint256 nftTokenId, uint256 payTokenAmount);
  function mortgageProxy(
    string memory tid,
    uint256 tokenAmount,
    address user
  ) external returns (uint256 nftTokenId, uint256 payTokenAmount);

  function mortgageAdd(uint256 nftTokenId, uint256 tokenAmount) external returns (uint256 payTokenAmount);
  function mortgageAddProxy(uint256 nftTokenId, uint256 tokenAmount) external returns (uint256 payTokenAmount);

  function redeem(uint256 nftTokenId, uint256 tokenAmount) external payable returns (uint256 payTokenAmount);
  function redeemProxy(uint256 nftTokenId, uint256 tokenAmount) external payable returns (uint256 payTokenAmount);

  function multiply(
    string memory tid,
    uint256 multiplyAmount
  ) external payable returns (uint256 nftTokenId, uint256 payTokenAmount);
  function multiplyProxy(
    string memory tid,
    uint256 multiplyAmount,
    address user
  ) external payable returns (uint256 nftTokenId, uint256 payTokenAmount);

  function multiplyAdd(uint256 nftTokenId, uint256 multiplyAmount) external payable returns (uint256 payTokenAmount);
  function multiplyAddProxy(
    uint256 nftTokenId,
    uint256 multiplyAmount
  ) external payable returns (uint256 payTokenAmount);

  function cash(uint256 nftTokenId, uint256 tokenAmount) external returns (uint256 payTokenAmount);
  function cashProxy(uint256 nftTokenId, uint256 tokenAmount) external returns (uint256 payTokenAmount);

  function merge(uint256 nftTokenId, uint256 otherNFTTokenId) external returns (uint256 payTokenAmount);
  function mergeProxy(uint256 nftTokenId, uint256 otherNFTTokenId) external returns (uint256 payTokenAmount);

  function split(
    uint256 nftTokenId,
    uint256 splitAmount
  ) external payable returns (uint256 payTokenAmount, uint256 newNFTTokenId);
  function splitProxy(
    uint256 nftTokenId,
    uint256 splitAmount
  ) external payable returns (uint256 payTokenAmount, uint256 newNFTTokenId);
}

// SPDX-License-Identifier: GPL-2.0-or-later
pragma solidity >=0.8.20;

interface IMortgageNFT {
  struct Info {
    string tid;
    uint256 tokenId;
    uint256 amount;
  }

  event Initialize(address market);

  event Mint(address to, string tid, uint256 amount);

  event Burn(uint256 tokenId);

  event Add(uint256 tokenId, uint256 amount);

  event Remove(uint256 tokenId, uint256 amount);

  event SetMortgageNFTView(address newMortgageNFTView, address sender);

  function foundry() external view returns (address);

  function appId() external view returns (uint256);

  function market() external view returns (address);

  function mortgageNFTView() external view returns (address);

  function info(uint256 tokenId) external view returns (string memory tid, uint256 amount);

  function initialize(address market) external;

  function isApprovedOrOwner(address addr, uint256 tokenId) external view returns (bool);

  function mint(address to, string memory tid, uint256 amount) external returns (uint256 tokenId);

  function burn(uint256 tokenId) external;

  function add(uint256 tokenId, uint256 amount) external;

  function remove(uint256 tokenId, uint256 amount) external;

  function setMortgageNFTView(address newMortgageNFTView) external;

  function tokenInfosOfOwner(address owner) external view returns (IMortgageNFT.Info[] memory infos);

  function tokenInfosOfOwnerByTid(
    address owner,
    string memory tid
  ) external view returns (IMortgageNFT.Info[] memory infos);
}

// SPDX-License-Identifier: GPL-2.0-or-later
pragma solidity >=0.8.20;

interface IPublicNFT {
  struct Info {
    string tid;
    uint256 percent;
    bytes data;
  }

  event Mint(string tid, uint256[] tokenIds, uint256[] percents, address[] owners, bytes[] data);

  event SetPublicNFTView(address newPublicNFTView, address sender);

  function foundry() external view returns (address);

  function appId() external view returns (uint256);

  function publicNFTView() external view returns (address);

  function tokenIdToInfo(
    uint256 tokenId
  ) external view returns (string memory tid, uint256 percent, bytes memory data, address owner);

  function tidToTokenIds(string memory tid) external view returns (uint256[] memory);

  function tidToInfos(
    string memory tid
  )
    external
    view
    returns (uint256[] memory tokenIds, uint256[] memory percents, bytes[] memory data, address[] memory owners);

  function mint(
    string memory tid,
    uint256[] memory percents,
    address[] memory owners,
    bytes[] memory data
  ) external returns (uint256[] memory tokenIds);

  function setPublicNFTView(address newPublicNFTView) external;
}

// SPDX-License-Identifier: GPL-2.0-or-later
pragma solidity >=0.8.20;

interface IPublicNFTVault {
  function recordReceiveBuySellFee(uint256 tokenId, uint256 amount) external returns (bool);
}

// SPDX-License-Identifier: BUSL-1.1
pragma solidity >=0.8.20;

import "./interfaces/IPublicNFT.sol";
import "./interfaces/IMortgageNFT.sol";
import "./interfaces/IMarket.sol";
import "./interfaces/IFoundry.sol";
import "./interfaces/ICurve.sol";
import "./interfaces/IPublicNFTVault.sol";

import "@openzeppelin/contracts/token/ERC721/IERC721.sol";
import "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
import "@openzeppelin/contracts/utils/ReentrancyGuard.sol";
import "@openzeppelin/contracts/utils/introspection/ERC165Checker.sol";

contract Market is IMarket, ReentrancyGuard {
  uint256 public immutable override feeDenominator;
  uint256 public immutable override totalPercent;

  address public immutable override foundry;
  uint256 public immutable override appId;

  address public immutable override curve;
  address public immutable override payToken;
  uint256 public immutable override buyFee;
  uint256 public immutable override sellFee;

  address public override publicNFT;
  address public override mortgageNFT;

  // tid => totalSupply
  mapping(string => uint256) private _totalSupply;

  // tid => account => amount
  mapping(string => mapping(address => uint256)) private _balanceOf;

  modifier onlyAppOperator() {
    require(msg.sender == IFoundry(foundry).apps(appId).operator, "onlyAppOperator");
    _;
  }

  constructor(
    address _foundry,
    uint256 _appId,
    uint256 _feeDenominator,
    uint256 _totalPercent,
    address _curve,
    address _payToken,
    uint256 _buyFee,
    uint256 _sellFee
  ) {
    foundry = _foundry;
    appId = _appId;

    feeDenominator = _feeDenominator;
    totalPercent = _totalPercent;

    curve = _curve;
    payToken = _payToken;
    buyFee = _buyFee;
    sellFee = _sellFee;
  }

  function initialize(address _publicNFT, address _mortgageNFT) external override {
    require(msg.sender == foundry, "onlyFoundry");

    publicNFT = _publicNFT;
    mortgageNFT = _mortgageNFT;

    emit Initialize(_publicNFT, _mortgageNFT);
  }

  function totalSupply(string memory tid) external view override returns (uint256) {
    return _totalSupply[tid];
  }

  function balanceOf(string memory tid, address account) external view override returns (uint256) {
    return _balanceOf[tid][account];
  }

  function getBuyPayTokenAmount(
    string memory tid,
    uint256 tokenAmount
  ) public view override returns (uint256 payTokenAmount) {
    uint256 ts = _totalSupply[tid];
    return getPayTokenAmount(ts, tokenAmount);
  }

  function getSellPayTokenAmount(
    string memory tid,
    uint256 tokenAmount
  ) public view override returns (uint256 payTokenAmount) {
    uint256 ts = _totalSupply[tid];
    return getPayTokenAmount(ts - tokenAmount, tokenAmount);
  }

  function getPayTokenAmount(uint256 base, uint256 add) public view override returns (uint256 payTokenAmount) {
    return ICurve(curve).curveMath(base, add);
  }

  function buy(
    string memory tid,
    uint256 tokenAmount
  ) external payable override nonReentrant returns (uint256 payTokenAmount) {
    payTokenAmount = _buy(tid, tokenAmount, msg.sender);
  }

  function buyProxy(
    string memory tid,
    uint256 tokenAmount,
    address user
  ) external payable override onlyAppOperator nonReentrant returns (uint256 payTokenAmount) {
    payTokenAmount = _buy(tid, tokenAmount, user);
  }

  function sell(
    string memory tid,
    uint256 tokenAmount
  ) external override nonReentrant returns (uint256 payTokenAmount) {
    payTokenAmount = _sell(tid, tokenAmount, msg.sender);
  }

  function sellProxy(
    string memory tid,
    uint256 tokenAmount,
    address user
  ) external override onlyAppOperator nonReentrant returns (uint256 payTokenAmount) {
    payTokenAmount = _sell(tid, tokenAmount, user);
  }

  function mortgage(
    string memory tid,
    uint256 tokenAmount
  ) external override nonReentrant returns (uint256 nftTokenId, uint256 payTokenAmount) {
    (nftTokenId, payTokenAmount) = _mortgage(tid, tokenAmount, msg.sender);
  }

  function mortgageProxy(
    string memory tid,
    uint256 tokenAmount,
    address user
  ) external override onlyAppOperator nonReentrant returns (uint256 nftTokenId, uint256 payTokenAmount) {
    (nftTokenId, payTokenAmount) = _mortgage(tid, tokenAmount, user);
  }

  function mortgageAdd(
    uint256 nftTokenId,
    uint256 tokenAmount
  ) external override nonReentrant returns (uint256 payTokenAmount) {
    require(IERC721(mortgageNFT).ownerOf(nftTokenId) == msg.sender, "AOE");
    payTokenAmount = _mortgageAdd(nftTokenId, tokenAmount);
  }

  function mortgageAddProxy(
    uint256 nftTokenId,
    uint256 tokenAmount
  ) external override onlyAppOperator nonReentrant returns (uint256 payTokenAmount) {
    payTokenAmount = _mortgageAdd(nftTokenId, tokenAmount);
  }

  function redeem(
    uint256 nftTokenId,
    uint256 tokenAmount
  ) external payable override nonReentrant returns (uint256 payTokenAmount) {
    require(IERC721(mortgageNFT).ownerOf(nftTokenId) == msg.sender, "AOE");
    payTokenAmount = _redeem(nftTokenId, tokenAmount);
  }

  function redeemProxy(
    uint256 nftTokenId,
    uint256 tokenAmount
  ) external payable override onlyAppOperator nonReentrant returns (uint256 payTokenAmount) {
    payTokenAmount = _redeem(nftTokenId, tokenAmount);
  }

  function multiply(
    string memory tid,
    uint256 multiplyAmount
  ) external payable override nonReentrant returns (uint256 nftTokenId, uint256 payTokenAmount) {
    (nftTokenId, payTokenAmount) = _multiply(tid, multiplyAmount, msg.sender);
  }

  function multiplyProxy(
    string memory tid,
    uint256 multiplyAmount,
    address user
  ) external payable override onlyAppOperator nonReentrant returns (uint256 nftTokenId, uint256 payTokenAmount) {
    (nftTokenId, payTokenAmount) = _multiply(tid, multiplyAmount, user);
  }

  function multiplyAdd(
    uint256 nftTokenId,
    uint256 multiplyAmount
  ) external payable override nonReentrant returns (uint256 payTokenAmount) {
    require(IERC721(mortgageNFT).ownerOf(nftTokenId) == msg.sender, "AOE");

    payTokenAmount = _multiplyAdd(nftTokenId, multiplyAmount);
  }

  function multiplyAddProxy(
    uint256 nftTokenId,
    uint256 multiplyAmount
  ) external payable override onlyAppOperator nonReentrant returns (uint256 payTokenAmount) {
    payTokenAmount = _multiplyAdd(nftTokenId, multiplyAmount);
  }

  function cash(
    uint256 nftTokenId,
    uint256 tokenAmount
  ) external override nonReentrant returns (uint256 payTokenAmount) {
    require(IERC721(mortgageNFT).ownerOf(nftTokenId) == msg.sender, "AOE");
    payTokenAmount = _cash(nftTokenId, tokenAmount);
  }

  function cashProxy(
    uint256 nftTokenId,
    uint256 tokenAmount
  ) external override onlyAppOperator nonReentrant returns (uint256 payTokenAmount) {
    payTokenAmount = _cash(nftTokenId, tokenAmount);
  }

  function merge(
    uint256 nftTokenId,
    uint256 otherNFTTokenId
  ) external override nonReentrant returns (uint256 payTokenAmount) {
    require(IERC721(mortgageNFT).ownerOf(nftTokenId) == msg.sender, "AOE1");
    require(IERC721(mortgageNFT).ownerOf(otherNFTTokenId) == msg.sender, "AOE2");

    payTokenAmount = _merge(nftTokenId, otherNFTTokenId);
  }

  function mergeProxy(
    uint256 nftTokenId,
    uint256 otherNFTTokenId
  ) external override onlyAppOperator nonReentrant returns (uint256 payTokenAmount) {
    payTokenAmount = _merge(nftTokenId, otherNFTTokenId);
  }

  function split(
    uint256 nftTokenId,
    uint256 splitAmount
  ) external payable override nonReentrant returns (uint256 payTokenAmount, uint256 newNFTTokenId) {
    require(IERC721(mortgageNFT).ownerOf(nftTokenId) == msg.sender, "AOE");

    (payTokenAmount, newNFTTokenId) = _split(nftTokenId, splitAmount);
  }

  function splitProxy(
    uint256 nftTokenId,
    uint256 splitAmount
  ) external payable override onlyAppOperator nonReentrant returns (uint256 payTokenAmount, uint256 newNFTTokenId) {
    (payTokenAmount, newNFTTokenId) = _split(nftTokenId, splitAmount);
  }

  function _buy(string memory tid, uint256 tokenAmount, address user) private returns (uint256 payTokenAmount) {
    require(IFoundry(foundry).tokenExist(appId, tid), "TE");

    require(tokenAmount > 0, "TAE");

    uint256[] memory feeTokenIds;
    address[] memory feeTos;
    uint256[] memory feeAmounts;

    (payTokenAmount, feeTokenIds, feeTos, feeAmounts) = _buyWithoutPay(user, tid, tokenAmount);

    if (_payTokenIsERC20()) {
      _transferFromERC20PayTokenFromSender(payTokenAmount);
      _batchTransferERC20PayTokenToNFTOwners(feeTokenIds, feeTos, feeAmounts);
    } else {
      require(msg.value >= payTokenAmount, "VE");
      _batchTransferEthToNFTOwners(feeTokenIds, feeTos, feeAmounts);
      _refundETH(payTokenAmount);
    }

    emit Buy(tid, tokenAmount, payTokenAmount, msg.sender, user, feeTokenIds, feeTos, feeAmounts);
  }

  function _sell(string memory tid, uint256 tokenAmount, address user) private returns (uint256 payTokenAmount) {
    require(IFoundry(foundry).tokenExist(appId, tid), "TE");

    require(tokenAmount > 0, "TAE");
    require(tokenAmount <= _balanceOf[tid][user], "TAE");

    uint256[] memory feeTokenIds;
    address[] memory feeTos;
    uint256[] memory feeAmounts;

    (payTokenAmount, feeTokenIds, feeTos, feeAmounts) = _sellWithoutPay(user, tid, tokenAmount);

    if (_payTokenIsERC20()) {
      _transferERC20PayToken(msg.sender, payTokenAmount);
      _batchTransferERC20PayTokenToNFTOwners(feeTokenIds, feeTos, feeAmounts);
    } else {
      _transferEth(msg.sender, payTokenAmount);
      _batchTransferEthToNFTOwners(feeTokenIds, feeTos, feeAmounts);
    }

    emit Sell(tid, tokenAmount, payTokenAmount, msg.sender, user, feeTokenIds, feeTos, feeAmounts);
  }

  function _mortgage(
    string memory tid,
    uint256 tokenAmount,
    address user
  ) private returns (uint256 nftTokenId, uint256 payTokenAmount) {
    require(IFoundry(foundry).tokenExist(appId, tid), "TE");
    require(tokenAmount > 0, "TAE");
    require(tokenAmount <= _balanceOf[tid][user], "TAE");

    nftTokenId = IMortgageNFT(mortgageNFT).mint(user, tid, tokenAmount);

    payTokenAmount = _mortgageAddBase(nftTokenId, tid, 0, tokenAmount, user);
  }

  function _mortgageAdd(uint256 nftTokenId, uint256 tokenAmount) private returns (uint256 payTokenAmount) {
    (string memory tid, uint256 oldAmount) = IMortgageNFT(mortgageNFT).info(nftTokenId);
    address user = IERC721(mortgageNFT).ownerOf(nftTokenId);

    require(tokenAmount > 0, "TAE");
    require(tokenAmount <= _balanceOf[tid][user], "TAE");

    IMortgageNFT(mortgageNFT).add(nftTokenId, tokenAmount);

    payTokenAmount = _mortgageAddBase(nftTokenId, tid, oldAmount, tokenAmount, user);
  }

  function _redeem(uint256 nftTokenId, uint256 tokenAmount) private returns (uint256 payTokenAmount) {
    (string memory tid, uint256 oldAmount) = IMortgageNFT(mortgageNFT).info(nftTokenId);
    address user = IERC721(mortgageNFT).ownerOf(nftTokenId);

    require(tokenAmount > 0, "TAE");
    require(tokenAmount <= oldAmount, "TAE");

    payTokenAmount = getPayTokenAmount(oldAmount - tokenAmount, tokenAmount);

    IMortgageNFT(mortgageNFT).remove(nftTokenId, tokenAmount);

    _balanceOf[tid][address(this)] -= tokenAmount;
    _balanceOf[tid][user] += tokenAmount;

    if (_payTokenIsERC20()) {
      _transferFromERC20PayTokenFromSender(payTokenAmount);
    } else {
      require(msg.value >= payTokenAmount, "VE");
      _refundETH(payTokenAmount);
    }

    emit Redeem(nftTokenId, tid, tokenAmount, payTokenAmount, msg.sender);
  }

  function _multiply(
    string memory tid,
    uint256 multiplyAmount,
    address user
  ) private returns (uint256 nftTokenId, uint256 payTokenAmount) {
    require(IFoundry(foundry).tokenExist(appId, tid), "TE");
    require(multiplyAmount > 0, "TAE");

    nftTokenId = IMortgageNFT(mortgageNFT).mint(user, tid, multiplyAmount);

    payTokenAmount = _multiplyAddBase(nftTokenId, tid, 0, multiplyAmount);
  }

  function _multiplyAdd(uint256 nftTokenId, uint256 multiplyAmount) private returns (uint256 payTokenAmount) {
    require(multiplyAmount > 0, "TAE");

    (string memory tid, uint256 oldAmount) = IMortgageNFT(mortgageNFT).info(nftTokenId);
    IMortgageNFT(mortgageNFT).add(nftTokenId, multiplyAmount);

    payTokenAmount = _multiplyAddBase(nftTokenId, tid, oldAmount, multiplyAmount);
  }

  function _cash(uint256 nftTokenId, uint256 tokenAmount) private returns (uint256 payTokenAmount) {
    (string memory tid, uint256 oldAmount) = IMortgageNFT(mortgageNFT).info(nftTokenId);
    require(tokenAmount > 0, "TAE");
    require(tokenAmount <= oldAmount, "TAE");

    IMortgageNFT(mortgageNFT).remove(nftTokenId, tokenAmount);

    (
      uint256 sellAmount,
      uint256[] memory feeTokenIds,
      address[] memory feeTos,
      uint256[] memory feeAmounts
    ) = _sellWithoutPay(address(this), tid, tokenAmount);

    uint256 redeemPayTokenAmount = getPayTokenAmount(oldAmount - tokenAmount, tokenAmount);

    require(sellAmount >= redeemPayTokenAmount, "CE");
    payTokenAmount = sellAmount - redeemPayTokenAmount;

    if (_payTokenIsERC20()) {
      _transferERC20PayToken(msg.sender, payTokenAmount);
      _batchTransferERC20PayTokenToNFTOwners(feeTokenIds, feeTos, feeAmounts);
    } else {
      _transferEth(msg.sender, payTokenAmount);
      _batchTransferEthToNFTOwners(feeTokenIds, feeTos, feeAmounts);
    }

    emit Cash(nftTokenId, tid, tokenAmount, payTokenAmount, msg.sender, feeTokenIds, feeTos, feeAmounts);
  }

  function _buyWithoutPay(
    address to,
    string memory tid,
    uint256 tokenAmount
  )
    private
    returns (uint256 payTokenAmount, uint256[] memory feeTokenIds, address[] memory feeTos, uint256[] memory feeAmounts)
  {
    uint256 amount = getBuyPayTokenAmount(tid, tokenAmount);

    uint256 totalFee;
    (totalFee, feeTokenIds, feeTos, feeAmounts) = _getFee(tid, amount, buyFee);
    payTokenAmount = amount + totalFee;

    _totalSupply[tid] += tokenAmount;
    _balanceOf[tid][to] += tokenAmount;
  }

  function _sellWithoutPay(
    address from,
    string memory tid,
    uint256 tokenAmount
  )
    private
    returns (uint256 payTokenAmount, uint256[] memory feeTokenIds, address[] memory feeTos, uint256[] memory feeAmounts)
  {
    uint256 amount = getSellPayTokenAmount(tid, tokenAmount);

    uint256 totalFee;
    (totalFee, feeTokenIds, feeTos, feeAmounts) = _getFee(tid, amount, sellFee);
    payTokenAmount = amount - totalFee;

    _totalSupply[tid] -= tokenAmount;
    _balanceOf[tid][from] -= tokenAmount;
  }

  function _mortgageAddBase(
    uint256 tokenId,
    string memory tid,
    uint256 oldAmount,
    uint256 addAmount,
    address user
  ) private returns (uint256 payTokenAmount) {
    uint256 curveAmount = getPayTokenAmount(oldAmount, addAmount);
    uint256 feeAmount = _mortgageFee(curveAmount);

    _balanceOf[tid][user] -= addAmount;
    _balanceOf[tid][address(this)] += addAmount;

    payTokenAmount = curveAmount - feeAmount;

    if (_payTokenIsERC20()) {
      _transferERC20PayToken(msg.sender, payTokenAmount);
      _transferERC20PayTokenToMortgageFeeRecipient(feeAmount);
    } else {
      _transferEth(msg.sender, payTokenAmount);
      _transferEthToMortgageFeeRecipient(feeAmount);
    }

    emit Mortgage(tokenId, tid, addAmount, payTokenAmount, feeAmount, msg.sender);
  }

  function _multiplyAddBase(
    uint256 nftTokenId,
    string memory tid,
    uint256 oldAmount,
    uint256 multiplyAmount
  ) private returns (uint256 payTokenAmount) {
    (
      uint256 multiplyPayTokenAmount,
      uint256[] memory feeTokenIds,
      address[] memory feeTos,
      uint256[] memory feeAmounts
    ) = _buyWithoutPay(address(this), tid, multiplyAmount);

    uint256 curveAmount = getPayTokenAmount(oldAmount, multiplyAmount);
    uint256 feeAmount = _mortgageFee(curveAmount);
    uint256 mortAmount = curveAmount - feeAmount;
    payTokenAmount = multiplyPayTokenAmount - mortAmount;

    if (_payTokenIsERC20()) {
      _transferFromERC20PayTokenFromSender(payTokenAmount);

      _transferERC20PayTokenToMortgageFeeRecipient(feeAmount);
      _batchTransferERC20PayTokenToNFTOwners(feeTokenIds, feeTos, feeAmounts);
    } else {
      require(msg.value >= payTokenAmount, "VE");

      _transferEthToMortgageFeeRecipient(feeAmount);
      _batchTransferEthToNFTOwners(feeTokenIds, feeTos, feeAmounts);
      _refundETH(payTokenAmount);
    }

    emit Multiply(
      nftTokenId,
      tid,
      multiplyAmount,
      payTokenAmount,
      feeAmount,
      msg.sender,
      feeTokenIds,
      feeTos,
      feeAmounts
    );
  }

  function _merge(uint256 nftTokenId, uint256 otherNFTTokenId) private returns (uint256 payTokenAmount) {
    (string memory tid, uint256 oldAmount) = IMortgageNFT(mortgageNFT).info(nftTokenId);
    (string memory otherTid, uint256 otherOldAmount) = IMortgageNFT(mortgageNFT).info(otherNFTTokenId);

    require(keccak256(abi.encodePacked(tid)) == keccak256(abi.encodePacked(otherTid)), "TE");

    IMortgageNFT(mortgageNFT).burn(otherNFTTokenId);
    IMortgageNFT(mortgageNFT).add(nftTokenId, otherOldAmount);

    uint256 curveAmount = getPayTokenAmount(oldAmount, otherOldAmount) - getPayTokenAmount(0, otherOldAmount);
    uint256 feeAmount = _mortgageFee(curveAmount);
    payTokenAmount = curveAmount - feeAmount;

    if (_payTokenIsERC20()) {
      _transferERC20PayToken(msg.sender, payTokenAmount);
      _transferERC20PayTokenToMortgageFeeRecipient(feeAmount);
    } else {
      _transferEth(msg.sender, payTokenAmount);
      _transferEthToMortgageFeeRecipient(feeAmount);
    }

    emit Merge(nftTokenId, tid, otherNFTTokenId, payTokenAmount, feeAmount, msg.sender);
  }

  function _split(
    uint256 nftTokenId,
    uint256 splitAmount
  ) private returns (uint256 payTokenAmount, uint256 newNFTTokenId) {
    (string memory tid, uint256 oldAmount) = IMortgageNFT(mortgageNFT).info(nftTokenId);
    require(splitAmount > 0, "SAE");
    require(splitAmount < oldAmount, "SAE");

    address user = IERC721(mortgageNFT).ownerOf(nftTokenId);

    IMortgageNFT(mortgageNFT).remove(nftTokenId, splitAmount);
    newNFTTokenId = IMortgageNFT(mortgageNFT).mint(user, tid, splitAmount);

    payTokenAmount = getPayTokenAmount(oldAmount - splitAmount, splitAmount) - getPayTokenAmount(0, splitAmount);

    if (_payTokenIsERC20()) {
      _transferFromERC20PayTokenFromSender(payTokenAmount);
    } else {
      require(msg.value >= payTokenAmount, "VE");
      _refundETH(payTokenAmount);
    }

    emit Split(nftTokenId, newNFTTokenId, tid, splitAmount, payTokenAmount, msg.sender);
  }

  function _getFee(
    string memory tid,
    uint256 amount,
    uint256 buyOrSellFee
  )
    private
    view
    returns (uint256 totalFee, uint256[] memory tokenIds, address[] memory owners, uint256[] memory feeAmounts)
  {
    uint256[] memory percents;
    (tokenIds, percents, , owners) = IPublicNFT(publicNFT).tidToInfos(tid);

    feeAmounts = new uint256[](percents.length);

    for (uint256 i = 0; i < percents.length; i++) {
      uint256 feeAmount = (amount * buyOrSellFee * percents[i]) / totalPercent / feeDenominator;
      feeAmounts[i] = feeAmount;
      totalFee += feeAmount;
    }
  }

  function _payTokenIsERC20() private view returns (bool) {
    return payToken != address(0);
  }

  function _transferFromERC20PayTokenFromSender(uint256 value) private {
    SafeERC20.safeTransferFrom(IERC20(payToken), msg.sender, address(this), value);
  }

  function _batchTransferEthToNFTOwners(
    uint256[] memory tokenIds,
    address[] memory tos,
    uint256[] memory amounts
  ) private {
    for (uint256 i = 0; i < amounts.length; i++) {
      bool sup = ERC165Checker.supportsInterface(tos[i], type(IPublicNFTVault).interfaceId);

      if (sup) {
        _transferEthWithData(tokenIds[i], tos[i], amounts[i]);
      } else {
        _transferEth(tos[i], amounts[i]);
      }
    }
  }

  function _batchTransferERC20PayTokenToNFTOwners(
    uint256[] memory tokenIds,
    address[] memory tos,
    uint256[] memory amounts
  ) private {
    for (uint256 i = 0; i < amounts.length; i++) {
      bool sup = ERC165Checker.supportsInterface(tos[i], type(IPublicNFTVault).interfaceId);

      if (sup) {
        _transferERC20PayTokenWithData(tokenIds[i], tos[i], amounts[i]);
      } else {
        _transferERC20PayToken(tos[i], amounts[i]);
      }
    }
  }

  function _transferEthToMortgageFeeRecipient(uint256 feeAmount) private {
    _transferEth(IFoundry(foundry).mortgageFeeRecipient(appId), feeAmount);
  }

  function _transferERC20PayTokenToMortgageFeeRecipient(uint256 feeAmount) private {
    _transferERC20PayToken(IFoundry(foundry).mortgageFeeRecipient(appId), feeAmount);
  }

  function _refundETH(uint256 needPay) private {
    uint256 refund = msg.value - needPay;
    if (refund > 0) {
      _transferEth(msg.sender, refund);
    }
  }

  function _transferEth(address to, uint256 value) private {
    if (value > 0) {
      (bool success, ) = to.call{value: value}(new bytes(0));
      require(success, "TEE");
    }
  }

  function _transferEthWithData(uint256 tokenId, address to, uint256 value) private {
    _transferEth(to, value);
    bool success = IPublicNFTVault(to).recordReceiveBuySellFee(tokenId, value);
    require(success, "TEWDE");
  }

  function _transferERC20PayToken(address to, uint256 value) private {
    if (value > 0) {
      SafeERC20.safeTransfer(IERC20(payToken), to, value);
    }
  }

  function _transferERC20PayTokenWithData(uint256 tokenId, address to, uint256 value) private {
    _transferERC20PayToken(to, value);
    bool success = IPublicNFTVault(to).recordReceiveBuySellFee(tokenId, value);
    require(success, "TE2WDE");
  }

  function _mortgageFee(uint256 amount) private view returns (uint256) {
    return (IFoundry(foundry).mortgageFee(appId) * amount) / feeDenominator;
  }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/ReentrancyGuard.sol)

pragma solidity ^0.8.20;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant NOT_ENTERED = 1;
    uint256 private constant ENTERED = 2;

    uint256 private _status;

    /**
     * @dev Unauthorized reentrant call.
     */
    error ReentrancyGuardReentrantCall();

    constructor() {
        _status = NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be NOT_ENTERED
        if (_status == ENTERED) {
            revert ReentrancyGuardReentrantCall();
        }

        // Any calls to nonReentrant after this point will fail
        _status = ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = NOT_ENTERED;
    }

    /**
     * @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
     * `nonReentrant` function in the call stack.
     */
    function _reentrancyGuardEntered() internal view returns (bool) {
        return _status == ENTERED;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.20;

import {IERC20} from "../IERC20.sol";
import {IERC20Permit} from "../extensions/IERC20Permit.sol";
import {Address} from "../../../utils/Address.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using Address for address;

    /**
     * @dev An operation with an ERC20 token failed.
     */
    error SafeERC20FailedOperation(address token);

    /**
     * @dev Indicates a failed `decreaseAllowance` request.
     */
    error SafeERC20FailedDecreaseAllowance(address spender, uint256 currentAllowance, uint256 requestedDecrease);

    /**
     * @dev Transfer `value` amount of `token` from the calling contract to `to`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transfer, (to, value)));
    }

    /**
     * @dev Transfer `value` amount of `token` from `from` to `to`, spending the approval given by `from` to the
     * calling contract. If `token` returns no value, non-reverting calls are assumed to be successful.
     */
    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transferFrom, (from, to, value)));
    }

    /**
     * @dev Increase the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 oldAllowance = token.allowance(address(this), spender);
        forceApprove(token, spender, oldAllowance + value);
    }

    /**
     * @dev Decrease the calling contract's allowance toward `spender` by `requestedDecrease`. If `token` returns no
     * value, non-reverting calls are assumed to be successful.
     */
    function safeDecreaseAllowance(IERC20 token, address spender, uint256 requestedDecrease) internal {
        unchecked {
            uint256 currentAllowance = token.allowance(address(this), spender);
            if (currentAllowance < requestedDecrease) {
                revert SafeERC20FailedDecreaseAllowance(spender, currentAllowance, requestedDecrease);
            }
            forceApprove(token, spender, currentAllowance - requestedDecrease);
        }
    }

    /**
     * @dev Set the calling contract's allowance toward `spender` to `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful. Meant to be used with tokens that require the approval
     * to be set to zero before setting it to a non-zero value, such as USDT.
     */
    function forceApprove(IERC20 token, address spender, uint256 value) internal {
        bytes memory approvalCall = abi.encodeCall(token.approve, (spender, value));

        if (!_callOptionalReturnBool(token, approvalCall)) {
            _callOptionalReturn(token, abi.encodeCall(token.approve, (spender, 0)));
            _callOptionalReturn(token, approvalCall);
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We use {Address-functionCall} to perform this call, which verifies that
        // the target address contains contract code and also asserts for success in the low-level call.

        bytes memory returndata = address(token).functionCall(data);
        if (returndata.length != 0 && !abi.decode(returndata, (bool))) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturn} that silents catches all reverts and returns a bool instead.
     */
    function _callOptionalReturnBool(IERC20 token, bytes memory data) private returns (bool) {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We cannot use {Address-functionCall} here since this should return false
        // and not revert is the subcall reverts.

        (bool success, bytes memory returndata) = address(token).call(data);
        return success && (returndata.length == 0 || abi.decode(returndata, (bool))) && address(token).code.length > 0;
    }
}

{
  "compilationTarget": {
    "contracts/Market.sol": "Market"
  },
  "evmVersion": "paris",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "none"
  },
  "optimizer": {
    "enabled": true,
    "runs": 800
  },
  "remappings": []
}