// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

/*
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}

// SPDX-License-Identifier: UNLICENSED

pragma solidity >=0.5.0;

interface IMicroManager {
    function microBridge(address _address) external view returns (bool);

    function treasuryAddress() external view returns (address);

    function microProtocolFee() external view returns (uint256);

    function oracleAddress() external view returns (address);
}

// SPDX-License-Identifier: MIT

pragma solidity >=0.5.0;

interface IPriceOracle {
    function convertUsdToWei(uint256 usdAmount) external view returns (uint256 weiAmount);
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.13;

import "@openzeppelin/contracts/security/ReentrancyGuard.sol";
import "@openzeppelin/contracts/access/Ownable.sol";
import "../MicroUtilityV4.sol";

interface MicroNFT {
    struct SaleConfiguration {
        uint64 editionSize;
        uint16 profitSharing;
        address payable fundsRecipient;
        uint256 publicSalePrice;
        uint32 maxSalePurchasePerAddress;
        uint64 publicSaleStart;
        uint64 publicSaleEnd;
        bytes32 presaleMerkleRoot;
        bool cancelable;
    }

    function saleConfig() external view returns (SaleConfiguration memory);

    function purchase(
        address minter,
        uint256 quantity
    ) external returns (uint256);

    function purchasePresale(
        address minter,
        uint256 quantity,
        bytes32[] calldata merkleProof
    ) external returns (uint256);
}

contract MicroGatewayV2 is Ownable, ReentrancyGuard, MicroUtilityV4 {
    using SafeMath for uint256;

    bool private _initialized;

    uint256 private percenPerDiscount = 1000;

    uint256 private percentCreator = 2000;

    uint256 private percenPerRef = 2000;

    uint256 private feeDenominator = 10000;

    error PurchaseWrongPrice(uint256 correctPrice);

    error Unauthorized();

    event NewCollectionMinted(
        address indexed sender,
        address indexed contractAddress,
        uint256 quantity
    );

    event FundsWithdrawn(
        address indexed sender,
        address indexed fundsRecipient,
        uint256 fund
    );

    function init(bytes memory initPayload) external returns (bool) {
        if (_initialized) {
            revert Unauthorized();
        }
        (address _owner, address _manager) = abi.decode(
            initPayload,
            (address, address)
        );
        transferOwnership(_owner);
        _setManager(_manager);
        _initialized = true;
        return true;
    }

    function requestPurchase(
        address nftAddress,
        uint256 quantity,
        address referral
    ) external payable nonReentrant {
        address minter = msg.sender;

        _isMinting(minter, nftAddress, quantity, referral);

        MicroNFT(nftAddress).purchase(minter, quantity);

        emit NewCollectionMinted(minter, nftAddress, quantity);
    }

    function requestPresale(
        address nftAddress,
        uint256 quantity,
        bytes32[] calldata merkleProof,
        address referral
    ) external payable nonReentrant {
        address minter = msg.sender;

        _isMinting(minter, nftAddress, quantity, referral);

        MicroNFT(nftAddress).purchasePresale(minter, quantity, merkleProof);

        emit NewCollectionMinted(minter, nftAddress, quantity);
    }

    function _payoutFundingRaise(
        uint256 totalPurchase,
        address fundsRecipient
    ) internal returns (bool) {
        if (fundsRecipient == address(0) || totalPurchase == 0) {
            return false;
        }

        _payoutRemainder(fundsRecipient, totalPurchase);

        emit FundsWithdrawn(msg.sender, fundsRecipient, totalPurchase);

        return true;
    }

    function _isMinting(
        address minter,
        address nftAddress,
        uint256 quantity,
        address referral
    ) internal {
        if (minter == referral) {
            revert Unauthorized();
        }

        MicroNFT.SaleConfiguration memory saleConfig = MicroNFT(nftAddress)
            .saleConfig();

        uint256 salePrice = saleConfig.publicSalePrice.mul(quantity);

        uint256 protocolFee = getMicroFeeWei(quantity);

        uint256 totalFee = salePrice.add(protocolFee);

        uint256 creatorFee = protocolFee.mul(percentCreator).div(
            feeDenominator
        );

        if (msg.value < totalFee) {
            revert PurchaseWrongPrice(totalFee);
        }

        if (referral == address(0)) {
            _payoutMicroFee(protocolFee.sub(creatorFee));

            _payoutFundingRaise(
                salePrice.add(creatorFee),
                saleConfig.fundsRecipient
            );

            _payoutRemainder(minter, msg.value.sub(totalFee));
        } else {
            uint256 refProtocolFee = protocolFee.mul(percenPerRef).div(
                feeDenominator
            );

            uint256 discountProtocolFee = protocolFee
                .mul(percenPerDiscount)
                .div(feeDenominator);

            uint256 profitSharing = salePrice.mul(saleConfig.profitSharing).div(
                100
            );

            uint256 treasuryFee = protocolFee
                .sub(refProtocolFee)
                .sub(discountProtocolFee)
                .sub(creatorFee);

            _payoutMicroFee(treasuryFee);

            _payoutFundingRaise(
                salePrice.add(creatorFee).sub(profitSharing),
                saleConfig.fundsRecipient
            );

            _payoutRemainder(referral, refProtocolFee.add(profitSharing));

            _payoutRemainder(
                minter,
                msg.value.sub(totalFee).add(discountProtocolFee)
            );
        }
    }

    function configFee(
        uint256 _creator,
        uint256 _discount,
        uint256 _referral
    ) external onlyOwner {
        percentCreator = _creator;
        percenPerDiscount = _discount;
        percenPerRef = _referral;
    }

    function editManager(address _manager) external onlyOwner {
        _setManager(_manager);
    }
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.4;
import "@openzeppelin/contracts/utils/math/SafeMath.sol";
import {IPriceOracle} from "./interfaces/IPriceOracle.sol";
import {IMicroManager} from "./interfaces/IMicroManager.sol";

error PaymentFailed();

contract MicroUtilityV4 {
    using SafeMath for uint256;
    IMicroManager public microManager;
    uint256 private constant STATIC_GAS_LIMIT = 210_000;

    event FeePayout(
        uint256 MicroMintFeeWei,
        address MicroFeeRecipient,
        bool success
    );

    /**
     * PUBLIC FUNCTIONS
     * state changing
     */

    function getMicroFeeWei(uint256 quantity) public view returns (uint256) {
        if (quantity == 0) {
            return 0;
        }
        return
            IPriceOracle(microManager.oracleAddress()).convertUsdToWei(
                microManager.microProtocolFee().mul(quantity)
            );
    }

    function _payoutMicroFee(uint256 microProtocolFee) internal {
        address treasury = microManager.treasuryAddress();
        _payoutRemainder(treasury, microProtocolFee);
        emit FeePayout(microProtocolFee, treasury, true);
    }

    function _setManager(address _manager) internal {
        microManager = IMicroManager(_manager);
    }

    function _payoutRemainder(address recipient, uint256 value) internal {
        if (value > 0) {
            (bool success, ) = payable(recipient).call{
                value: value,
                gas: gasleft() > STATIC_GAS_LIMIT ? STATIC_GAS_LIMIT : gasleft()
            }("");
            if (!success) {
                revert PaymentFailed();
            }
        }
    }
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

