pragma solidity ^0.8.17;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize, which returns 0 for contracts in
        // construction, since the code is only stored at the end of the
        // constructor execution.

        uint256 size;
        // solhint-disable-next-line no-inline-assembly
        assembly {
            size := extcodesize(account)
        }
        return size > 0;
    }

    /**
     * @dev Converts an `address` into `address payable`. Note that this is
     * simply a type cast: the actual underlying value is not changed.
     *
     * _Available since v2.4.0._
     */
    function toPayable(
        address account
    ) internal pure returns (address payable) {
        return payable(address(uint160(account)));
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://diligence.consensys.net/posts/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.5.11/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     *
     * _Available since v2.4.0._
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(
            address(this).balance >= amount,
            "Address: insufficient balance"
        );

        // solhint-disable-next-line avoid-call-value
        (bool success, ) = recipient.call{value: amount}("");
        require(
            success,
            "Address: unable to send value, recipient may have reverted"
        );
    }
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.17;

import "./SafeMath.sol";
import "./Initializable.sol";

/**
 * @dev Implementation of the {IERC20} interface.
 *
 * This implementation is agnostic to the way tokens are created. This means
 * that a supply mechanism has to be added in a derived contract using {_mint}.
 * For a generic mechanism see {ERC20PresetMinterPauser}.
 *
 * TIP: For a detailed writeup see our guide
 * https://forum.zeppelin.solutions/t/how-to-implement-erc20-supply-mechanisms/226[How
 * to implement supply mechanisms].
 *
 * We have followed general OpenZeppelin guidelines: functions revert instead
 * of returning `false` on failure. This behavior is nonetheless conventional
 * and does not conflict with the expectations of ERC20 applications.
 *
 * Additionally, an {Approval} event is emitted on calls to {transferFrom}.
 * This allows applications to reconstruct the allowance for all accounts just
 * by listening to said events. Other implementations of the EIP may not emit
 * these events, as it isn't required by the specification.
 *
 * Finally, the non-standard {decreaseAllowance} and {increaseAllowance}
 * functions have been added to mitigate the well-known issues around setting
 * allowances. See {IERC20-approve}.
 */
