// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (utils/Address.sol)

pragma solidity ^0.8.1;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     * ====
     *
     * [IMPORTANT]
     * ====
     * You shouldn't rely on `isContract` to protect against flash loan attacks!
     *
     * Preventing calls from contracts is highly discouraged. It breaks composability, breaks support for smart wallets
     * like Gnosis Safe, and does not provide security since it can be circumvented by calling from a contract
     * constructor.
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize/address.code.length, which returns 0
        // for contracts in construction, since the code is only stored at the end
        // of the constructor execution.

        return account.code.length > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://diligence.consensys.net/posts/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.5.11/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        (bool success, ) = recipient.call{value: amount}("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionDelegateCall(target, data, "Address: low-level delegate call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and revert (either by bubbling
     * the revert reason or using the provided one) in case of unsuccessful call or if target was not a contract.
     *
     * _Available since v4.8._
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        if (success) {
            if (returndata.length == 0) {
                // only check isContract if the call was successful and the return data is empty
                // otherwise we already know that it was a contract
                require(isContract(target), "Address: call to non-contract");
            }
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and revert if it wasn't, either by bubbling the
     * revert reason or using the provided one.
     *
     * _Available since v4.3._
     */
    function verifyCallResult(
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal pure returns (bytes memory) {
        if (success) {
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    function _revert(bytes memory returndata, string memory errorMessage) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            /// @solidity memory-safe-assembly
            assembly {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert(errorMessage);
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Context.sol)

pragma solidity ^0.8.0;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.6.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `from` to `to` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(
        address from,
        address to,
        uint256 amount
    ) external returns (bool);
}

// SPDX-License-Identifier: UNLICENSED
pragma solidity ^0.8.18;

interface IStakingGenesisNFT {
    /**
     * @notice Sets timestamp by which staking ends
     * @param finalTimestamp timestamp after which staking ends
     */
    function setFinalTimestamp(uint256 finalTimestamp) external;

    /**
     * @notice Submits token for staking. Requires transfer approval for all the tokens.
     * @param tokenIdsSmall IDs of small (Gen. 2) tokens
     * @param tokenIdsLarge IDs of large (Gen. 1) tokens
     */
    function stake(uint256[] calldata tokenIdsSmall, uint256[] calldata tokenIdsLarge) external;

    /**
     * @notice Retrieves tokens from staking alongside WLTH reward
     * @param tokenIdsSmall IDs of small (Gen. 2) tokens
     * @param tokenIdsLarge IDs of large (Gen. 1) tokens
     */
    function unstake(uint256[] calldata tokenIdsSmall, uint256[] calldata tokenIdsLarge) external;

    /**
     * @notice Calculates current staking reward for small (Gen. 2) tokens
     * @param account address to calculate for
     */
    function getRewardSmall(address account) external view returns (uint256);

    /**
     * @notice Calculates current staking reward for large (Gen. 1) tokens
     * @param account address to calculate for
     */
    function getRewardLarge(address account) external view returns (uint256);

    /**
     * @notice Number of currently staked small tokens
     * @param account address to calculate for
     */
    function getStakedTokensSmall(address account) external view returns (uint256[] memory);

    /**
     * @notice Number of currently staked large tokens
     * @param account address to calculate for
     */
    function getStakedTokensLarge(address account) external view returns (uint256[] memory);
}

// SPDX-License-Identifier: UNLICENSED
pragma solidity ^0.8.18;

/**
 * @title Interface for Staking Genesis NFT Vesting
 * @notice This interface defines functions and structures for managing vesting of rewards for Staking Genesis NFTs.
 */
interface IStakingGenesisNFTVesting {
    /**
     * @notice Struct for storing rewards information.
     */
    struct Rewards {
        address account; // Address of the account receiving rewards
        uint256 series1Rewards; // Amount of Series 1 rewards allocated to the account
        uint256 series2Rewards; // Amount of Series 2 rewards allocated to the account
    }

    /**
     * @notice Event emitted when rewards are released.
     */
    event Released(address indexed beneficiary, uint256 indexed amount);

    /**
     * @notice Event emitted when rewards are set for multiple accounts.
     */
    event RewardsSet(Rewards[] rewards);

    /**
     * @notice Event emitted when a wallet is set as lost.
     */
    event LostWalletSet(address indexed wallet);

    /**
     * @notice Event emitted when a wallet is reset from lost status.
     */
    event LostWalletReseted(address indexed wallet);

    /**
     * @notice Event emitted when emergency withdrawal is performed.
     */
    event EmergencyWithdrawalPerformed(address indexed from, address indexed to);

    /**
     * @notice Event emitted when distribution start timestamp is set.
     */
    event DistributionStartTimestampSet(uint256 timestamp);

    /**
     * @notice Releases vested rewards to the caller.
     */
    function release() external;

    /**
     * @notice Sets rewards for multiple accounts.
     * @param _rewards Array of Rewards structs containing rewards information for multiple accounts.
     */
    function setRewards(Rewards[] memory _rewards) external;

    /**
     * @notice Sets the wallet address for which access is lost.
     * @param _wallet Address of the wallet to receive lost tokens.
     */
    function setLostWallet(address _wallet) external;

    /**
     * @notice Sets the distribution start timestamp.
     * @param _timestamp Timestamp when reward distribution starts.
     */
    function setDistributionStartTimestamp(uint256 _timestamp) external;

    /**
     * @notice Resets the wallet address which was set as lost.
     * @param _wallet Address of the wallet to reset.
     */
    function resetLostWallet(address _wallet) external;

    /**
     * @notice Allows for emergency withdrawal of tokens to another address.
     * @param _from Address from which tokens will be withdrawn.
     * @param _to Address to which tokens will be transferred.
     */
    function emergencyWithdraw(address _from, address _to) external;

    /**
     * @notice Returns the amount of rewards that can be released for a given account.
     * @param _account Address of the account.
     * @return Amount of rewards that can be released.
     */
    function releaseableAmount(address _account) external view returns (uint256);

    /**
     * @notice Returns the address of the WLTH token.
     * @return Address of the WLTH token contract.
     */
    function wlth() external view returns (address);

    /**
     * @notice Returns the allocation amount for rewards.
     * @return Allocation amount for rewards.
     */
    function allocation() external view returns (uint256);

    /**
     * @notice Returns the timestamp when reward distribution starts.
     * @return Timestamp when reward distribution starts.
     */
    function distributionStartTimestamp() external view returns (uint256);

    /**
     * @notice Returns the amount of released tokens.
     * @return Amount of released tokens.
     */
    function releasedAmount() external view returns (uint256);

    /**
     * @notice Returns the total amount of rewards allocated.
     * @return Total amount of rewards allocated.
     */
    function totalRewards() external view returns (uint256);

    /**
     * @notice Checks whether the specified account has claimed rewards.
     * @param _account Address of the account.
     * @return True if the account has claimed rewards, false otherwise.
     */
    function userClaimed(address _account) external view returns (bool);

    /**
     * @notice Returns the amount of Series 1 rewards allocated to the specified account.
     * @param _account Address of the account.
     * @return Amount of Series 1 rewards allocated.
     */
    function series1Rewards(address _account) external view returns (uint256);

    /**
     * @notice Returns the amount of Series 2 rewards allocated to the specified account.
     * @param _account Address of the account.
     * @return Amount of Series 2 rewards allocated.
     */
    function series2Rewards(address _account) external view returns (uint256);

    /**
     * @notice Checks if the specified wallet address was set as lost.
     * @param _wallet Address of the wallet to check.
     * @return True if the wallet address was set as lost, false otherwise.
     */
    function lostWallet(address _wallet) external view returns (bool);
}

// SPDX-License-Identifier: UNLICENSED
pragma solidity ^0.8.18;

/**
 * @title IWithdrawal
 * @notice An interface for contracts that allow withdrawal functionality.
 */
interface IWithdrawal {
    /**
     * @notice Event emitted when leftover tokens are withdrawn.
     */
    event LeftoversWithdrawn(address indexed account, uint256 indexed amount);

    /**
     * @notice Event emitted when surplus tokens are withdrawn.
     */
    event SurplusWithdrawn(address indexed account, uint256 indexed amount);

    /**
     * @notice Withdraws any leftover tokens to a specific account.
     * @param _account Address of the account to withdraw leftover tokens for.
     */
    function withdrawLeftovers(address _account) external;

    /**
     * @notice Withdraws any surplus tokens to a specific account.
     * @param _account Address of the account to withdraw surplus tokens for.
     */
    function withdrawSurplus(address _account) external;

    /**
     * @notice Returns the delay when leftover tokens can be unlocked after the vesting is ended.
     * @return Deley when leftover tokens can be unlocked after the vesting is ended.
     */
    function leftoversUnlockDelay() external view returns (uint256);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.7.0) (access/Ownable.sol)

pragma solidity ^0.8.0;

import "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _transferOwnership(_msgSender());
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions anymore. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby removing any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.0;

import "../IERC20.sol";
import "../extensions/draft-IERC20Permit.sol";
import "../../../utils/Address.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using Address for address;

    function safeTransfer(
        IERC20 token,
        address to,
        uint256 value
    ) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transfer.selector, to, value));
    }

    function safeTransferFrom(
        IERC20 token,
        address from,
        address to,
        uint256 value
    ) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transferFrom.selector, from, to, value));
    }

    /**
     * @dev Deprecated. This function has issues similar to the ones found in
     * {IERC20-approve}, and its usage is discouraged.
     *
     * Whenever possible, use {safeIncreaseAllowance} and
     * {safeDecreaseAllowance} instead.
     */
    function safeApprove(
        IERC20 token,
        address spender,
        uint256 value
    ) internal {
        // safeApprove should only be called when setting an initial allowance,
        // or when resetting it to zero. To increase and decrease it, use
        // 'safeIncreaseAllowance' and 'safeDecreaseAllowance'
        require(
            (value == 0) || (token.allowance(address(this), spender) == 0),
            "SafeERC20: approve from non-zero to non-zero allowance"
        );
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, value));
    }

    function safeIncreaseAllowance(
        IERC20 token,
        address spender,
        uint256 value
    ) internal {
        uint256 newAllowance = token.allowance(address(this), spender) + value;
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, newAllowance));
    }

    function safeDecreaseAllowance(
        IERC20 token,
        address spender,
        uint256 value
    ) internal {
        unchecked {
            uint256 oldAllowance = token.allowance(address(this), spender);
            require(oldAllowance >= value, "SafeERC20: decreased allowance below zero");
            uint256 newAllowance = oldAllowance - value;
            _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, newAllowance));
        }
    }

    function safePermit(
        IERC20Permit token,
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) internal {
        uint256 nonceBefore = token.nonces(owner);
        token.permit(owner, spender, value, deadline, v, r, s);
        uint256 nonceAfter = token.nonces(owner);
        require(nonceAfter == nonceBefore + 1, "SafeERC20: permit did not succeed");
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We use {Address-functionCall} to perform this call, which verifies that
        // the target address contains contract code and also asserts for success in the low-level call.

        bytes memory returndata = address(token).functionCall(data, "SafeERC20: low-level call failed");
        if (returndata.length > 0) {
            // Return data is optional
            require(abi.decode(returndata, (bool)), "SafeERC20: ERC20 operation did not succeed");
        }
    }
}

