// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/Address.sol)

pragma solidity ^0.8.20;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev The ETH balance of the account is not enough to perform the operation.
     */
    error AddressInsufficientBalance(address account);

    /**
     * @dev There's no code at `target` (it is not a contract).
     */
    error AddressEmptyCode(address target);

    /**
     * @dev A call to an address target failed. The target may have reverted.
     */
    error FailedInnerCall();

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.8.20/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        if (address(this).balance < amount) {
            revert AddressInsufficientBalance(address(this));
        }

        (bool success, ) = recipient.call{value: amount}("");
        if (!success) {
            revert FailedInnerCall();
        }
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason or custom error, it is bubbled
     * up by this function (like regular Solidity function calls). However, if
     * the call reverted with no returned reason, this function reverts with a
     * {FailedInnerCall} error.
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        if (address(this).balance < value) {
            revert AddressInsufficientBalance(address(this));
        }
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and reverts if the target
     * was not a contract or bubbling up the revert reason (falling back to {FailedInnerCall}) in case of an
     * unsuccessful call.
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata
    ) internal view returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            // only check if target is a contract if the call was successful and the return data is empty
            // otherwise we already know that it was a contract
            if (returndata.length == 0 && target.code.length == 0) {
                revert AddressEmptyCode(target);
            }
            return returndata;
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and reverts if it wasn't, either by bubbling the
     * revert reason or with a default {FailedInnerCall} error.
     */
    function verifyCallResult(bool success, bytes memory returndata) internal pure returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            return returndata;
        }
    }

    /**
     * @dev Reverts with returndata if present. Otherwise reverts with {FailedInnerCall}.
     */
    function _revert(bytes memory returndata) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            /// @solidity memory-safe-assembly
            assembly {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert FailedInnerCall();
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}

// SPDX-License-Identifier: AGPL-3.0-only
pragma solidity >=0.8.0;