import "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _setOwner(_msgSender());
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
        _;
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions anymore. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby removing any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _setOwner(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _setOwner(newOwner);
    }

    function _setOwner(address newOwner) private {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant _NOT_ENTERED = 1;
    uint256 private constant _ENTERED = 2;

    uint256 private _status;

    constructor() {
        _status = _NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and make it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        // On the first call to nonReentrant, _notEntered will be true
        require(_status != _ENTERED, "ReentrancyGuard: reentrant call");

        // Any calls to nonReentrant after this point will fail
        _status = _ENTERED;

        _;

        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = _NOT_ENTERED;
    }
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

// CAUTION
// This version of SafeMath should only be used with Solidity 0.8 or later,
// because it relies on the compiler's built in overflow checks.

/**
 * @dev Wrappers over Solidity's arithmetic operations.
 *
 * NOTE: `SafeMath` is no longer needed starting with Solidity 0.8. The compiler
 * now has built in overflow checking.
 */
library SafeMath {
    /**
     * @dev Returns the addition of two unsigned integers, with an overflow flag.
     *
     * _Available since v3.4._
     */
    function tryAdd(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            uint256 c = a + b;
            if (c < a) return (false, 0);
            return (true, c);
        }
    }

    /**
     * @dev Returns the substraction of two unsigned integers, with an overflow flag.
     *
     * _Available since v3.4._
     */
    function trySub(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            if (b > a) return (false, 0);
            return (true, a - b);
        }
    }

    /**
     * @dev Returns the multiplication of two unsigned integers, with an overflow flag.
     *
     * _Available since v3.4._
     */
    function tryMul(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            // Gas optimization: this is cheaper than requiring 'a' not being zero, but the
            // benefit is lost if 'b' is also tested.
            // See: https://github.com/OpenZeppelin/openzeppelin-contracts/pull/522
            if (a == 0) return (true, 0);
            uint256 c = a * b;
            if (c / a != b) return (false, 0);
            return (true, c);
        }
    }

    /**
     * @dev Returns the division of two unsigned integers, with a division by zero flag.
     *
     * _Available since v3.4._
     */
    function tryDiv(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            if (b == 0) return (false, 0);
            return (true, a / b);
        }
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers, with a division by zero flag.
     *
     * _Available since v3.4._
     */
    function tryMod(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            if (b == 0) return (false, 0);
            return (true, a % b);
        }
    }

    /**
     * @dev Returns the addition of two unsigned integers, reverting on
     * overflow.
     *
     * Counterpart to Solidity's `+` operator.
     *
     * Requirements:
     *
     * - Addition cannot overflow.
     */
    function add(uint256 a, uint256 b) internal pure returns (uint256) {
        return a + b;
    }

    /**
     * @dev Returns the subtraction of two unsigned integers, reverting on
     * overflow (when the result is negative).
     *
     * Counterpart to Solidity's `-` operator.
     *
     * Requirements:
     *
     * - Subtraction cannot overflow.
     */
    function sub(uint256 a, uint256 b) internal pure returns (uint256) {
        return a - b;
    }

    /**
     * @dev Returns the multiplication of two unsigned integers, reverting on
     * overflow.
     *
     * Counterpart to Solidity's `*` operator.
     *
     * Requirements:
     *
     * - Multiplication cannot overflow.
     */
    function mul(uint256 a, uint256 b) internal pure returns (uint256) {
        return a * b;
    }

    /**
     * @dev Returns the integer division of two unsigned integers, reverting on
     * division by zero. The result is rounded towards zero.
     *
     * Counterpart to Solidity's `/` operator.
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function div(uint256 a, uint256 b) internal pure returns (uint256) {
        return a / b;
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers. (unsigned integer modulo),
     * reverting when dividing by zero.
     *
     * Counterpart to Solidity's `%` operator. This function uses a `revert`
     * opcode (which leaves remaining gas untouched) while Solidity uses an
     * invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function mod(uint256 a, uint256 b) internal pure returns (uint256) {
        return a % b;
    }

    /**
     * @dev Returns the subtraction of two unsigned integers, reverting with custom message on
     * overflow (when the result is negative).
     *
     * CAUTION: This function is deprecated because it requires allocating memory for the error
     * message unnecessarily. For custom revert reasons use {trySub}.
     *
     * Counterpart to Solidity's `-` operator.
     *
     * Requirements:
     *
     * - Subtraction cannot overflow.
     */
    function sub(
        uint256 a,
        uint256 b,
        string memory errorMessage
    ) internal pure returns (uint256) {
        unchecked {
            require(b <= a, errorMessage);
            return a - b;
        }
    }

    /**
     * @dev Returns the integer division of two unsigned integers, reverting with custom message on
     * division by zero. The result is rounded towards zero.
     *
     * Counterpart to Solidity's `/` operator. Note: this function uses a
     * `revert` opcode (which leaves remaining gas untouched) while Solidity
     * uses an invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function div(
        uint256 a,
        uint256 b,
        string memory errorMessage
    ) internal pure returns (uint256) {
        unchecked {
            require(b > 0, errorMessage);
            return a / b;
        }
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers. (unsigned integer modulo),
     * reverting with custom message when dividing by zero.
     *
     * CAUTION: This function is deprecated because it requires allocating memory for the error
     * message unnecessarily. For custom revert reasons use {tryMod}.
     *
     * Counterpart to Solidity's `%` operator. This function uses a `revert`
     * opcode (which leaves remaining gas untouched) while Solidity uses an
     * invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function mod(
        uint256 a,
        uint256 b,
        string memory errorMessage
    ) internal pure returns (uint256) {
        unchecked {
            require(b > 0, errorMessage);
            return a % b;
        }
    }
}

{
  "compilationTarget": {
    "contracts/minter/MicroGatewayV2.sol": "MicroGatewayV2"
  },
  "evmVersion": "london",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": true,
    "runs": 200
  },
  "remappings": []
}