contract ERC20Upgradeable is Initializable {
    using SafeMath for uint256;

    mapping(address => uint256) private _balances;

    mapping(address => mapping(address => uint256)) private _allowances;

    uint256 private _totalSupply;

    string private _name;
    string private _symbol;
    uint8 private _decimals;

    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(
        address indexed owner,
        address indexed spender,
        uint256 value
    );

    /**
     * @dev Sets the values for {name} and {symbol}, initializes {decimals} with
     * a default value of 18.
     *
     * To select a different value for {decimals}, use {_setupDecimals}.
     *
     * All three of these values are immutable: they can only be set once during
     * construction.
     */
    // constructor (string memory name_, string memory symbol_) public {
    //     _name = name_;
    //     _symbol = symbol_;
    //     _decimals = 18;
    // }

    function __ERC20_init(
        string memory name_,
        string memory symbol_
    ) internal initializer {
        __ERC20_init_unchained(name_, symbol_);
    }

    function __ERC20_init_unchained(
        string memory name_,
        string memory symbol_
    ) internal initializer {
        _name = name_;
        _symbol = symbol_;
        _decimals = 18;
    }

    /**
     * @dev Returns the name of the token.
     */
    function name() public view returns (string memory) {
        return _name;
    }

    /**
     * @dev Returns the symbol of the token, usually a shorter version of the
     * name.
     */
    function symbol() public view returns (string memory) {
        return _symbol;
    }

    /**
     * @dev Returns the number of decimals used to get its user representation.
     * For example, if `decimals` equals `2`, a balance of `505` tokens should
     * be displayed to a user as `5,05` (`505 / 10 ** 2`).
     *
     * Tokens usually opt for a value of 18, imitating the relationship between
     * Ether and Wei. This is the value {ERC20} uses, unless {_setupDecimals} is
     * called.
     *
     * NOTE: This information is only used for _display_ purposes: it in
     * no way affects any of the arithmetic of the contract, including
     * {IERC20-balanceOf} and {IERC20-transfer}.
     */
    function decimals() public view returns (uint8) {
        return _decimals;
    }

    /**
     * @dev See {IERC20-totalSupply}.
     */
    function totalSupply() public view returns (uint256) {
        return _totalSupply;
    }

    /**
     * @dev See {IERC20-balanceOf}.
     */
    function balanceOf(address account) public view returns (uint256) {
        return _balances[account];
    }

    /**
     * @dev See {IERC20-transfer}.
     *
     * Requirements:
     *
     * - `recipient` cannot be the zero address.
     * - the caller must have a balance of at least `amount`.
     */
    function transfer(address recipient, uint256 amount) public returns (bool) {
        _transfer(msg.sender, recipient, amount);
        return true;
    }

    /**
     * @dev See {IERC20-allowance}.
     */
    function allowance(
        address owner,
        address spender
    ) public view returns (uint256) {
        return _allowances[owner][spender];
    }

    /**
     * @dev See {IERC20-approve}.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function approve(
        address spender,
        uint256 amount
    ) public virtual returns (bool) {
        _approve(msg.sender, spender, amount);
        return true;
    }

    /**
     * @dev See {IERC20-transferFrom}.
     *
     * Emits an {Approval} event indicating the updated allowance. This is not
     * required by the EIP. See the note at the beginning of {ERC20}.
     *
     * Requirements:
     *
     * - `sender` and `recipient` cannot be the zero address.
     * - `sender` must have a balance of at least `amount`.
     * - the caller must have allowance for ``sender``'s tokens of at least
     * `amount`.
     */
    function transferFrom(
        address sender,
        address recipient,
        uint256 amount
    ) public returns (bool) {
        _transfer(sender, recipient, amount);
        _approve(
            sender,
            msg.sender,
            _allowances[sender][msg.sender].sub(
                amount,
                "ERC20: transfer amount exceeds allowance"
            )
        );
        return true;
    }

    /**
     * @dev Atomically increases the allowance granted to `spender` by the caller.
     *
     * This is an alternative to {approve} that can be used as a mitigation for
     * problems described in {IERC20-approve}.
     *
     * Emits an {Approval} event indicating the updated allowance.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function increaseAllowance(
        address spender,
        uint256 addedValue
    ) public virtual returns (bool) {
        _approve(
            msg.sender,
            spender,
            _allowances[msg.sender][spender].add(addedValue)
        );
        return true;
    }

    /**
     * @dev Atomically decreases the allowance granted to `spender` by the caller.
     *
     * This is an alternative to {approve} that can be used as a mitigation for
     * problems described in {IERC20-approve}.
     *
     * Emits an {Approval} event indicating the updated allowance.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `spender` must have allowance for the caller of at least
     * `subtractedValue`.
     */
    function decreaseAllowance(
        address spender,
        uint256 subtractedValue
    ) public virtual returns (bool) {
        _approve(
            msg.sender,
            spender,
            _allowances[msg.sender][spender].sub(
                subtractedValue,
                "ERC20: decreased allowance below zero"
            )
        );
        return true;
    }

    /**
     * @dev Moves tokens `amount` from `sender` to `recipient`.
     *
     * This is internal function is equivalent to {transfer}, and can be used to
     * e.g. implement automatic token fees, slashing mechanisms, etc.
     *
     * Emits a {Transfer} event.
     *
     * Requirements:
     *
     * - `sender` cannot be the zero address.
     * - `recipient` cannot be the zero address.
     * - `sender` must have a balance of at least `amount`.
     */
    function _transfer(
        address sender,
        address recipient,
        uint256 amount
    ) internal {
        require(sender != address(0), "ERC20: transfer from the zero address");
        require(recipient != address(0), "ERC20: transfer to the zero address");

        _beforeTokenTransfer(sender, recipient, amount);

        _balances[sender] = _balances[sender].sub(
            amount,
            "ERC20: transfer amount exceeds balance"
        );
        _balances[recipient] = _balances[recipient].add(amount);
        emit Transfer(sender, recipient, amount);

        _afterTokenTransfer(sender, recipient, amount);
    }

    /** @dev Creates `amount` tokens and assigns them to `account`, increasing
     * the total supply.
     *
     * Emits a {Transfer} event with `from` set to the zero address.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     */
    function _mint(address account, uint256 amount) internal virtual {
        require(account != address(0), "ERC20: mint to the zero address");

        _beforeTokenTransfer(address(0), account, amount);

        _totalSupply = _totalSupply.add(amount);
        _balances[account] = _balances[account].add(amount);
        emit Transfer(address(0), account, amount);

        _afterTokenTransfer(address(0), account, amount);
    }

    /**
     * @dev Destroys `amount` tokens from `account`, reducing the
     * total supply.
     *
     * Emits a {Transfer} event with `to` set to the zero address.
     *
     * Requirements:
     *
     * - `account` cannot be the zero address.
     * - `account` must have at least `amount` tokens.
     */
    function _burn(address account, uint256 amount) internal virtual {
        require(account != address(0), "ERC20: burn from the zero address");

        _beforeTokenTransfer(account, address(0), amount);

        _balances[account] = _balances[account].sub(
            amount,
            "ERC20: burn amount exceeds balance"
        );
        _totalSupply = _totalSupply.sub(amount);
        emit Transfer(account, address(0), amount);

        _afterTokenTransfer(account, address(0), amount);
    }

    /**
     * @dev Sets `amount` as the allowance of `spender` over the `owner` s tokens.
     *
     * This internal function is equivalent to `approve`, and can be used to
     * e.g. set automatic allowances for certain subsystems, etc.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `owner` cannot be the zero address.
     * - `spender` cannot be the zero address.
     */
    function _approve(address owner, address spender, uint256 amount) internal {
        require(owner != address(0), "ERC20: approve from the zero address");
        require(spender != address(0), "ERC20: approve to the zero address");

        _allowances[owner][spender] = amount;
        emit Approval(owner, spender, amount);
    }

    /**
     * @dev Sets {decimals} to a value other than the default one of 18.
     *
     * WARNING: This function should only be called from the constructor. Most
     * applications that interact with token contracts will not expect
     * {decimals} to ever change, and may work incorrectly if it does.
     */
    function _setupDecimals(uint8 decimals_) internal {
        _decimals = decimals_;
    }

    /**
     * @dev Hook that is called before any transfer of tokens. This includes
     * minting and burning.
     *
     * Calling conditions:
     *
     * - when `from` and `to` are both non-zero, `amount` of ``from``'s tokens
     * will be to transferred to `to`.
     * - when `from` is zero, `amount` tokens will be minted for `to`.
     * - when `to` is zero, `amount` of ``from``'s tokens will be burned.
     * - `from` and `to` are never both zero.
     *
     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
     */
    function _beforeTokenTransfer(
        address from,
        address to,
        uint256 amount
    ) internal virtual {}

    /**
     * @dev Hook that is called after any transfer of tokens. This includes
     * minting and burning.
     */
    function _afterTokenTransfer(
        address from,
        address to,
        uint256 amount
    ) internal {}

    uint256[44] private __gap;
}

