// SPDX-License-Identifier: GPL-3.0

pragma solidity >=0.7.0 <0.9.0;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.0 (utils/introspection/IERC165.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[EIP].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[EIP section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.0 (token/ERC721/IERC721.sol)

pragma solidity ^0.8.0;

import "./IERC165.sol";

/**
 * @dev Required interface of an ERC721 compliant contract.
 */
interface IERC721 is IERC165 {
    /**
     * @dev Emitted when `tokenId` token is transferred from `from` to `to`.
     */
    event Transfer(address indexed from, address indexed to, uint256 indexed tokenId);

    /**
     * @dev Emitted when `owner` enables `approved` to manage the `tokenId` token.
     */
    event Approval(address indexed owner, address indexed approved, uint256 indexed tokenId);

    /**
     * @dev Emitted when `owner` enables or disables (`approved`) `operator` to manage all of its assets.
     */
    event ApprovalForAll(address indexed owner, address indexed operator, bool approved);

    /**
     * @dev Returns the number of tokens in ``owner``'s account.
     */
    function balanceOf(address owner) external view returns (uint256 balance);

    /**
     * @dev Returns the owner of the `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function ownerOf(uint256 tokenId) external view returns (address owner);

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`, checking first that contract recipients
     * are aware of the ERC721 protocol to prevent tokens from being forever locked.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must be have been allowed to move this token by either {approve} or {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId
    ) external;

    /**
     * @dev Transfers `tokenId` token from `from` to `to`.
     *
     * WARNING: Usage of this method is discouraged, use {safeTransferFrom} whenever possible.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(
        address from,
        address to,
        uint256 tokenId
    ) external;

    /**
     * @dev Gives permission to `to` to transfer `tokenId` token to another account.
     * The approval is cleared when the token is transferred.
     *
     * Only a single account can be approved at a time, so approving the zero address clears previous approvals.
     *
     * Requirements:
     *
     * - The caller must own the token or be an approved operator.
     * - `tokenId` must exist.
     *
     * Emits an {Approval} event.
     */
    function approve(address to, uint256 tokenId) external;

    /**
     * @dev Returns the account approved for `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function getApproved(uint256 tokenId) external view returns (address operator);

    /**
     * @dev Approve or remove `operator` as an operator for the caller.
     * Operators can call {transferFrom} or {safeTransferFrom} for any token owned by the caller.
     *
     * Requirements:
     *
     * - The `operator` cannot be the caller.
     *
     * Emits an {ApprovalForAll} event.
     */
    function setApprovalForAll(address operator, bool _approved) external;

    /**
     * @dev Returns if the `operator` is allowed to manage all of the assets of `owner`.
     *
     * See {setApprovalForAll}
     */
    function isApprovedForAll(address owner, address operator) external view returns (bool);

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId,
        bytes calldata data
    ) external;
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.0 (access/Ownable.sol)

pragma solidity ^0.8.0;

import "./Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _transferOwnership(_msgSender());
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
        _;
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions anymore. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby removing any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

import "./IERC721.sol";
import "./Ownable.sol";

contract Staking is Ownable {
    IERC721 public nftContract;
    
    bool public openStake;
    
    uint256 public startTime;
    uint256 public finishTime;
    mapping(uint256 => address) public termStaked;

    struct StakeData {
        address staker;
        uint64 stakeTime;
    }
    uint32 public minTempStakeTime;
    mapping(uint256 => StakeData) public tempStaked;

    event TermStaked(address indexed nftContract, address indexed staker, uint256 indexed tokenId);
    event TermUnstaked(address indexed nftContract, address indexed staker, uint256 indexed tokenId);
    
    event TempStaked(address indexed nftContract, address indexed staker, uint256 indexed tokenId);
    event TempUnstaked(address indexed nftContract, address indexed staker, uint256 indexed tokenId);

    constructor() {
        openStake = true;
        minTempStakeTime = 259200;
    }

    function setOpenStake(bool open) public onlyOwner {
        openStake = open;
    }

    function setNftContract(address nc) public onlyOwner {
        nftContract = IERC721(nc);
    }

    function setTermTime(uint256 start, uint256 finish) public onlyOwner {
        startTime = start;
        finishTime = finish;
    }

    modifier isOpenStake() {
        require(openStake, "TermStaking: stake is not open");
        _;
    }

    function termStake(uint256 tokenId) public isOpenStake {
        require(block.timestamp < startTime, "TermStaking: Not within the scheduled time period");
        nftContract.transferFrom(msg.sender, address(this), tokenId);
        termStaked[tokenId] = msg.sender;
        emit TermStaked(address(nftContract), msg.sender, tokenId);
    }

    function termBatStake(uint256 [] memory tokenIds) public isOpenStake {
        require(block.timestamp < startTime, "TermStaking: Not within the scheduled time period");
        
        for (uint256 i = 0; i < tokenIds.length; i ++) {
            uint256 tokenId = tokenIds[i];
            nftContract.transferFrom(msg.sender, address(this), tokenId);
            termStaked[tokenId] = msg.sender;
            emit TermStaked(address(nftContract), msg.sender, tokenId);
        }
    }

    function termUnstake(uint256 [] memory tokenIds) public isOpenStake {
        require(block.timestamp >= finishTime, "TermStaking: The scheduled time period has not ended yet");
        for (uint256 i = 0; i < tokenIds.length; i ++) {
            uint256 tokenId = tokenIds[i];
            require(termStaked[tokenId] == msg.sender, "TermStaking: You do not stake this NFT");
            delete termStaked[tokenId];
            nftContract.transferFrom(address(this), msg.sender, tokenId);
            emit TermUnstaked(address(nftContract), msg.sender, tokenId);
        }
    }
	
    function getTermStake(uint256 tokenId) public view returns (address) {
        return termStaked[tokenId];
    }

    function setMinTempStakeTime(uint32 minTime) public onlyOwner {
        minTempStakeTime = minTime;
    }

    function tempStake(uint256 tokenId) public isOpenStake {
        nftContract.transferFrom(msg.sender, address(this), tokenId);
        tempStaked[tokenId].staker = msg.sender;
        tempStaked[tokenId].stakeTime = uint64(block.timestamp);
        emit TempStaked(address(nftContract), msg.sender, tokenId);
    }

    function tempBatStake(uint256 [] memory tokenIds) public isOpenStake {
        for (uint256 i = 0; i < tokenIds.length; i ++) {
            uint256 tokenId = tokenIds[i];
            nftContract.transferFrom(msg.sender, address(this), tokenId);
            tempStaked[tokenId].staker = msg.sender;
            tempStaked[tokenId].stakeTime = uint64(block.timestamp);

            emit TempStaked(address(nftContract), msg.sender, tokenId);
        }
    }

    function tempUnstake(uint256 [] memory tokenIds) public isOpenStake {
        for (uint256 i = 0; i < tokenIds.length; i ++) {
            uint256 tokenId = tokenIds[i];
            require(tempStaked[tokenId].staker == msg.sender, "TempStaking: You do not stake this NFT");
            require((tempStaked[tokenId].stakeTime + uint64(minTempStakeTime)) < uint64(block.timestamp), "TempStaking: The staking time has not yet arrived");

            delete tempStaked[tokenId];
            nftContract.transferFrom(address(this), msg.sender, tokenId);
            emit TempUnstaked(address(nftContract), msg.sender, tokenId);
        }
    }
	
    function getTempStake(uint256 tokenId) public view returns (address, uint64) {
        return (tempStaked[tokenId].staker, tempStaked[tokenId].stakeTime);
    }
}

{
  "compilationTarget": {
    "contracts/Staking.sol": "Staking"
  },
  "evmVersion": "shanghai",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": false,
    "runs": 200
  },
  "remappings": []
}