// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/ERC20.sol)

pragma solidity ^0.8.20;

import {IERC20} from "./IERC20.sol";
import {IERC20Metadata} from "./extensions/IERC20Metadata.sol";
import {Context} from "../../utils/Context.sol";
import {IERC20Errors} from "../../interfaces/draft-IERC6093.sol";

/**
 * @dev Implementation of the {IERC20} interface.
 *
 * This implementation is agnostic to the way tokens are created. This means
 * that a supply mechanism has to be added in a derived contract using {_mint}.
 *
 * TIP: For a detailed writeup see our guide
 * https://forum.openzeppelin.com/t/how-to-implement-erc20-supply-mechanisms/226[How
 * to implement supply mechanisms].
 *
 * The default value of {decimals} is 18. To change this, you should override
 * this function so it returns a different value.
 *
 * We have followed general OpenZeppelin Contracts guidelines: functions revert
 * instead returning `false` on failure. This behavior is nonetheless
 * conventional and does not conflict with the expectations of ERC20
 * applications.
 *
 * Additionally, an {Approval} event is emitted on calls to {transferFrom}.
 * This allows applications to reconstruct the allowance for all accounts just
 * by listening to said events. Other implementations of the EIP may not emit
 * these events, as it isn't required by the specification.
 */
abstract contract ERC20 is Context, IERC20, IERC20Metadata, IERC20Errors {
    mapping(address account => uint256) private _balances;

    mapping(address account => mapping(address spender => uint256)) private _allowances;

    uint256 private _totalSupply;

    string private _name;
    string private _symbol;

    /**
     * @dev Sets the values for {name} and {symbol}.
     *
     * All two of these values are immutable: they can only be set once during
     * construction.
     */
    constructor(string memory name_, string memory symbol_) {
        _name = name_;
        _symbol = symbol_;
    }

    /**
     * @dev Returns the name of the token.
     */
    function name() public view virtual returns (string memory) {
        return _name;
    }

    /**
     * @dev Returns the symbol of the token, usually a shorter version of the
     * name.
     */
    function symbol() public view virtual returns (string memory) {
        return _symbol;
    }

    /**
     * @dev Returns the number of decimals used to get its user representation.
     * For example, if `decimals` equals `2`, a balance of `505` tokens should
     * be displayed to a user as `5.05` (`505 / 10 ** 2`).
     *
     * Tokens usually opt for a value of 18, imitating the relationship between
     * Ether and Wei. This is the default value returned by this function, unless
     * it's overridden.
     *
     * NOTE: This information is only used for _display_ purposes: it in
     * no way affects any of the arithmetic of the contract, including
     * {IERC20-balanceOf} and {IERC20-transfer}.
     */
    function decimals() public view virtual returns (uint8) {
        return 18;
    }

    /**
     * @dev See {IERC20-totalSupply}.
     */
    function totalSupply() public view virtual returns (uint256) {
        return _totalSupply;
    }

    /**
     * @dev See {IERC20-balanceOf}.
     */
    function balanceOf(address account) public view virtual returns (uint256) {
        return _balances[account];
    }

    /**
     * @dev See {IERC20-transfer}.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     * - the caller must have a balance of at least `value`.
     */
    function transfer(address to, uint256 value) public virtual returns (bool) {
        address owner = _msgSender();
        _transfer(owner, to, value);
        return true;
    }

    /**
     * @dev See {IERC20-allowance}.
     */
    function allowance(address owner, address spender) public view virtual returns (uint256) {
        return _allowances[owner][spender];
    }

    /**
     * @dev See {IERC20-approve}.
     *
     * NOTE: If `value` is the maximum `uint256`, the allowance is not updated on
     * `transferFrom`. This is semantically equivalent to an infinite approval.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function approve(address spender, uint256 value) public virtual returns (bool) {
        address owner = _msgSender();
        _approve(owner, spender, value);
        return true;
    }

    /**
     * @dev See {IERC20-transferFrom}.
     *
     * Emits an {Approval} event indicating the updated allowance. This is not
     * required by the EIP. See the note at the beginning of {ERC20}.
     *
     * NOTE: Does not update the allowance if the current allowance
     * is the maximum `uint256`.
     *
     * Requirements:
     *
     * - `from` and `to` cannot be the zero address.
     * - `from` must have a balance of at least `value`.
     * - the caller must have allowance for ``from``'s tokens of at least
     * `value`.
     */
    function transferFrom(address from, address to, uint256 value) public virtual returns (bool) {
        address spender = _msgSender();
        _spendAllowance(from, spender, value);
        _transfer(from, to, value);
        return true;
    }

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to`.
     *
     * This internal function is equivalent to {transfer}, and can be used to
     * e.g. implement automatic token fees, slashing mechanisms, etc.
     *
     * Emits a {Transfer} event.
     *
     * NOTE: This function is not virtual, {_update} should be overridden instead.
     */
    function _transfer(address from, address to, uint256 value) internal {
        if (from == address(0)) {
            revert ERC20InvalidSender(address(0));
        }
        if (to == address(0)) {
            revert ERC20InvalidReceiver(address(0));
        }
        _update(from, to, value);
    }

    /**
     * @dev Transfers a `value` amount of tokens from `from` to `to`, or alternatively mints (or burns) if `from`
     * (or `to`) is the zero address. All customizations to transfers, mints, and burns should be done by overriding
     * this function.
     *
     * Emits a {Transfer} event.
     */
    function _update(address from, address to, uint256 value) internal virtual {
        if (from == address(0)) {
            // Overflow check required: The rest of the code assumes that totalSupply never overflows
            _totalSupply += value;
        } else {
            uint256 fromBalance = _balances[from];
            if (fromBalance < value) {
                revert ERC20InsufficientBalance(from, fromBalance, value);
            }
            unchecked {
                // Overflow not possible: value <= fromBalance <= totalSupply.
                _balances[from] = fromBalance - value;
            }
        }

        if (to == address(0)) {
            unchecked {
                // Overflow not possible: value <= totalSupply or value <= fromBalance <= totalSupply.
                _totalSupply -= value;
            }
        } else {
            unchecked {
                // Overflow not possible: balance + value is at most totalSupply, which we know fits into a uint256.
                _balances[to] += value;
            }
        }

        emit Transfer(from, to, value);
    }

    /**
     * @dev Creates a `value` amount of tokens and assigns them to `account`, by transferring it from address(0).
     * Relies on the `_update` mechanism
     *
     * Emits a {Transfer} event with `from` set to the zero address.
     *
     * NOTE: This function is not virtual, {_update} should be overridden instead.
     */
    function _mint(address account, uint256 value) internal {
        if (account == address(0)) {
            revert ERC20InvalidReceiver(address(0));
        }
        _update(address(0), account, value);
    }

    /**
     * @dev Destroys a `value` amount of tokens from `account`, lowering the total supply.
     * Relies on the `_update` mechanism.
     *
     * Emits a {Transfer} event with `to` set to the zero address.
     *
     * NOTE: This function is not virtual, {_update} should be overridden instead
     */
    function _burn(address account, uint256 value) internal {
        if (account == address(0)) {
            revert ERC20InvalidSender(address(0));
        }
        _update(account, address(0), value);
    }

    /**
     * @dev Sets `value` as the allowance of `spender` over the `owner` s tokens.
     *
     * This internal function is equivalent to `approve`, and can be used to
     * e.g. set automatic allowances for certain subsystems, etc.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `owner` cannot be the zero address.
     * - `spender` cannot be the zero address.
     *
     * Overrides to this logic should be done to the variant with an additional `bool emitEvent` argument.
     */
    function _approve(address owner, address spender, uint256 value) internal {
        _approve(owner, spender, value, true);
    }

    /**
     * @dev Variant of {_approve} with an optional flag to enable or disable the {Approval} event.
     *
     * By default (when calling {_approve}) the flag is set to true. On the other hand, approval changes made by
     * `_spendAllowance` during the `transferFrom` operation set the flag to false. This saves gas by not emitting any
     * `Approval` event during `transferFrom` operations.
     *
     * Anyone who wishes to continue emitting `Approval` events on the`transferFrom` operation can force the flag to
     * true using the following override:
     * ```
     * function _approve(address owner, address spender, uint256 value, bool) internal virtual override {
     *     super._approve(owner, spender, value, true);
     * }
     * ```
     *
     * Requirements are the same as {_approve}.
     */
    function _approve(address owner, address spender, uint256 value, bool emitEvent) internal virtual {
        if (owner == address(0)) {
            revert ERC20InvalidApprover(address(0));
        }
        if (spender == address(0)) {
            revert ERC20InvalidSpender(address(0));
        }
        _allowances[owner][spender] = value;
        if (emitEvent) {
            emit Approval(owner, spender, value);
        }
    }

    /**
     * @dev Updates `owner` s allowance for `spender` based on spent `value`.
     *
     * Does not update the allowance value in case of infinite allowance.
     * Revert if not enough allowance is available.
     *
     * Does not emit an {Approval} event.
     */
    function _spendAllowance(address owner, address spender, uint256 value) internal virtual {
        uint256 currentAllowance = allowance(owner, spender);
        if (currentAllowance != type(uint256).max) {
            if (currentAllowance < value) {
                revert ERC20InsufficientAllowance(spender, currentAllowance, value);
            }
            unchecked {
                _approve(owner, spender, currentAllowance - value, false);
            }
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/extensions/IERC20Metadata.sol)

pragma solidity ^0.8.20;

import {IERC20} from "../IERC20.sol";

/**
 * @dev Interface for the optional metadata functions from the ERC20 standard.
 */
interface IERC20Metadata is IERC20 {
    /**
     * @dev Returns the name of the token.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the symbol of the token.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the decimals places of the token.
     */
    function decimals() external view returns (uint8);
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.20;

interface IUniswapV2Factory {
    event PairCreated(
        address indexed token0,
        address indexed token1,
        address pair,
        uint256
    );

    function feeTo() external view returns (address);

    function feeToSetter() external view returns (address);

    function getPair(
        address tokenA,
        address tokenB
    ) external view returns (address pair);

    function allPairs(uint256) external view returns (address pair);

    function allPairsLength() external view returns (uint256);

    function createPair(
        address tokenA,
        address tokenB
    ) external returns (address pair);

    function setFeeTo(address) external;

    function setFeeToSetter(address) external;
}

////// src/IUniswapV2Pair.sol
/* pragma solidity 0.8.10; */
/* pragma experimental ABIEncoderV2; */

interface IUniswapV2Pair {
    event Approval(
        address indexed owner,
        address indexed spender,
        uint256 value
    );
    event Transfer(address indexed from, address indexed to, uint256 value);

    function name() external pure returns (string memory);

    function symbol() external pure returns (string memory);

    function decimals() external pure returns (uint8);

    function totalSupply() external view returns (uint256);

    function balanceOf(address owner) external view returns (uint256);

    function allowance(
        address owner,
        address spender
    ) external view returns (uint256);

    function approve(address spender, uint256 value) external returns (bool);

    function transfer(address to, uint256 value) external returns (bool);

    function transferFrom(
        address from,
        address to,
        uint256 value
    ) external returns (bool);

    function DOMAIN_SEPARATOR() external view returns (bytes32);

    function PERMIT_TYPEHASH() external pure returns (bytes32);

    function nonces(address owner) external view returns (uint256);

    function permit(
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external;

    event Mint(address indexed sender, uint256 amount0, uint256 amount1);
    event Burn(
        address indexed sender,
        uint256 amount0,
        uint256 amount1,
        address indexed to
    );
    event Swap(
        address indexed sender,
        uint256 amount0In,
        uint256 amount1In,
        uint256 amount0Out,
        uint256 amount1Out,
        address indexed to
    );
    event Sync(uint112 reserve0, uint112 reserve1);

    function MINIMUM_LIQUIDITY() external pure returns (uint256);

    function factory() external view returns (address);

    function token0() external view returns (address);

    function token1() external view returns (address);

    function getReserves()
        external
        view
        returns (uint112 reserve0, uint112 reserve1, uint32 blockTimestampLast);

    function price0CumulativeLast() external view returns (uint256);

    function price1CumulativeLast() external view returns (uint256);

    function kLast() external view returns (uint256);

    function mint(address to) external returns (uint256 liquidity);

    function burn(
        address to
    ) external returns (uint256 amount0, uint256 amount1);

    function swap(
        uint256 amount0Out,
        uint256 amount1Out,
        address to,
        bytes calldata data
    ) external;

    function skim(address to) external;

    function sync() external;

    function initialize(address, address) external;
}

interface IUniswapV2Router02 {
    function factory() external pure returns (address);

    function WETH() external pure returns (address);

    function addLiquidity(
        address tokenA,
        address tokenB,
        uint256 amountADesired,
        uint256 amountBDesired,
        uint256 amountAMin,
        uint256 amountBMin,
        address to,
        uint256 deadline
    ) external returns (uint256 amountA, uint256 amountB, uint256 liquidity);

    function addLiquidityETH(
        address token,
        uint256 amountTokenDesired,
        uint256 amountTokenMin,
        uint256 amountETHMin,
        address to,
        uint256 deadline
    )
        external
        payable
        returns (uint256 amountToken, uint256 amountETH, uint256 liquidity);

    function swapExactETHForTokens(
        uint256 amountOutMin,
        address[] calldata path,
        address to,
        uint256 deadline
    ) external payable returns (uint256[] memory amounts);

    function swapExactTokensForETH(
        uint256 amountIn,
        uint256 amountOutMin,
        address[] calldata path,
        address to,
        uint256 deadline
    ) external returns (uint256[] memory amounts);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable.sol)

pragma solidity ^0.8.20;

import {Context} from "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is set to the address provided by the deployer. This can
 * later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    /**
     * @dev The caller account is not authorized to perform an operation.
     */
    error OwnableUnauthorizedAccount(address account);

    /**
     * @dev The owner is not a valid owner account. (eg. `address(0)`)
     */
    error OwnableInvalidOwner(address owner);

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the address provided by the deployer as the initial owner.
     */
    constructor(address initialOwner) {
        if (initialOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(initialOwner);
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        if (owner() != _msgSender()) {
            revert OwnableUnauthorizedAccount(_msgSender());
        }
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        if (newOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.20;

import {ERC20} from "@openzeppelin/contracts/token/ERC20/ERC20.sol";
import {IERC20} from "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import {Ownable} from "@openzeppelin/contracts/access/Ownable.sol";
import "@openzeppelin/contracts/utils/ReentrancyGuard.sol";
import "./Interfaces.sol";

contract PVP is ERC20, Ownable, ReentrancyGuard {
    error LiquidityAlreadyLoaded();
    error InsufficientTokenBalanceForLiquidity();
    error MustSendETHToAddLiquidity();
    error CannotPlaceRaidOnSelf();
    error ThisWalletIsExcludedFromRaids();
    error ThisWalletIsOnCooldown();
    error TheWalletMustBeATokenHolder();
    error TooManyTokensPurchased();
    error RaidCannotBeClaimedYet();
    error ThereIsNoRaidOnThisWallet();
    error NoTrappedETHToClaim();
    error FailedToSendTrappedETH();
    error TransferNotAllowedSendingWalletIsUnderRaid();
    error TransferNotAllowedReceivingWalletIsUnderRaid();
    error InsufficientETHSent();
    error RaidMustBeGreaterThanMinimumRaidAmount();
    error RaidHasAlreadyBeenSuccessful();
    error YouMustMatchTheRaidBid();
    error CannotOutbidYourOwnRaid();
    error ThereIsNoRaidOnYourWallet();
    error RaidMustBeGreaterThanWalletMinimumRaidAmount();
    error NewRaidMustBeGreaterThanCurrentRaidByAtLeast10Percent();

    uint public liquidityLoadedBlock;
    uint256 public constant MAX_SUPPLY = 1_000_000_000 * 10 ** 18; // 1 billion tokens
    uint256 constant MAX_BUY = 10_000_000 * 10 ** 18; // Each wallet can buy up to 1%

    IUniswapV2Router02 public immutable uniswapV2Router;
    address public immutable uniswapV2Pair;

    struct Raid {
        address creator_address;
        uint256 raid_price;
        uint256 eth_locked;
        uint256 block_expiry;
    }

    mapping(address => Raid) public currentRaidByAddress;
    mapping(address => Raid[]) public lostRaidsByPotAddress;
    mapping(address => bool) public walletsExcludedFromRaids;

    // These 2 are up for tweaking
    mapping(address => uint256) public blockCooldownByAddress;
    mapping(address => uint256) public minimumRaidAmountByWallet;

    mapping(address => uint256) public ethClaimableByWallet;
    address constant burnAddress = address(0);

    uint256 public minimumRaidAmount;
    uint256 raidBlockReset;
    uint256 raidCooldown;

    uint256 ethEarnedByContract;
    uint256 ethForBuyback;
    uint256 buybackMinimum;

    // Events
    event TokensTransferred(
        address indexed from,
        address indexed to,
        uint256 amount
    );
    event PairCreated(address indexed pair);
    event InitialLiquidityLoaded(uint256 ethAmount, uint256 tokenAmount);
    event TokensBoughtAndBurned(uint256 ethAmount, uint256 tokenAmount);
    event WalletExclusionUpdated(
        address indexed walletAddress,
        bool exclusionStatus
    );

    event NewRaidCreated(
        address indexed walletUnderRaid,
        address indexed raidCreator,
        uint256 bidPrice,
        uint256 ethLocked,
        uint256 tokensLocked,
        uint256 blockExpiry
    );
    event RaidPaid(
        address indexed walletUnderRaid,
        uint256 ethAmount,
        uint256 tokensUnlocked,
        uint256 blockCooldown,
        uint256 minimumRaid
    );
    event RaidSettled(
        address indexed walletUnderRaid,
        address indexed raidCreator,
        uint256 ethSentToRaidWallet,
        uint256 tokensClaimed,
        uint256 ethClaimed
    );

    // Event for ETH transfers
    event EthClaimAdded(address indexed claimer, uint256 amount);
    event EthClaimed(address indexed claimer, uint256 amount);

    // New events
    event RaidBidPayout(address indexed walletAddress, uint256 ethAmount);
    event RaidBidPayoutFailed(address indexed walletAddress, uint256 ethAmount);
    event FailedBidsPayout(address indexed walletAddress, uint256 ethAmount);

    uint256 public _feeBps = 100;
    uint256 public _burnBps = 100;

    constructor() ERC20("PVP", "PVP") Ownable(msg.sender) {
        IUniswapV2Router02 _uniswapV2Router = IUniswapV2Router02(
            0x4752ba5DBc23f44D87826276BF6Fd6b1C372aD24
        ); // Base Uni V2

        uniswapV2Router = _uniswapV2Router;

        uniswapV2Pair = IUniswapV2Factory(_uniswapV2Router.factory())
            .createPair(address(this), _uniswapV2Router.WETH());

        emit PairCreated(uniswapV2Pair);

        walletsExcludedFromRaids[address(this)] = true;
        walletsExcludedFromRaids[msg.sender] = true;
        walletsExcludedFromRaids[address(uniswapV2Pair)] = true;
        walletsExcludedFromRaids[burnAddress] = true;

        emit WalletExclusionUpdated(address(this), true);
        emit WalletExclusionUpdated(msg.sender, true);
        emit WalletExclusionUpdated(burnAddress, true);
        emit WalletExclusionUpdated(address(uniswapV2Pair), true);

        minimumRaidAmount = 0.001 ether;
        raidBlockReset = 25; // Reset to 25 blocks (5 minutes)
        raidCooldown = 300; // 300 blocks until the wallet can be bid on again.
        buybackMinimum = 0.01 ether; // Every time there's 0.01e in ethForBuyback, buy and add to LP.

        _mint(address(this), MAX_SUPPLY);
    }

    function loadLiquidity() external payable onlyOwner {
        if (liquidityLoadedBlock != 0) revert LiquidityAlreadyLoaded();
        uint256 tokenAmount = balanceOf(address(this));
        if (tokenAmount == 0) revert InsufficientTokenBalanceForLiquidity();
        if (msg.value == 0) revert MustSendETHToAddLiquidity();

        // Approve the router to spend tokens
        _approve(address(this), address(uniswapV2Router), tokenAmount);

        // Add liquidity and send LP tokens to owner
        uniswapV2Router.addLiquidityETH{value: msg.value}(
            address(this),
            tokenAmount,
            0, // slippage is unavoidable
            0, // slippage is unavoidable
            owner(),
            block.timestamp
        );

        liquidityLoadedBlock = block.number;
        emit InitialLiquidityLoaded(msg.value, tokenAmount);
    }

    function toggleExclusionForWallet(
        address walletAddress,
        bool excluded
    ) external onlyOwner {
        walletsExcludedFromRaids[walletAddress] = excluded;
        emit WalletExclusionUpdated(walletAddress, excluded);
    }

    // Function to calculate the raid length based on the blocks passed
    function getRaidLength() public view returns (uint256) {
        // Calculate how many blocks have passed
        uint256 blocksPassed = block.number - liquidityLoadedBlock;

        // Round up to the nearest multiple of 1800 and cap at 43200 (1 day)
        uint256 roundedBlocks = ((blocksPassed + 1799) / 1800) * 1800; // round up to nearest hour

        // Ensure it doesn't exceed 43200
        if (roundedBlocks > 43200) {
            roundedBlocks = 43200;
        }

        return roundedBlocks;
    }

    function createRaid(address walletAddress) external payable nonReentrant {
        if (msg.value < minimumRaidAmount)
            revert RaidMustBeGreaterThanMinimumRaidAmount();
        if (msg.value < minimumRaidAmountByWallet[walletAddress])
            revert RaidMustBeGreaterThanWalletMinimumRaidAmount();
        if (walletAddress == msg.sender) revert CannotPlaceRaidOnSelf();
        if (walletsExcludedFromRaids[walletAddress])
            revert ThisWalletIsExcludedFromRaids();
        if (blockCooldownByAddress[walletAddress] >= block.number)
            revert ThisWalletIsOnCooldown();
        if (balanceOf(walletAddress) == 0) revert TheWalletMustBeATokenHolder();

        uint256 amount_for_burn = (msg.value * _burnBps) / 10000;
        uint256 amount_for_contract = (msg.value * _feeBps) / 10000;
        uint256 amount_locked = msg.value -
            amount_for_burn -
            amount_for_contract;

        if (currentRaidByAddress[walletAddress].creator_address == address(0)) {
            // Distribute Eth
            ethEarnedByContract += amount_for_contract;
            ethForBuyback += amount_for_burn;

            if (ethForBuyback >= buybackMinimum) {
                _buyAndBurn(ethForBuyback);
                ethForBuyback = 0;
            }

            // Get the dynamic raid length
            uint256 raidLength = getRaidLength();

            // Use the dynamic raid length instead of the fixed raidBlockLength
            uint256 blockExpiry = block.number + raidLength;

            // Create new raid.
            Raid memory newRaid = Raid({
                creator_address: msg.sender,
                raid_price: msg.value,
                eth_locked: amount_locked,
                block_expiry: blockExpiry
            });

            currentRaidByAddress[walletAddress] = newRaid;
            emit NewRaidCreated(
                walletAddress,
                msg.sender,
                msg.value,
                amount_locked,
                balanceOf(walletAddress),
                blockExpiry
            );
        } else {
            Raid storage currentRaid = currentRaidByAddress[walletAddress];
            if (block.number > currentRaid.block_expiry)
                revert RaidHasAlreadyBeenSuccessful();
            if (
                msg.value <
                currentRaid.raid_price + (currentRaid.raid_price / 10)
            ) revert NewRaidMustBeGreaterThanCurrentRaidByAtLeast10Percent();
            if (currentRaid.creator_address == msg.sender)
                revert CannotOutbidYourOwnRaid();

            // Could get into an underflow situation here. Is there a test for this? roll block forward by 25 hours to see what happens...
            uint256 block_expiry = (currentRaid.block_expiry - block.number) <
                raidBlockReset
                ? (block.number + raidBlockReset)
                : currentRaid.block_expiry; // Reset timer to raidBlockReset blocks if below raidBlockReset

            // Distribute Eth
            ethEarnedByContract += amount_for_contract;
            ethForBuyback += amount_for_burn;

            if (ethForBuyback >= buybackMinimum) {
                _buyAndBurn(ethForBuyback);
                ethForBuyback = 0;
            }

            // Append to lostRaids
            lostRaidsByPotAddress[walletAddress].push(currentRaid);

            // Create new raid
            Raid memory newRaid = Raid({
                creator_address: msg.sender,
                raid_price: msg.value,
                eth_locked: amount_locked,
                block_expiry: block_expiry
            });

            currentRaidByAddress[walletAddress] = newRaid;

            emit NewRaidCreated(
                walletAddress,
                msg.sender,
                msg.value,
                amount_locked,
                balanceOf(walletAddress),
                block_expiry
            );
        }
    }

    // Function called by the holder to pay the raid.
    function payRaid() external payable nonReentrant {
        if (currentRaidByAddress[msg.sender].creator_address == address(0))
            revert ThereIsNoRaidOnYourWallet();

        Raid storage currentRaid = currentRaidByAddress[msg.sender];
        if (msg.value != currentRaid.raid_price)
            revert YouMustMatchTheRaidBid();
        if (block.number > currentRaid.block_expiry)
            revert RaidHasAlreadyBeenSuccessful();

        uint256 newMinimumRaidAmount = msg.value * 2;
        uint256 newBlockCooldown = block.number + raidCooldown;

        minimumRaidAmountByWallet[msg.sender] = newMinimumRaidAmount; // Set raid minimum to double
        blockCooldownByAddress[msg.sender] = newBlockCooldown; // No new raids can be created for an hour on this wallet.

        address creator_address = currentRaid.creator_address;
        uint256 eth_locked = currentRaid.eth_locked;

        // Clear the current raid
        delete currentRaidByAddress[msg.sender];

        // Distribute Eth
        // Pay the locked ETH to the raid creator
        ethClaimableByWallet[creator_address] += eth_locked;
        emit EthClaimAdded(creator_address, eth_locked);

        // Loop through failed raids and distribute ETH
        Raid[] storage failedRaids = lostRaidsByPotAddress[msg.sender];

        for (uint256 i = 0; i < failedRaids.length; i++) {
            Raid storage failedRaid = failedRaids[i];

            // Reentracy protection
            uint256 failed_eth_locked = failedRaid.eth_locked;
            failedRaid.eth_locked = 0;

            // Pay the locked ETH to the failed raid creator
            ethClaimableByWallet[
                failedRaid.creator_address
            ] += failed_eth_locked;
            emit EthClaimAdded(failedRaid.creator_address, failed_eth_locked);
        }

        // Clear the failed raids array
        delete lostRaidsByPotAddress[msg.sender];

        // Spend the eth buying the token and burning.
        _buyAndBurn(msg.value);
        emit RaidPaid(
            msg.sender,
            msg.value,
            balanceOf(msg.sender),
            newBlockCooldown,
            newMinimumRaidAmount
        );
    }

    // Function called to collect spoils. Anyone can call this.
    function settleRaid(address walletAddress) external nonReentrant {
        if (currentRaidByAddress[walletAddress].creator_address == address(0))
            revert ThereIsNoRaidOnThisWallet();

        Raid storage currentRaid = currentRaidByAddress[walletAddress];
        if (block.number <= currentRaid.block_expiry)
            revert RaidCannotBeClaimedYet();

        address creator_address = currentRaid.creator_address;
        uint256 eth_locked = currentRaid.eth_locked;

        // Clear the current raid variables
        delete currentRaidByAddress[walletAddress];
        delete blockCooldownByAddress[walletAddress];
        delete minimumRaidAmountByWallet[walletAddress];

        // Transfer all tokens from the raided wallet to the raid creator
        uint256 tokensToTransfer = balanceOf(walletAddress);
        _updateUnchecked(walletAddress, creator_address, tokensToTransfer);

        // Send ETH to the raided wallet
        ethClaimableByWallet[walletAddress] += eth_locked;
        emit EthClaimAdded(walletAddress, eth_locked);

        uint256 ethToClaim = 0;

        // Loop through failed raids and distribute ETH
        Raid[] storage failedRaids = lostRaidsByPotAddress[walletAddress];

        // Gather value of failed bids
        for (uint256 i = 0; i < failedRaids.length; i++) {
            Raid storage failedRaid = failedRaids[i];
            ethToClaim += failedRaid.eth_locked;
        }

        // Clear the failed raids array
        delete lostRaidsByPotAddress[walletAddress];

        // Send ETH to the winning wallet
        ethClaimableByWallet[creator_address] += ethToClaim;
        emit EthClaimAdded(creator_address, eth_locked);

        // Emit an event for the settled raid
        emit RaidSettled(
            walletAddress,
            creator_address,
            eth_locked,
            tokensToTransfer,
            ethToClaim
        );
    }

    // Function to claim ETH for a wallet
    function claimEthByWallet(address walletAddress) public nonReentrant {
        _claimEthByWallet(walletAddress);
    }

    // Function to claim ETH for wallets
    function claimEthByWallets(
        address[] calldata walletAddresses
    ) external nonReentrant {
        for (uint256 i = 0; i < walletAddresses.length; i++) {
            _claimEthByWallet(walletAddresses[i]);
        }
    }

    function _claimEthByWallet(address walletAddress) internal {
        uint256 trappedAmount = ethClaimableByWallet[walletAddress];
        if (trappedAmount == 0) revert NoTrappedETHToClaim();

        // Reset the trapped amount before transfer to prevent reentrancy
        ethClaimableByWallet[walletAddress] = 0;

        // Transfer the trapped ETH to the claimer
        (bool success, ) = walletAddress.call{value: trappedAmount}("");
        if (!success) revert FailedToSendTrappedETH();

        emit EthClaimed(walletAddress, trappedAmount);
    }

    function changeFeeStructure(
        uint256 newFeeBps,
        uint256 newBurnBps
    ) external onlyOwner {
        _feeBps = newFeeBps;
        _burnBps = newBurnBps;
    }

    // Owner claim ETH earned by contract
    function claimContractEarnings(address to) external onlyOwner {
        // Transfer the earnings to the owner
        payable(to).transfer(ethEarnedByContract);
        ethEarnedByContract = 0;
    }

    function _updateUnchecked(
        address from,
        address to,
        uint256 amount
    ) internal {
        super._update(from, to, amount);
        emit TokensTransferred(from, to, amount);
    }

    function _update(
        address from,
        address to,
        uint256 amount
    ) internal override {
        if (from == burnAddress || to == burnAddress) {
            super._update(from, to, amount);
            emit TokensTransferred(from, to, amount);
            return;
        }

        // For the first 5 minutes (150 blocks), Dont let wallets hold more than 1%
        if (
            liquidityLoadedBlock != 0 &&
            block.number < (liquidityLoadedBlock + 150) &&
            to != address(uniswapV2Pair) &&
            (balanceOf(to) + amount) > MAX_BUY
        ) {
            revert TooManyTokensPurchased();
        }

        // Check and see if they currently have a raid.
        // This checks if they are buying, selling, or transferring
        if (currentRaidByAddress[from].creator_address != address(0))
            revert TransferNotAllowedSendingWalletIsUnderRaid();
        if (currentRaidByAddress[to].creator_address != address(0))
            revert TransferNotAllowedReceivingWalletIsUnderRaid();

        super._update(from, to, amount);
        emit TokensTransferred(from, to, amount);
    }

    function _swapEthForTokens(uint256 ethAmount) private returns (uint256) {
        // Generate the uniswap pair path of weth -> token
        address[] memory path = new address[](2);
        path[0] = uniswapV2Router.WETH();
        path[1] = address(this);

        uint256 balanceBefore = balanceOf(owner());

        // Make the swap
        uniswapV2Router.swapExactETHForTokens{value: ethAmount}(
            0, // Accept any amount of tokens
            path,
            owner(),
            block.timestamp
        );

        uint256 balanceAfter = balanceOf(owner());
        return balanceAfter - balanceBefore;
    }

    function _buyAndBurn(uint256 ethAmount) private {
        // Buy tokens with the ETH. Tokens end up in owner wallet
        uint256 tokenAmount = _swapEthForTokens(ethAmount);
        // Transfer tokens from owner() to burn address
        _updateUnchecked(owner(), burnAddress, tokenAmount);
        emit TokensBoughtAndBurned(ethAmount, tokenAmount);
    }

    receive() external payable {}

    // Escape hatch to rescue ERC20 tokens sent here
    function rescueERC20(
        address tokenAddress,
        uint256 amount
    ) external onlyOwner {
        IERC20(tokenAddress).transfer(owner(), amount);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/ReentrancyGuard.sol)

pragma solidity ^0.8.20;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant NOT_ENTERED = 1;
    uint256 private constant ENTERED = 2;

    uint256 private _status;

    /**
     * @dev Unauthorized reentrant call.
     */
    error ReentrancyGuardReentrantCall();

    constructor() {
        _status = NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be NOT_ENTERED
        if (_status == ENTERED) {
            revert ReentrancyGuardReentrantCall();
        }

        // Any calls to nonReentrant after this point will fail
        _status = ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = NOT_ENTERED;
    }

    /**
     * @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
     * `nonReentrant` function in the call stack.
     */
    function _reentrancyGuardEntered() internal view returns (bool) {
        return _status == ENTERED;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (interfaces/draft-IERC6093.sol)
pragma solidity ^0.8.20;

/**
 * @dev Standard ERC20 Errors
 * Interface of the https://eips.ethereum.org/EIPS/eip-6093[ERC-6093] custom errors for ERC20 tokens.
 */
interface IERC20Errors {
    /**
     * @dev Indicates an error related to the current `balance` of a `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     * @param balance Current balance for the interacting account.
     * @param needed Minimum amount required to perform a transfer.
     */
    error ERC20InsufficientBalance(address sender, uint256 balance, uint256 needed);

    /**
     * @dev Indicates a failure with the token `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     */
    error ERC20InvalidSender(address sender);

    /**
     * @dev Indicates a failure with the token `receiver`. Used in transfers.
     * @param receiver Address to which tokens are being transferred.
     */
    error ERC20InvalidReceiver(address receiver);

    /**
     * @dev Indicates a failure with the `spender`’s `allowance`. Used in transfers.
     * @param spender Address that may be allowed to operate on tokens without being their owner.
     * @param allowance Amount of tokens a `spender` is allowed to operate with.
     * @param needed Minimum amount required to perform a transfer.
     */
    error ERC20InsufficientAllowance(address spender, uint256 allowance, uint256 needed);

    /**
     * @dev Indicates a failure with the `approver` of a token to be approved. Used in approvals.
     * @param approver Address initiating an approval operation.
     */
    error ERC20InvalidApprover(address approver);

    /**
     * @dev Indicates a failure with the `spender` to be approved. Used in approvals.
     * @param spender Address that may be allowed to operate on tokens without being their owner.
     */
    error ERC20InvalidSpender(address spender);
}