// SPDX-License-Identifier: GPL-3.0

pragma solidity >=0.5.0;

interface IERC20 {
    event Approval(address indexed owner, address indexed spender, uint value);
    event Transfer(address indexed from, address indexed to, uint value);

    function name() external view returns (string memory);
    function symbol() external view returns (string memory);
    function decimals() external view returns (uint8);
    function totalSupply() external view returns (uint);
    function balanceOf(address owner) external view returns (uint);
    function allowance(address owner, address spender) external view returns (uint);

    function approve(address spender, uint value) external returns (bool);
    function transfer(address to, uint value) external returns (bool);
    function transferFrom(address from, address to, uint value) external returns (bool);
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.17;

/**
 * @title Initializable
 *
 * @dev Helper contract to support initializer functions. To use it, replace
 * the constructor with a function that has the `initializer` modifier.
 * WARNING: Unlike constructors, initializer functions must be manually
 * invoked. This applies both to deploying an Initializable contract, as well
 * as extending an Initializable contract via inheritance.
 * WARNING: When used with inheritance, manual care must be taken to not invoke
 * a parent initializer twice, or ensure that all initializers are idempotent,
 * because this is not dealt with automatically as with constructors.
 */
contract Initializable {
    /**
     * @dev Indicates that the contract has been initialized.
     */
    bool private initialized;

    /**
     * @dev Indicates that the contract is in the process of being initialized.
     */
    bool private initializing;

    /**
     * @dev Modifier to use in the initializer function of a contract.
     */
    modifier initializer() {
        require(
            initializing || isConstructor() || !initialized,
            "Contract instance has already been initialized"
        );

        bool isTopLevelCall = !initializing;
        if (isTopLevelCall) {
            initializing = true;
            initialized = true;
        }

        _;

        if (isTopLevelCall) {
            initializing = false;
        }
    }

    /// @dev Returns true if and only if the function is running in the constructor
    function isConstructor() private view returns (bool) {
        // extcodesize checks the size of the code stored in an address, and
        // address returns the current address. Since the code is still not
        // deployed when running a constructor, any checks on its code size will
        // yield zero, making it an effective way to detect if a contract is
        // under construction or not.
        address self = address(this);
        uint256 cs;
        assembly {
            cs := extcodesize(self)
        }
        return cs == 0;
    }

    // Reserved storage space to allow for layout changes in the future.
    uint256[50] private ______gap;
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.17;

import "./Initializable.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 *
 * Reference:
 *
 * - https://github.com/OpenZeppelin/openzeppelin-contracts/blob/v3.0.1/contracts/access/Ownable.sol
 */
contract OwnableUpgradeable is Initializable {
    address private _owner;

    event OwnershipTransferred(
        address indexed previousOwner,
        address indexed newOwner
    );

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    // constructor () internal {
    //     address msgSender = msg.sender;
    //     _owner = msgSender;
    //     emit OwnershipTransferred(address(0), msgSender);
    // }

    function __Ownable_init() internal initializer {
        __Ownable_init_unchained();
    }

    function __Ownable_init_unchained() internal initializer {
        address msgSender = msg.sender;
        _owner = msgSender;
        emit OwnershipTransferred(address(0), msgSender);
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        require(owner() == msg.sender, "Ownable: caller is not the owner");
        _;
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions anymore. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby removing any functionality that is only available to the owner.
     */
    function renounceOwnership() public onlyOwner {
        emit OwnershipTransferred(_owner, address(0));
        _owner = address(0);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public onlyOwner {
        require(
            newOwner != address(0),
            "Ownable: new owner is the zero address"
        );
        emit OwnershipTransferred(_owner, newOwner);
        _owner = newOwner;
    }

    uint256[49] private __gap;
}

pragma solidity ^0.8.17;

import "../interfaces/IERC20.sol";
import "./SafeMath.sol";
import "./Address.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for ERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using SafeMath for uint256;
    using Address for address;

    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        callOptionalReturn(
            token,
            abi.encodeWithSelector(token.transfer.selector, to, value)
        );
    }

    function safeTransferFrom(
        IERC20 token,
        address from,
        address to,
        uint256 value
    ) internal {
        callOptionalReturn(
            token,
            abi.encodeWithSelector(token.transferFrom.selector, from, to, value)
        );
    }

    function safeApprove(
        IERC20 token,
        address spender,
        uint256 value
    ) internal {
        // safeApprove should only be called when setting an initial allowance,
        // or when resetting it to zero. To increase and decrease it, use
        // 'safeIncreaseAllowance' and 'safeDecreaseAllowance'
        // solhint-disable-next-line max-line-length
        require(
            (value == 0) || (token.allowance(address(this), spender) == 0),
            "SafeERC20: approve from non-zero to non-zero allowance"
        );
        callOptionalReturn(
            token,
            abi.encodeWithSelector(token.approve.selector, spender, value)
        );
    }

    function safeIncreaseAllowance(
        IERC20 token,
        address spender,
        uint256 value
    ) internal {
        uint256 newAllowance = token.allowance(address(this), spender).add(
            value
        );
        callOptionalReturn(
            token,
            abi.encodeWithSelector(
                token.approve.selector,
                spender,
                newAllowance
            )
        );
    }

    function safeDecreaseAllowance(
        IERC20 token,
        address spender,
        uint256 value
    ) internal {
        uint256 newAllowance = token.allowance(address(this), spender).sub(
            value,
            "SafeERC20: decreased allowance below zero"
        );
        callOptionalReturn(
            token,
            abi.encodeWithSelector(
                token.approve.selector,
                spender,
                newAllowance
            )
        );
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function callOptionalReturn(IERC20 token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves.

        // A Solidity high level call has three parts:
        //  1. The target address is checked to verify it contains contract code
        //  2. The call itself is made, and success asserted
        //  3. The return value is decoded, which in turn checks the size of the returned data.
        // solhint-disable-next-line max-line-length
        require(address(token).isContract(), "SafeERC20: call to non-contract");

        // solhint-disable-next-line avoid-low-level-calls
        (bool success, bytes memory returndata) = address(token).call(data);
        require(success, "SafeERC20: low-level call failed");

        if (returndata.length > 0) {
            // Return data is optional
            // solhint-disable-next-line max-line-length
            require(
                abi.decode(returndata, (bool)),
                "SafeERC20: ERC20 operation did not succeed"
            );
        }
    }
}

// SPDX-License-Identifier: MIT

pragma solidity =0.8.17;

/**
 * @dev Wrappers over Solidity's arithmetic operations with added overflow
 * checks.
 *
 * Arithmetic operations in Solidity wrap on overflow. This can easily result
 * in bugs, because programmers usually assume that an overflow raises an
 * error, which is the standard behavior in high level programming languages.
 * `SafeMath` restores this intuition by reverting the transaction when an
 * operation overflows.
 *
 * Using this library instead of the unchecked operations eliminates an entire
 * class of bugs, so it's recommended to use it always.
 */
library SafeMath {
    /**
     * @dev Returns the addition of two unsigned integers, with an overflow flag.
     *
     * _Available since v3.4._
     */
    function tryAdd(
        uint256 a,
        uint256 b
    ) internal pure returns (bool, uint256) {
        uint256 c = a + b;
        if (c < a) return (false, 0);
        return (true, c);
    }

    /**
     * @dev Returns the substraction of two unsigned integers, with an overflow flag.
     *
     * _Available since v3.4._
     */
    function trySub(
        uint256 a,
        uint256 b
    ) internal pure returns (bool, uint256) {
        if (b > a) return (false, 0);
        return (true, a - b);
    }

    /**
     * @dev Returns the multiplication of two unsigned integers, with an overflow flag.
     *
     * _Available since v3.4._
     */
    function tryMul(
        uint256 a,
        uint256 b
    ) internal pure returns (bool, uint256) {
        // Gas optimization: this is cheaper than requiring 'a' not being zero, but the
        // benefit is lost if 'b' is also tested.
        // See: https://github.com/OpenZeppelin/openzeppelin-contracts/pull/522
        if (a == 0) return (true, 0);
        uint256 c = a * b;
        if (c / a != b) return (false, 0);
        return (true, c);
    }

    /**
     * @dev Returns the division of two unsigned integers, with a division by zero flag.
     *
     * _Available since v3.4._
     */
    function tryDiv(
        uint256 a,
        uint256 b
    ) internal pure returns (bool, uint256) {
        if (b == 0) return (false, 0);
        return (true, a / b);
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers, with a division by zero flag.
     *
     * _Available since v3.4._
     */
    function tryMod(
        uint256 a,
        uint256 b
    ) internal pure returns (bool, uint256) {
        if (b == 0) return (false, 0);
        return (true, a % b);
    }

    /**
     * @dev Returns the addition of two unsigned integers, reverting on
     * overflow.
     *
     * Counterpart to Solidity's `+` operator.
     *
     * Requirements:
     *
     * - Addition cannot overflow.
     */
    function add(uint256 a, uint256 b) internal pure returns (uint256) {
        uint256 c = a + b;
        require(c >= a, "SafeMath: addition overflow");
        return c;
    }

    /**
     * @dev Returns the subtraction of two unsigned integers, reverting on
     * overflow (when the result is negative).
     *
     * Counterpart to Solidity's `-` operator.
     *
     * Requirements:
     *
     * - Subtraction cannot overflow.
     */
    function sub(uint256 a, uint256 b) internal pure returns (uint256) {
        require(b <= a, "SafeMath: subtraction overflow");
        return a - b;
    }

    /**
     * @dev Returns the multiplication of two unsigned integers, reverting on
     * overflow.
     *
     * Counterpart to Solidity's `*` operator.
     *
     * Requirements:
     *
     * - Multiplication cannot overflow.
     */
    function mul(uint256 a, uint256 b) internal pure returns (uint256) {
        if (a == 0) return 0;
        uint256 c = a * b;
        require(c / a == b, "SafeMath: multiplication overflow");
        return c;
    }

    /**
     * @dev Returns the integer division of two unsigned integers, reverting on
     * division by zero. The result is rounded towards zero.
     *
     * Counterpart to Solidity's `/` operator. Note: this function uses a
     * `revert` opcode (which leaves remaining gas untouched) while Solidity
     * uses an invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function div(uint256 a, uint256 b) internal pure returns (uint256) {
        require(b > 0, "SafeMath: division by zero");
        return a / b;
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers. (unsigned integer modulo),
     * reverting when dividing by zero.
     *
     * Counterpart to Solidity's `%` operator. This function uses a `revert`
     * opcode (which leaves remaining gas untouched) while Solidity uses an
     * invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function mod(uint256 a, uint256 b) internal pure returns (uint256) {
        require(b > 0, "SafeMath: modulo by zero");
        return a % b;
    }

    /**
     * @dev Returns the subtraction of two unsigned integers, reverting with custom message on
     * overflow (when the result is negative).
     *
     * CAUTION: This function is deprecated because it requires allocating memory for the error
     * message unnecessarily. For custom revert reasons use {trySub}.
     *
     * Counterpart to Solidity's `-` operator.
     *
     * Requirements:
     *
     * - Subtraction cannot overflow.
     */
    function sub(
        uint256 a,
        uint256 b,
        string memory errorMessage
    ) internal pure returns (uint256) {
        require(b <= a, errorMessage);
        return a - b;
    }

    /**
     * @dev Returns the integer division of two unsigned integers, reverting with custom message on
     * division by zero. The result is rounded towards zero.
     *
     * CAUTION: This function is deprecated because it requires allocating memory for the error
     * message unnecessarily. For custom revert reasons use {tryDiv}.
     *
     * Counterpart to Solidity's `/` operator. Note: this function uses a
     * `revert` opcode (which leaves remaining gas untouched) while Solidity
     * uses an invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function div(
        uint256 a,
        uint256 b,
        string memory errorMessage
    ) internal pure returns (uint256) {
        require(b > 0, errorMessage);
        return a / b;
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers. (unsigned integer modulo),
     * reverting with custom message when dividing by zero.
     *
     * CAUTION: This function is deprecated because it requires allocating memory for the error
     * message unnecessarily. For custom revert reasons use {tryMod}.
     *
     * Counterpart to Solidity's `%` operator. This function uses a `revert`
     * opcode (which leaves remaining gas untouched) while Solidity uses an
     * invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function mod(
        uint256 a,
        uint256 b,
        string memory errorMessage
    ) internal pure returns (uint256) {
        require(b > 0, errorMessage);
        return a % b;
    }
}

pragma solidity ^0.8.17;
pragma experimental ABIEncoderV2;

import "./libraries/ERC20Upgradeable.sol";
import "./libraries/OwnableUpgradeable.sol";
import "./libraries/SafeERC20.sol";
import "./libraries/Initializable.sol";

interface IPLXDistributor {
    struct UserInfo {
        int256 rewardDebt;
        uint256 totalClaimedPLX;
    }

    function harvest(address user) external;

    function pendingPLX(address user) external view returns (uint256);

    function userInfo(
        address user
    ) external view returns (UserInfo calldata _userInfo);

    function deposit(address user, uint256 amount) external;

    function withdraw(address user, uint256 amount) external;

    function totalPlxDistribute() external view returns (uint256);
}

interface IPLX {
    function burn(uint256 amount) external;
}

contract gPLX is Initializable, ERC20Upgradeable, OwnableUpgradeable {
    using SafeERC20 for IERC20;
    struct TokenStakingList {
        uint256 plxAmount;
        uint256 startTime;
        uint256 endDay;
    }

    struct TokenStake {
        TokenStakingList[] stakingList;
        uint256 startIdx;
        uint256 unstakebleAmount;
    }

    IERC20 public PLX;
    IPLXDistributor public PLXDistributor;
    uint256 startTimestamp;

    event Stake(
        uint256 idx,
        address user,
        uint256 PlxAmount,
        uint256 periodAmount,
        uint8 period,
        uint256 startDay,
        uint256 endDay
    );
    event UnStake(
        uint256[] idxs,
        address user,
        uint256 PlxAmount,
        uint256 periodAmount,
        uint8 period
    );

    mapping(uint8 => uint256) public stakingPeriod;
    mapping(address => mapping(uint8 => uint256[])) public userDaysList;
    mapping(address => mapping(uint8 => TokenStake)) public staked;

    // // Disable some ERC20 features
    /// @notice PLX token transfer is disabled.
    function _beforeTokenTransfer(
        address from,
        address to,
        uint256 amount
    ) internal override {
        super._beforeTokenTransfer(from, to, amount);
        require(
            from == address(0) || to == address(0),
            "PLXToken: transfer disabled"
        );
    }

    function _mint(address account, uint256 amount) internal override {
        PLXDistributor.deposit(account, amount);
        super._mint(account, amount);
    }

    function _burn(address account, uint256 amount) internal override {
        PLXDistributor.withdraw(account, amount);
        super._burn(account, amount);
    }

    function _calculmonth(uint256 _num) internal pure returns (uint256) {
        return _num * 30 days;
    }

    function setPLXDistributor(
        IPLXDistributor _distributor
    ) external onlyOwner {
        PLXDistributor = _distributor;
    }

    function init(
        IERC20 _PLX,
        IPLXDistributor _PLXDistributor,
        uint256 startTime
    ) public initializer {
        __ERC20_init("gPLX", "gPLX");
        __Ownable_init();
        PLX = _PLX;
        PLXDistributor = _PLXDistributor;
        startTimestamp = startTime;
        stakingPeriod[0] = _calculmonth(2);
        stakingPeriod[1] = _calculmonth(4);
        stakingPeriod[2] = _calculmonth(8);
        stakingPeriod[3] = _calculmonth(12);
        stakingPeriod[4] = _calculmonth(24);
    }

    function staking(uint256 amount, uint8 _period) external {
        require(block.timestamp >= startTimestamp);
        uint256 period = stakingPeriod[_period];
        require(period != 0, "invalid period");
        require(amount > 0, "Mint amount is zero");
        uint256 endDay = block.timestamp + period;
        PLX.safeTransferFrom(msg.sender, address(this), amount);
        userDaysList[msg.sender][_period].push(block.timestamp);
        TokenStake storage tokenStake = staked[msg.sender][_period];
        tokenStake.stakingList.push(
            TokenStakingList({
                plxAmount: amount,
                startTime: block.timestamp,
                endDay: endDay
            })
        );
        uint256 stakingAmount = getPeriodAmount(_period, amount);

        _mint(msg.sender, stakingAmount);
        emit Stake(
            tokenStake.stakingList.length - 1,
            msg.sender,
            amount,
            stakingAmount,
            _period,
            block.timestamp,
            endDay
        );
    }

    function unstaking(uint8 _period) external {
        uint256 period = stakingPeriod[_period];
        require(period != 0, "Invalid period");
        TokenStake storage tokenStake = staked[msg.sender][_period];
        uint256 startIdx = tokenStake.startIdx;
        uint256 plxAmount = tokenStake.stakingList[startIdx].plxAmount;
        require(
            tokenStake.stakingList[startIdx].endDay < block.timestamp,
            "The staking period has not ended."
        );
        require(plxAmount > 0, "There is no quantity available for unstaking.");
        PLX.safeTransfer(msg.sender, plxAmount);
        tokenStake.stakingList[startIdx].plxAmount = 0;
        uint256[] memory idxs = new uint256[](1);
        idxs[0] = startIdx;
        uint256 periodAmount = getPeriodAmount(_period, plxAmount);
        emit UnStake(idxs, msg.sender, plxAmount, periodAmount, _period);
        _burn(msg.sender, periodAmount);
        tokenStake.startIdx += 1;
    }

    function unStakeAll(uint8 _period) external {
        uint256 period = stakingPeriod[_period];
        require(period != 0, "Invalid period");
        TokenStake storage tokenStake = staked[msg.sender][_period];
        uint256[] memory idxs = _updateTokenStakedList(tokenStake);
        uint256 amount = tokenStake.unstakebleAmount;
        require(amount > 0, "Unstakeble amount is zero");
        tokenStake.unstakebleAmount = 0;

        PLX.safeTransfer(msg.sender, amount);
        uint256 periodAmount = getPeriodAmount(_period, amount);
        emit UnStake(idxs, msg.sender, amount, periodAmount, _period);
        _burn(msg.sender, periodAmount);
    }

    function unStakingForAllPeriod() external {
        uint256 totalPLXAmount = 0;
        uint256 totalgPLXAmount = 0;
        for (uint8 i = 0; i <= 4; i++) {
            TokenStake storage tokenStake = staked[msg.sender][i];
            uint256[] memory idxs = _updateTokenStakedList(tokenStake);
            uint256 amount = tokenStake.unstakebleAmount;
            if (amount > 0) {
                tokenStake.unstakebleAmount = 0;
                totalPLXAmount = totalPLXAmount + amount;
                uint256 periodAmount = getPeriodAmount(i, amount);
                totalgPLXAmount = totalgPLXAmount + periodAmount;
                emit UnStake(idxs, msg.sender, amount, periodAmount, i);
            }
        }
        require(
            totalPLXAmount > 0 && totalgPLXAmount > 0,
            "UnstakebleAMount is zero"
        );
        PLX.safeTransfer(msg.sender, totalPLXAmount);
        _burn(msg.sender, totalgPLXAmount);
    }

    function unStakePenaltyAmount(
        address user,
        uint8 _period
    ) external view returns (uint256 penaltyAmount, uint256 burnedAmount) {
        uint256 period = stakingPeriod[_period];
        uint256 startIdx = staked[user][_period].startIdx;
        TokenStakingList[] memory tokenStake = staked[user][_period]
            .stakingList;

        uint256 plxAmount = tokenStake[startIdx].plxAmount;
        uint256 afterStakingDay = block.timestamp -
            staked[user][_period].stakingList[startIdx].startTime;
        penaltyAmount = (plxAmount * afterStakingDay) / period;
        burnedAmount = plxAmount - penaltyAmount;
    }

    function unstakeWithPenalty(uint8 _period) external returns (uint256) {
        uint256 period = stakingPeriod[_period];
        require(period != 0, "Invalid period");

        TokenStakingList[] storage tokenStakingList = staked[msg.sender][
            _period
        ].stakingList;

        uint256 idx = staked[msg.sender][_period].startIdx;
        uint256 transferAmount = 0;
        uint256 burnedAmount = 0;
        uint256 plxAmount = tokenStakingList[idx].plxAmount;
        uint256 afterStakingDay = 0;

        afterStakingDay = block.timestamp - tokenStakingList[idx].startTime;
        transferAmount = (plxAmount * afterStakingDay) / period;
        burnedAmount = plxAmount - transferAmount;
        uint256 periodAmount = getPeriodAmount(_period, plxAmount);
        _burn(msg.sender, periodAmount);
        IPLX(address(PLX)).burn(burnedAmount);
        PLX.safeTransfer(msg.sender, transferAmount);
        uint256[] memory idxs = new uint256[](1);
        idxs[0] = idx;
        tokenStakingList[idx].plxAmount = 0;
        emit UnStake(idxs, msg.sender, plxAmount, periodAmount, _period);
        staked[msg.sender][_period].startIdx = idx + 1;
        return burnedAmount;
    }

    function _updateTokenStakedList(
        TokenStake storage tokenStake
    ) internal returns (uint256[] memory) {
        uint256 startIdx = tokenStake.startIdx;
        uint256 endIdx = tokenStake.stakingList.length;
        TokenStakingList[] storage stakingList = tokenStake.stakingList;
        uint256 i = startIdx;
        uint256 newUnstakebleAmount = 0;
        uint256 currentDay = block.timestamp;
        for (; i < endIdx; i++) {
            if (currentDay <= stakingList[i].endDay) {
                break;
            }
        }
        endIdx = i;
        uint256[] memory idxs = new uint256[](endIdx - startIdx);
        for (i = startIdx; i < endIdx; ++i) {
            newUnstakebleAmount += stakingList[i].plxAmount;
            stakingList[i].plxAmount = 0;
            idxs[i - startIdx] = i;
        }
        tokenStake.unstakebleAmount += newUnstakebleAmount;

        tokenStake.startIdx = i;
        return idxs;
    }

    function stakedPLXInfo(
        address user,
        uint8 _period
    )
        external
        view
        returns (
            uint256 unStakebleAmount,
            uint256 totalStakedAmount,
            uint256[] memory startDays,
            uint256[] memory stakedAmounts,
            uint256[] memory endDays
        )
    {
        TokenStake memory tokenStake = staked[user][_period];
        unStakebleAmount = tokenStake.unstakebleAmount;
        uint256 startIdx = tokenStake.startIdx;
        uint256 idxLength = tokenStake.stakingList.length;
        TokenStakingList[] memory tokenStakingList = tokenStake.stakingList;
        uint256 i = startIdx;
        uint256 curDay = block.timestamp;
        for (; i < idxLength; ++i) {
            if (curDay > tokenStakingList[i].endDay) {
                unStakebleAmount += tokenStakingList[i].plxAmount;
            } else {
                break;
            }
        }

        totalStakedAmount = unStakebleAmount;
        uint256 stakedIdx = i;
        startDays = new uint256[](idxLength - stakedIdx);
        stakedAmounts = new uint256[](idxLength - stakedIdx);
        endDays = new uint256[](idxLength - stakedIdx);
        for (; i < idxLength; ++i) {
            startDays[i - stakedIdx] = tokenStakingList[i].startTime;
            stakedAmounts[i - stakedIdx] = tokenStakingList[i].plxAmount;
            endDays[i - stakedIdx] = tokenStakingList[i].endDay;
            totalStakedAmount += tokenStakingList[i].plxAmount;
        }
    }

    function stakeInfoForallPeriod(
        address user
    )
        external
        view
        returns (uint256 totalUnStakebleAmount, uint256 totalPLXAmount)
    {
        for (uint8 i = 0; i <= 4; i++) {
            TokenStake memory tokenStake = staked[user][i];
            uint256 startIdx = tokenStake.startIdx;
            uint256 endIdx = tokenStake.stakingList.length;
            TokenStakingList[] memory stakingList = tokenStake.stakingList;

            for (uint256 j = startIdx; j < endIdx; j++) {
                if (block.timestamp > stakingList[j].endDay) {
                    totalUnStakebleAmount += stakingList[j].plxAmount;
                    totalPLXAmount += stakingList[j].plxAmount;
                } else {
                    totalPLXAmount += stakingList[j].plxAmount;
                }
            }
        }
    }

    function rawStakedPLXInfo(
        address user,
        uint8 period
    ) external view returns (TokenStake memory tokenStake) {
        tokenStake = staked[user][period];
    }

    function getPeriodAmount(
        uint8 period,
        uint256 amount
    ) internal pure returns (uint256 periodAmount) {
        if (period == 0) {
            periodAmount = amount;
        } else if (period == 1) {
            periodAmount = amount * 2;
        } else if (period == 2) {
            periodAmount = amount * 4;
        } else if (period == 3) {
            periodAmount = amount * 6;
        } else if (period == 4) {
            periodAmount = amount * 12;
        }
    }

    function harvestPlx() public {
        PLXDistributor.harvest(msg.sender);
    }

    function userPlxTotalClaimed(address user) external view returns (uint256) {
        return PLXDistributor.userInfo(user).totalClaimedPLX;
    }

    function userPlxPendingPLX(address user) external view returns (uint256) {
        return PLXDistributor.pendingPLX(user);
    }

    function userPlxPendingAndTotalClaimed(
        address user
    ) external view returns (uint256, uint256) {
        uint256 totalClaimed = PLXDistributor.userInfo(user).totalClaimedPLX;
        uint256 pendingPLX = PLXDistributor.pendingPLX(user);
        return (totalClaimed, pendingPLX);
    }

    function totalPlxDistributeAmount() external view returns (uint256) {
        return PLXDistributor.totalPlxDistribute();
    }
}

{
  "compilationTarget": {
    "contracts/gPLX.sol": "gPLX"
  },
  "evmVersion": "london",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": true,
    "runs": 200
  },
  "remappings": []
}