/// @notice Modern and gas efficient ERC20 + EIP-2612 implementation.
/// @author Solmate (https://github.com/transmissions11/solmate/blob/main/src/tokens/ERC20.sol)
/// @author Modified from Uniswap (https://github.com/Uniswap/uniswap-v2-core/blob/master/contracts/UniswapV2ERC20.sol)
/// @dev Do not manually set balances without updating totalSupply, as the sum of all user balances must not exceed it.
abstract contract ERC20 {
    /*//////////////////////////////////////////////////////////////
                                 EVENTS
    //////////////////////////////////////////////////////////////*/

    event Transfer(address indexed from, address indexed to, uint256 amount);

    event Approval(address indexed owner, address indexed spender, uint256 amount);

    /*//////////////////////////////////////////////////////////////
                            METADATA STORAGE
    //////////////////////////////////////////////////////////////*/

    string public name;

    string public symbol;

    uint8 public immutable decimals;

    /*//////////////////////////////////////////////////////////////
                              ERC20 STORAGE
    //////////////////////////////////////////////////////////////*/

    uint256 public totalSupply;

    mapping(address => uint256) public balanceOf;

    mapping(address => mapping(address => uint256)) public allowance;

    /*//////////////////////////////////////////////////////////////
                            EIP-2612 STORAGE
    //////////////////////////////////////////////////////////////*/

    uint256 internal immutable INITIAL_CHAIN_ID;

    bytes32 internal immutable INITIAL_DOMAIN_SEPARATOR;

    mapping(address => uint256) public nonces;

    /*//////////////////////////////////////////////////////////////
                               CONSTRUCTOR
    //////////////////////////////////////////////////////////////*/

    constructor(
        string memory _name,
        string memory _symbol,
        uint8 _decimals
    ) {
        name = _name;
        symbol = _symbol;
        decimals = _decimals;

        INITIAL_CHAIN_ID = block.chainid;
        INITIAL_DOMAIN_SEPARATOR = computeDomainSeparator();
    }

    /*//////////////////////////////////////////////////////////////
                               ERC20 LOGIC
    //////////////////////////////////////////////////////////////*/

    function approve(address spender, uint256 amount) public virtual returns (bool) {
        allowance[msg.sender][spender] = amount;

        emit Approval(msg.sender, spender, amount);

        return true;
    }

    function transfer(address to, uint256 amount) public virtual returns (bool) {
        balanceOf[msg.sender] -= amount;

        // Cannot overflow because the sum of all user
        // balances can't exceed the max uint256 value.
        unchecked {
            balanceOf[to] += amount;
        }

        emit Transfer(msg.sender, to, amount);

        return true;
    }

    function transferFrom(
        address from,
        address to,
        uint256 amount
    ) public virtual returns (bool) {
        uint256 allowed = allowance[from][msg.sender]; // Saves gas for limited approvals.

        if (allowed != type(uint256).max) allowance[from][msg.sender] = allowed - amount;

        balanceOf[from] -= amount;

        // Cannot overflow because the sum of all user
        // balances can't exceed the max uint256 value.
        unchecked {
            balanceOf[to] += amount;
        }

        emit Transfer(from, to, amount);

        return true;
    }

    /*//////////////////////////////////////////////////////////////
                             EIP-2612 LOGIC
    //////////////////////////////////////////////////////////////*/

    function permit(
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) public virtual {
        require(deadline >= block.timestamp, "PERMIT_DEADLINE_EXPIRED");

        // Unchecked because the only math done is incrementing
        // the owner's nonce which cannot realistically overflow.
        unchecked {
            address recoveredAddress = ecrecover(
                keccak256(
                    abi.encodePacked(
                        "\x19\x01",
                        DOMAIN_SEPARATOR(),
                        keccak256(
                            abi.encode(
                                keccak256(
                                    "Permit(address owner,address spender,uint256 value,uint256 nonce,uint256 deadline)"
                                ),
                                owner,
                                spender,
                                value,
                                nonces[owner]++,
                                deadline
                            )
                        )
                    )
                ),
                v,
                r,
                s
            );

            require(recoveredAddress != address(0) && recoveredAddress == owner, "INVALID_SIGNER");

            allowance[recoveredAddress][spender] = value;
        }

        emit Approval(owner, spender, value);
    }

    function DOMAIN_SEPARATOR() public view virtual returns (bytes32) {
        return block.chainid == INITIAL_CHAIN_ID ? INITIAL_DOMAIN_SEPARATOR : computeDomainSeparator();
    }

    function computeDomainSeparator() internal view virtual returns (bytes32) {
        return
            keccak256(
                abi.encode(
                    keccak256("EIP712Domain(string name,string version,uint256 chainId,address verifyingContract)"),
                    keccak256(bytes(name)),
                    keccak256("1"),
                    block.chainid,
                    address(this)
                )
            );
    }

    /*//////////////////////////////////////////////////////////////
                        INTERNAL MINT/BURN LOGIC
    //////////////////////////////////////////////////////////////*/

    function _mint(address to, uint256 amount) internal virtual {
        totalSupply += amount;

        // Cannot overflow because the sum of all user
        // balances can't exceed the max uint256 value.
        unchecked {
            balanceOf[to] += amount;
        }

        emit Transfer(address(0), to, amount);
    }

    function _burn(address from, uint256 amount) internal virtual {
        balanceOf[from] -= amount;

        // Cannot underflow because a user's balance
        // will never be larger than the total supply.
        unchecked {
            totalSupply -= amount;
        }

        emit Transfer(from, address(0), amount);
    }
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.20;

import "@bb-referral/ReferralSystem.sol";
import "@openzeppelin/contracts/access/Ownable.sol";
import "@openzeppelin/contracts/token/ERC20/ERC20.sol";
import "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
import "./NativeSender.sol";

abstract contract FeeSender is Ownable {
    using SafeERC20 for ERC20;

    ReferralSystem public referralSystem;

    uint public constant BASIS_POINTS = 10000;

    address public feeReceiver;

    uint256 public baseFee;
    uint256 public discountedBaseFee;

    uint256 public referralFeeOfBaseFee; // Takes share of protocol fee to

    event ProtocolFeePercentageUpdated(
        uint256 oldFeeInBasisPoints,
        uint256 newFeeInBasisPoints
    );

    event ReferralFeePercentageUpdated(
        uint256 oldFeeInBasisPoints,
        uint256 newFeeInBasisPoints
    );

    event BaseFeePercentageUpdated(
        uint256 oldBaseFeeInBasisPoints,
        uint256 oldDiscountedBaseFeeInBasisPoints,
        uint256 newBaseFee,
        uint256 newDiscountedBaseFee
    );

    event ReferralFeeUpdated(uint256 oldReferralFee, uint256 newReferralFee);

    event FeeReceiverUpdated(address oldFeeReceiver, address newFeeReceiver);

    constructor(
        address referralSystem_,
        address feeReceiver_,
        uint256 baseFee_,
        uint256 discountedBaseFee_,
        uint256 referralFeeInBasisPointsOfBaseFee_
    ) Ownable(msg.sender) {
        referralSystem = ReferralSystem(referralSystem_);

        feeReceiver = feeReceiver_;

        baseFee = baseFee_;
        discountedBaseFee = discountedBaseFee_;

        referralFeeOfBaseFee = referralFeeInBasisPointsOfBaseFee_;
    }

    function _sendFees(
        address token,
        uint actionAmount,
        bytes32 referralCodeHash
    ) internal returns (uint totalFees) {
        (
            uint256 protocolFee,
            uint256 referralFee
        ) = _getProtocolAndReferralFees(
                msg.sender,
                actionAmount,
                referralCodeHash
            );

        totalFees = protocolFee + referralFee;

        _isNative(token)
            ? _sendProtocolFeesInNative(protocolFee)
            : _sendProtocolFeesInToken(token, protocolFee);

        if (referralFee == 0) return totalFees;

        bytes32 registeredReferralCodeHash = referralSystem
            .getReferralCodeHashByReferral(msg.sender);

        _isNative(token)
            ? _sendReferralFeesInNative(referralFee, registeredReferralCodeHash)
            : _sendReferralFeesInToken(
                token,
                referralFee,
                registeredReferralCodeHash
            );
    }

    /* ========== RESTRICTED FUNCTIONS ========== */

    function updateBaseFeePercentage(
        uint256 newBaseFee_,
        uint256 newDiscountedBaseFee_
    ) external onlyOwner {
        uint256 oldBaseFeeInBasisPoints = baseFee;
        uint256 oldDiscountedBaseFeeInBasisPoints = discountedBaseFee;

        baseFee = newBaseFee_;
        discountedBaseFee = newDiscountedBaseFee_;

        emit BaseFeePercentageUpdated(
            oldBaseFeeInBasisPoints,
            oldDiscountedBaseFeeInBasisPoints,
            newBaseFee_,
            newDiscountedBaseFee_
        );
    }

    function updateProtocolFeeReceiver(
        address feeReceiver_
    ) external onlyOwner {
        address oldFeeReceiver = feeReceiver;
        feeReceiver = feeReceiver_;

        emit FeeReceiverUpdated(oldFeeReceiver, feeReceiver_);
    }

    function updateReferralFeeBasisPoints(
        uint referralFeeInBasisPointsOfBaseFee_
    ) external onlyOwner {
        uint oldReferralFee = referralFeeOfBaseFee;

        referralFeeOfBaseFee = referralFeeInBasisPointsOfBaseFee_;

        emit ReferralFeeUpdated(
            oldReferralFee,
            referralFeeInBasisPointsOfBaseFee_
        );
    }

    /* ========== INTERNAL FUNCTIONS ========== */

    function _getProtocolAndReferralFees(
        address referral,
        uint256 actionAmount,
        bytes32 referralCodeHash
    ) internal returns (uint256 protocolFee, uint256 referralFee) {
        bool isInReferralSystem = _getReferralStatus(referral);

        uint256 _baseFee;

        if (isInReferralSystem) {
            // Make discount on base fee
            _baseFee = (actionAmount * discountedBaseFee) / BASIS_POINTS;
            referralFee = (_baseFee * referralFeeOfBaseFee) / BASIS_POINTS;
        } else {
            if (referralCodeHash == bytes32(0)) {
                _baseFee = (actionAmount * baseFee) / BASIS_POINTS;
                referralFee = 0;
            } else {
                referralSystem.registerReferral(referral, referralCodeHash);

                _baseFee = (actionAmount * discountedBaseFee) / BASIS_POINTS;
                referralFee = (_baseFee * referralFeeOfBaseFee) / BASIS_POINTS;
            }
        }

        protocolFee = _baseFee - referralFee;
    }

    function _isNative(address token) internal pure returns (bool) {
        return token == address(0);
    }

    function _getReferralStatus(address referral) internal view returns (bool) {
        bytes32 recordedReferralCodeHash = referralSystem
            .getReferralCodeHashByReferral(referral);

        return recordedReferralCodeHash != bytes32(0);
    }

    function _sendProtocolFeesInNative(uint256 protocolFee) internal {
        new NativeSender{value: protocolFee}(feeReceiver);
    }

    function _sendProtocolFeesInToken(
        address token,
        uint256 protocolFee
    ) internal {
        ERC20(token).safeTransfer(feeReceiver, protocolFee);
    }

    function _sendReferralFeesInNative(
        uint256 referralFee,
        bytes32 referralCodeHash
    ) internal {
        referralSystem.accrueNativeReferralReward{value: referralFee}(
            referralCodeHash
        );
    }

    function _sendReferralFeesInToken(
        address token,
        uint256 referralFee,
        bytes32 referralCodeHash
    ) internal {
        ERC20(token).forceApprove(address(referralSystem), type(uint256).max);

        referralSystem.accrueTokenReferralReward(
            token,
            referralFee,
            referralCodeHash
        );
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC1155/IERC1155Receiver.sol)

pragma solidity ^0.8.20;

import {IERC165} from "../../utils/introspection/IERC165.sol";

/**
 * @dev Interface that must be implemented by smart contracts in order to receive
 * ERC-1155 token transfers.
 */
interface IERC1155Receiver is IERC165 {
    /**
     * @dev Handles the receipt of a single ERC1155 token type. This function is
     * called at the end of a `safeTransferFrom` after the balance has been updated.
     *
     * NOTE: To accept the transfer, this must return
     * `bytes4(keccak256("onERC1155Received(address,address,uint256,uint256,bytes)"))`
     * (i.e. 0xf23a6e61, or its own function selector).
     *
     * @param operator The address which initiated the transfer (i.e. msg.sender)
     * @param from The address which previously owned the token
     * @param id The ID of the token being transferred
     * @param value The amount of tokens being transferred
     * @param data Additional data with no specified format
     * @return `bytes4(keccak256("onERC1155Received(address,address,uint256,uint256,bytes)"))` if transfer is allowed
     */
    function onERC1155Received(
        address operator,
        address from,
        uint256 id,
        uint256 value,
        bytes calldata data
    ) external returns (bytes4);

    /**
     * @dev Handles the receipt of a multiple ERC1155 token types. This function
     * is called at the end of a `safeBatchTransferFrom` after the balances have
     * been updated.
     *
     * NOTE: To accept the transfer(s), this must return
     * `bytes4(keccak256("onERC1155BatchReceived(address,address,uint256[],uint256[],bytes)"))`
     * (i.e. 0xbc197c81, or its own function selector).
     *
     * @param operator The address which initiated the batch transfer (i.e. msg.sender)
     * @param from The address which previously owned the token
     * @param ids An array containing ids of each token being transferred (order and length must match values array)
     * @param values An array containing amounts of each token being transferred (order and length must match ids array)
     * @param data Additional data with no specified format
     * @return `bytes4(keccak256("onERC1155BatchReceived(address,address,uint256[],uint256[],bytes)"))` if transfer is allowed
     */
    function onERC1155BatchReceived(
        address operator,
        address from,
        uint256[] calldata ids,
        uint256[] calldata values,
        bytes calldata data
    ) external returns (bytes4);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/introspection/IERC165.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[EIP].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[EIP section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/extensions/IERC20Metadata.sol)

pragma solidity ^0.8.20;

import {IERC20} from "../IERC20.sol";

/**
 * @dev Interface for the optional metadata functions from the ERC20 standard.
 */
interface IERC20Metadata is IERC20 {
    /**
     * @dev Returns the name of the token.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the symbol of the token.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the decimals places of the token.
     */
    function decimals() external view returns (uint8);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/extensions/IERC20Permit.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC20 Permit extension allowing approvals to be made via signatures, as defined in
 * https://eips.ethereum.org/EIPS/eip-2612[EIP-2612].
 *
 * Adds the {permit} method, which can be used to change an account's ERC20 allowance (see {IERC20-allowance}) by
 * presenting a message signed by the account. By not relying on {IERC20-approve}, the token holder account doesn't
 * need to send a transaction, and thus is not required to hold Ether at all.
 *
 * ==== Security Considerations
 *
 * There are two important considerations concerning the use of `permit`. The first is that a valid permit signature
 * expresses an allowance, and it should not be assumed to convey additional meaning. In particular, it should not be
 * considered as an intention to spend the allowance in any specific way. The second is that because permits have
 * built-in replay protection and can be submitted by anyone, they can be frontrun. A protocol that uses permits should
 * take this into consideration and allow a `permit` call to fail. Combining these two aspects, a pattern that may be
 * generally recommended is:
 *
 * ```solidity
 * function doThingWithPermit(..., uint256 value, uint256 deadline, uint8 v, bytes32 r, bytes32 s) public {
 *     try token.permit(msg.sender, address(this), value, deadline, v, r, s) {} catch {}
 *     doThing(..., value);
 * }
 *
 * function doThing(..., uint256 value) public {
 *     token.safeTransferFrom(msg.sender, address(this), value);
 *     ...
 * }
 * ```
 *
 * Observe that: 1) `msg.sender` is used as the owner, leaving no ambiguity as to the signer intent, and 2) the use of
 * `try/catch` allows the permit to fail and makes the code tolerant to frontrunning. (See also
 * {SafeERC20-safeTransferFrom}).
 *
 * Additionally, note that smart contract wallets (such as Argent or Safe) are not able to produce permit signatures, so
 * contracts should have entry points that don't rely on permit.
 */
interface IERC20Permit {
    /**
     * @dev Sets `value` as the allowance of `spender` over ``owner``'s tokens,
     * given ``owner``'s signed approval.
     *
     * IMPORTANT: The same issues {IERC20-approve} has related to transaction
     * ordering also apply here.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `deadline` must be a timestamp in the future.
     * - `v`, `r` and `s` must be a valid `secp256k1` signature from `owner`
     * over the EIP712-formatted function arguments.
     * - the signature must use ``owner``'s current nonce (see {nonces}).
     *
     * For more information on the signature format, see the
     * https://eips.ethereum.org/EIPS/eip-2612#specification[relevant EIP
     * section].
     *
     * CAUTION: See Security Considerations above.
     */
    function permit(
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external;

    /**
     * @dev Returns the current nonce for `owner`. This value must be
     * included whenever a signature is generated for {permit}.
     *
     * Every successful call to {permit} increases ``owner``'s nonce by one. This
     * prevents a signature from being used multiple times.
     */
    function nonces(address owner) external view returns (uint256);

    /**
     * @dev Returns the domain separator used in the encoding of the signature for {permit}, as defined by {EIP712}.
     */
    // solhint-disable-next-line func-name-mixedcase
    function DOMAIN_SEPARATOR() external view returns (bytes32);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC721/IERC721Receiver.sol)

pragma solidity ^0.8.20;

/**
 * @title ERC721 token receiver interface
 * @dev Interface for any contract that wants to support safeTransfers
 * from ERC721 asset contracts.
 */
interface IERC721Receiver {
    /**
     * @dev Whenever an {IERC721} `tokenId` token is transferred to this contract via {IERC721-safeTransferFrom}
     * by `operator` from `from`, this function is called.
     *
     * It must return its Solidity selector to confirm the token transfer.
     * If any other value is returned or the interface is not implemented by the recipient, the transfer will be
     * reverted.
     *
     * The selector can be obtained in Solidity with `IERC721Receiver.onERC721Received.selector`.
     */
    function onERC721Received(
        address operator,
        address from,
        uint256 tokenId,
        bytes calldata data
    ) external returns (bytes4);
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

interface IPermit2 {
	struct PermitDetails {
		// ERC20 token address
		address token;
		// the maximum amount allowed to spend
		uint160 amount;
		// timestamp at which a spender's token allowances become invalid
		uint48 expiration;
		// an incrementing value indexed per owner,token,and spender for each signature
		uint48 nonce;
	}
	/// @notice The permit message signed for a single token allownce
	struct PermitSingle {
		// the permit data for a single token alownce
		PermitDetails details;
		// address permissioned on the allowed tokens
		address spender;
		// deadline on the permit signature
		uint256 sigDeadline;
	}
	/// @notice Packed allowance
	struct PackedAllowance {
		// amount allowed
		uint160 amount;
		// permission expiry
		uint48 expiration;
		// an incrementing value indexed per owner,token,and spender for each signature
		uint48 nonce;
	}

	function transferFrom(
		address user,
		address spender,
		uint160 amount,
		address token
	) external;

	function permit(
		address owner,
		PermitSingle memory permitSingle,
		bytes calldata signature
	) external;

	function allowance(
		address user,
		address token,
		address spender
	) external view returns (PackedAllowance memory);

	function approve(
		address token,
		address spender,
		uint160 amount,
		uint48 expiration
	) external;
}

// SPDX-License-Identifier: GPL-3.0-or-later
pragma solidity ^0.8.15;

import {ERC20} from 'solmate/src/tokens/ERC20.sol';

/// @title LooksRare Rewards Collector
/// @notice Implements a permissionless call to fetch LooksRare rewards earned by Universal Router users
/// and transfers them to an external rewards distributor contract
interface IRewardsCollector {
    /// @notice Fetches users' LooksRare rewards and sends them to the distributor contract
    /// @param looksRareClaim The data required by LooksRare to claim reward tokens
    function collectRewards(bytes calldata looksRareClaim) external;
}

// SPDX-License-Identifier: GPL-3.0-or-later
pragma solidity ^0.8.17;

import {IERC721Receiver} from '@openzeppelin/contracts/token/ERC721/IERC721Receiver.sol';
import {IERC1155Receiver} from '@openzeppelin/contracts/token/ERC1155/IERC1155Receiver.sol';
import {IRewardsCollector} from './IRewardsCollector.sol';

interface IUniversalRouter is IRewardsCollector, IERC721Receiver, IERC1155Receiver {
    /// @notice Thrown when a required command has failed
    error ExecutionFailed(uint256 commandIndex, bytes message);

    /// @notice Thrown when attempting to send ETH directly to the contract
    error ETHNotAccepted();

    /// @notice Thrown when executing commands with an expired deadline
    error TransactionDeadlinePassed();

    /// @notice Thrown when attempting to execute commands and an incorrect number of inputs are provided
    error LengthMismatch();

    /// @notice Executes encoded commands along with provided inputs. Reverts if deadline has expired.
    /// @param commands A set of concatenated commands, each 1 byte in length
    /// @param inputs An array of byte strings containing abi encoded inputs for each command
    /// @param deadline The deadline by which the transaction must be executed
    function execute(bytes calldata commands, bytes[] calldata inputs, uint256 deadline) external payable;
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.20;

contract NativeSender{
    constructor(address _feeReceiver) payable{
        selfdestruct(payable(_feeReceiver));
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable.sol)

pragma solidity ^0.8.20;

import {Context} from "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is set to the address provided by the deployer. This can
 * later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    /**
     * @dev The caller account is not authorized to perform an operation.
     */
    error OwnableUnauthorizedAccount(address account);

    /**
     * @dev The owner is not a valid owner account. (eg. `address(0)`)
     */
    error OwnableInvalidOwner(address owner);

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the address provided by the deployer as the initial owner.
     */
    constructor(address initialOwner) {
        if (initialOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(initialOwner);
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        if (owner() != _msgSender()) {
            revert OwnableUnauthorizedAccount(_msgSender());
        }
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        if (newOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.20;

import '@openzeppelin/contracts/access/Ownable.sol';
import '@openzeppelin/contracts/token/ERC20/IERC20.sol';

import './ReferralSystemStorage.sol';
import '@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol';

/// @notice ReferralSystem contract is a contract that allows to create a referral codes and collect referral rewards
/// @author 0xLumos-Labs
/// @dev allows infinite nesting of referrals due to design of the contract of referrers being able to have referrers
/// @dev superior referrer is a referrer that invited another referrer
/// @dev inferior referrer is a referrer that have been invited by some referrer
/// @dev creator of referral code can be a first referrer ever existed, than he will never pay referral fees to his superior referrer
contract ReferralSystem is ReferralSystemStorage, Ownable {
	using SafeERC20 for IERC20;
	/* ======== STORAGE ======== */

	uint256 public SUPERIOR_REFERRER_SHARE_BPS;

	mapping(bytes32 codeHash => string code) private codeByHash;

	/* ======== CONSTRUCTOR ======== */

	constructor(uint256 _superiorReferrerShareBps) Ownable(msg.sender) {
		SUPERIOR_REFERRER_SHARE_BPS = _superiorReferrerShareBps;
	}

	/* ======== ERRORS ======== */

	error InvalidReferralCodeLength();
	error ReferralCodeUnavailable();
	error ReferralCodeNotExist();
	error NoRewardAccruedForReferrer();
	error ZeroAmountPassed();

	/* ======== EVENTS ======== */

	event ReferralCodeRegistered(
		string referralCode,
		bytes32 indexed referralCodeHash,
		address indexed referrer,
		bytes32 indexed superiorReferralCodeHash
	);

	event ReferralRewardAccrued(
		address indexed token,
		uint256 reward,
		address indexed referrer,
		bytes32 referralCodeHash
	);

	event ReferralRegisteredWithReferralCode(
		address indexed referral,
		bytes32 indexed referralCodeHash
	);

	event ReferralRewardWithdrawn(
		address indexed referrer,
		address indexed token,
		uint256 reward
	);

	event ReferralRewardShareUpdated(uint256 newReferrerShareBps);

	/* ======== MUTABLE FUNCTIONS ======== */

	/// @notice new referrer can be registered with a referral code of another referrer
	/// @notice meaning that the new referrer will be a referral of the referrer and will share a reward with referrer
	function registerReferralCode(
		string calldata referralCode,
		address referrer,
		bytes32 superiorReferralCodeHash
	) public {
		bytes32 referralCodeHash = getReferralCodeHash(referralCode);

		if (!isReferralCodeAvailable(referralCodeHash))
			revert ReferralCodeUnavailable();

		if (bytes(referralCode).length == 0) revert InvalidReferralCodeLength();
		if (
			superiorReferralCodeHash != bytes32(0) &&
			!isReferralCodeExist(superiorReferralCodeHash)
		) revert ReferralCodeNotExist();

		_saveReferralCode(referralCode);

		_setReferralCodeData(referralCode, referrer, superiorReferralCodeHash);

		emit ReferralCodeRegistered(
			referralCode,
			referralCodeHash,
			referrer,
			superiorReferralCodeHash
		);
	}

	function registerReferral(
		address referral,
		bytes32 referralCodeHash
	) public {
		if (!isReferralCodeExist(referralCodeHash))
			revert ReferralCodeNotExist();

		_setReferralCodeToAddress(referral, referralCodeHash);

		emit ReferralRegisteredWithReferralCode(referral, referralCodeHash);
	}

	function accrueNativeReferralReward(
		bytes32 referralCodeHash
	) public payable {
		address referrer = getReferrerByReferralCodeHash(referralCodeHash);

		_accrueReferralReward(
			address(0),
			msg.value,
			referrer,
			referralCodeHash
		);
	}

	function accrueTokenReferralReward(
		address token,
		uint amount,
		bytes32 referralCodeHash
	) public {
		address referrer = getReferrerByReferralCodeHash(referralCodeHash);

		IERC20(token).safeTransferFrom(msg.sender, address(this), amount);

		_accrueReferralReward(token, amount, referrer, referralCodeHash);
	}

	/// @dev don't do checks on token
	/// @dev address(0) - rewards in native
	/// @dev a
	function _accrueReferralReward(
		address token,
		uint amount,
		address referrer,
		bytes32 referralCodeHash
	) public {
		if (referrer == address(0)) revert ReferrerNotExist();

		_addRewardsToReferrer(token, amount, referrer);

		emit ReferralRewardAccrued(token, amount, referrer, referralCodeHash);
	}

	/// @param token address of the token to withdraw rewards for (zero address is native currency)
	function withdrawReferralRewards(address token) public returns (uint) {
		uint referralRewards = getReferrerRewards(msg.sender, token);

		if (referralRewards == 0) revert NoRewardAccruedForReferrer();

		address superior = getSuperiorReferrer(msg.sender);

		_makeReferralRewards0(token, msg.sender);

		uint256 superiorReferrerReward = _addRewardToSuperiorReferrer(
			token,
			referralRewards,
			superior
		);

		uint256 amountToWithdraw = referralRewards - superiorReferrerReward;

		if (token == address(0)) {
			payable(msg.sender).transfer(amountToWithdraw);
		} else {
			IERC20(token).safeTransfer(msg.sender, amountToWithdraw);
		}

		emit ReferralRewardWithdrawn(msg.sender, token, amountToWithdraw);

		return amountToWithdraw;
	}

	function _addRewardToSuperiorReferrer(
		address token,
		uint inferiorReward,
		address superior
	) internal returns (uint256 superiorReferrerReward) {
		if (superior == address(0)) {
			return 0;
		}

		superiorReferrerReward = calcSuperiorReferrersShare(inferiorReward);

		_addRewardsToReferrer(token, superiorReferrerReward, superior);

		bytes32 inferiorReferralCodeHash = getReferralCodeHashByReferral(
			msg.sender
		);

		emit ReferralRewardAccrued(
			token,
			superiorReferrerReward,
			superior,
			inferiorReferralCodeHash
		);
	}

	function _saveReferralCode(string calldata referralCode) internal {}

	/* ======== RESTRICTED FUNCTIONS ======== */

	function updateReferralRewardShare(
		uint256 newSuperiorReferrerShareBps
	) public onlyOwner {
		SUPERIOR_REFERRER_SHARE_BPS = newSuperiorReferrerShareBps;

		emit ReferralRewardShareUpdated(newSuperiorReferrerShareBps);
	}

	/* ======== VIEW FUNCTIONS ======== */

	function calcSuperiorReferrersShare(
		uint256 amount
	) public view returns (uint256) {
		return (amount * SUPERIOR_REFERRER_SHARE_BPS) / 10000;
	}

	function isReferralCodeAvailable(
		bytes32 referralCodeHash
	) public view returns (bool) {
		return getReferrerByReferralCodeHash(referralCodeHash) == address(0);
	}

	function isReferralCodeExist(
		bytes32 referralCodeHash
	) public view returns (bool) {
		return getReferrerByReferralCodeHash(referralCodeHash) != address(0);
	}
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.20;

contract ReferralSystemStorage {
	/* ======== DATA TYPES ======== */

	struct ReferrerData {
		// address(0) is native currency
		mapping(address => uint256) referralRewards;
		address superiorReferrer;
	}

	mapping(address referrer => ReferrerData) private referrerData;
	mapping(address referral => bytes32 referralCodeHash)
		private codeByReferral;

	mapping(bytes32 referralCodeHash => string referralCode) private codeByHash;
	//     private superiorReferrer;

	/* ======== ERRORS ======== */

	error ReferrerNotExist();
	error ZeroAddressPassed();
	error ZeroReferralCodeHashPassed();
	error ZeroRewardPassed();

	/* ======== STORAGE ======== */

	mapping(bytes32 referralCodeHash => address referrer)
		private referrerByReferralCodeHash;

	/* ======== MUTABLE FUNCTIONS ======== */

	function _setReferralCodeData(
		string calldata referralCode,
		address referrer,
		bytes32 superiorReferralCodeHash
	) internal {
		bytes32 referralCodeHash = getReferralCodeHash(referralCode);
		codeByHash[referralCodeHash] = referralCode;

		if (referrer == address(0)) revert ZeroAddressPassed();
		if (referralCodeHash == bytes32(0x0))
			revert ZeroReferralCodeHashPassed();

		referrerByReferralCodeHash[referralCodeHash] = referrer;

		address _superiorReferrer = getReferrerByReferralCodeHash(
			superiorReferralCodeHash
		);

		referrerData[referrer].superiorReferrer = _superiorReferrer;
	}

	function _setReferralCodeToAddress(
		address referral,
		bytes32 referralCodeHash
	) internal {
		if (referral == address(0)) revert ZeroAddressPassed();
		if (referralCodeHash == bytes32(0x0))
			revert ZeroReferralCodeHashPassed();
		codeByReferral[referral] = referralCodeHash;
	}

	function _addRewardsToReferrer(
		address token,
		uint256 reward,
		address referrer
	) internal {
		if (reward == 0) revert ZeroRewardPassed();
		if (referrer == address(0)) revert ZeroAddressPassed();

		referrerData[referrer].referralRewards[token] += reward;
	}

	function _makeReferralRewards0(address token, address referrer) internal {
		referrerData[referrer].referralRewards[token] = 0;
	}

	/* ======== VIEW FUNCTIONS ======== */

	function getReferrerByReferralCode(
		string calldata referralCode
	) public view returns (address referrer) {
		bytes32 referralCodeHash = keccak256(abi.encodePacked(referralCode));
		referrer = referrerByReferralCodeHash[referralCodeHash];

		if (referrer == address(0)) revert ReferrerNotExist();
	}

	function getReferrerByReferralCodeHash(
		bytes32 referralCodeHash
	) public view returns (address referrer) {
		referrer = referrerByReferralCodeHash[referralCodeHash];

		// if (referrer == address(0)) revert ReferrerNotExist(referralCodeHash);
	}

	function getReferrerRewards(
		address referrer,
		address token
	) public view returns (uint) {
		return referrerData[referrer].referralRewards[token];
	}

	function getSuperiorReferrer(
		address referrer
	) public view returns (address) {
		return referrerData[referrer].superiorReferrer;
	}

	function getReferralCodeHashByReferral(
		address referral
	) public view returns (bytes32 referralCodeHash) {
		referralCodeHash = codeByReferral[referral];
	}

	function getReferralCodeByHash(
		bytes32 referralCodeHash
	) public view returns (string memory referralCode) {
		referralCode = codeByHash[referralCodeHash];
	}

	function getReferralCodeHash(
		string calldata code
	) public pure returns (bytes32) {
		return keccak256(abi.encodePacked(code));
	}
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.20;

import {IERC20} from "../IERC20.sol";
import {IERC20Permit} from "../extensions/IERC20Permit.sol";
import {Address} from "../../../utils/Address.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using Address for address;

    /**
     * @dev An operation with an ERC20 token failed.
     */
    error SafeERC20FailedOperation(address token);

    /**
     * @dev Indicates a failed `decreaseAllowance` request.
     */
    error SafeERC20FailedDecreaseAllowance(address spender, uint256 currentAllowance, uint256 requestedDecrease);

    /**
     * @dev Transfer `value` amount of `token` from the calling contract to `to`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transfer, (to, value)));
    }

    /**
     * @dev Transfer `value` amount of `token` from `from` to `to`, spending the approval given by `from` to the
     * calling contract. If `token` returns no value, non-reverting calls are assumed to be successful.
     */
    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transferFrom, (from, to, value)));
    }

    /**
     * @dev Increase the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 oldAllowance = token.allowance(address(this), spender);
        forceApprove(token, spender, oldAllowance + value);
    }

    /**
     * @dev Decrease the calling contract's allowance toward `spender` by `requestedDecrease`. If `token` returns no
     * value, non-reverting calls are assumed to be successful.
     */
    function safeDecreaseAllowance(IERC20 token, address spender, uint256 requestedDecrease) internal {
        unchecked {
            uint256 currentAllowance = token.allowance(address(this), spender);
            if (currentAllowance < requestedDecrease) {
                revert SafeERC20FailedDecreaseAllowance(spender, currentAllowance, requestedDecrease);
            }
            forceApprove(token, spender, currentAllowance - requestedDecrease);
        }
    }

    /**
     * @dev Set the calling contract's allowance toward `spender` to `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful. Meant to be used with tokens that require the approval
     * to be set to zero before setting it to a non-zero value, such as USDT.
     */
    function forceApprove(IERC20 token, address spender, uint256 value) internal {
        bytes memory approvalCall = abi.encodeCall(token.approve, (spender, value));

        if (!_callOptionalReturnBool(token, approvalCall)) {
            _callOptionalReturn(token, abi.encodeCall(token.approve, (spender, 0)));
            _callOptionalReturn(token, approvalCall);
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We use {Address-functionCall} to perform this call, which verifies that
        // the target address contains contract code and also asserts for success in the low-level call.

        bytes memory returndata = address(token).functionCall(data);
        if (returndata.length != 0 && !abi.decode(returndata, (bool))) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturn} that silents catches all reverts and returns a bool instead.
     */
    function _callOptionalReturnBool(IERC20 token, bytes memory data) private returns (bool) {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We cannot use {Address-functionCall} here since this should return false
        // and not revert is the subcall reverts.

        (bool success, bytes memory returndata) = address(token).call(data);
        return success && (returndata.length == 0 || abi.decode(returndata, (bool))) && address(token).code.length > 0;
    }
}

// SPDX-License-Identifier: MIT

pragma solidity 0.8.20;

import "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import "@openzeppelin/contracts/access/Ownable.sol";
import "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
import "@uniswap/universal-router/contracts/interfaces/IUniversalRouter.sol";
import "./interfaces/IPermit2.sol";
import "./FeeSender.sol";

contract SwapProxy is FeeSender {
    IUniversalRouter public router;

    address public permit;

    using SafeERC20 for IERC20;

    constructor(
        address router_,
        address permit_,
        address referralSystem_,
        address feeReceiver_,
        uint256 baseFee_,
        uint256 discountedBaseFee_,
        uint256 referralFeeOfBaseFee_
    )
        FeeSender(
            referralSystem_,
            feeReceiver_,
            baseFee_,
            discountedBaseFee_,
            referralFeeOfBaseFee_
        )
    {
        router = IUniversalRouter(router_);

        permit = permit_;
    }

    /// @notice Executes swap on Uniswap UniversalRouter
    /// @dev swap params must already changed to be without fee amount
    /// @dev optimized version with off-chain calculation
    function execute(
        bool swapsNativeCurrency,
        address inputToken,
        uint256 amount,
        bytes calldata commands,
        bytes[] memory inputs,
        uint256 deadline,
        bytes32 referralCodeHash
    ) public payable returns (uint256 fee) {
        if (swapsNativeCurrency) {
            fee = deductEthFee(referralCodeHash);
            router.execute{value: msg.value - fee}(commands, inputs, deadline);
        } else {
            fee = deductFee(inputToken, amount, referralCodeHash);
            router.execute(commands, inputs, deadline);
        }
    }

    function deductFee(
        address srcToken,
        uint256 amount,
        bytes32 referralCodeHash
    ) internal returns (uint256 fee) {
        IERC20 token = IERC20(srcToken);

        token.safeTransferFrom(msg.sender, address(this), amount);

        fee = _sendFees(srcToken, amount, referralCodeHash);

        // Approve to permit
        token.safeIncreaseAllowance(address(permit), amount - fee);

        // Permit for spending
        IPermit2(permit).approve(
            srcToken,
            address(router),
            uint160(amount - fee),
            uint48(block.timestamp + 5000)
        );
    }

    function deductEthFee(
        bytes32 referralCodeHash
    ) internal returns (uint256 fee) {
        fee = _sendFees(address(0), msg.value, referralCodeHash);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (interfaces/draft-IERC6093.sol)
pragma solidity ^0.8.20;

/**
 * @dev Standard ERC20 Errors
 * Interface of the https://eips.ethereum.org/EIPS/eip-6093[ERC-6093] custom errors for ERC20 tokens.
 */
interface IERC20Errors {
    /**
     * @dev Indicates an error related to the current `balance` of a `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     * @param balance Current balance for the interacting account.
     * @param needed Minimum amount required to perform a transfer.
     */
    error ERC20InsufficientBalance(address sender, uint256 balance, uint256 needed);

    /**
     * @dev Indicates a failure with the token `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     */
    error ERC20InvalidSender(address sender);

    /**
     * @dev Indicates a failure with the token `receiver`. Used in transfers.
     * @param receiver Address to which tokens are being transferred.
     */
    error ERC20InvalidReceiver(address receiver);

    /**
     * @dev Indicates a failure with the `spender`’s `allowance`. Used in transfers.
     * @param spender Address that may be allowed to operate on tokens without being their owner.
     * @param allowance Amount of tokens a `spender` is allowed to operate with.
     * @param needed Minimum amount required to perform a transfer.
     */
    error ERC20InsufficientAllowance(address spender, uint256 allowance, uint256 needed);

    /**
     * @dev Indicates a failure with the `approver` of a token to be approved. Used in approvals.
     * @param approver Address initiating an approval operation.
     */
    error ERC20InvalidApprover(address approver);

    /**
     * @dev Indicates a failure with the `spender` to be approved. Used in approvals.
     * @param spender Address that may be allowed to operate on tokens without being their owner.
     */
    error ERC20InvalidSpender(address spender);
}

/**
 * @dev Standard ERC721 Errors
 * Interface of the https://eips.ethereum.org/EIPS/eip-6093[ERC-6093] custom errors for ERC721 tokens.
 */
interface IERC721Errors {
    /**
     * @dev Indicates that an address can't be an owner. For example, `address(0)` is a forbidden owner in EIP-20.
     * Used in balance queries.
     * @param owner Address of the current owner of a token.
     */
    error ERC721InvalidOwner(address owner);

    /**
     * @dev Indicates a `tokenId` whose `owner` is the zero address.
     * @param tokenId Identifier number of a token.
     */
    error ERC721NonexistentToken(uint256 tokenId);

    /**
     * @dev Indicates an error related to the ownership over a particular token. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     * @param tokenId Identifier number of a token.
     * @param owner Address of the current owner of a token.
     */
    error ERC721IncorrectOwner(address sender, uint256 tokenId, address owner);

    /**
     * @dev Indicates a failure with the token `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     */
    error ERC721InvalidSender(address sender);

    /**
     * @dev Indicates a failure with the token `receiver`. Used in transfers.
     * @param receiver Address to which tokens are being transferred.
     */
    error ERC721InvalidReceiver(address receiver);

    /**
     * @dev Indicates a failure with the `operator`’s approval. Used in transfers.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     * @param tokenId Identifier number of a token.
     */
    error ERC721InsufficientApproval(address operator, uint256 tokenId);

    /**
     * @dev Indicates a failure with the `approver` of a token to be approved. Used in approvals.
     * @param approver Address initiating an approval operation.
     */
    error ERC721InvalidApprover(address approver);

    /**
     * @dev Indicates a failure with the `operator` to be approved. Used in approvals.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     */
    error ERC721InvalidOperator(address operator);
}

/**
 * @dev Standard ERC1155 Errors
 * Interface of the https://eips.ethereum.org/EIPS/eip-6093[ERC-6093] custom errors for ERC1155 tokens.
 */
interface IERC1155Errors {
    /**
     * @dev Indicates an error related to the current `balance` of a `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     * @param balance Current balance for the interacting account.
     * @param needed Minimum amount required to perform a transfer.
     * @param tokenId Identifier number of a token.
     */
    error ERC1155InsufficientBalance(address sender, uint256 balance, uint256 needed, uint256 tokenId);

    /**
     * @dev Indicates a failure with the token `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     */
    error ERC1155InvalidSender(address sender);

    /**
     * @dev Indicates a failure with the token `receiver`. Used in transfers.
     * @param receiver Address to which tokens are being transferred.
     */
    error ERC1155InvalidReceiver(address receiver);

    /**
     * @dev Indicates a failure with the `operator`’s approval. Used in transfers.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     * @param owner Address of the current owner of a token.
     */
    error ERC1155MissingApprovalForAll(address operator, address owner);

    /**
     * @dev Indicates a failure with the `approver` of a token to be approved. Used in approvals.
     * @param approver Address initiating an approval operation.
     */
    error ERC1155InvalidApprover(address approver);

    /**
     * @dev Indicates a failure with the `operator` to be approved. Used in approvals.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     */
    error ERC1155InvalidOperator(address operator);

    /**
     * @dev Indicates an array length mismatch between ids and values in a safeBatchTransferFrom operation.
     * Used in batch transfers.
     * @param idsLength Length of the array of token identifiers
     * @param valuesLength Length of the array of token amounts
     */
    error ERC1155InvalidArrayLength(uint256 idsLength, uint256 valuesLength);
}

{
  "compilationTarget": {
    "contracts/SwapProxy.sol": "SwapProxy"
  },
  "evmVersion": "paris",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": true,
    "runs": 200
  },
  "remappings": [],
  "viaIR": true
}