// SPDX-License-Identifier: UNLICENSED
pragma solidity ^0.8.18;

import {Ownable} from "@openzeppelin/contracts/access/Ownable.sol";
import {IStakingGenesisNFT} from "../interfaces/IStakingGenesisNFT.sol";
import {IERC20} from "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import {SafeERC20} from "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
import {IStakingGenesisNFTVesting} from "../interfaces/IStakingGenesisNFTVesting.sol";
import {IWithdrawal} from "../interfaces/IWithdrawal.sol";

error StakingGenesisNFTVesting__OwnerZeroAddress();
error StakingGenesisNFTVesting__WlthZeroAddress();
error StakingGenesisNFTVesting__AddressFromZeroAddress();
error StakingGenesisNFTVesting__AddressToZeroAddress();
error StakingGenesisNFTVesting__DistributionNotStarted();
error StakingGenesisNFTVesting__NotEnoughTokens();
error StakingGenesisNFTVesting__PastDistributionStartTimestamp();
error StakingGenesisNFTVesting__NoRewardsForUser(address account);
error StakingGenesisNFTVesting__RewardsTooHigh(uint256 allocation, uint256 totalRewards);
error StakingGenesisNFTVesting__DistributionStartTimestampAlreadySet();
error StakingGenesisNFTVesting__LeftoversWithdrawalLocked();
error StakingGenesisNFTVesting__WalletLost(address wallet);
error StakingGenesisNFTVesting__WalletAlreadyLost(address wallet);
error StakingGenesisNFTVesting__WalletNotLost(address wallet);
error StakingGenesisNFTVesting__NoSurplus(uint256 balance, uint256 released, uint256 allocation);