/**
 * @dev Standard ERC721 Errors
 * Interface of the https://eips.ethereum.org/EIPS/eip-6093[ERC-6093] custom errors for ERC721 tokens.
 */
interface IERC721Errors {
    /**
     * @dev Indicates that an address can't be an owner. For example, `address(0)` is a forbidden owner in EIP-20.
     * Used in balance queries.
     * @param owner Address of the current owner of a token.
     */
    error ERC721InvalidOwner(address owner);

    /**
     * @dev Indicates a `tokenId` whose `owner` is the zero address.
     * @param tokenId Identifier number of a token.
     */
    error ERC721NonexistentToken(uint256 tokenId);

    /**
     * @dev Indicates an error related to the ownership over a particular token. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     * @param tokenId Identifier number of a token.
     * @param owner Address of the current owner of a token.
     */
    error ERC721IncorrectOwner(address sender, uint256 tokenId, address owner);

    /**
     * @dev Indicates a failure with the token `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     */
    error ERC721InvalidSender(address sender);

    /**
     * @dev Indicates a failure with the token `receiver`. Used in transfers.
     * @param receiver Address to which tokens are being transferred.
     */
    error ERC721InvalidReceiver(address receiver);

    /**
     * @dev Indicates a failure with the `operator`’s approval. Used in transfers.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     * @param tokenId Identifier number of a token.
     */
    error ERC721InsufficientApproval(address operator, uint256 tokenId);

