//.:::.     .........  ...     ...       ....    ...     ....     ...        ...       
//  .*@@@@@@@*.  @@@@@@@@@: #@@@-  :@@#       #@@*   +@@%    =@@@@=    #@@+      =@@%       
//  @@@*. .+##*  @@@+::::.  #@@@@#::@@#       #@@#:::*@@%   .@@%%@@:   #@@+      =@@%       
// :@@@: +%%%%#  @@@@@@@@=  #@@%@@@%@@#       #@@@@@@@@@%   %@@:-@@%   #@@+      =@@%       
//  @@@*.:-#@@@  @@@+.....  #@@-:#@@@@#       #@@#...+@@%  *@@@##@@@*  #@@*::::: =@@@:::::  
//  :#@@@@@@#@@  @@@@@@@@@- #@@-  -@@@#       #@@*   +@@% -@@@====@@@= #@@@@@@@@ =@@@@@@@@= 
//     .::.  ..  .........  ...     ...       ....    ... ....    .... .........  ........

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;

interface IGenHallInterface {
    function upgradeGenHallTokenContract(address _genHallTokenAddress) external;

    function setAllowGen(bool allow) external;

    function genAllowed() external view returns (bool);

    function getMembershipTier(uint256 _membershipId) external view returns (uint256);

    function transferFrom(
        address _from,
        address _to,
        uint256 _amount
    ) external;

    function balanceOf(address _owner) external view returns (uint256);

    function ownerOf(uint256 _membershipId) external view returns (address);
}

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(
        address indexed previousOwner,
        address indexed newOwner
    );

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _setOwner(_msgSender());
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
        _;
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(
            newOwner != address(0),
            "Ownable: new owner is the zero address"
        );
        _setOwner(newOwner);
    }

    function _setOwner(address newOwner) private {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

/**
 * @title Counters
 * @author Matt Condon (@shrugs)
 * @dev Provides counters that can only be incremented, decremented or reset. This can be used e.g. to track the number
 * of elements in a mapping, issuing ERC721 ids, or counting request ids.
 *
 * Include with `using Counters for Counters.Counter;`
 */
library Counters {
    struct Counter {
        // This variable should never be directly accessed by users of the library: interactions must be restricted to
        // the library's function. As of Solidity v0.5.2, this cannot be enforced, though there is a proposal to add
        // this feature: see https://github.com/ethereum/solidity/issues/4637
        uint256 _value; // default: 0
    }

    function current(Counter storage counter) internal view returns (uint256) {
        return counter._value;
    }

    function increment(Counter storage counter) internal {
        unchecked {
            counter._value += 1;
        }
    }

    function decrement(Counter storage counter) internal {
        uint256 value = counter._value;
        require(value > 0, "Counter: decrement overflow");
        unchecked {
            counter._value = value - 1;
        }
    }

    function reset(Counter storage counter) internal {
        counter._value = 0;
    }
}

/**
 * @dev String operations.
 */
library Strings {
    bytes16 private constant _HEX_SYMBOLS = "0123456789abcdef";

    /**
     * @dev Converts a `uint256` to its ASCII `string` decimal representation.
     */
    function toString(uint256 value) internal pure returns (string memory) {
        // Inspired by OraclizeAPI's implementation - MIT licence
        // https://github.com/oraclize/ethereum-api/blob/b42146b063c7d6ee1358846c198246239e9360e8/oraclizeAPI_0.4.25.sol

        if (value == 0) {
            return "0";
        }
        uint256 temp = value;
        uint256 digits;
        while (temp != 0) {
            digits++;
            temp /= 10;
        }
        bytes memory buffer = new bytes(digits);
        while (value != 0) {
            digits -= 1;
            buffer[digits] = bytes1(uint8(48 + uint256(value % 10)));
            value /= 10;
        }
        return string(buffer);
    }
}

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize, which returns 0 for contracts in
        // construction, since the code is only stored at the end of the
        // constructor execution.

        uint256 size;
        assembly {
            size := extcodesize(account)
        }
        return size > 0;
    }
}

// CAUTION
// This version of SafeMath should only be used with Solidity 0.8 or later,
// because it relies on the compiler's built in overflow checks.

/**
 * @dev Wrappers over Solidity's arithmetic operations.
 *
 * NOTE: `SafeMath` is no longer needed starting with Solidity 0.8. The compiler
 * now has built in overflow checking.
 */