/**
 * @title StakingGenesisNFTVesting
 * @notice This contract manages the vesting of rewards for Staking Genesis NFTs.
 */
contract StakingGenesisNFTVesting is IStakingGenesisNFTVesting, IWithdrawal, Ownable {
    using SafeERC20 for IERC20;

    /**
     * @notice Instance of the WLTH token contract.
     */
    IERC20 private immutable i_wlth;

    /**
     * @notice Allocation amount for rewards.
     */
    uint256 private immutable i_allocation;

    /**
     * @notice Delay when leftover tokens can be withdrawn after the vesting is ended.
     */
    uint256 private immutable i_leftoversUnlockDelay;

    /**
     * @notice Timestamp when reward distribution starts.
     */
    uint256 private s_distributionStartTimestamp;

    /**
     * @notice Total amount of rewards released.
     */
    uint256 private s_releasedAmount;

    /**
     * @notice Total amount of rewards allocated.
     */
    uint256 private s_totalRewards;

    /**
     * @notice Mapping to track whether user claimed rewards.
     */
    mapping(address => bool) private s_userClaimed;

    /**
     * @notice Mapping to store Series 1 rewards allocated to users.
     */
    mapping(address => uint256) private s_series1Rewards;

    /**
     * @notice Mapping to store Series 2 rewards allocated to users.
     */
    mapping(address => uint256) private s_series2Rewards;

    /**
     * @notice Mapping to store whether wallet access is lost.
     */
    mapping(address => bool) private s_walletAccessLost;

    /**
     * @notice Modifier to check if the reward distribution has started.
     */
    modifier distributionStarted() {
        if (s_distributionStartTimestamp == 0 || block.timestamp < s_distributionStartTimestamp)
            revert StakingGenesisNFTVesting__DistributionNotStarted();
        _;
    }

    /**
     * @notice Contract constructor.
     * @param _owner Address of the owner of the contract.
     * @param _wlth Address of the WLTH token contract.
     * @param _allocation Allocation amount for rewards.
     * @param _distributionStartTimestamp Timestamp when reward distribution starts.
     * @param _leftoversUnlockDelay Delay when leftover tokens can be withdrawn after the distribution is started.
     */
    constructor(
        address _owner,
        address _wlth,
        uint256 _allocation,
        uint256 _distributionStartTimestamp,
        uint256 _leftoversUnlockDelay
    ) {
        if (_owner == address(0)) revert StakingGenesisNFTVesting__OwnerZeroAddress();
        if (_wlth == address(0)) revert StakingGenesisNFTVesting__WlthZeroAddress();
        if (_distributionStartTimestamp > 0 && _distributionStartTimestamp < block.timestamp)
            revert StakingGenesisNFTVesting__PastDistributionStartTimestamp();

        i_wlth = IERC20(_wlth);
        i_allocation = _allocation;
        i_leftoversUnlockDelay = _leftoversUnlockDelay;
        s_distributionStartTimestamp = _distributionStartTimestamp;
        _transferOwnership(_owner);
    }

    /**
     * @inheritdoc IStakingGenesisNFTVesting
     */
    function release() external override {
        if (s_walletAccessLost[msg.sender]) revert StakingGenesisNFTVesting__WalletLost(msg.sender);
        _release(msg.sender, msg.sender);
    }

    /**
     * @inheritdoc IStakingGenesisNFTVesting
     */
    function setRewards(Rewards[] calldata _rewards) external override onlyOwner {
        uint256 rewards = s_totalRewards;
        for (uint256 i; i < _rewards.length; ) {
            rewards += _rewards[i].series1Rewards + _rewards[i].series2Rewards;

            if (rewards > i_allocation) revert StakingGenesisNFTVesting__RewardsTooHigh(i_allocation, rewards);

            s_series1Rewards[_rewards[i].account] = _rewards[i].series1Rewards;
            s_series2Rewards[_rewards[i].account] = _rewards[i].series2Rewards;

            unchecked {
                i++;
            }
        }

        s_totalRewards = rewards;

        emit RewardsSet(_rewards);
    }

    /**
     * @inheritdoc IStakingGenesisNFTVesting
     */
    function setLostWallet(address _wallet) external override onlyOwner {
        if (s_walletAccessLost[_wallet]) revert StakingGenesisNFTVesting__WalletAlreadyLost(_wallet);
        s_walletAccessLost[_wallet] = true;

        emit LostWalletSet(_wallet);
    }

    /**
     * @inheritdoc IStakingGenesisNFTVesting
     */
    function resetLostWallet(address _wallet) external override onlyOwner {
        if (!s_walletAccessLost[_wallet]) revert StakingGenesisNFTVesting__WalletNotLost(_wallet);
        s_walletAccessLost[_wallet] = false;

        emit LostWalletReseted(_wallet);
    }

    /**
     * @inheritdoc IStakingGenesisNFTVesting
     */
    function setDistributionStartTimestamp(uint256 _timestamp) external override onlyOwner {
        if (s_distributionStartTimestamp != 0) revert StakingGenesisNFTVesting__DistributionStartTimestampAlreadySet();
        if (_timestamp < block.timestamp) revert StakingGenesisNFTVesting__PastDistributionStartTimestamp();
        s_distributionStartTimestamp = _timestamp;

        emit DistributionStartTimestampSet(_timestamp);
    }

    /**
     * @inheritdoc IStakingGenesisNFTVesting
     */
    function emergencyWithdraw(address _from, address _to) external override onlyOwner {
        if (!s_walletAccessLost[_from]) revert StakingGenesisNFTVesting__WalletNotLost(_from);

        emit EmergencyWithdrawalPerformed(_from, _to);

        _release(_from, _to);
    }

    /**
     * @inheritdoc IWithdrawal
     */
    function withdrawLeftovers(address _account) external override onlyOwner distributionStarted {
        if (block.timestamp < s_distributionStartTimestamp + i_leftoversUnlockDelay)
            revert StakingGenesisNFTVesting__LeftoversWithdrawalLocked();
        emit LeftoversWithdrawn(_account, i_wlth.balanceOf(address(this)));

        i_wlth.safeTransfer(_account, i_wlth.balanceOf(address(this)));
    }

    /**
     * @inheritdoc IWithdrawal
     */
    function withdrawSurplus(address _wallet) external override onlyOwner {
        uint256 balance = i_wlth.balanceOf(address(this));
        uint256 alreadyReleased = s_releasedAmount;

        if (balance + alreadyReleased <= i_allocation)
            revert StakingGenesisNFTVesting__NoSurplus(balance, alreadyReleased, i_allocation);

        uint256 surplus = balance + alreadyReleased - i_allocation;

        emit SurplusWithdrawn(_wallet, surplus);

        i_wlth.safeTransfer(_wallet, surplus);
    }

    /**
     * @inheritdoc IStakingGenesisNFTVesting
     */
    function wlth() external view override returns (address) {
        return address(i_wlth);
    }

    /**
     * @inheritdoc IStakingGenesisNFTVesting
     */
    function allocation() external view override returns (uint256) {
        return i_allocation;
    }

    /**
     * @inheritdoc IStakingGenesisNFTVesting
     */
    function distributionStartTimestamp() external view override returns (uint256) {
        return s_distributionStartTimestamp;
    }

    /**
     * @inheritdoc IStakingGenesisNFTVesting
     */
    function releasedAmount() external view override returns (uint256) {
        return s_releasedAmount;
    }

    /**
     * @inheritdoc IStakingGenesisNFTVesting
     */
    function totalRewards() external view override returns (uint256) {
        return s_totalRewards;
    }

    /**
     * @inheritdoc IStakingGenesisNFTVesting
     */
    function userClaimed(address _account) external view override returns (bool) {
        return s_userClaimed[_account];
    }

    /**
     * @inheritdoc IStakingGenesisNFTVesting
     */
    function series1Rewards(address _account) external view override returns (uint256) {
        return s_series1Rewards[_account];
    }

    /**
     * @inheritdoc IStakingGenesisNFTVesting
     */
    function series2Rewards(address _account) external view override returns (uint256) {
        return s_series2Rewards[_account];
    }

    /**
     * @inheritdoc IStakingGenesisNFTVesting
     */
    function releaseableAmount(address _account) public view override returns (uint256) {
        return s_userClaimed[_account] ? 0 : s_series1Rewards[_account] + s_series2Rewards[_account];
    }

    /**
     * @inheritdoc IWithdrawal
     */
    function leftoversUnlockDelay() external view override returns (uint256) {
        return i_leftoversUnlockDelay;
    }

    /**
     * @inheritdoc IStakingGenesisNFTVesting
     */
    function lostWallet(address _wallet) external view override returns (bool) {
        return s_walletAccessLost[_wallet];
    }

    function _release(address _from, address _to) private distributionStarted {
        if (_from == address(0)) revert StakingGenesisNFTVesting__AddressFromZeroAddress();
        if (_to == address(0)) revert StakingGenesisNFTVesting__AddressToZeroAddress();
        uint256 amount = releaseableAmount(_from);

        if (amount == 0) revert StakingGenesisNFTVesting__NoRewardsForUser(_from);
        if (amount > i_wlth.balanceOf(address(this))) revert StakingGenesisNFTVesting__NotEnoughTokens();

        s_releasedAmount += amount;
        s_userClaimed[_from] = true;

        emit Released(_to, amount);

        i_wlth.safeTransfer(_to, amount);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (token/ERC20/extensions/draft-IERC20Permit.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 Permit extension allowing approvals to be made via signatures, as defined in
 * https://eips.ethereum.org/EIPS/eip-2612[EIP-2612].
 *
 * Adds the {permit} method, which can be used to change an account's ERC20 allowance (see {IERC20-allowance}) by
 * presenting a message signed by the account. By not relying on {IERC20-approve}, the token holder account doesn't
 * need to send a transaction, and thus is not required to hold Ether at all.
 */
interface IERC20Permit {
    /**
     * @dev Sets `value` as the allowance of `spender` over ``owner``'s tokens,
     * given ``owner``'s signed approval.
     *
     * IMPORTANT: The same issues {IERC20-approve} has related to transaction
     * ordering also apply here.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `deadline` must be a timestamp in the future.
     * - `v`, `r` and `s` must be a valid `secp256k1` signature from `owner`
     * over the EIP712-formatted function arguments.
     * - the signature must use ``owner``'s current nonce (see {nonces}).
     *
     * For more information on the signature format, see the
     * https://eips.ethereum.org/EIPS/eip-2612#specification[relevant EIP
     * section].
     */
    function permit(
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external;

    /**
     * @dev Returns the current nonce for `owner`. This value must be
     * included whenever a signature is generated for {permit}.
     *
     * Every successful call to {permit} increases ``owner``'s nonce by one. This
     * prevents a signature from being used multiple times.
     */
    function nonces(address owner) external view returns (uint256);

    /**
     * @dev Returns the domain separator used in the encoding of the signature for {permit}, as defined by {EIP712}.
     */
    // solhint-disable-next-line func-name-mixedcase
    function DOMAIN_SEPARATOR() external view returns (bytes32);
}

{
  "compilationTarget": {
    "contracts/tge/StakingGenesisNFTVesting.sol": "StakingGenesisNFTVesting"
  },
  "evmVersion": "paris",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs",
    "useLiteralContent": true
  },
  "optimizer": {
    "enabled": true,
    "runs": 200
  },
  "remappings": []
}