// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/ERC20.sol)

pragma solidity 0.8.20;

import {IERC20} from "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import {IERC20Metadata} from "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
import {Context} from "@openzeppelin/contracts/utils/Context.sol";

interface IERC20Errors {
    error ERC20InvalidSender(address sender);
    error ERC20InvalidReceiver(address receiver);
    error ERC20InvalidApprover(address approver);
    error ERC20InvalidSpender(address spender);
    error ERC20InsufficientBalance(address owner, uint256 balance, uint256 value);
    error ERC20InsufficientAllowance(address spender, uint256 allowance, uint256 value);
}

/**
 * @dev Implementation of the {IERC20} interface.
 *
 * This implementation is agnostic to the way tokens are created. This means
 * that a supply mechanism has to be added in a derived contract using {_mint}.
 *
 * TIP: For a detailed writeup see our guide
 * https://forum.openzeppelin.com/t/how-to-implement-erc20-supply-mechanisms/226[How
 * to implement supply mechanisms].
 *
 * The default value of {decimals} is 18. To change this, you should override
 * this function so it returns a different value.
 *
 * We have followed general OpenZeppelin Contracts guidelines: functions revert
 * instead returning `false` on failure. This behavior is nonetheless
 * conventional and does not conflict with the expectations of ERC-20
 * applications.
 */
