// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Context.sol)

pragma solidity ^0.8.0;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.7.0) (access/Ownable.sol)

pragma solidity ^0.8.0;

import "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _transferOwnership(_msgSender());
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions anymore. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby removing any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.12;

import "./BaseContracts/Withdrawable.interface.sol";

abstract contract PaymentReceiverInterface is WithdrawableInterface {
    
    // ==== General Contract Admin ====

    function enablePayments() public virtual;

    function disablePayments() public virtual;


    // ==== Core Contract Functionality ====

    function pay(string calldata paymentSessionid) payable public virtual;
    
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.12;

import "@openzeppelin/contracts/access/Ownable.sol";

import "./BaseContracts/Withdrawable.sol";
import "./PaymentReceiver.interface.sol";

contract PaymentReceiver is PaymentReceiverInterface, Withdrawable, Ownable {

    // ==== Variables ====

    bool public isPaymentEnabled = false;

    // ==== Events ====

    event Payment(uint amount, string paymentSessionid, address sender);

    // ==== Modifiers ====

    modifier onlyWhenPaymentEnabled() {
        require(isPaymentEnabled, "Payment is not enabled");
        _;
    }
    
    // ==== General Contract Admin ====

    function enablePayments() public override onlyOwner {
        isPaymentEnabled = true;
    }

    function disablePayments() public override onlyOwner {
        isPaymentEnabled = false;
    }

    // ==== Core Contract Functionality ====

    function pay(string calldata paymentSessionid) payable public override onlyWhenPaymentEnabled {
        emit Payment(msg.value, paymentSessionid, _msgSender());
    }

}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.12;

abstract contract WithdrawableInterface {
    
    // ==== General Contract Admin ====

    function addAdmin(address adminAddress) external virtual;

    function removeAdmin(address adminAddress) external virtual;

    // ==== Core Contract Functionality ====

    function withdraw() external virtual;
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.12;

import "./Withdrawable.interface.sol";

abstract contract Withdrawable is WithdrawableInterface {

    // ==== Variables ====

    mapping(address => bool) private admins;
    uint256 public adminCount;

    // ======== Constructor =========
    
    constructor() {
        // The address that creates the contract becomes it's first admin
         admins[msg.sender] = true;
         adminCount = 1;
    }

    // ======== Events =========

    event Received(address, uint256);

    // ==== Modifiers ====

    modifier onlyAdmins() {
        require(admins[msg.sender], "Admin access only");
        _;
    }

    // ==== General Contract Admin ====

    function addAdmin(address walletAddress) external override onlyAdmins {
        if (admins[walletAddress]) {
            return;
        }
        admins[walletAddress] = true;
        adminCount += 1;
    }

    function removeAdmin(address walletAddress) external override onlyAdmins {
        if (!admins[walletAddress]) {
            return;
        }
        require(adminCount > 1, "Contract needs at least one admin");
        delete admins[walletAddress];
        adminCount -= 1;
    }

    // ==== Core Contract Functionality ====

    function withdraw() external override onlyAdmins {
        uint256 balance = address(this).balance;
        (bool success, ) = msg.sender.call{value: balance}("");
        require(success, "Withdraw failed");
    }

    receive() external payable {
        emit Received(msg.sender, msg.value);
    }
}

{
  "compilationTarget": {
    "contracts/PaymentReceiver.sol": "PaymentReceiver"
  },
  "evmVersion": "london",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": false,
    "runs": 200
  },
  "remappings": []
}