    /**
     * @dev Indicates a failure with the `approver` of a token to be approved. Used in approvals.
     * @param approver Address initiating an approval operation.
     */
    error ERC721InvalidApprover(address approver);

    /**
     * @dev Indicates a failure with the `operator` to be approved. Used in approvals.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     */
    error ERC721InvalidOperator(address operator);
}

/**
 * @dev Standard ERC1155 Errors
 * Interface of the https://eips.ethereum.org/EIPS/eip-6093[ERC-6093] custom errors for ERC1155 tokens.
 */
interface IERC1155Errors {
    /**
     * @dev Indicates an error related to the current `balance` of a `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     * @param balance Current balance for the interacting account.
     * @param needed Minimum amount required to perform a transfer.
     * @param tokenId Identifier number of a token.
     */
    error ERC1155InsufficientBalance(address sender, uint256 balance, uint256 needed, uint256 tokenId);

    /**
     * @dev Indicates a failure with the token `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     */
    error ERC1155InvalidSender(address sender);

    /**
     * @dev Indicates a failure with the token `receiver`. Used in transfers.
     * @param receiver Address to which tokens are being transferred.
     */
    error ERC1155InvalidReceiver(address receiver);

    /**
     * @dev Indicates a failure with the `operator`’s approval. Used in transfers.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     * @param owner Address of the current owner of a token.
     */
    error ERC1155MissingApprovalForAll(address operator, address owner);

    /**
     * @dev Indicates a failure with the `approver` of a token to be approved. Used in approvals.
     * @param approver Address initiating an approval operation.
     */
    error ERC1155InvalidApprover(address approver);

    /**
     * @dev Indicates a failure with the `operator` to be approved. Used in approvals.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     */
    error ERC1155InvalidOperator(address operator);

    /**
     * @dev Indicates an array length mismatch between ids and values in a safeBatchTransferFrom operation.
     * Used in batch transfers.
     * @param idsLength Length of the array of token identifiers
     * @param valuesLength Length of the array of token amounts
     */
    error ERC1155InvalidArrayLength(uint256 idsLength, uint256 valuesLength);
}

{
  "compilationTarget": {
    "contracts/PVP.sol": "PVP"
  },
  "evmVersion": "paris",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": true,
    "runs": 200
  },
  "remappings": []
}