// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.2.0) (utils/Address.sol)

pragma solidity ^0.8.20;

import {Errors} from "./Errors.sol";

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev There's no code at `target` (it is not a contract).
     */
    error AddressEmptyCode(address target);

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.8.20/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        if (address(this).balance < amount) {
            revert Errors.InsufficientBalance(address(this).balance, amount);
        }

        (bool success, bytes memory returndata) = recipient.call{value: amount}("");
        if (!success) {
            _revert(returndata);
        }
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason or custom error, it is bubbled
     * up by this function (like regular Solidity function calls). However, if
     * the call reverted with no returned reason, this function reverts with a
     * {Errors.FailedCall} error.
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        if (address(this).balance < value) {
            revert Errors.InsufficientBalance(address(this).balance, value);
        }
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and reverts if the target
     * was not a contract or bubbling up the revert reason (falling back to {Errors.FailedCall}) in case
     * of an unsuccessful call.
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata
    ) internal view returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            // only check if target is a contract if the call was successful and the return data is empty
            // otherwise we already know that it was a contract
            if (returndata.length == 0 && target.code.length == 0) {
                revert AddressEmptyCode(target);
            }
            return returndata;
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and reverts if it wasn't, either by bubbling the
     * revert reason or with a default {Errors.FailedCall} error.
     */
    function verifyCallResult(bool success, bytes memory returndata) internal pure returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            return returndata;
        }
    }

    /**
     * @dev Reverts with returndata if present. Otherwise reverts with {Errors.FailedCall}.
     */
    function _revert(bytes memory returndata) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            assembly ("memory-safe") {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert Errors.FailedCall();
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (utils/Errors.sol)

pragma solidity ^0.8.20;

/**
 * @dev Collection of common custom errors used in multiple contracts
 *
 * IMPORTANT: Backwards compatibility is not guaranteed in future versions of the library.
 * It is recommended to avoid relying on the error API for critical functionality.
 *
 * _Available since v5.1._
 */
library Errors {
    /**
     * @dev The ETH balance of the account is not enough to perform the operation.
     */
    error InsufficientBalance(uint256 balance, uint256 needed);

    /**
     * @dev A call to an address target failed. The target may have reverted.
     */
    error FailedCall();

    /**
     * @dev The deployment failed.
     */
    error FailedDeployment();

    /**
     * @dev A necessary precompile is missing.
     */
    error MissingPrecompile(address);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable.sol)

pragma solidity ^0.8.20;

import {Context} from "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is set to the address provided by the deployer. This can
 * later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    /**
     * @dev The caller account is not authorized to perform an operation.
     */
    error OwnableUnauthorizedAccount(address account);

    /**
     * @dev The owner is not a valid owner account. (eg. `address(0)`)
     */
    error OwnableInvalidOwner(address owner);

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the address provided by the deployer as the initial owner.
     */
    constructor(address initialOwner) {
        if (initialOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(initialOwner);
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        if (owner() != _msgSender()) {
            revert OwnableUnauthorizedAccount(_msgSender());
        }
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        if (newOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.7.0) (security/Pausable.sol)

pragma solidity ^0.8.0;

import "../utils/Context.sol";

/**
 * @dev Contract module which allows children to implement an emergency stop
 * mechanism that can be triggered by an authorized account.
 *
 * This module is used through inheritance. It will make available the
 * modifiers `whenNotPaused` and `whenPaused`, which can be applied to
 * the functions of your contract. Note that they will not be pausable by
 * simply including this module, only once the modifiers are put in place.
 */
abstract contract Pausable is Context {
    /**
     * @dev Emitted when the pause is triggered by `account`.
     */
    event Paused(address account);

    /**
     * @dev Emitted when the pause is lifted by `account`.
     */
    event Unpaused(address account);

    bool private _paused;

    /**
     * @dev Initializes the contract in unpaused state.
     */
    constructor() {
        _paused = false;
    }

    /**
     * @dev Modifier to make a function callable only when the contract is not paused.
     *
     * Requirements:
     *
     * - The contract must not be paused.
     */
    modifier whenNotPaused() {
        _requireNotPaused();
        _;
    }

    /**
     * @dev Modifier to make a function callable only when the contract is paused.
     *
     * Requirements:
     *
     * - The contract must be paused.
     */
    modifier whenPaused() {
        _requirePaused();
        _;
    }

    /**
     * @dev Returns true if the contract is paused, and false otherwise.
     */
    function paused() public view virtual returns (bool) {
        return _paused;
    }

    /**
     * @dev Throws if the contract is paused.
     */
    function _requireNotPaused() internal view virtual {
        require(!paused(), "Pausable: paused");
    }

    /**
     * @dev Throws if the contract is not paused.
     */
    function _requirePaused() internal view virtual {
        require(paused(), "Pausable: not paused");
    }

    /**
     * @dev Triggers stopped state.
     *
     * Requirements:
     *
     * - The contract must not be paused.
     */
    function _pause() internal virtual whenNotPaused {
        _paused = true;
        emit Paused(_msgSender());
    }

    /**
     * @dev Returns to normal state.
     *
     * Requirements:
     *
     * - The contract must be paused.
     */
    function _unpause() internal virtual whenPaused {
        _paused = false;
        emit Unpaused(_msgSender());
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (security/ReentrancyGuard.sol)

pragma solidity ^0.8.0;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant _NOT_ENTERED = 1;
    uint256 private constant _ENTERED = 2;

    uint256 private _status;

    constructor() {
        _status = _NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be _NOT_ENTERED
        require(_status != _ENTERED, "ReentrancyGuard: reentrant call");

        // Any calls to nonReentrant after this point will fail
        _status = _ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = _NOT_ENTERED;
    }

    /**
     * @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
     * `nonReentrant` function in the call stack.
     */
    function _reentrancyGuardEntered() internal view returns (bool) {
        return _status == _ENTERED;
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;

import "@openzeppelin/contracts/access/Ownable.sol";
import "@openzeppelin/contracts/security/ReentrancyGuard.sol";
import "@openzeppelin/contracts/security/Pausable.sol";
import "@openzeppelin/contracts/utils/Address.sol";

/**
 * @title SayGM
 * @dev Smart contract that allows users to send "SayGM" messages on-chain,
 * with a fee requirement and a time limit between messages.
 * It includes streak tracking, leaderboard functionality, and additional security features.
 * Fees are accumulated in the contract and can be withdrawn to an address specified by the owner.
 */
contract SayGM is Ownable, ReentrancyGuard, Pausable {
    using Address for address payable;

    // Basic state variables
    mapping(address => uint256) public lastGm;
    mapping(address => uint256) public totalGMs;        // Total GM count
    mapping(address => uint256) public longestStreak;   // Longest streak
    mapping(address => uint256) public currentStreak;   // Current streak

    // Structure for the leaderboard
    struct UserStats {
        address userAddress;
        uint256 currentStreak;
        uint256 longestStreak;
        uint256 totalGMs;
    }
    
    UserStats[] public leaderboard;
    // 1-indexed mapping: a value of 0 indicates that the user is not on the leaderboard.
    mapping(address => uint256) private leaderboardIndex;
    uint256 public constant MAX_LEADERBOARD_SIZE = 100;

    // Contract settings
    address public feeRecipient;
    uint256 public gmFee;
    uint256 public timeLimit;
    
    // Event declarations
    event SayGMEvent(
        address indexed sender,
        address indexed receiver,
        string message,
        uint256 timestamp
    );
    event FeeRecipientUpdated(address indexed previousRecipient, address indexed newRecipient);
    event GMFeeUpdated(uint256 previousFee, uint256 newFee);
    event TimeLimitUpdated(uint256 previousTimeLimit, uint256 newTimeLimit);
    event FeesWithdrawn(address indexed recipient, uint256 amount);
    event StreakUpdated(address indexed user, uint256 newStreak);
    event NewLongestStreak(address indexed user, uint256 newRecord);
    event LeaderboardUpdated(address indexed user, uint256 rank);

    /**
     * @dev Initializes the contract with initial settings.
     * @param _feeRecipient The address where the accumulated fees will be sent.
     */
    constructor(address _feeRecipient) Ownable(msg.sender) {
        require(_feeRecipient != address(0), "SayGM: Invalid fee recipient");
        feeRecipient = _feeRecipient;
        gmFee = 0.000029 ether;  // Initial fee
        timeLimit = 24 hours;    // Initial time limit
    }

    /**
     * @dev Allows the user to send a SayGM message to themselves. An optional message can be added.
     */
    function sayGM(string calldata message) external payable nonReentrant whenNotPaused {
        require(msg.value == gmFee, "SayGM: Incorrect ETH fee");
        require(block.timestamp >= lastGm[msg.sender] + timeLimit, "SayGM: Wait before sending another GM");

        _processGM(msg.sender, msg.sender, message);
    }

    /**
     * @dev Allows the user to send a SayGM message to another address. An optional message can be added.
     * Only the sender's statistics are updated.
     */
    function sayGMTo(address recipient, string calldata message) external payable nonReentrant whenNotPaused {
        require(msg.value == gmFee, "SayGM: Incorrect ETH fee");
        require(recipient != address(0), "SayGM: Cannot send to zero address");
        require(block.timestamp >= lastGm[msg.sender] + timeLimit, "SayGM: Wait before sending another GM");

        _processGM(msg.sender, recipient, message);
    }

    /**
     * @dev Processes a GM message by updating statistics and the leaderboard.
     * It first stores the previous GM time, updates the streak, then updates lastGm and the leaderboard.
     * @param sender The address sending the GM.
     * @param recipient The address receiving the GM.
     * @param message The GM message.
     */
    function _processGM(address sender, address recipient, string calldata message) internal {
        uint256 previousGmTime = lastGm[sender]; // Store previous GM time
        _updateStreak(sender, previousGmTime);
        lastGm[sender] = block.timestamp; // Update lastGm afterwards
        _updateLeaderboard(sender);
        emit SayGMEvent(sender, recipient, message, block.timestamp);
    }

    /**
     * @dev Updates the user's streak information.
     * @param user The address of the user.
     * @param previousGmTime The timestamp of the previous GM message.
     */
    function _updateStreak(address user, uint256 previousGmTime) internal {
        uint256 currentTime = block.timestamp;
        
        if (totalGMs[user] == 0) {
            // First GM message
            currentStreak[user] = 1;
            longestStreak[user] = 1;
        } else {
            // Calculate the number of days passed since the previous GM (1 day = 86400 seconds)
            uint256 daysSinceLastGm = (currentTime - previousGmTime) / 86400;
            
            if (daysSinceLastGm <= 1) {
                // If one day or less has passed, the streak continues
                currentStreak[user]++;
                if (currentStreak[user] > longestStreak[user]) {
                    longestStreak[user] = currentStreak[user];
                    emit NewLongestStreak(user, longestStreak[user]);
                }
            } else {
                // Otherwise, reset the streak
                currentStreak[user] = 1;
            }
        }
        
        totalGMs[user]++;
        emit StreakUpdated(user, currentStreak[user]);
    }

    /**
     * @dev Updates the leaderboard.
     * It retrieves the user's current statistics (streak, total GM, etc.) and,
     * if the user is not yet on the leaderboard, adds them; if the leaderboard is full,
     * it compares with the user with the lowest score.
     * @param user The address of the user.
     */
    function _updateLeaderboard(address user) internal {
        UserStats memory stats = UserStats({
            userAddress: user,
            currentStreak: currentStreak[user],
            longestStreak: longestStreak[user],
            totalGMs: totalGMs[user]
        });

        if (leaderboardIndex[user] == 0) { // User is not yet on the leaderboard
            if (leaderboard.length < MAX_LEADERBOARD_SIZE) {
                leaderboard.push(stats);
                // 1-indexed: position = leaderboard.length
                leaderboardIndex[user] = leaderboard.length;
                _sortLeaderboard();
            } else {
                // If the leaderboard is full, compare the new user's streak with the lowest streak on the leaderboard
                if (stats.currentStreak > leaderboard[leaderboard.length - 1].currentStreak) {
                    address replacedUser = leaderboard[leaderboard.length - 1].userAddress;
                    leaderboard[leaderboard.length - 1] = stats;
                    // Remove the old user from the leaderboard (reset their index)
                    leaderboardIndex[replacedUser] = 0;
                    leaderboardIndex[user] = leaderboard.length;
                    _sortLeaderboard();
                }
            }
        } else {
            // If the user is already on the leaderboard, update their statistics.
            uint256 idx = leaderboardIndex[user] - 1;
            leaderboard[idx] = stats;
            _sortLeaderboard();
        }

        emit LeaderboardUpdated(user, leaderboardIndex[user]);
    }

    /**
     * @dev Sorts the leaderboard using a bubble sort algorithm,
     * ordering the entries in descending order based on current streak (highest streak at the top).
     * Suitable for up to 100 entries.
     */
    function _sortLeaderboard() internal {
        uint256 n = leaderboard.length;
        for (uint256 i = 0; i < n - 1; i++) {
            for (uint256 j = 0; j < n - i - 1; j++) {
                if (leaderboard[j].currentStreak < leaderboard[j + 1].currentStreak) {
                    UserStats memory temp = leaderboard[j];
                    leaderboard[j] = leaderboard[j + 1];
                    leaderboard[j + 1] = temp;
                    
                    // Update indices in 1-indexed format
                    leaderboardIndex[leaderboard[j].userAddress] = j + 1;
                    leaderboardIndex[leaderboard[j + 1].userAddress] = j + 2;
                }
            }
        }
    }

    /**
     * @dev Returns the top N users from the leaderboard.
     * @param n The number of users to return.
     */
    function getTopUsers(uint256 n) external view returns (UserStats[] memory) {
        require(n > 0 && n <= leaderboard.length, "SayGM: Invalid number of users requested");
        
        UserStats[] memory topUsers = new UserStats[](n);
        for (uint256 i = 0; i < n; i++) {
            topUsers[i] = leaderboard[i];
        }
        
        return topUsers;
    }

    /**
     * @dev Returns the statistics of a specific user.
     * @param user The address of the user.
     */
    function getUserStats(address user) external view returns (UserStats memory) {
        return UserStats({
            userAddress: user,
            currentStreak: currentStreak[user],
            longestStreak: longestStreak[user],
            totalGMs: totalGMs[user]
        });
    }

    /**
     * @dev Returns the rank (1-indexed) of a specific user on the leaderboard.
     * @param user The address of the user.
     */
    function getUserRank(address user) external view returns (uint256) {
        uint256 index = leaderboardIndex[user];
        require(index > 0, "SayGM: User not in leaderboard");
        return index;
    }

    /**
     * @dev Allows the owner to update the fee recipient address.
     * @param newFeeRecipient The new fee recipient address.
     */
    function setFeeRecipient(address newFeeRecipient) external onlyOwner {
        require(newFeeRecipient != address(0), "SayGM: Invalid fee recipient");
        emit FeeRecipientUpdated(feeRecipient, newFeeRecipient);
        feeRecipient = newFeeRecipient;
    }

    /**
     * @dev Allows the owner to update the SayGM fee.
     * @param newGmFee The new SayGM fee.
     */
    function setGmFee(uint256 newGmFee) external onlyOwner {
        emit GMFeeUpdated(gmFee, newGmFee);
        gmFee = newGmFee;
    }

    /**
     * @dev Allows the owner to update the time limit between consecutive SayGM messages.
     * @param newTimeLimit The new time limit (in seconds).
     */
    function setTimeLimit(uint256 newTimeLimit) external onlyOwner {
        require(newTimeLimit > 0, "SayGM: Time limit must be greater than 0");
        emit TimeLimitUpdated(timeLimit, newTimeLimit);
        timeLimit = newTimeLimit;
    }

    /**
     * @dev Withdraws all accumulated fees to the feeRecipient address.
     * Uses OpenZeppelin's Address library for secure transfers.
     */
    function withdrawFees() external onlyOwner nonReentrant {
        uint256 amount = address(this).balance;
        require(amount > 0, "SayGM: No fees to withdraw");

        payable(feeRecipient).sendValue(amount);
        emit FeesWithdrawn(feeRecipient, amount);
    }

    /**
     * @dev Returns the current ETH balance of the contract.
     */
    function contractBalance() external view returns (uint256) {
        return address(this).balance;
    }

    /**
     * @dev Pauses the contract to prevent SayGM messages in emergency situations.
     */
    function pause() external onlyOwner {
        _pause();
    }

    /**
     * @dev Unpauses the contract.
     */
    function unpause() external onlyOwner {
        _unpause();
    }

    /**
     * @dev Prevents direct ETH transfers to the contract.
     */
    receive() external payable {
        revert("SayGM: Direct ETH transfers not allowed");
    }
}

{
  "compilationTarget": {
    "contracts/SayGm.sol": "SayGM"
  },
  "evmVersion": "paris",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": true,
    "runs": 200
  },
  "remappings": []
}