abstract contract ERC20 is Context, IERC20, IERC20Metadata, IERC20Errors {
    mapping(address account => uint256) internal _balances;

    mapping(address account => mapping(address spender => uint256)) private _allowances;

    uint256 internal _totalSupply;

    string private _name;
    string private _symbol;

    /**
     * @dev Sets the values for {name} and {symbol}.
     *
     * All two of these values are immutable: they can only be set once during
     * construction.
     */
    constructor(string memory name_, string memory symbol_) {
        _name = name_;
        _symbol = symbol_;
    }

    /**
     * @dev Returns the name of the token.
     */
    function name() public view virtual returns (string memory) {
        return _name;
    }

    /**
     * @dev Returns the symbol of the token, usually a shorter version of the
     * name.
     */
    function symbol() public view virtual returns (string memory) {
        return _symbol;
    }

    /**
     * @dev Returns the number of decimals used to get its user representation.
     * For example, if `decimals` equals `2`, a balance of `505` tokens should
     * be displayed to a user as `5.05` (`505 / 10 ** 2`).
     *
     * Tokens usually opt for a value of 18, imitating the relationship between
     * Ether and Wei. This is the default value returned by this function, unless
     * it's overridden.
     *
     * NOTE: This information is only used for _display_ purposes: it in
     * no way affects any of the arithmetic of the contract, including
     * {IERC20-balanceOf} and {IERC20-transfer}.
     */
    function decimals() public view virtual returns (uint8) {
        return 18;
    }

    /**
     * @dev See {IERC20-totalSupply}.
     */
    function totalSupply() public view virtual returns (uint256) {
        return _totalSupply;
    }

    /**
     * @dev See {IERC20-balanceOf}.
     */
    function balanceOf(address account) public view virtual returns (uint256) {
        return _balances[account];
    }

    /**
     * @dev See {IERC20-transfer}.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     * - the caller must have a balance of at least `value`.
     */
    function transfer(address to, uint256 value) public virtual returns (bool) {
        address owner = _msgSender();
        _transfer(owner, to, value);
        return true;
    }

    /**
     * @dev See {IERC20-allowance}.
     */
    function allowance(address owner, address spender) public view virtual returns (uint256) {
        return _allowances[owner][spender];
    }

    /**
     * @dev See {IERC20-approve}.
     *
     * NOTE: If `value` is the maximum `uint256`, the allowance is not updated on
     * `transferFrom`. This is semantically equivalent to an infinite approval.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function approve(address spender, uint256 value) public virtual returns (bool) {
        address owner = _msgSender();
        _approve(owner, spender, value);
        return true;
    }

    /**
     * @dev See {IERC20-transferFrom}.
     *
     * Skips emitting an {Approval} event indicating an allowance update. This is not
     * required by the ERC. See {xref-ERC20-_approve-address-address-uint256-bool-}[_approve].
     *
     * NOTE: Does not update the allowance if the current allowance
     * is the maximum `uint256`.
     *
     * Requirements:
     *
     * - `from` and `to` cannot be the zero address.
     * - `from` must have a balance of at least `value`.
     * - the caller must have allowance for ``from``'s tokens of at least
     * `value`.
     */
    function transferFrom(address from, address to, uint256 value) public virtual returns (bool) {
        address spender = _msgSender();
        _spendAllowance(from, spender, value);
        _transfer(from, to, value);
        return true;
    }

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to`.
     *
     * This internal function is equivalent to {transfer}, and can be used to
     * e.g. implement automatic token fees, slashing mechanisms, etc.
     *
     * Emits a {Transfer} event.
     *
     * NOTE: This function is not virtual, {_update} should be overridden instead.
     */
    function _transfer(address from, address to, uint256 value) internal {
        if (from == address(0)) {
            revert ERC20InvalidSender(address(0));
        }
        if (to == address(0)) {
            revert ERC20InvalidReceiver(address(0));
        }
        _update(from, to, value);
    }

    /**
     * @dev Transfers a `value` amount of tokens from `from` to `to`, or alternatively mints (or burns) if `from`
     * (or `to`) is the zero address. All customizations to transfers, mints, and burns should be done by overriding
     * this function.
     *
     * Emits a {Transfer} event.
     */
    function _update(address from, address to, uint256 value) internal virtual {
        if (from == address(0)) {
            // Overflow check required: The rest of the code assumes that totalSupply never overflows
            _totalSupply += value;
        } else {
            uint256 fromBalance = _balances[from];
            if (fromBalance < value) {
                revert ERC20InsufficientBalance(from, fromBalance, value);
            }
            unchecked {
                // Overflow not possible: value <= fromBalance <= totalSupply.
                _balances[from] = fromBalance - value;
            }
        }

        if (to == address(0)) {
            unchecked {
                // Overflow not possible: value <= totalSupply or value <= fromBalance <= totalSupply.
                _totalSupply -= value;
            }
        } else {
            unchecked {
                // Overflow not possible: balance + value is at most totalSupply, which we know fits into a uint256.
                _balances[to] += value;
            }
        }

        emit Transfer(from, to, value);
    }

    /**
     * @dev Creates a `value` amount of tokens and assigns them to `account`, by transferring it from address(0).
     * Relies on the `_update` mechanism
     *
     * Emits a {Transfer} event with `from` set to the zero address.
     *
     * NOTE: This function is not virtual, {_update} should be overridden instead.
     */
    function _mint(address account, uint256 value) internal {
        if (account == address(0)) {
            revert ERC20InvalidReceiver(address(0));
        }
        _update(address(0), account, value);
    }

    /**
     * @dev Destroys a `value` amount of tokens from `account`, lowering the total supply.
     * Relies on the `_update` mechanism.
     *
     * Emits a {Transfer} event with `to` set to the zero address.
     *
     * NOTE: This function is not virtual, {_update} should be overridden instead
     */
    function _burn(address account, uint256 value) internal {
        if (account == address(0)) {
            revert ERC20InvalidSender(address(0));
        }
        _update(account, address(0), value);
    }

    /**
     * @dev Sets `value` as the allowance of `spender` over the `owner` s tokens.
     *
     * This internal function is equivalent to `approve`, and can be used to
     * e.g. set automatic allowances for certain subsystems, etc.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `owner` cannot be the zero address.
     * - `spender` cannot be the zero address.
     *
     * Overrides to this logic should be done to the variant with an additional `bool emitEvent` argument.
     */
    function _approve(address owner, address spender, uint256 value) internal {
        _approve(owner, spender, value, true);
    }

    /**
     * @dev Variant of {_approve} with an optional flag to enable or disable the {Approval} event.
     *
     * By default (when calling {_approve}) the flag is set to true. On the other hand, approval changes made by
     * `_spendAllowance` during the `transferFrom` operation set the flag to false. This saves gas by not emitting any
     * `Approval` event during `transferFrom` operations.
     *
     * Anyone who wishes to continue emitting `Approval` events on the`transferFrom` operation can force the flag to
     * true using the following override:
     *
     * ```solidity
     * function _approve(address owner, address spender, uint256 value, bool) internal virtual override {
     *     super._approve(owner, spender, value, true);
     * }
     * ```
     *
     * Requirements are the same as {_approve}.
     */
    function _approve(address owner, address spender, uint256 value, bool emitEvent) internal virtual {
        if (owner == address(0)) {
            revert ERC20InvalidApprover(address(0));
        }
        if (spender == address(0)) {
            revert ERC20InvalidSpender(address(0));
        }
        _allowances[owner][spender] = value;
        if (emitEvent) {
            emit Approval(owner, spender, value);
        }
    }

    /**
     * @dev Updates `owner` s allowance for `spender` based on spent `value`.
     *
     * Does not update the allowance value in case of infinite allowance.
     * Revert if not enough allowance is available.
     *
     * Does not emit an {Approval} event.
     */
    function _spendAllowance(address owner, address spender, uint256 value) internal virtual {
        uint256 currentAllowance = allowance(owner, spender);
        if (currentAllowance != type(uint256).max) {
            if (currentAllowance < value) {
                revert ERC20InsufficientAllowance(spender, currentAllowance, value);
            }
            unchecked {
                _approve(owner, spender, currentAllowance - value, false);
            }
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/extensions/IERC20Metadata.sol)

pragma solidity ^0.8.20;

import {IERC20} from "../IERC20.sol";

/**
 * @dev Interface for the optional metadata functions from the ERC20 standard.
 */
interface IERC20Metadata is IERC20 {
    /**
     * @dev Returns the name of the token.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the symbol of the token.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the decimals places of the token.
     */
    function decimals() external view returns (uint8);
}

// SPDX-License-Identifier: UNLICENSED
pragma solidity ^0.8.20;

interface IOnlyUpFactory {
    function createToken(string memory name, string memory symbol) external returns (address token);
    function tradeFee() external view returns (uint256);
    function mainToTax() external view returns (uint256);
    function mainFromTax() external view returns (uint256);
    function creatorShare() external view returns (uint256);
    function treasuryShare() external view returns (uint256);
    function ownerGraduationMintShare() external view returns (uint256);
    function feeShares() external view returns (address treasury, uint256 creatorShare, uint256 treasuryShare);
    function getTaxes(address _from, address _to) external view returns (uint256 fromTax, uint256 toTax);
    function addInitialLiquidity(uint256 _reserve0, uint256 _reserve1) external;
    function tokenPriceBuffer() external view returns (int256);
    function graduationMintRatio() external view returns (uint256);
}

// SPDX-License-Identifier: UNLICENSED
pragma solidity 0.8.20;

interface IOnlyUpToken {
    /// @notice Thrown when minting is disabled
    error MintingDisabled();

    /// @notice Thrown when reentrancy is detected
    error NoReentrancy();

    /// @notice Thrown when token is not yet eligible for disabling
    error DisableTimeNotReached();

    /// @notice Thrown when airdrop token is invalid
    error InvalidAirdropToken();

    /// @notice Thrown when token must be disabled before airdrop
    error TokenNotDisabled();

    /// @notice Thrown when swap parameters are invalid
    error InvalidSwapParameters();

    /// @notice Thrown when airdrop is not initiated
    error AirdropNotInitiated();

    /// @notice Thrown when transfer is restricted
    error RestrictedTransfer();

    /// @notice Thrown when airdrop period is invalid
    error InvalidAirdropPeriod();

    /// @notice Thrown when reserve is invalid
    error InvalidReserveIn();

    /// @notice Thrown when sender is invalid
    error InvalidSender();

    /* ================================ EVENTS ================================ */
    /// @notice Emitted when the owner burns tokens.
    /// @param sender The address that initiated the burn.
    /// @param amount The amount of tokens burned.
    event OwnerBurn(address indexed sender, uint256 amount);

    /// @notice Emitted when the token evolves to a normal ERC20.
    /// @param token The address of the token.
    /// @param timestamp The timestamp of the evolve.
    event Evolve(address indexed token, uint256 timestamp);

    /// @notice Emitted on swaps, mimicking a Uni V2 pool interface.
    /// @param sender The address initiating the swap.
    /// @param amount0In The amount of Ether-based asset input.
    /// @param amount1In The amount of token input.
    /// @param amount0Out The amount of Ether-based asset output.
    /// @param amount1Out The amount of token output.
    /// @param to The recipient address of the output.
    event Swap(
        address indexed sender,
        uint256 amount0In,
        uint256 amount1In,
        uint256 amount0Out,
        uint256 amount1Out,
        address indexed to
    );

    /// @notice Emitted when liquidity is minted (not traditionally used here, but for Uni V2 compatibility).
    /// @param sender The address minting liquidity.
    /// @param amount0 The amount of Ether-based liquidity added.
    /// @param amount1 The amount of token liquidity added.
    event Mint(address indexed sender, uint256 amount0, uint256 amount1);

    /// @notice Emitted when liquidity is burned (not traditionally used here, but for Uni V2 compatibility).
    /// @param sender The address burning liquidity.
    /// @param amount0 The amount of Ether-based liquidity removed.
    /// @param amount1 The amount of token liquidity removed.
    event Burn(address indexed sender, uint256 amount0, uint256 amount1);

    /// @notice Emitted when the token is disabled.
    /// @param sender The address that initiated the disable.
    /// @param timestamp The timestamp of the disable.
    event Disable(address indexed sender, uint256 timestamp);

    /* ================================ FUNCTIONS ================================ */

    /// @notice Mints new tokens by depositing ETH or WETH
    /// @dev Converts the input ETH/WETH to token shares based on current ratio
    /// @param _receiver The address that will receive the minted tokens
    function mint(address _receiver) external payable;

    /// @notice Redeems tokens for ETH/WETH
    /// @dev Burns tokens and returns corresponding ETH/WETH amount minus fees
    /// @param _receiver The address that will receive the ETH/WETH
    /// @param _tokenAmount The amount of tokens to redeem
    function redeem(address _receiver, uint256 _tokenAmount) external;

    /// @notice Performs a swap operation (UniswapV2 compatibility)
    /// @dev Handles both token minting and redemption based on output parameters
    /// @param amount0Out The amount of ETH/WETH to output
    /// @param amount1Out The amount of tokens to output
    /// @param to The recipient address
    /// @param data Additional calldata (unused, for V2 compatibility)
    function swap(uint256 amount0Out, uint256 amount1Out, address to, bytes calldata data) external payable;

    /// @notice Calculates the tax amount for a transfer
    /// @dev Uses factory tax settings to determine the tax
    /// @param _from Source address
    /// @param _to Destination address
    /// @param _value Transfer amount
    /// @return The calculated tax amount
    function determineTax(address _from, address _to, uint256 _value) external view returns (uint256);

    /// @notice Gets the current reserves of the token and WETH
    /// @dev Used for price calculations and V2 compatibility
    /// @return reserve0 The token reserve
    /// @return reserve1 The WETH reserve
    /// @return blockTimestampLast The timestamp of the last update
    function getReserves() external view returns (uint112 reserve0, uint112 reserve1, uint32 blockTimestampLast);

    /// @notice Calculates the amount of tokens to receive for a given ETH input
    /// @param _amountIn The amount of ETH to swap
    /// @param _reserve0 Current token reserve
    /// @param _reserve1 Current WETH reserve
    /// @return The amount of tokens to receive
    function getAmountOut(uint256 _amountIn, uint256 _reserve0, uint256 _reserve1) external view returns (uint256);

    /// @notice Calculates the amount of ETH needed for a given token output
    /// @param _amountOut The desired amount of tokens
    /// @param _reserve0 Current token reserve
    /// @param _reserve1 Current WETH reserve
    /// @return The amount of ETH needed
    function getAmountIn(uint256 _amountOut, uint256 _reserve0, uint256 _reserve1) external view returns (uint256);
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.20;

interface IWETH {
    function deposit() external payable;

    function transfer(address to, uint256 value) external returns (bool);

    function withdraw(uint256) external;

    function balanceOf(address) external view returns (uint256);
}

// SPDX-License-Identifier: UNLICENSED
pragma solidity 0.8.20;

import {ERC20} from "./ERC20.sol";
import {IWETH} from "../interfaces/IWETH.sol";
import {IOnlyUpFactory} from "../interfaces/IOnlyUpFactory.sol";
import {IOnlyUpToken} from "../interfaces/IOnlyUpToken.sol";
import {Ownable} from "@openzeppelin/contracts/access/Ownable.sol";

/**
 * @title OnlyUpToken - A Self-Contained Liquidity Token
 * @notice A token that acts as its own liquidity pool before evolving to Uniswap V3
 * @dev Implements:
 *      1. Internal liquidity pool before evolution
 *      2. Configurable buy/sell taxes (max 25%)
 *      3. Fee distribution between owner (40%) and treasury (60%)
 *      4. Evolution to Uniswap V3 at 5 ETH threshold
 *      5. Tax burning mechanism to benefit holders
 * @author Robert M.C. Forster, Chiranjibi Poudyal
 */
contract OnlyUpToken is ERC20, IOnlyUpToken, Ownable {
    /* ================================ CONSTANTS ================================ */
    uint256 constant DIVISOR = 10_000;
    uint256 constant BUFFER = 1e18;
    uint256 constant INITIAL_ETH_PER_TOKEN = 1e13;
    int24 constant TICK_SPACING = 200;
    uint256 constant INITIAL_LIQUIDITY_MINT_RATIO = 4;

    /* ================================ STATE VARIABLES ================================ */
    IWETH private weth;
    IOnlyUpFactory public factory;

    bool public disabled;
    uint256 public genesis;
    address public token0;
    address public token1;
    bool private locked;

    uint256 private reserve1;
    uint256 private reserve0;
    uint256 private blockTimestampLast;

    /* ================================ CONSTRUCTOR ================================ */

    /// @notice Initializes the contract with a owner, token name, and symbol.
    /// @dev Sets up initial references, disables airdrop and accumulation periods by default.
    /// @param _owner The address designated as the owner of the contract.
    /// @param _name The name of the ERC20 token.
    /// @param _symbol The symbol of the ERC20 token.
    /// @param _weth The address of the WETH contract.
    constructor(address _owner, string memory _name, string memory _symbol, address _weth)
        ERC20(_name, _symbol)
        Ownable(_owner)
    {
        factory = IOnlyUpFactory(msg.sender);
        genesis = block.timestamp;
        weth = IWETH(_weth);
        token0 = address(this);
        token1 = _weth;
    }

    /* ================================ MODIFIERS ================================ */

    /// @dev Reverts if the contract is disabled (after a certain period).
    modifier notDisabled() {
        if (disabled) revert MintingDisabled();
        _;
    }

    /// @dev Prevents reentrant calls.
    modifier nonReentrant() {
        if (locked) revert NoReentrancy();
        locked = true;
        _;
        locked = false;
    }

    /* =========================== EXTERNAL - MAIN FUNCTIONS =========================== */

    /// @notice Buys tokens by depositing Ether or WETH, converting them into token shares.
    /// @dev Applies buy fees and updates reserves after minting shares.
    ///      If no Ether is sent, it uses excess WETH reserve in the contract as input.
    /// @param _receiver The address receiving the newly minted tokens.
    function mint(address _receiver) public payable notDisabled nonReentrant {
        uint256 ethAmount = msg.value;

        if (ethAmount > 0) weth.deposit{value: msg.value}();
        else ethAmount = weth.balanceOf(address(this)) - reserve1;

        uint256 fee = ethAmount * factory.tradeFee() / DIVISOR;
        uint256 ethAmtAfterFee = ethAmount - fee;
        _sendFees(fee);
        uint256 shares = convertToShares(ethAmtAfterFee);
        _mint(_receiver, shares);
        _updateReserves();

        // emit mint event
        emit Mint(msg.sender, 0, shares);
        emit Swap(msg.sender, ethAmount, 0, 0, shares, _receiver);
    }

    /// @notice Redeems tokens for Ether or WETH, reducing the caller’s token balance.
    /// @dev Applies sell fees and taxes, then withdraws Ether if called directly or
    ///      transfers WETH if called via a router. Only works when the token is not disabled.
    /// @param _receiver The address receiving the redeemed Ether or WETH.
    /// @param _tokenAmount The amount of tokens to redeem. If zero, uses the contract’s token balance.
    function redeem(address _receiver, uint256 _tokenAmount) public nonReentrant notDisabled {
        uint256 tokenAmount = _tokenAmount > 0 ? _tokenAmount : balanceOf(address(this));
        address burnFrom = _tokenAmount == 0 ? address(this) : msg.sender;
        _burn(burnFrom, tokenAmount);

        uint256 tax = (tokenAmount * factory.mainFromTax()) / DIVISOR;
        uint256 tokenAmountAfterTax = tokenAmount - tax;
        uint256 ethAmount = convertToAssets(tokenAmountAfterTax);
        uint256 fee = ethAmount * factory.tradeFee() / DIVISOR;
        _sendFees(fee);
        ethAmount -= fee;

        if (_tokenAmount == 0) {
            weth.transfer(_receiver, ethAmount);
        } else {
            weth.withdraw(ethAmount);
            payable(_receiver).transfer(ethAmount);
        }

        _updateReserves();
        emit Burn(msg.sender, 0, tokenAmount);
        emit Swap(msg.sender, 0, tokenAmount, ethAmount, 0, _receiver);
    }

    /* =========================== EXTERNAL - UNI V2 COMPATIBILITY =========================== */

    /// @notice Uni V2 style swap function.
    /// @dev If amount1Out > 0 and amount0Out == 0, acts as a buy (mint). If reversed, acts as a sell (redeem).
    /// @param amount0Out The token amount (Ether-based) to send out.
    /// @param amount1Out The token amount (OnlyUpToken) to send out.
    /// @param to The address receiving the output tokens.
    function swap(uint256 amount0Out, uint256 amount1Out, address to, bytes calldata) external payable {
        if (amount1Out > 0 && amount0Out == 0) {
            mint(to);
        } else if (amount0Out > 0 && amount1Out == 0) {
            redeem(to, amount0Out);
        } else {
            revert InvalidSwapParameters();
        }
    }

    receive() external payable {}

    /* ================================ VIEW FUNCTIONS ================================ */

    /// @notice Converts a given token amount into its underlying Ether value.
    /// @param _tokenAmount The amount of tokens.
    /// @return ethAmount The corresponding amount of Ether-based assets.
    function convertToAssets(uint256 _tokenAmount) public view returns (uint256 ethAmount) {
        uint256 ethPerToken = _totalSupply == 0 ? INITIAL_ETH_PER_TOKEN : (reserve1 * BUFFER) / _totalSupply;
        ethAmount = (_tokenAmount * ethPerToken) / BUFFER;
    }

    /// @notice Converts a given Ether amount into token shares.
    /// @param _ethAmount The amount of Ether-based assets.
    /// @return tokenAmount The corresponding token share amount.
    function convertToShares(uint256 _ethAmount) public view returns (uint256 tokenAmount) {
        uint256 ethPerToken = _totalSupply == 0 ? INITIAL_ETH_PER_TOKEN : ((reserve1 * BUFFER) / _totalSupply);
        tokenAmount = (_ethAmount * BUFFER) / ethPerToken;
    }

    /// @notice Returns the current reserves and last block timestamp.
    /// @return _reserve0 The reserve of the main token supply.
    /// @return _reserve1 The reserve of the Ether-based asset (WETH).
    /// @return _blockTimestampLast The last timestamp the reserves were updated.
    function getReserves() public view returns (uint112 _reserve0, uint112 _reserve1, uint32 _blockTimestampLast) {
        _reserve0 = uint112(reserve0);
        _reserve1 = uint112(reserve1);
        _blockTimestampLast = uint32(blockTimestampLast);
    }

    /// @notice Returns the taxes that would be applied for a given amount and direction (buy/sell).
    /// @param _amount The amount of assets (Ether or tokens).
    /// @param _buy True if buying (Ether -> token), false if selling (token -> Ether).
    /// @return taxes The calculated tax amount.
    function getTaxes(uint256 _amount, bool _buy) public view returns (uint256 taxes) {
        uint256 tax = _buy ? factory.mainFromTax() : factory.mainToTax();
        uint256 actualTax;
        if (_buy) {
            actualTax = (tax * reserve1 * BUFFER) / (reserve1 + _amount);
        } else {
            actualTax = (tax * _totalSupply * BUFFER) / (_totalSupply + _amount);
        }

        taxes = (_amount * actualTax) / DIVISOR / BUFFER;
    }

    /// @notice Calculates the tax amount for a token transfer between two addresses
    /// @dev This is a public wrapper around the internal _determineTax function
    function determineTax(address _from, address _to, uint256 _value) public view returns (uint256) {
        return _determineTax(_from, _to, _value);
    }

    /* =========================== VIEW - UNI V2 COMPATIBILITY =========================== */

    /// @notice Returns the output amount for a given input, emulating Uni V2 `getAmountOut`.
    /// @param _amountIn The input amount.
    /// @param _reserveIn The reserve corresponding to the input token.
    /// @return amountOut The output amount after taxes and fees.
    function getAmountOut(uint256 _amountIn, uint256 _reserveIn, uint256) public view returns (uint256 amountOut) {
        if (_reserveIn != reserve1 && _reserveIn != reserve0) revert InvalidReserveIn();
        address tokenIn = _reserveIn == reserve0 ? address(weth) : address(this);

        if (tokenIn == address(this)) {
            uint256 taxAmt = (_amountIn * factory.mainToTax()) / DIVISOR;
            uint256 actualAmt = _amountIn - taxAmt;
            uint256 ethAmount = convertToAssets(actualAmt); // converts mainTokenShares -> WETH
            uint256 fee = (ethAmount * factory.tradeFee()) / DIVISOR;
            amountOut = ethAmount - fee;
        } else {
            uint256 taxAmt = (_amountIn * factory.mainFromTax()) / DIVISOR;
            uint256 actualAmt = _amountIn - taxAmt;
            uint256 tokenAmount = convertToShares(actualAmt); // converts WETH -> mainTokenShares
            uint256 fee = (tokenAmount * factory.tradeFee()) / DIVISOR;
            amountOut = tokenAmount - fee;
        }
    }

    /// @notice Returns the input amount required for a given output, emulating Uni V2 `getAmountIn`.
    /// @param _amountOut The desired output amount.
    /// @param _reserveIn The reserve corresponding to the input token.
    /// @return amountIn The input amount required to achieve the given output after taxes and fees.
    function getAmountIn(uint256 _amountOut, uint256 _reserveIn, uint256) public view returns (uint256 amountIn) {
        if (_reserveIn != reserve1 && _reserveIn != reserve0) revert InvalidReserveIn();
        address tokenIn = _reserveIn == reserve0 ? address(weth) : address(this);

        uint256 tradeFee = factory.tradeFee();
        uint256 mainFromTax = factory.mainFromTax();
        uint256 mainToTax = factory.mainToTax();

        if (tokenIn == address(this)) {
            uint256 assetsNeeded = (_amountOut * DIVISOR) / (DIVISOR - tradeFee);
            uint256 sharesNeeded = convertToShares(assetsNeeded); // converts WETH -> mainTokenShares
            amountIn = (sharesNeeded * DIVISOR) / (DIVISOR - mainToTax);
        } else {
            uint256 sharesNeeded = (_amountOut * DIVISOR) / (DIVISOR - tradeFee);
            uint256 assetsNeeded = convertToAssets(sharesNeeded); // converts mainTokenShares -> WETH
            amountIn = (assetsNeeded * DIVISOR) / (DIVISOR - mainFromTax);
        }
    }

    /* ================================ INTERNAL FUNCTIONS ================================ */

    /// @dev Sends fees to the owner and treasury according to the factory’s fee distribution.
    /// @param _amount The amount of Ether-based fees to distribute.
    function _sendFees(uint256 _amount) internal {
        weth.withdraw(_amount);
        (address treasury, uint256 creatorShare, uint256 treasuryShare) = factory.feeShares();
        payable(owner()).transfer((_amount * creatorShare) / DIVISOR);
        payable(treasury).transfer((_amount * treasuryShare) / DIVISOR);
    }

    /// @dev Updates the internal reserves and timestamp. Called after minting/burning.
    function _updateReserves() internal {
        reserve1 = weth.balanceOf(address(this));
        reserve0 = _totalSupply;
        blockTimestampLast = block.timestamp;
    }

    /// @dev Internal accounting hook overriding `_update` in ERC20. Applies taxes and points updates on transfers.
    /// @param from The sender address.
    /// @param to The recipient address.
    /// @param value The transferred amount.
    function _update(address from, address to, uint256 value) internal virtual override {
        uint256 tax;
        if (!disabled) {
            tax = _determineTax(from, to, value);
            // burn the taxes so that holders get benefited from the tax
            if (tax > 0) {
                _awardTaxes(from, tax);
            }
        }
        // Final value to be received by address.
        uint256 receiveValue = value - tax;
        if (from == address(0)) {
            _totalSupply += receiveValue;
        } else {
            uint256 fromBalance = _balances[from];
            if (fromBalance < receiveValue) revert ERC20InsufficientBalance(from, fromBalance, receiveValue);
            unchecked {
                _balances[from] = fromBalance - receiveValue;
            }
        }

        if (to == address(0)) {
            unchecked {
                _totalSupply -= receiveValue;
            }
        } else {
            unchecked {
                _balances[to] += receiveValue;
            }
        }

        emit Transfer(from, to, receiveValue);
    }

    /// @dev Determines the tax amount for a given transfer.
    /// @param _from The sender address.
    /// @param _to The recipient address.
    /// @param _value The transfer amount.
    /// @return taxAmount The calculated tax.
    function _determineTax(address _from, address _to, uint256 _value) internal view returns (uint256 taxAmount) {
        if (_to == address(this)) return 0;
        (uint256 fromTax, uint256 toTax) = factory.getTaxes(_from, _to);
        taxAmount += (_value * fromTax) / DIVISOR;
        taxAmount += (_value * toTax) / DIVISOR;
    }

    /// @dev Burns the taxed amount and updates reserves, benefiting holders by increasing asset per share.
    /// @param _from The address from which tax is collected.
    /// @param _amount The tax amount to burn.
    function _awardTaxes(address _from, uint256 _amount) internal {
        address to = address(this);
        if (_from != address(0)) {
            _balances[_from] -= _amount;
            _totalSupply -= _amount;
            emit Transfer(_from, to, _amount);
            emit Transfer(to, _from, _amount);
        } else {
            emit Transfer(address(0), to, _amount);
            emit Transfer(to, address(0), _amount);
        }
    }

    /**
     * @notice Graduates token to Uniswap V3 liquidity positions
     * @dev External function that:
     *      1. Disables further minting/redeeming
     *      2. Mints additional supply based on graduationMintRatio
     *      3. Transfers all WETH to factory
     *      4. Creates two Uniswap V3 positions:
     *         - Token-only position with price buffer
     *         - WETH-only position for concentrated liquidity
     */
    function graduate() external onlyOwner {
        disabled = true;
        emit Disable(address(this), block.timestamp);
        uint256 mintAmount = (_totalSupply * factory.graduationMintRatio()) / DIVISOR;
        uint256 ownerAmount = mintAmount * factory.ownerGraduationMintShare() / DIVISOR;
        uint256 liquidityAmount = mintAmount - ownerAmount;

        // mint graduationMintRatio * current supply to factory
        _mint(address(factory), liquidityAmount);
        _mint(owner(), ownerAmount);

        // add liquidity to Sushiswap V3 Pool
        uint256 wethAmount = weth.balanceOf(address(this));
        // transfer weth so that we can add liquidity at one tick
        weth.transfer(address(factory), wethAmount);
        factory.addInitialLiquidity(mintAmount, wethAmount);

        // renounce ownership
        _transferOwnership(address(0));
        emit Evolve(address(this), block.timestamp);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable.sol)

pragma solidity ^0.8.20;

import {Context} from "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is set to the address provided by the deployer. This can
 * later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    /**
     * @dev The caller account is not authorized to perform an operation.
     */
    error OwnableUnauthorizedAccount(address account);

    /**
     * @dev The owner is not a valid owner account. (eg. `address(0)`)
     */
    error OwnableInvalidOwner(address owner);

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the address provided by the deployer as the initial owner.
     */
    constructor(address initialOwner) {
        if (initialOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(initialOwner);
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        if (owner() != _msgSender()) {
            revert OwnableUnauthorizedAccount(_msgSender());
        }
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        if (newOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

{
  "compilationTarget": {
    "src/tokens/OnlyUpToken.sol": "OnlyUpToken"
  },
  "evmVersion": "shanghai",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": true,
    "runs": 200
  },
  "remappings": [
    ":@chainlink/contracts/=lib/chainlink-brownie-contracts/contracts/",
    ":@openzeppelin/contracts-upgradeable/=lib/openzeppelin-contracts-upgradeable/contracts/",
    ":@openzeppelin/contracts/=lib/openzeppelin-contracts/contracts/",
    ":chainlink-brownie-contracts/=lib/chainlink-brownie-contracts/",
    ":ds-test/=lib/solmate/lib/ds-test/src/",
    ":erc4626-tests/=lib/openzeppelin-contracts-upgradeable/lib/erc4626-tests/",
    ":forge-std/=lib/forge-std/src/",
    ":openzeppelin-contracts-upgradeable/=lib/openzeppelin-contracts-upgradeable/",
    ":openzeppelin-contracts/=lib/openzeppelin-contracts/",
    ":solmate/=lib/solmate/src/"
  ]
}