library SafeMath {
    /**
     * @dev Returns the addition of two unsigned integers, with an overflow flag.
     *
     * _Available since v3.4._
     */
    function tryAdd(uint256 a, uint256 b)
        internal
        pure
        returns (bool, uint256)
    {
        unchecked {
            uint256 c = a + b;
            if (c < a) return (false, 0);
            return (true, c);
        }
    }

    /**
     * @dev Returns the substraction of two unsigned integers, with an overflow flag.
     *
     * _Available since v3.4._
     */
    function trySub(uint256 a, uint256 b)
        internal
        pure
        returns (bool, uint256)
    {
        unchecked {
            if (b > a) return (false, 0);
            return (true, a - b);
        }
    }

    /**
     * @dev Returns the multiplication of two unsigned integers, with an overflow flag.
     *
     * _Available since v3.4._
     */
    function tryMul(uint256 a, uint256 b)
        internal
        pure
        returns (bool, uint256)
    {
        unchecked {
            // Gas optimization: this is cheaper than requiring 'a' not being zero, but the
            // benefit is lost if 'b' is also tested.
            // See: https://github.com/OpenZeppelin/openzeppelin-contracts/pull/522
            if (a == 0) return (true, 0);
            uint256 c = a * b;
            if (c / a != b) return (false, 0);
            return (true, c);
        }
    }

    /**
     * @dev Returns the division of two unsigned integers, with a division by zero flag.
     *
     * _Available since v3.4._
     */
    function tryDiv(uint256 a, uint256 b)
        internal
        pure
        returns (bool, uint256)
    {
        unchecked {
            if (b == 0) return (false, 0);
            return (true, a / b);
        }
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers, with a division by zero flag.
     *
     * _Available since v3.4._
     */
    function tryMod(uint256 a, uint256 b)
        internal
        pure
        returns (bool, uint256)
    {
        unchecked {
            if (b == 0) return (false, 0);
            return (true, a % b);
        }
    }

    /**
     * @dev Returns the addition of two unsigned integers, reverting on
     * overflow.
     *
     * Counterpart to Solidity's `+` operator.
     *
     * Requirements:
     *
     * - Addition cannot overflow.
     */
    function add(uint256 a, uint256 b) internal pure returns (uint256) {
        return a + b;
    }

    /**
     * @dev Returns the subtraction of two unsigned integers, reverting on
     * overflow (when the result is negative).
     *
     * Counterpart to Solidity's `-` operator.
     *
     * Requirements:
     *
     * - Subtraction cannot overflow.
     */
    function sub(uint256 a, uint256 b) internal pure returns (uint256) {
        return a - b;
    }

    /**
     * @dev Returns the multiplication of two unsigned integers, reverting on
     * overflow.
     *
     * Counterpart to Solidity's `*` operator.
     *
     * Requirements:
     *
     * - Multiplication cannot overflow.
     */
    function mul(uint256 a, uint256 b) internal pure returns (uint256) {
        return a * b;
    }

    /**
     * @dev Returns the integer division of two unsigned integers, reverting on
     * division by zero. The result is rounded towards zero.
     *
     * Counterpart to Solidity's `/` operator.
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function div(uint256 a, uint256 b) internal pure returns (uint256) {
        return a / b;
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers. (unsigned integer modulo),
     * reverting when dividing by zero.
     *
     * Counterpart to Solidity's `%` operator. This function uses a `revert`
     * opcode (which leaves remaining gas untouched) while Solidity uses an
     * invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function mod(uint256 a, uint256 b) internal pure returns (uint256) {
        return a % b;
    }

    /**
     * @dev Returns the subtraction of two unsigned integers, reverting with custom message on
     * overflow (when the result is negative).
     *
     * CAUTION: This function is deprecated because it requires allocating memory for the error
     * message unnecessarily. For custom revert reasons use {trySub}.
     *
     * Counterpart to Solidity's `-` operator.
     *
     * Requirements:
     *
     * - Subtraction cannot overflow.
     */
    function sub(
        uint256 a,
        uint256 b,
        string memory errorMessage
    ) internal pure returns (uint256) {
        unchecked {
            require(b <= a, errorMessage);
            return a - b;
        }
    }

    /**
     * @dev Returns the integer division of two unsigned integers, reverting with custom message on
     * division by zero. The result is rounded towards zero.
     *
     * Counterpart to Solidity's `/` operator. Note: this function uses a
     * `revert` opcode (which leaves remaining gas untouched) while Solidity
     * uses an invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function div(
        uint256 a,
        uint256 b,
        string memory errorMessage
    ) internal pure returns (uint256) {
        unchecked {
            require(b > 0, errorMessage);
            return a / b;
        }
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers. (unsigned integer modulo),
     * reverting with custom message when dividing by zero.
     *
     * CAUTION: This function is deprecated because it requires allocating memory for the error
     * message unnecessarily. For custom revert reasons use {tryMod}.
     *
     * Counterpart to Solidity's `%` operator. This function uses a `revert`
     * opcode (which leaves remaining gas untouched) while Solidity uses an
     * invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function mod(
        uint256 a,
        uint256 b,
        string memory errorMessage
    ) internal pure returns (uint256) {
        unchecked {
            require(b > 0, errorMessage);
            return a % b;
        }
    }
}

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `recipient`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address recipient, uint256 amount)
        external
        returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender)
        external
        view
        returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `sender` to `recipient` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(
        address sender,
        address recipient,
        uint256 amount
    ) external returns (bool);

    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(
        address indexed owner,
        address indexed spender,
        uint256 value
    );
}

/**
 * @title ERC721 token receiver interface
 * @dev Interface for any contract that wants to support safeTransfers
 * from ERC721 asset contracts.
 */
interface IERC721Receiver {
    /**
     * @dev Whenever an {IERC721} `tokenId` token is transferred to this contract via {IERC721-safeTransferFrom}
     * by `operator` from `from`, this function is called.
     *
     * It must return its Solidity selector to confirm the token transfer.
     * If any other value is returned or the interface is not implemented by the recipient, the transfer will be reverted.
     *
     * The selector can be obtained in Solidity with `IERC721.onERC721Received.selector`.
     */
    function onERC721Received(
        address operator,
        address from,
        uint256 tokenId,
        bytes calldata data
    ) external returns (bytes4);
}

/**
 * @dev Interface of the ERC165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[EIP].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[EIP section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}

/**
 * @dev Implementation of the {IERC165} interface.
 *
 * Contracts that want to implement ERC165 should inherit from this contract and override {supportsInterface} to check
 * for the additional interface id that will be supported. For example:
 *
 * ```solidity
 * function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
 *     return interfaceId == type(MyInterface).interfaceId || super.supportsInterface(interfaceId);
 * }
 * ```
 *
 * Alternatively, {ERC165Storage} provides an easier to use but more expensive implementation.
 */
abstract contract ERC165 is IERC165 {
    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId)
        public
        view
        virtual
        override
        returns (bool)
    {
        return interfaceId == type(IERC165).interfaceId;
    }
}

/**
 * @dev Required interface of an ERC721 compliant contract.
 */
interface IERC721 is IERC165 {
    /**
     * @dev Emitted when `tokenId` token is transferred from `from` to `to`.
     */
    event Transfer(
        address indexed from,
        address indexed to,
        uint256 indexed tokenId
    );

    /**
     * @dev Emitted when `owner` enables `approved` to manage the `tokenId` token.
     */
    event Approval(
        address indexed owner,
        address indexed approved,
        uint256 indexed tokenId
    );

    /**
     * @dev Emitted when `owner` enables or disables (`approved`) `operator` to manage all of its assets.
     */
    event ApprovalForAll(
        address indexed owner,
        address indexed operator,
        bool approved
    );

    /**
     * @dev Returns the number of tokens in ``owner``'s account.
     */
    function balanceOf(address owner) external view returns (uint256 balance);

    /**
     * @dev Returns the owner of the `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function ownerOf(uint256 tokenId) external view returns (address owner);

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`, checking first that contract recipients
     * are aware of the ERC721 protocol to prevent tokens from being forever locked.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must be have been allowed to move this token by either {approve} or {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId
    ) external;

    /**
     * @dev Transfers `tokenId` token from `from` to `to`.
     *
     * WARNING: Usage of this method is discouraged, use {safeTransferFrom} whenever possible.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(
        address from,
        address to,
        uint256 tokenId
    ) external;

    /**
     * @dev Gives permission to `to` to transfer `tokenId` token to another account.
     * The approval is cleared when the token is transferred.
     *
     * Only a single account can be approved at a time, so approving the zero address clears previous approvals.
     *
     * Requirements:
     *
     * - The caller must own the token or be an approved operator.
     * - `tokenId` must exist.
     *
     * Emits an {Approval} event.
     */
    function approve(address to, uint256 tokenId) external;

    /**
     * @dev Returns the account approved for `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function getApproved(uint256 tokenId)
        external
        view
        returns (address operator);

    /**
     * @dev Approve or remove `operator` as an operator for the caller.
     * Operators can call {transferFrom} or {safeTransferFrom} for any token owned by the caller.
     *
     * Requirements:
     *
     * - The `operator` cannot be the caller.
     *
     * Emits an {ApprovalForAll} event.
     */
    function setApprovalForAll(address operator, bool _approved) external;

    /**
     * @dev Returns if the `operator` is allowed to manage all of the assets of `owner`.
     *
     * See {setApprovalForAll}
     */
    function isApprovedForAll(address owner, address operator)
        external
        view
        returns (bool);

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId,
        bytes calldata data
    ) external;
}

