// SPDX-License-Identifier: MIT
pragma solidity ^0.8.13;
import "./interfaces/IERC20.sol";
import "../common/Ownable.sol";
import "../common/SigLib.sol";

contract BondCurveDistro is Ownable {
    address public claimSigner;
    address public rewardToken;
    mapping(address => mapping(uint256 => mapping(uint256 => bool))) public usedClaimNonces;
    mapping(address => uint256) public claims;
    uint256 public devAlloc;
    uint public devFeeBp;
    uint256 public devFeeEthBal;
    uint256 public claimedBalance;
    uint256 public airdropAlloc;
    uint256 public k = 127330000000;
    uint256 public bondingCurveAlloc;
    uint256 public initialBondingCurveAlloc;
    uint256 public bondingCurveEthBal;
    bool public allowTrade = false;
    bool public allowClaim = false;
    bool public allowWithdraw = false;
    bool public allowSell = false;
    bool public allowBuyTransfer = false;
    uint256 scale = 1 ether;

    /// @dev Initialize contract
    /// @param _rewardToken The reward token address
    /// @param _airdropAlloc The airdrop supply
    /// @param _devAlloc The dev supply
    /// @param _bondingCurveAlloc The bonding curve supply
    /// @param _devFeeBp The dev fee in basis points
    constructor(address _rewardToken, uint256 _airdropAlloc, uint256 _devAlloc, uint256 _bondingCurveAlloc, uint256 _devFeeBp) {
        rewardToken = _rewardToken;
        bondingCurveAlloc = _bondingCurveAlloc;
        initialBondingCurveAlloc = _bondingCurveAlloc;
        devAlloc = _devAlloc;
        devFeeBp = _devFeeBp;
        airdropAlloc = _airdropAlloc;
    }

    event Claimed(address addr, uint claimId, uint nonce, uint256 allocation);
    event ClaimWithdrawn(address addr, uint256 amount);
    event WithdrawnToken(address beneficiary, uint256 amount);
    event AllowTrade(bool allowTrade);
    event AllowSell(bool allowSell);
    event AllowClaim(bool allowClaim);
    event AllowWithdraw(bool allowWithdraw);
    event AllowBuyTransfer(bool allowBuyTransfer);
    event Buy(address buyer, uint256 input, uint256 output, uint256 fee);
    event Sell(address seller, uint256 input, uint256 output, uint256 fee);
    event UpdatedDevFeeBp(uint devFeeBp);
    event WithdrawnEth(address beneficiary, uint256 amount);
    event WithdrawnDevFee(address beneficiary, uint256 amount);
    event ReInitialized(
        address rewardToken,
        uint256 airdropAlloc,
        uint256 devAlloc,
        uint256 bondingCurveAlloc,
        uint256 devFeeBp,
        uint256 k
    );
    event ClaimSignerUpdated(address newSigner, address oldSigner);

    /// @notice Reinitialize the contract
    /// @param _rewardToken The reward token address
    /// @param _airdropAlloc The airdrop supply
    /// @param _devAlloc The dev supply
    /// @param _bondingCurveAlloc The bonding curve supply
    /// @param _devFeeBp The dev fee in basis points
    /// @param _k The k value
    function reInit(
        address _rewardToken,
        uint256 _airdropAlloc,
        uint256 _devAlloc,
        uint256 _bondingCurveAlloc,
        uint256 _devFeeBp,
        uint256 _k
    ) public onlyOwner {
        rewardToken = _rewardToken;
        airdropAlloc = _airdropAlloc;
        devAlloc = _devAlloc;
        initialBondingCurveAlloc = _bondingCurveAlloc;
        bondingCurveAlloc = _bondingCurveAlloc;
        devFeeBp = _devFeeBp;
        k = _k;
        emit ReInitialized(_rewardToken, _airdropAlloc, _devAlloc, _bondingCurveAlloc, _devFeeBp, _k);
    }

    /// @notice Toggle to enable or disable buy/sell operations
    function toggleAllowTrade() public onlyOwner {
        allowTrade = !allowTrade;
        emit AllowTrade(allowTrade);
    }

    /// @notice Toggle to enable or disable sell option
    function toggleAllowSell() public onlyOwner {
        allowSell = !allowSell;
        emit AllowSell(allowSell);
    }

    /// @notice Toggle to enable or disable claim option
    function toggleAllowClaim() public onlyOwner {
        allowClaim = !allowClaim;
        emit AllowClaim(allowClaim);
    }

    /// @notice Toggle to enable or disable buy transfer option
    function toggleAllowBuyTransfer() public onlyOwner {
        allowBuyTransfer = !allowBuyTransfer;
        emit AllowBuyTransfer(allowBuyTransfer);
    }

    /// @notice Toggle to enable or disable withdraw option
    function toggleAllowWithdraw() public onlyOwner {
        allowWithdraw = !allowWithdraw;
        emit AllowWithdraw(allowWithdraw);
    }

    /// @notice Set the claim signer
    /// @param _claimSigner The claim signer address
    function setClaimSigner(address _claimSigner) public onlyOwner {
        emit ClaimSignerUpdated(_claimSigner, claimSigner);
        claimSigner = _claimSigner;
    }

    /// @notice Set the dev fee in basis points
    /// @param _devFeeBp The dev fee in basis points
    function setDevFeeBp(uint _devFeeBp) public onlyOwner {
        require(_devFeeBp <= 1000, "FEE_TOO_HIGH");
        devFeeBp = _devFeeBp;
        emit UpdatedDevFeeBp(devFeeBp);
    }

    function claim(uint256 amount, uint claimId, uint nonce, bytes memory sig) public {
        require(allowClaim, "CLAIM_NOT_ALLOWED");
        require(verifyClaimSig(claimSigner, msg.sender, amount, claimId, nonce, sig), "INVALID_SIG");

        // check if the nonce is used for the sender
        require(!usedClaimNonces[msg.sender][claimId][nonce], "NONCE_USED");
        usedClaimNonces[msg.sender][claimId][nonce] = true;

        // Increment claimed balance
        claimedBalance += amount;
        require(claimedBalance <= airdropAlloc, "CLAIM_ALLOC_EXCEEDED");

        claims[msg.sender] += amount;
        emit Claimed(msg.sender, claimId, nonce, amount);
    }

    /// @notice Verify a claim signature
    /// @param signer The market manager's address
    /// @param beneficiary The beneficiary address
    /// @param amount The amount to claim
    /// @param claimId The claim id
    /// @param nonce The nonce
    /// @param signature The signature created by the manager
    function verifyClaimSig(
        address signer,
        address beneficiary,
        uint256 amount,
        uint claimId,
        uint nonce,
        bytes memory signature
    ) internal view returns (bool) {
        if (address(0) == signer) return false;
        bytes32 messageHash = keccak256(abi.encode(block.chainid, beneficiary, amount, claimId, nonce));
        bytes32 ethSignedMessageHash = SigLib.getSignedMessageHash(messageHash);
        return SigLib.recoverSigner(ethSignedMessageHash, signature) == signer;
    }

    /// @notice Verify and claim multiple rewards
    /// @param signatures The signatures
    /// @param nonces The nonces
    /// @param allocations The allocations
    function claimMulti(bytes[] memory signatures, uint[] memory claimIds, uint[] memory nonces, uint256[] memory allocations) public {
        for (uint i = 0; i < signatures.length; i++) {
            claim(allocations[i], claimIds[i], nonces[i], signatures[i]);
        }
    }

    /// @notice Withdraw a claim
    function withdrawClaim() public {
        require(allowWithdraw, "WITHDRAW_NOT_ALLOWED");
        uint256 amount = claims[msg.sender];
        claims[msg.sender] = 0;
        IERC20(rewardToken).transfer(msg.sender, amount);
        emit ClaimWithdrawn(msg.sender, amount);
    }

    /// @notice Withdraw all tokens from the contract
    /// @param beneficiary The beneficiary address
    function withdrawToken(address beneficiary) public onlyOwner {
        require(beneficiary != address(0), "INVALID_BENEFICIARY");
        uint256 amount = IERC20(rewardToken).balanceOf(address(this));
        IERC20(rewardToken).transfer(beneficiary, amount);
        emit WithdrawnToken(beneficiary, amount);
    }

    /// @notice Withdraw all ETH from the contract
    function withdrawEth(address beneficiary) public onlyOwner {
        require(beneficiary != address(0), "INVALID_BENEFICIARY");
        uint256 amount = address(this).balance;
        emit WithdrawnEth(beneficiary, amount);
        payable(beneficiary).transfer(amount);
    }

    /// @notice Withdraw all dev fee from the contract
    function withdrawDevFee(address beneficiary) public onlyOwner {
        require(beneficiary != address(0), "INVALID_BENEFICIARY");
        uint256 amount = devFeeEthBal;
        devFeeEthBal = 0;
        emit WithdrawnDevFee(beneficiary, amount);
        payable(beneficiary).transfer(amount);
    }

    /// @notice Returns the circulating supply
    function circulatingSupply() public view returns (uint256) {
        return devAlloc + claimedBalance + (initialBondingCurveAlloc - bondingCurveAlloc);
    }

    /// @notice Buy tokens
    function buy(uint256 maxPrice) public payable {
        require(allowTrade, "TRADE_NOT_ALLOWED");

        uint256 value = msg.value;
        require(value > 0, "INVALID_AMOUNT");

        uint256 devFee = (value * devFeeBp) / 10000;
        value = value - devFee;
        devFeeEthBal += devFee;

        uint256 price = buyPrice(circulatingSupply());
        require(price <= maxPrice, "PRICE_TOO_HIGH");

        uint256 amount = (value * scale) / price;
        require(amount <= bondingCurveAlloc, "INSUFFICIENT_ALLOC");
        bondingCurveAlloc -= amount;
        bondingCurveEthBal += value;

        if (allowBuyTransfer) {
            IERC20(rewardToken).transfer(msg.sender, amount);
        } else {
            claims[msg.sender] += amount;
        }

        emit Buy(msg.sender, msg.value, amount, devFee);
    }

    /// @notice Sell tokens
    /// @param amount The amount to sell
    /// @param minPrice The minimum price to sell
    function sell(uint256 amount, uint256 minPrice) public {
        require(allowTrade, "TRADE_NOT_ALLOWED");
        require(allowSell, "SELL_NOT_ALLOWED");
        require(amount > 0, "INVALID_AMOUNT");

        uint256 price = sellPrice(circulatingSupply(), amount);
        require(price >= minPrice, "PRICE_TOO_LOW");

        uint256 value = (amount * price) / scale;

        bondingCurveAlloc += amount;
        bondingCurveEthBal -= value;

        uint256 devFee = (value * devFeeBp) / 10000;
        devFeeEthBal += devFee;
        value = value - devFee;

        payable(msg.sender).transfer(value);
        IERC20(rewardToken).transferFrom(msg.sender, address(this), amount);

        emit Sell(msg.sender, amount, value, devFee);
    }

    /// @notice Get the buy price
    /// @param supply The supply
    function buyPrice(uint256 supply) public view returns (uint256) {
        if (supply <= 0) return 0;
        return (k * (supply ** 2)) / (scale * scale) / scale;
    }

    /// @notice Get the sell price
    /// @param supply The supply
    /// @param amountToSell The amount to sell
    function sellPrice(uint256 supply, uint256 amountToSell) public view returns (uint256) {
        require(supply >= amountToSell, "INSUFFICIENT_SUPPLY");
        if (supply <= 0 || amountToSell <= 0) return 0;

        uint256 newSupply = supply - amountToSell;
        if (newSupply == 0) return scale;

        uint256 price = (k * (newSupply ** 2)) / (scale * scale) / scale;
        return price > 0 ? price : scale;
    }

    receive() external payable {
        buy(buyPrice(circulatingSupply()));
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Context.sol)

pragma solidity ^0.8.0;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (utils/cryptography/ECDSA.sol)

pragma solidity ^0.8.0;

import "../Strings.sol";

/**
 * @dev Elliptic Curve Digital Signature Algorithm (ECDSA) operations.
 *
 * These functions can be used to verify that a message was signed by the holder
 * of the private keys of a given address.
 */
library ECDSA {
    enum RecoverError {
        NoError,
        InvalidSignature,
        InvalidSignatureLength,
        InvalidSignatureS,
        InvalidSignatureV // Deprecated in v4.8
    }

    function _throwError(RecoverError error) private pure {
        if (error == RecoverError.NoError) {
            return; // no error: do nothing
        } else if (error == RecoverError.InvalidSignature) {
            revert("ECDSA: invalid signature");
        } else if (error == RecoverError.InvalidSignatureLength) {
            revert("ECDSA: invalid signature length");
        } else if (error == RecoverError.InvalidSignatureS) {
            revert("ECDSA: invalid signature 's' value");
        }
    }

    /**
     * @dev Returns the address that signed a hashed message (`hash`) with
     * `signature` or error string. This address can then be used for verification purposes.
     *
     * The `ecrecover` EVM opcode allows for malleable (non-unique) signatures:
     * this function rejects them by requiring the `s` value to be in the lower
     * half order, and the `v` value to be either 27 or 28.
     *
     * IMPORTANT: `hash` _must_ be the result of a hash operation for the
     * verification to be secure: it is possible to craft signatures that
     * recover to arbitrary addresses for non-hashed data. A safe way to ensure
     * this is by receiving a hash of the original message (which may otherwise
     * be too long), and then calling {toEthSignedMessageHash} on it.
     *
     * Documentation for signature generation:
     * - with https://web3js.readthedocs.io/en/v1.3.4/web3-eth-accounts.html#sign[Web3.js]
     * - with https://docs.ethers.io/v5/api/signer/#Signer-signMessage[ethers]
     *
     * _Available since v4.3._
     */
    function tryRecover(bytes32 hash, bytes memory signature) internal pure returns (address, RecoverError) {
        if (signature.length == 65) {
            bytes32 r;
            bytes32 s;
            uint8 v;
            // ecrecover takes the signature parameters, and the only way to get them
            // currently is to use assembly.
            /// @solidity memory-safe-assembly
            assembly {
                r := mload(add(signature, 0x20))
                s := mload(add(signature, 0x40))
                v := byte(0, mload(add(signature, 0x60)))
            }
            return tryRecover(hash, v, r, s);
        } else {
            return (address(0), RecoverError.InvalidSignatureLength);
        }
    }

    /**
     * @dev Returns the address that signed a hashed message (`hash`) with
     * `signature`. This address can then be used for verification purposes.
     *
     * The `ecrecover` EVM opcode allows for malleable (non-unique) signatures:
     * this function rejects them by requiring the `s` value to be in the lower
     * half order, and the `v` value to be either 27 or 28.
     *
     * IMPORTANT: `hash` _must_ be the result of a hash operation for the
     * verification to be secure: it is possible to craft signatures that
     * recover to arbitrary addresses for non-hashed data. A safe way to ensure
     * this is by receiving a hash of the original message (which may otherwise
     * be too long), and then calling {toEthSignedMessageHash} on it.
     */
    function recover(bytes32 hash, bytes memory signature) internal pure returns (address) {
        (address recovered, RecoverError error) = tryRecover(hash, signature);
        _throwError(error);
        return recovered;
    }

    /**
     * @dev Overload of {ECDSA-tryRecover} that receives the `r` and `vs` short-signature fields separately.
     *
     * See https://eips.ethereum.org/EIPS/eip-2098[EIP-2098 short signatures]
     *
     * _Available since v4.3._
     */
    function tryRecover(
        bytes32 hash,
        bytes32 r,
        bytes32 vs
    ) internal pure returns (address, RecoverError) {
        bytes32 s = vs & bytes32(0x7fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffff);
        uint8 v = uint8((uint256(vs) >> 255) + 27);
        return tryRecover(hash, v, r, s);
    }

    /**
     * @dev Overload of {ECDSA-recover} that receives the `r and `vs` short-signature fields separately.
     *
     * _Available since v4.2._
     */
    function recover(
        bytes32 hash,
        bytes32 r,
        bytes32 vs
    ) internal pure returns (address) {
        (address recovered, RecoverError error) = tryRecover(hash, r, vs);
        _throwError(error);
        return recovered;
    }

    /**
     * @dev Overload of {ECDSA-tryRecover} that receives the `v`,
     * `r` and `s` signature fields separately.
     *
     * _Available since v4.3._
     */
    function tryRecover(
        bytes32 hash,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) internal pure returns (address, RecoverError) {
        // EIP-2 still allows signature malleability for ecrecover(). Remove this possibility and make the signature
        // unique. Appendix F in the Ethereum Yellow paper (https://ethereum.github.io/yellowpaper/paper.pdf), defines
        // the valid range for s in (301): 0 < s < secp256k1n ÷ 2 + 1, and for v in (302): v ∈ {27, 28}. Most
        // signatures from current libraries generate a unique signature with an s-value in the lower half order.
        //
        // If your library generates malleable signatures, such as s-values in the upper range, calculate a new s-value
        // with 0xFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFEBAAEDCE6AF48A03BBFD25E8CD0364141 - s1 and flip v from 27 to 28 or
        // vice versa. If your library also generates signatures with 0/1 for v instead 27/28, add 27 to v to accept
        // these malleable signatures as well.
        if (uint256(s) > 0x7FFFFFFFFFFFFFFFFFFFFFFFFFFFFFFF5D576E7357A4501DDFE92F46681B20A0) {
            return (address(0), RecoverError.InvalidSignatureS);
        }

        // If the signature is valid (and not malleable), return the signer address
        address signer = ecrecover(hash, v, r, s);
        if (signer == address(0)) {
            return (address(0), RecoverError.InvalidSignature);
        }

        return (signer, RecoverError.NoError);
    }

    /**
     * @dev Overload of {ECDSA-recover} that receives the `v`,
     * `r` and `s` signature fields separately.
     */
    function recover(
        bytes32 hash,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) internal pure returns (address) {
        (address recovered, RecoverError error) = tryRecover(hash, v, r, s);
        _throwError(error);
        return recovered;
    }

    /**
     * @dev Returns an Ethereum Signed Message, created from a `hash`. This
     * produces hash corresponding to the one signed with the
     * https://eth.wiki/json-rpc/API#eth_sign[`eth_sign`]
     * JSON-RPC method as part of EIP-191.
     *
     * See {recover}.
     */
    function toEthSignedMessageHash(bytes32 hash) internal pure returns (bytes32) {
        // 32 is the length in bytes of hash,
        // enforced by the type signature above
        return keccak256(abi.encodePacked("\x19Ethereum Signed Message:\n32", hash));
    }

    /**
     * @dev Returns an Ethereum Signed Message, created from `s`. This
     * produces hash corresponding to the one signed with the
     * https://eth.wiki/json-rpc/API#eth_sign[`eth_sign`]
     * JSON-RPC method as part of EIP-191.
     *
     * See {recover}.
     */
    function toEthSignedMessageHash(bytes memory s) internal pure returns (bytes32) {
        return keccak256(abi.encodePacked("\x19Ethereum Signed Message:\n", Strings.toString(s.length), s));
    }

    /**
     * @dev Returns an Ethereum Signed Typed Data, created from a
     * `domainSeparator` and a `structHash`. This produces hash corresponding
     * to the one signed with the
     * https://eips.ethereum.org/EIPS/eip-712[`eth_signTypedData`]
     * JSON-RPC method as part of EIP-712.
     *
     * See {recover}.
     */
    function toTypedDataHash(bytes32 domainSeparator, bytes32 structHash) internal pure returns (bytes32) {
        return keccak256(abi.encodePacked("\x19\x01", domainSeparator, structHash));
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.13;

interface IERC20 {
    function balanceOf(address account) external view returns (uint256);

    function transfer(address recipient, uint256 amount) external returns (bool);

    function transferFrom(address sender, address recipient, uint256 amount) external returns (bool);

    function decimals() external view returns (uint8);

    function allowance(address owner, address spender) external view returns (uint256);

    function burn(uint256 amount) external;

    function mint(address to, uint256 amount) external;

    function approve(address spender, uint256 amount) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (utils/math/Math.sol)

pragma solidity ^0.8.0;

/**
 * @dev Standard math utilities missing in the Solidity language.
 */
library Math {
    enum Rounding {
        Down, // Toward negative infinity
        Up, // Toward infinity
        Zero // Toward zero
    }

    /**
     * @dev Returns the largest of two numbers.
     */
    function max(uint256 a, uint256 b) internal pure returns (uint256) {
        return a > b ? a : b;
    }

    /**
     * @dev Returns the smallest of two numbers.
     */
    function min(uint256 a, uint256 b) internal pure returns (uint256) {
        return a < b ? a : b;
    }

    /**
     * @dev Returns the average of two numbers. The result is rounded towards
     * zero.
     */
    function average(uint256 a, uint256 b) internal pure returns (uint256) {
        // (a + b) / 2 can overflow.
        return (a & b) + (a ^ b) / 2;
    }

    /**
     * @dev Returns the ceiling of the division of two numbers.
     *
     * This differs from standard division with `/` in that it rounds up instead
     * of rounding down.
     */
    function ceilDiv(uint256 a, uint256 b) internal pure returns (uint256) {
        // (a + b - 1) / b can overflow on addition, so we distribute.
        return a == 0 ? 0 : (a - 1) / b + 1;
    }

    /**
     * @notice Calculates floor(x * y / denominator) with full precision. Throws if result overflows a uint256 or denominator == 0
     * @dev Original credit to Remco Bloemen under MIT license (https://xn--2-umb.com/21/muldiv)
     * with further edits by Uniswap Labs also under MIT license.
     */
    function mulDiv(
        uint256 x,
        uint256 y,
        uint256 denominator
    ) internal pure returns (uint256 result) {
        unchecked {
            // 512-bit multiply [prod1 prod0] = x * y. Compute the product mod 2^256 and mod 2^256 - 1, then use
            // use the Chinese Remainder Theorem to reconstruct the 512 bit result. The result is stored in two 256
            // variables such that product = prod1 * 2^256 + prod0.
            uint256 prod0; // Least significant 256 bits of the product
            uint256 prod1; // Most significant 256 bits of the product
            assembly {
                let mm := mulmod(x, y, not(0))
                prod0 := mul(x, y)
                prod1 := sub(sub(mm, prod0), lt(mm, prod0))
            }

            // Handle non-overflow cases, 256 by 256 division.
            if (prod1 == 0) {
                return prod0 / denominator;
            }

            // Make sure the result is less than 2^256. Also prevents denominator == 0.
            require(denominator > prod1);

            ///////////////////////////////////////////////
            // 512 by 256 division.
            ///////////////////////////////////////////////

            // Make division exact by subtracting the remainder from [prod1 prod0].
            uint256 remainder;
            assembly {
                // Compute remainder using mulmod.
                remainder := mulmod(x, y, denominator)

                // Subtract 256 bit number from 512 bit number.
                prod1 := sub(prod1, gt(remainder, prod0))
                prod0 := sub(prod0, remainder)
            }

            // Factor powers of two out of denominator and compute largest power of two divisor of denominator. Always >= 1.
            // See https://cs.stackexchange.com/q/138556/92363.

            // Does not overflow because the denominator cannot be zero at this stage in the function.
            uint256 twos = denominator & (~denominator + 1);
            assembly {
                // Divide denominator by twos.
                denominator := div(denominator, twos)

                // Divide [prod1 prod0] by twos.
                prod0 := div(prod0, twos)

                // Flip twos such that it is 2^256 / twos. If twos is zero, then it becomes one.
                twos := add(div(sub(0, twos), twos), 1)
            }

            // Shift in bits from prod1 into prod0.
            prod0 |= prod1 * twos;

            // Invert denominator mod 2^256. Now that denominator is an odd number, it has an inverse modulo 2^256 such
            // that denominator * inv = 1 mod 2^256. Compute the inverse by starting with a seed that is correct for
            // four bits. That is, denominator * inv = 1 mod 2^4.
            uint256 inverse = (3 * denominator) ^ 2;

            // Use the Newton-Raphson iteration to improve the precision. Thanks to Hensel's lifting lemma, this also works
            // in modular arithmetic, doubling the correct bits in each step.
            inverse *= 2 - denominator * inverse; // inverse mod 2^8
            inverse *= 2 - denominator * inverse; // inverse mod 2^16
            inverse *= 2 - denominator * inverse; // inverse mod 2^32
            inverse *= 2 - denominator * inverse; // inverse mod 2^64
            inverse *= 2 - denominator * inverse; // inverse mod 2^128
            inverse *= 2 - denominator * inverse; // inverse mod 2^256

            // Because the division is now exact we can divide by multiplying with the modular inverse of denominator.
            // This will give us the correct result modulo 2^256. Since the preconditions guarantee that the outcome is
            // less than 2^256, this is the final result. We don't need to compute the high bits of the result and prod1
            // is no longer required.
            result = prod0 * inverse;
            return result;
        }
    }

    /**
     * @notice Calculates x * y / denominator with full precision, following the selected rounding direction.
     */
    function mulDiv(
        uint256 x,
        uint256 y,
        uint256 denominator,
        Rounding rounding
    ) internal pure returns (uint256) {
        uint256 result = mulDiv(x, y, denominator);
        if (rounding == Rounding.Up && mulmod(x, y, denominator) > 0) {
            result += 1;
        }
        return result;
    }

    /**
     * @dev Returns the square root of a number. If the number is not a perfect square, the value is rounded down.
     *
     * Inspired by Henry S. Warren, Jr.'s "Hacker's Delight" (Chapter 11).
     */
    function sqrt(uint256 a) internal pure returns (uint256) {
        if (a == 0) {
            return 0;
        }

        // For our first guess, we get the biggest power of 2 which is smaller than the square root of the target.
        //
        // We know that the "msb" (most significant bit) of our target number `a` is a power of 2 such that we have
        // `msb(a) <= a < 2*msb(a)`. This value can be written `msb(a)=2**k` with `k=log2(a)`.
        //
        // This can be rewritten `2**log2(a) <= a < 2**(log2(a) + 1)`
        // → `sqrt(2**k) <= sqrt(a) < sqrt(2**(k+1))`
        // → `2**(k/2) <= sqrt(a) < 2**((k+1)/2) <= 2**(k/2 + 1)`
        //
        // Consequently, `2**(log2(a) / 2)` is a good first approximation of `sqrt(a)` with at least 1 correct bit.
        uint256 result = 1 << (log2(a) >> 1);

        // At this point `result` is an estimation with one bit of precision. We know the true value is a uint128,
        // since it is the square root of a uint256. Newton's method converges quadratically (precision doubles at
        // every iteration). We thus need at most 7 iteration to turn our partial result with one bit of precision
        // into the expected uint128 result.
        unchecked {
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            return min(result, a / result);
        }
    }

    /**
     * @notice Calculates sqrt(a), following the selected rounding direction.
     */
    function sqrt(uint256 a, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = sqrt(a);
            return result + (rounding == Rounding.Up && result * result < a ? 1 : 0);
        }
    }

    /**
     * @dev Return the log in base 2, rounded down, of a positive value.
     * Returns 0 if given 0.
     */
    function log2(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >> 128 > 0) {
                value >>= 128;
                result += 128;
            }
            if (value >> 64 > 0) {
                value >>= 64;
                result += 64;
            }
            if (value >> 32 > 0) {
                value >>= 32;
                result += 32;
            }
            if (value >> 16 > 0) {
                value >>= 16;
                result += 16;
            }
            if (value >> 8 > 0) {
                value >>= 8;
                result += 8;
            }
            if (value >> 4 > 0) {
                value >>= 4;
                result += 4;
            }
            if (value >> 2 > 0) {
                value >>= 2;
                result += 2;
            }
            if (value >> 1 > 0) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 2, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log2(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log2(value);
            return result + (rounding == Rounding.Up && 1 << result < value ? 1 : 0);
        }
    }

    /**
     * @dev Return the log in base 10, rounded down, of a positive value.
     * Returns 0 if given 0.
     */
    function log10(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >= 10**64) {
                value /= 10**64;
                result += 64;
            }
            if (value >= 10**32) {
                value /= 10**32;
                result += 32;
            }
            if (value >= 10**16) {
                value /= 10**16;
                result += 16;
            }
            if (value >= 10**8) {
                value /= 10**8;
                result += 8;
            }
            if (value >= 10**4) {
                value /= 10**4;
                result += 4;
            }
            if (value >= 10**2) {
                value /= 10**2;
                result += 2;
            }
            if (value >= 10**1) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 10, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log10(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log10(value);
            return result + (rounding == Rounding.Up && 10**result < value ? 1 : 0);
        }
    }

    /**
     * @dev Return the log in base 256, rounded down, of a positive value.
     * Returns 0 if given 0.
     *
     * Adding one to the result gives the number of pairs of hex symbols needed to represent `value` as a hex string.
     */
    function log256(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >> 128 > 0) {
                value >>= 128;
                result += 16;
            }
            if (value >> 64 > 0) {
                value >>= 64;
                result += 8;
            }
            if (value >> 32 > 0) {
                value >>= 32;
                result += 4;
            }
            if (value >> 16 > 0) {
                value >>= 16;
                result += 2;
            }
            if (value >> 8 > 0) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 10, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log256(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log256(value);
            return result + (rounding == Rounding.Up && 1 << (result * 8) < value ? 1 : 0);
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (access/Ownable.sol)

pragma solidity ^0.8.13;

import "@openzeppelin/contracts/utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _transferOwnership(_msgSender());
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        require(owner() == _msgSender(), "OWNABLE: NOT_OWNER");
        _;
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions anymore. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby removing any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "INVALID_ADDRESS");
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: BUSL-1.1
pragma solidity ^0.8.13;

import "@openzeppelin/contracts/utils/cryptography/ECDSA.sol";

library SigLib {
    function getSignedMessageHash(bytes32 _messageHash) internal pure returns (bytes32) {
        return keccak256(abi.encodePacked("\x19Ethereum Signed Message:\n32", _messageHash));
    }

    function recoverSigner(bytes32 _ethSignedMessageHash, bytes memory _signature) internal pure returns (address) {
        (bytes32 r, bytes32 s, uint8 v) = splitSignature(_signature);
        (address addr, ) = ECDSA.tryRecover(_ethSignedMessageHash, v, r, s);
        return addr;
    }

    function splitSignature(bytes memory sig) internal pure returns (bytes32 r, bytes32 s, uint8 v) {
        require(sig.length == 65, "invalid signature length");
        assembly {
            r := mload(add(sig, 32))
            s := mload(add(sig, 64))
            v := byte(0, mload(add(sig, 96)))
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (utils/Strings.sol)

pragma solidity ^0.8.0;

import "./math/Math.sol";

/**
 * @dev String operations.
 */
library Strings {
    bytes16 private constant _SYMBOLS = "0123456789abcdef";
    uint8 private constant _ADDRESS_LENGTH = 20;

    /**
     * @dev Converts a `uint256` to its ASCII `string` decimal representation.
     */
    function toString(uint256 value) internal pure returns (string memory) {
        unchecked {
            uint256 length = Math.log10(value) + 1;
            string memory buffer = new string(length);
            uint256 ptr;
            /// @solidity memory-safe-assembly
            assembly {
                ptr := add(buffer, add(32, length))
            }
            while (true) {
                ptr--;
                /// @solidity memory-safe-assembly
                assembly {
                    mstore8(ptr, byte(mod(value, 10), _SYMBOLS))
                }
                value /= 10;
                if (value == 0) break;
            }
            return buffer;
        }
    }

    /**
     * @dev Converts a `uint256` to its ASCII `string` hexadecimal representation.
     */
    function toHexString(uint256 value) internal pure returns (string memory) {
        unchecked {
            return toHexString(value, Math.log256(value) + 1);
        }
    }

    /**
     * @dev Converts a `uint256` to its ASCII `string` hexadecimal representation with fixed length.
     */
    function toHexString(uint256 value, uint256 length) internal pure returns (string memory) {
        bytes memory buffer = new bytes(2 * length + 2);
        buffer[0] = "0";
        buffer[1] = "x";
        for (uint256 i = 2 * length + 1; i > 1; --i) {
            buffer[i] = _SYMBOLS[value & 0xf];
            value >>= 4;
        }
        require(value == 0, "Strings: hex length insufficient");
        return string(buffer);
    }

    /**
     * @dev Converts an `address` with fixed length of 20 bytes to its not checksummed ASCII `string` hexadecimal representation.
     */
    function toHexString(address addr) internal pure returns (string memory) {
        return toHexString(uint256(uint160(addr)), _ADDRESS_LENGTH);
    }
}

{
  "compilationTarget": {
    "contracts/token/BondCurveDistro.sol": "BondCurveDistro"
  },
  "evmVersion": "london",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": true,
    "runs": 200
  },
  "remappings": []
}