// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable.sol)

pragma solidity ^0.8.20;

import {Context} from "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is set to the address provided by the deployer. This can
 * later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    /**
     * @dev The caller account is not authorized to perform an operation.
     */
    error OwnableUnauthorizedAccount(address account);

    /**
     * @dev The owner is not a valid owner account. (eg. `address(0)`)
     */
    error OwnableInvalidOwner(address owner);

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the address provided by the deployer as the initial owner.
     */
    constructor(address initialOwner) {
        if (initialOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(initialOwner);
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        if (owner() != _msgSender()) {
            revert OwnableUnauthorizedAccount(_msgSender());
        }
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        if (newOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.24;

import "@openzeppelin/contracts/access/Ownable.sol";

/// @title TokiemonUserRegistry
/// @notice Human readable username registry for users on leaderboard and referral system
/// @dev This contract manages the mapping between Ethereum addresses and usernames for our game

contract TokiemonUserRegistry is Ownable {
    mapping(address => string) private addressToUsername;
    mapping(string => address) private usernameToAddress;

    uint8 public constant MAX_USERNAME_LENGTH = 14;

    event UsernameSet(address indexed user, string username);

    constructor() Ownable(msg.sender) {}

    /// @notice Get the username associated with a given address
    /// @param _user The address to look up
    /// @return The username associated with the given address
    function getUsername(address _user) public view returns (string memory) {
        return addressToUsername[_user];
    }

    /// @notice Get the address associated with a given username
    /// @param _username The username to look up
    /// @return The address associated with the given username
    function getAddress(string memory _username) public view returns (address) {
        return usernameToAddress[_username];
    }

    /// @notice Set or update the username for the caller's address
    /// @param _username The new username to set
    /// @dev Emits UsernameSet event
    function setUsername(string memory _username) public {
        require(bytes(_username).length > 0, "Username cannot be empty");
        require(bytes(_username).length <= MAX_USERNAME_LENGTH, "Username too long");
        require(usernameToAddress[_username] == address(0), "Username already taken");
        require(isValidUsername(_username), "Username must be lowercase letters and numbers only");

        string memory oldUsername = addressToUsername[msg.sender];

        if (bytes(oldUsername).length > 0) {
            delete usernameToAddress[oldUsername];
        }

        addressToUsername[msg.sender] = _username;
        usernameToAddress[_username] = msg.sender;
        emit UsernameSet(msg.sender, _username);
    }

    /// @notice Set or update the username for a specific user address by the owner
    /// @param _user The address of the user to set the username for
    /// @param _username The new username to set
    /// @dev Emits UsernameSet event
    function setUsernameByOwner(address _user, string memory _username) public onlyOwner {
        require(bytes(_username).length > 0, "Username cannot be empty");
        require(usernameToAddress[_username] == address(0), "Username already taken");

        string memory oldUsername = addressToUsername[_user];

        if (bytes(oldUsername).length > 0) {
            delete usernameToAddress[oldUsername];
        }

        addressToUsername[_user] = _username;
        usernameToAddress[_username] = _user;
        emit UsernameSet(_user, _username);
    }

    /// @notice Check if a username contains only lowercase letters and numbers
    /// @param _username The username to check
    /// @return True if the username is valid, false otherwise
    function isValidUsername(string memory _username) internal pure returns (bool) {
        bytes memory b = bytes(_username);
        for (uint i; i < b.length; i++) {
            bytes1 char = b[i];
            if (!(char >= 0x30 && char <= 0x39) && !(char >= 0x61 && char <= 0x7A)) {
                return false;
            }
        }
        return true;
    }
}

{
  "compilationTarget": {
    "src/TokiemonUserRegistry.sol": "TokiemonUserRegistry"
  },
  "evmVersion": "paris",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": true,
    "runs": 200
  },
  "remappings": []
}