/**
 * @title ERC-721 Non-Fungible Token Standard, optional enumeration extension
 * @dev See https://eips.ethereum.org/EIPS/eip-721
 */
interface IERC721Enumerable is IERC721 {
    /**
     * @dev Returns the total amount of tokens stored by the contract.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns a token ID owned by `owner` at a given `index` of its token list.
     * Use along with {balanceOf} to enumerate all of ``owner``'s tokens.
     */
    function tokenOfOwnerByIndex(address owner, uint256 index)
        external
        view
        returns (uint256 tokenId);

    /**
     * @dev Returns a token ID at a given `index` of all the tokens stored by the contract.
     * Use along with {totalSupply} to enumerate all tokens.
     */
    function tokenByIndex(uint256 index) external view returns (uint256);
}

/**
 * @title ERC-721 Non-Fungible Token Standard, optional metadata extension
 * @dev See https://eips.ethereum.org/EIPS/eip-721
 */
interface IERC721Metadata is IERC721 {
    /**
     * @dev Returns the token collection name.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the token collection symbol.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the Uniform Resource Identifier (URI) for `tokenId` token.
     */
    function tokenURI(uint256 tokenId) external view returns (string memory);
}

/**
 * @dev Implementation of https://eips.ethereum.org/EIPS/eip-721[ERC721] Non-Fungible Token Standard, including
 * the Metadata extension, but not including the Enumerable extension, which is available separately as
 * {ERC721Enumerable}.
 */

contract GenHallCollection is
    Context,
    ERC165,
    IERC721,
    IERC721Metadata,
    IERC721Enumerable,
    Ownable
{
    using Address for address;
    using Strings for uint256;
    using Counters for Counters.Counter;
    using SafeMath for uint256;

    struct Collection {
        bool active;
        uint256 tier;
        uint256 invocations;
        uint256 maxInvocations;
        uint256 maxMint;
        bool requiresMembership;
        string script;
        uint256 price;
        uint256 priceGen;
        uint256 artistPercentage;
        uint256 artistRewards;
        address artist;
        mapping(address => uint256) collaboratorPercentages;
        mapping(address => uint256) collaboratorShares;
        address[] collaborators;
        uint256[] maxMintPerMembershipTier;
        uint256 maxMintPerTransaction;
    }

    event Mint(address to, uint256 collectionId, uint256 tokenId, bytes32 hash);

    // IGenHallMintState _genHallMintState;
    mapping(uint256 => Collection) private _collectionsMap;

    // Mapping collectionId to membershipId and total mints
    mapping(uint256 => mapping(uint256 => uint256)) private _collectionsMembershipMintMap;
    mapping(uint256 => mapping(address => uint256)) private _collectionsMintMap;

    mapping(uint256 => bytes32) private _tokenIdToHashMap;
    mapping(uint256 => uint256) private _tokenIdToCollectionIdMap;
    Counters.Counter private _collectionIdCounter;
    IGenHallInterface private _genHallInterface;

    function getCurrentCounter() public view returns(uint256) {
        return _collectionIdCounter.current();
    }

    // Token name
    string private _name;

    // Token symbol
    string private _symbol;

    // Base URI
    string private _baseURI;

    // Mapping from token ID to owner address
    mapping(uint256 => address) private _owners;

    // Mapping owner address to token count
    mapping(address => uint256) private _balances;

    // Mapping from token ID to approved address
    mapping(uint256 => address) private _tokenApprovals;

    // Mapping from owner to operator approvals
    mapping(address => mapping(address => bool)) private _operatorApprovals;

    // Mapping from owner to list of owned token IDs
    mapping(address => mapping(uint256 => uint256)) private _ownedTokens;

    // Mapping from token ID to index of the owner tokens list
    mapping(uint256 => uint256) private _ownedTokensIndex;

    // Array with all token ids, used for enumeration
    uint256[] private _allTokens;

    // Mapping from token id to position in the allTokens array
    mapping(uint256 => uint256) private _allTokensIndex;

    /**
     * @dev Initializes the contract by setting a `name` and a `symbol` to the token collection.
     */
    constructor(
        string memory name_,
        string memory symbol_
    ) {
        _name = name_;
        _symbol = symbol_;
        _collectionIdCounter.increment();
    }

    modifier onlyArtist(uint256 _collectionId) {
        require(
            _collectionsMap[_collectionId].artist == _msgSender(),
            "GenHallCollection: only artist can call this function"
        );
        _;
    }

    modifier onlyCollaborator(uint256 _collectionId) {
        require(
            _collectionsMap[_collectionId].collaboratorPercentages[_msgSender()] > 0,
            "GenHallCollection: only collaborators can call this function"
        );
        _;
    }

    function setMembershipRequired(uint256 _collectionId, bool membershipRequired) public onlyOwner {
        _collectionsMap[_collectionId].requiresMembership = membershipRequired;
    }

    function getMembershipRequired(uint256 _collectionId) public view returns(bool){
        return _collectionsMap[_collectionId].requiresMembership;
    }

    function setCollectionActive(uint256 _collectionId, bool active) public onlyOwner {
        _collectionsMap[_collectionId].active = active;
    }

    function isCollectionActive(uint256 _collectionId) public view returns(bool){
        return _collectionsMap[_collectionId].active;
    }

    function getArtistRewards(uint256 _collectionId) public view returns(uint256) {
        return _collectionsMap[_collectionId].artistRewards;
    }

    function getArtistPercentage(uint256 _collectionId) public view returns(uint256) {
        return _collectionsMap[_collectionId].artistPercentage;
    }

    function withdrawArtist(uint256 _collectionId) public onlyArtist(_collectionId) {
        uint256 withdrawAmount = _collectionsMap[_collectionId].artistRewards;

        _collectionsMap[_collectionId].artistRewards = 0;

        payable(_msgSender()).transfer(withdrawAmount);
    }

    function getCollaboratorShares(uint256 _collectionId, address _collaboratorAddress) public view returns(uint256) {
        return _collectionsMap[_collectionId].collaboratorShares[_collaboratorAddress];
    }

    function getCollaboratorPercentage(uint256 _collectionId, address _collaboratorAddress) public view returns(uint256) {
        return _collectionsMap[_collectionId].collaboratorPercentages[_collaboratorAddress];
    }

    function withdrawCollaborator(uint256 _collectionId) public onlyCollaborator(_collectionId) {
        uint256 withdrawAmount = _collectionsMap[_collectionId].collaboratorShares[_msgSender()];

        _collectionsMap[_collectionId].collaboratorShares[_msgSender()] = 0;

        payable(_msgSender()).transfer(withdrawAmount);
    }

    function createCollection(
        address _artist,
        uint256 _artistPercentage,
        uint256 _price,
        uint256 _priceGen,
        uint256 _maxInvocations,
        uint256 _maxMint,
        bool _requiresMembership,
        address[] memory _collaborators,
        uint256[] memory _collaboratorPercentages,
        uint256 _maxMintPerTransaction
    ) public onlyOwner {
        uint256 _collectionId = _collectionIdCounter.current();

        Collection storage collection = _collectionsMap[_collectionId];

        collection.active = false;
        collection.tier = 1;
        collection.maxMintPerMembershipTier = [1];
        collection.invocations = 0;
        collection.maxInvocations = _maxInvocations;
        collection.maxMint = _maxMint;
        collection.requiresMembership = _requiresMembership;
        collection.price = _price;
        collection.priceGen = _priceGen;
        collection.artistPercentage = _artistPercentage;
        collection.artist = _artist;
        collection.collaborators = _collaborators;
        collection.maxMintPerTransaction = _maxMintPerTransaction;

        uint256 sharesPercentageTotal = _artistPercentage;

        for (uint i = 0; i < collection.collaborators.length; i++) {
            sharesPercentageTotal += _collaboratorPercentages[i];
            collection.collaboratorPercentages[collection.collaborators[i]] =
                _collaboratorPercentages[i];
        }

        require(sharesPercentageTotal == 100, "The shares percentages (artist + collaborators) must add up to 100");

        _collectionIdCounter.increment();
    }

    function updateMaxMint(uint256 _collectionId, uint256 _maxMint) public onlyOwner {
        _collectionsMap[_collectionId].maxMint = _maxMint;
    }

    function updateTier(uint256 _collectionId, uint256 _tier) public onlyOwner {
        _collectionsMap[_collectionId].tier = _tier;
    }

    function updateMaxMintPerMembershipTier(uint256 _collectionId, uint256[] memory _maxMintPerMembershipTier) public onlyOwner {
        _collectionsMap[_collectionId].maxMintPerMembershipTier = _maxMintPerMembershipTier;
    }

    function checkMint(
        address _sender,
        uint256 _collectionId,
        uint256 _membershipId,
        uint256 _value,
        uint256 _amount,
        bool _isEthPayment
    ) internal virtual {
        require(
            _collectionsMap[_collectionId].active == true,
            "GenHallCollection: the collection is still not active, and thus cannot be minted"
        );

        require(
            _collectionsMap[_collectionId].invocations <
                _collectionsMap[_collectionId].maxInvocations,
            "GenHallCollection: max invocations was reached"
        );

        require(
            _amount <= _collectionsMap[_collectionId].maxMintPerTransaction,
            "GenHallCollection: mint amount is over max mint per transaction"
        );

        uint256 avaliableMints = _collectionsMap[_collectionId].maxMint;

        if (_collectionsMap[_collectionId].requiresMembership) {
            address _membershipOwner = _genHallInterface.ownerOf(_membershipId);
            require(
                _membershipOwner == _sender,
                "GenHallCollection: sender must be membership owner"
            );
            uint256 _tier = _genHallInterface.getMembershipTier(_membershipId);
            require(
                _tier >= _collectionsMap[_collectionId].tier,
                "GenHallCollection: no valid membership"
            );
            avaliableMints = getAllowedMintForMembership(
                _collectionId,
                _membershipId
            );
        }
        else{
            avaliableMints = _collectionsMap[_collectionId].maxMint - _collectionsMintMap[_collectionId][_msgSender()];
        }

        require(
            avaliableMints >= _amount,
            "GenHallCollection: not enough mints avaliable for your allowance"
        );
        if (_isEthPayment) {
            require(
                _collectionsMap[_collectionId].price * _amount <= _value,
                "GenHallCollection: incorrect amount sent"
            );
        } else {
            require(
                _collectionsMap[_collectionId].priceGen * _amount <= _value,
                "GenHallCollection: insufficient $GENHALL balance"
            );
        }
    }

    function mint(
        address _to,
        uint256 _collectionId,
        uint256 _membershipId
    ) public payable {
        checkMint(_msgSender(), _collectionId, _membershipId, msg.value, 1, true);
        updateMintState(_collectionId, _membershipId, 1);
        _mintOne(_to, _collectionId);
        splitFunds(_msgSender(), _collectionId, 1, true);
    }

    function mintGen(
        address _to,
        uint256 _collectionId,
        uint256 _membershipId
    ) public {
        bool _genAllowed = _genHallInterface.genAllowed();
        require(_genAllowed, "Mint with $GENHALL not allowed");
        uint256 balance = _genHallInterface.balanceOf(_msgSender());
        checkMint(_msgSender(), _collectionId, _membershipId, balance, 1, false);
        updateMintState(_collectionId, _membershipId, 1);
        _mintOne(_to, _collectionId);
        splitFunds(_msgSender(), _collectionId, 1, false);
    }

    function mintMany(
        address _to,
        uint256 _collectionId,
        uint256 _membershipId,
        uint256 _amount
    ) public payable {
        checkMint(
            _msgSender(),
            _collectionId,
            _membershipId,
            msg.value,
            _amount,
            true
        );
        updateMintState(_collectionId, _membershipId, _amount);
        _mintMany(_to, _collectionId, _amount);
        splitFunds(_msgSender(), _collectionId, _amount, true);
    }

    function mintManyGen(
        address _to,
        uint256 _collectionId,
        uint256 _membershipId,
        uint256 _amount
    ) public {
        bool _genAllowed = _genHallInterface.genAllowed();
        require(_genAllowed, "Mint with $GENHALL not allowed");
        uint256 balance = _genHallInterface.balanceOf(_msgSender());
        checkMint(
            _msgSender(),
            _collectionId,
            _membershipId,
            balance,
            _amount,
            false
        );
        updateMintState(_collectionId, _membershipId, _amount);
        _mintMany(_to, _collectionId, _amount);
        splitFunds(_msgSender(), _collectionId, _amount, false);
    }

    function _mintMany(
        address _to,
        uint256 _collectionId,
        uint256 _amount
    ) internal virtual {
        for (uint256 i = 0; i < _amount; i++) {
            _mintOne(_to, _collectionId);
        }
    }

    function _mintOne(address _to, uint256 _collectionId) internal virtual {
        uint256 invocation = _collectionsMap[_collectionId].invocations + 1;
        uint256 _tokenId = _collectionId * 100000 + invocation;
        _collectionsMap[_collectionId].invocations = invocation;

        bytes32 hash = keccak256(
            abi.encodePacked(invocation, block.number, block.difficulty, _to)
        );
        _tokenIdToHashMap[_tokenId] = hash;
        _tokenIdToCollectionIdMap[_tokenId] = _collectionId;

        _safeMint(_to, _tokenId);

        emit Mint(_to, _collectionId, _tokenId, hash);
    }

    function splitFunds(
        address _sender,
        uint256 _collectionId,
        uint256 _amount,
        bool _isEthPayment
    ) internal virtual {
        uint256 value = _isEthPayment
            ? _collectionsMap[_collectionId].price * _amount
            : _collectionsMap[_collectionId].priceGen * _amount;
        address _owner = owner();
        uint256 artistReward = (value *
            _collectionsMap[_collectionId].artistPercentage) / 100;

        if (_isEthPayment) {
            _collectionsMap[_collectionId].artistRewards += artistReward;

            for (uint i = 0; i < _collectionsMap[_collectionId].collaborators.length; i++) {
                uint256 collaboratorShare = (value *
                    _collectionsMap[_collectionId].collaboratorPercentages[_collectionsMap[_collectionId].collaborators[i]]) / 100;

                _collectionsMap[_collectionId].collaboratorShares[_collectionsMap[_collectionId].collaborators[i]] += collaboratorShare;
            }
        } else {
            // handle collaborators
            uint256 collaboratorSharesTotal = 0;
            for (uint i = 0; i < _collectionsMap[_collectionId].collaborators.length; i++) {
                uint256 collaboratorShare = (value *
                    _collectionsMap[_collectionId].collaboratorPercentages[_collectionsMap[_collectionId].collaborators[i]]) / 100;
                _genHallInterface.transferFrom(
                    _sender,
                    _collectionsMap[_collectionId].collaborators[i],
                    collaboratorShare
                );
                collaboratorSharesTotal += collaboratorShare;
            }

            // handle artist
            _genHallInterface.transferFrom(
                _sender,
                _collectionsMap[_collectionId].artist,
                artistReward
            );

            // finally, handle owner who gets remaining
            _genHallInterface.transferFrom(
                _sender,
                _owner,
                value - artistReward - collaboratorSharesTotal
            );
        }
    }

    function burn(uint256 _tokenId) public {
        _burn(_tokenId);
    }

    function getMaxMintPerTransaction(uint256 _collectionId) public view returns(uint256){
        return _collectionsMap[_collectionId].maxMintPerTransaction;
    }

    function getMaxMintForMembership(
        uint256 _collectionId,
        uint256 _membershipId
    ) public view returns (uint256) {
        uint256 _tier = _genHallInterface.getMembershipTier(_membershipId);

        return _tier < _collectionsMap[_collectionId].maxMintPerMembershipTier.length ?
            _collectionsMap[_collectionId].maxMintPerMembershipTier[_tier] :
            _collectionsMap[_collectionId].maxMintPerMembershipTier[_collectionsMap[_collectionId].maxMintPerMembershipTier.length - 1];
    }

    function getMembershipTier(uint256 _membershipId) public view returns(uint256) {
        return _genHallInterface.getMembershipTier(_membershipId);
    }

    function getAllowedMintForMembership(
        uint256 _collectionId,
        uint256 _membershipId
    ) public view returns (uint256) {
        return getMaxMintForMembership(_collectionId, _membershipId) - _collectionsMembershipMintMap[_collectionId][_membershipId];
    }

    function getMaxMintForNonMembership(uint256 _collectionId) public view returns(uint256) {
        return _collectionsMap[_collectionId].maxMint;
    }

    function remainingNonMembershipMint(uint256 _collectionId) public view returns(uint256) {
        return _collectionsMap[_collectionId].maxMint - _collectionsMintMap[_collectionId][_msgSender()];
    }

    function updateMintState(
        uint256 _collectionId,
        uint256 _membershipId,
        uint256 _amount
    ) internal virtual {
        if (_collectionsMap[_collectionId].requiresMembership) {
            _collectionsMembershipMintMap[_collectionId][_membershipId] =
                _collectionsMembershipMintMap[_collectionId][_membershipId] +
                _amount;
        } else {
            _collectionsMintMap[_collectionId][_msgSender()] =
                _collectionsMintMap[_collectionId][_msgSender()] +
                _amount;
        }
    }

    function updateArtistAddress(uint256 _collectionId, address _artist)
        public
        onlyArtist(_collectionId)
    {
        _collectionsMap[_collectionId].artist = _artist;
    }

    function updateMaxInvocations(
        uint256 _collectionId,
        uint256 _maxInvocations
    ) public onlyOwner {
        _collectionsMap[_collectionId].maxInvocations = _maxInvocations;
    }

    function updateScript(uint256 _collectionId, string memory _script)
        public
        onlyOwner
    {
        _collectionsMap[_collectionId].script = _script;
    }

    function upgradeGenHallInterfaceContract(address _genHallInterfaceAddress)
        public
        onlyOwner
    {
        _genHallInterface = IGenHallInterface(_genHallInterfaceAddress);
    }

    function updatePrice(
        uint256 _collectionId,
        uint256 _price,
        uint256 _priceGen
    ) public onlyOwner {
        _collectionsMap[_collectionId].price = _price;
        _collectionsMap[_collectionId].priceGen = _priceGen;
    }

    function getCollectionInfo(uint256 _collectionId)
        public
        view
        returns (
            uint256 invocations,
            uint256 maxInvocations,
            uint256 price,
            uint256 priceGen,
            address artist,
            uint256 artistPercentage,
            bool requiresMembership
        )
    {
        return (
            _collectionsMap[_collectionId].invocations,
            _collectionsMap[_collectionId].maxInvocations,
            _collectionsMap[_collectionId].price,
            _collectionsMap[_collectionId].priceGen,
            _collectionsMap[_collectionId].artist,
            _collectionsMap[_collectionId].artistPercentage,
            _collectionsMap[_collectionId].requiresMembership
        );
    }

    function getTokenInfo(uint256 _tokenId)
        public
        view
        returns (
            uint256,
            uint256,
            address,
            bytes32
        )
    {
        _exists(_tokenId);
        bytes32 hash = _tokenIdToHashMap[_tokenId];
        uint256 _collectionId = _tokenIdToCollectionIdMap[_tokenId];
        address owner = GenHallCollection.ownerOf(_tokenId);

        return (_tokenId, _collectionId, owner, hash);
    }

    function getTokensByOwner(address _owner)
        public
        view
        returns (uint256[] memory)
    {
        uint256 tokenCount = balanceOf(_owner);
        uint256[] memory tokenIds = new uint256[](tokenCount);
        for (uint256 i; i < tokenCount; i++) {
            tokenIds[i] = tokenOfOwnerByIndex(_owner, i);
        }

        return tokenIds;
    }

    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId)
        public
        view
        virtual
        override(ERC165, IERC165)
        returns (bool)
    {
        return
            interfaceId == type(IERC721).interfaceId ||
            interfaceId == type(IERC721Metadata).interfaceId ||
            interfaceId == type(IERC721Enumerable).interfaceId ||
            super.supportsInterface(interfaceId);
    }

    /**
     * @dev See {IERC721-balanceOf}.
     */
    function balanceOf(address owner)
        public
        view
        virtual
        override
        returns (uint256)
    {
        require(
            owner != address(0),
            "ERC721: balance query for the zero address"
        );
        return _balances[owner];
    }

    /**
     * @dev See {IERC721-ownerOf}.
     */
    function ownerOf(uint256 tokenId)
        public
        view
        virtual
        override
        returns (address)
    {
        address owner = _owners[tokenId];
        require(
            owner != address(0),
            "ERC721: owner query for nonexistent token"
        );
        return owner;
    }

    /**
     * @dev See {IERC721Metadata-name}.
     */
    function name() public view virtual override returns (string memory) {
        return _name;
    }

    /**
     * @dev See {IERC721Metadata-symbol}.
     */
    function symbol() public view virtual override returns (string memory) {
        return _symbol;
    }

    /**
     * @dev See {IERC721Metadata-tokenURI}.
     */
    function tokenURI(uint256 tokenId)
        public
        view
        virtual
        override
        returns (string memory)
    {
        require(
            _exists(tokenId),
            "ERC721Metadata: URI query for nonexistent token"
        );

        string memory baseURI_ = baseURI();
        return
            bytes(baseURI_).length > 0
                ? string(abi.encodePacked(baseURI_, tokenId.toString()))
                : "";
    }

    /**
     * @dev Base URI for computing {tokenURI}. If set, the resulting URI for each
     * token will be the concatenation of the `baseURI` and the `tokenId`. Empty
     * by default, can be overriden in child contracts.
     */
    function baseURI() internal view virtual returns (string memory) {
        return _baseURI;
    }

    /**
     * @dev Internal function to set the base URI for all token IDs. It is
     * automatically added as a prefix to the value returned in {tokenURI},
     * or to the token ID if {tokenURI} is empty.
     */
    function setBaseURI(string memory baseURI_) public onlyOwner {
        _baseURI = baseURI_;
    }

    /**
     * @dev See {IERC721-approve}.
     */
    function approve(address to, uint256 tokenId) public virtual override {
        address owner = GenHallCollection.ownerOf(tokenId);
        require(to != owner, "ERC721: approval to current owner");

        require(
            _msgSender() == owner || isApprovedForAll(owner, _msgSender()),
            "ERC721: approve caller is not owner nor approved for all"
        );

        _approve(to, tokenId);
    }

    /**
     * @dev See {IERC721-getApproved}.
     */
    function getApproved(uint256 tokenId)
        public
        view
        virtual
        override
        returns (address)
    {
        require(
            _exists(tokenId),
            "ERC721: approved query for nonexistent token"
        );

        return _tokenApprovals[tokenId];
    }

    /**
     * @dev See {IERC721-setApprovalForAll}.
     */
    function setApprovalForAll(address operator, bool approved)
        public
        virtual
        override
    {
        require(operator != _msgSender(), "ERC721: approve to caller");

        _operatorApprovals[_msgSender()][operator] = approved;
        emit ApprovalForAll(_msgSender(), operator, approved);
    }

    /**
     * @dev See {IERC721-isApprovedForAll}.
     */
    function isApprovedForAll(address owner, address operator)
        public
        view
        virtual
        override
        returns (bool)
    {
        return _operatorApprovals[owner][operator];
    }

    /**
     * @dev See {IERC721-transferFrom}.
     */
    function transferFrom(
        address from,
        address to,
        uint256 tokenId
    ) public virtual override {
        //solhint-disable-next-line max-line-length
        require(
            _isApprovedOrOwner(_msgSender(), tokenId),
            "ERC721: transfer caller is not owner nor approved"
        );

        _transfer(from, to, tokenId);
    }

    /**
     * @dev See {IERC721-safeTransferFrom}.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId
    ) public virtual override {
        safeTransferFrom(from, to, tokenId, "");
    }

    /**
     * @dev See {IERC721-safeTransferFrom}.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId,
        bytes memory _data
    ) public virtual override {
        require(
            _isApprovedOrOwner(_msgSender(), tokenId),
            "ERC721: transfer caller is not owner nor approved"
        );
        _safeTransfer(from, to, tokenId, _data);
    }

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`, checking first that contract recipients
     * are aware of the ERC721 protocol to prevent tokens from being forever locked.
     *
     * `_data` is additional data, it has no specified format and it is sent in call to `to`.
     *
     * This internal function is equivalent to {safeTransferFrom}, and can be used to e.g.
     * implement alternative mechanisms to perform token transfer, such as signature-based.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function _safeTransfer(
        address from,
        address to,
        uint256 tokenId,
        bytes memory _data
    ) internal virtual {
        _transfer(from, to, tokenId);
        require(
            _checkOnERC721Received(from, to, tokenId, _data),
            "ERC721: transfer to non ERC721Receiver implementer"
        );
    }

    /**
     * @dev Returns whether `tokenId` exists.
     *
     * Tokens can be managed by their owner or approved accounts via {approve} or {setApprovalForAll}.
     *
     * Tokens start existing when they are minted (`_mint`),
     * and stop existing when they are burned (`_burn`).
     */
    function _exists(uint256 tokenId) internal view virtual returns (bool) {
        return _owners[tokenId] != address(0);
    }

    /**
     * @dev Returns whether `spender` is allowed to manage `tokenId`.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function _isApprovedOrOwner(address spender, uint256 tokenId)
        internal
        view
        virtual
        returns (bool)
    {
        require(
            _exists(tokenId),
            "ERC721: operator query for nonexistent token"
        );
        address owner = GenHallCollection.ownerOf(tokenId);
        return (spender == owner ||
            getApproved(tokenId) == spender ||
            isApprovedForAll(owner, spender));
    }

    /**
     * @dev Safely mints `tokenId` and transfers it to `to`.
     *
     * Requirements:
     *
     * - `tokenId` must not exist.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function _safeMint(address to, uint256 tokenId) internal virtual {
        _safeMint(to, tokenId, "");
    }

    /**
     * @dev Same as {xref-ERC721-_safeMint-address-uint256-}[`_safeMint`], with an additional `data` parameter which is
     * forwarded in {IERC721Receiver-onERC721Received} to contract recipients.
     */
    function _safeMint(
        address to,
        uint256 tokenId,
        bytes memory _data
    ) internal virtual {
        _mint(to, tokenId);
        require(
            _checkOnERC721Received(address(0), to, tokenId, _data),
            "ERC721: transfer to non ERC721Receiver implementer"
        );
    }

    /**
     * @dev Mints `tokenId` and transfers it to `to`.
     *
     * WARNING: Usage of this method is discouraged, use {_safeMint} whenever possible
     *
     * Requirements:
     *
     * - `tokenId` must not exist.
     * - `to` cannot be the zero address.
     *
     * Emits a {Transfer} event.
     */
    function _mint(address to, uint256 tokenId) internal virtual {
        require(to != address(0), "ERC721: mint to the zero address");
        require(!_exists(tokenId), "ERC721: token already minted");

        _beforeTokenTransfer(address(0), to, tokenId);

        _balances[to] += 1;
        _owners[tokenId] = to;

        emit Transfer(address(0), to, tokenId);
    }

    /**
     * @dev Destroys `tokenId`.
     * The approval is cleared when the token is burned.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     *
     * Emits a {Transfer} event.
     */
    function _burn(uint256 tokenId) internal virtual {
        address owner = GenHallCollection.ownerOf(tokenId);
        require(
            _msgSender() == owner,
            "GenHallCollection: only token owner can burn"
        );
        _beforeTokenTransfer(owner, address(0), tokenId);
        // Clear approvals
        _approve(address(0), tokenId);

        _balances[owner] -= 1;
        delete _owners[tokenId];

        emit Transfer(owner, address(0), tokenId);
    }

    /**
     * @dev Transfers `tokenId` from `from` to `to`.
     *  As opposed to {transferFrom}, this imposes no restrictions on _msgSender().
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     * - `tokenId` token must be owned by `from`.
     *
     * Emits a {Transfer} event.
     */
    function _transfer(
        address from,
        address to,
        uint256 tokenId
    ) internal virtual {
        require(
            GenHallCollection.ownerOf(tokenId) == from,
            "ERC721: transfer of token that is not own"
        );
        require(to != address(0), "ERC721: transfer to the zero address");

        _beforeTokenTransfer(from, to, tokenId);

        // Clear approvals from the previous owner
        _approve(address(0), tokenId);

        _balances[from] -= 1;
        _balances[to] += 1;
        _owners[tokenId] = to;

        emit Transfer(from, to, tokenId);
    }

    /**
     * @dev Approve `to` to operate on `tokenId`
     *
     * Emits a {Approval} event.
     */
    function _approve(address to, uint256 tokenId) internal virtual {
        _tokenApprovals[tokenId] = to;
        emit Approval(GenHallCollection.ownerOf(tokenId), to, tokenId);
    }

    /**
     * @dev Internal function to invoke {IERC721Receiver-onERC721Received} on a target address.
     * The call is not executed if the target address is not a contract.
     *
     * @param from address representing the previous owner of the given token ID
     * @param to target address that will receive the tokens
     * @param tokenId uint256 ID of the token to be transferred
     * @param _data bytes optional data to send along with the call
     * @return bool whether the call correctly returned the expected magic value
     */
    function _checkOnERC721Received(
        address from,
        address to,
        uint256 tokenId,
        bytes memory _data
    ) private returns (bool) {
        if (to.isContract()) {
            try
                IERC721Receiver(to).onERC721Received(
                    _msgSender(),
                    from,
                    tokenId,
                    _data
                )
            returns (bytes4 retval) {
                return retval == IERC721Receiver.onERC721Received.selector;
            } catch (bytes memory reason) {
                if (reason.length == 0) {
                    revert(
                        "ERC721: transfer to non ERC721Receiver implementer"
                    );
                } else {
                    assembly {
                        revert(add(32, reason), mload(reason))
                    }
                }
            }
        } else {
            return true;
        }
    }

    /**
     * @dev See {IERC721Enumerable-tokenOfOwnerByIndex}.
     */
    function tokenOfOwnerByIndex(address owner, uint256 index)
        public
        view
        virtual
        override
        returns (uint256)
    {
        require(
            index < GenHallCollection.balanceOf(owner),
            "ERC721Enumerable: owner index out of bounds"
        );
        return _ownedTokens[owner][index];
    }

    /**
     * @dev See {IERC721Enumerable-totalSupply}.
     */
    function totalSupply() public view virtual override returns (uint256) {
        return _allTokens.length;
    }

    /**
     * @dev See {IERC721Enumerable-tokenByIndex}.
     */
    function tokenByIndex(uint256 index)
        public
        view
        virtual
        override
        returns (uint256)
    {
        require(
            index < GenHallCollection.totalSupply(),
            "ERC721Enumerable: global index out of bounds"
        );
        return _allTokens[index];
    }

    /**
     * @dev Hook that is called before any token transfer. This includes minting
     * and burning.
     *
     * Calling conditions:
     *
     * - When `from` and `to` are both non-zero, ``from``'s `tokenId` will be
     * transferred to `to`.
     * - When `from` is zero, `tokenId` will be minted for `to`.
     * - When `to` is zero, ``from``'s `tokenId` will be burned.
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     *
     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
     */
    function _beforeTokenTransfer(
        address from,
        address to,
        uint256 tokenId
    ) internal virtual {
        if (from == address(0)) {
            _addTokenToAllTokensEnumeration(tokenId);
        } else if (from != to) {
            _removeTokenFromOwnerEnumeration(from, tokenId);
        }
        if (to == address(0)) {
            _removeTokenFromAllTokensEnumeration(tokenId);
        } else if (to != from) {
            _addTokenToOwnerEnumeration(to, tokenId);
        }
    }

    /**
     * @dev Private function to add a token to this extension's ownership-tracking data structures.
     * @param to address representing the new owner of the given token ID
     * @param tokenId uint256 ID of the token to be added to the tokens list of the given address
     */
    function _addTokenToOwnerEnumeration(address to, uint256 tokenId) private {
        uint256 length = GenHallCollection.balanceOf(to);
        _ownedTokens[to][length] = tokenId;
        _ownedTokensIndex[tokenId] = length;
    }

    /**
     * @dev Private function to add a token to this extension's token tracking data structures.
     * @param tokenId uint256 ID of the token to be added to the tokens list
     */
    function _addTokenToAllTokensEnumeration(uint256 tokenId) private {
        _allTokensIndex[tokenId] = _allTokens.length;
        _allTokens.push(tokenId);
    }

    /**
     * @dev Private function to remove a token from this extension's ownership-tracking data structures. Note that
     * while the token is not assigned a new owner, the `_ownedTokensIndex` mapping is _not_ updated: this allows for
     * gas optimizations e.g. when performing a transfer operation (avoiding double writes).
     * This has O(1) time complexity, but alters the order of the _ownedTokens array.
     * @param from address representing the previous owner of the given token ID
     * @param tokenId uint256 ID of the token to be removed from the tokens list of the given address
     */
    function _removeTokenFromOwnerEnumeration(address from, uint256 tokenId)
        private
    {
        // To prevent a gap in from's tokens array, we store the last token in the index of the token to delete, and
        // then delete the last slot (swap and pop).

        uint256 lastTokenIndex = GenHallCollection.balanceOf(from) - 1;
        uint256 tokenIndex = _ownedTokensIndex[tokenId];

        // When the token to delete is the last token, the swap operation is unnecessary
        if (tokenIndex != lastTokenIndex) {
            uint256 lastTokenId = _ownedTokens[from][lastTokenIndex];

            _ownedTokens[from][tokenIndex] = lastTokenId; // Move the last token to the slot of the to-delete token
            _ownedTokensIndex[lastTokenId] = tokenIndex; // Update the moved token's index
        }

        // This also deletes the contents at the last position of the array
        delete _ownedTokensIndex[tokenId];
        delete _ownedTokens[from][lastTokenIndex];
    }

    /**
     * @dev Private function to remove a token from this extension's token tracking data structures.
     * This has O(1) time complexity, but alters the order of the _allTokens array.
     * @param tokenId uint256 ID of the token to be removed from the tokens list
     */
    function _removeTokenFromAllTokensEnumeration(uint256 tokenId) private {
        // To prevent a gap in the tokens array, we store the last token in the index of the token to delete, and
        // then delete the last slot (swap and pop).

        uint256 lastTokenIndex = _allTokens.length - 1;
        uint256 tokenIndex = _allTokensIndex[tokenId];

        // When the token to delete is the last token, the swap operation is unnecessary. However, since this occurs so
        // rarely (when the last minted token is burnt) that we still do the swap here to avoid the gas cost of adding
        // an 'if' statement (like in _removeTokenFromOwnerEnumeration)
        uint256 lastTokenId = _allTokens[lastTokenIndex];

        _allTokens[tokenIndex] = lastTokenId; // Move the last token to the slot of the to-delete token
        _allTokensIndex[lastTokenId] = tokenIndex; // Update the moved token's index

        // This also deletes the contents at the last position of the array
        delete _allTokensIndex[tokenId];
        _allTokens.pop();
    }
}

{
  "compilationTarget": {
    "GenHallCollection.sol": "GenHallCollection"
  },
  "evmVersion": "london",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": true,
    "runs": 200
  },
  "remappings": []
}