// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.7.0) (utils/Address.sol)

pragma solidity ^0.8.1;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     * ====
     *
     * [IMPORTANT]
     * ====
     * You shouldn't rely on `isContract` to protect against flash loan attacks!
     *
     * Preventing calls from contracts is highly discouraged. It breaks composability, breaks support for smart wallets
     * like Gnosis Safe, and does not provide security since it can be circumvented by calling from a contract
     * constructor.
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize/address.code.length, which returns 0
        // for contracts in construction, since the code is only stored at the end
        // of the constructor execution.

        return account.code.length > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://diligence.consensys.net/posts/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.5.11/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        (bool success, ) = recipient.call{value: amount}("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCall(target, data, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        require(isContract(target), "Address: call to non-contract");

        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        require(isContract(target), "Address: static call to non-contract");

        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionDelegateCall(target, data, "Address: low-level delegate call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(isContract(target), "Address: delegate call to non-contract");

        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Tool to verifies that a low level call was successful, and revert if it wasn't, either by bubbling the
     * revert reason using the provided one.
     *
     * _Available since v4.3._
     */
    function verifyCallResult(
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal pure returns (bytes memory) {
        if (success) {
            return returndata;
        } else {
            // Look for revert reason and bubble it up if present
            if (returndata.length > 0) {
                // The easiest way to bubble the revert reason is using memory via assembly
                /// @solidity memory-safe-assembly
                assembly {
                    let returndata_size := mload(returndata)
                    revert(add(32, returndata), returndata_size)
                }
            } else {
                revert(errorMessage);
            }
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Context.sol)

pragma solidity ^0.8.0;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/introspection/ERC165.sol)

pragma solidity ^0.8.0;

import "./IERC165.sol";

/**
 * @dev Implementation of the {IERC165} interface.
 *
 * Contracts that want to implement ERC165 should inherit from this contract and override {supportsInterface} to check
 * for the additional interface id that will be supported. For example:
 *
 * ```solidity
 * function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
 *     return interfaceId == type(MyInterface).interfaceId || super.supportsInterface(interfaceId);
 * }
 * ```
 *
 * Alternatively, {ERC165Storage} provides an easier to use but more expensive implementation.
 */
abstract contract ERC165 is IERC165 {
    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
        return interfaceId == type(IERC165).interfaceId;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (token/ERC721/ERC721.sol)

pragma solidity ^0.8.0;

import "./IERC721.sol";
import "./IERC721Receiver.sol";
import "./extensions/IERC721Metadata.sol";
import "../../utils/Address.sol";
import "../../utils/Context.sol";
import "../../utils/Strings.sol";
import "../../utils/introspection/ERC165.sol";

/**
 * @dev Implementation of https://eips.ethereum.org/EIPS/eip-721[ERC721] Non-Fungible Token Standard, including
 * the Metadata extension, but not including the Enumerable extension, which is available separately as
 * {ERC721Enumerable}.
 */
contract ERC721 is Context, ERC165, IERC721, IERC721Metadata {
    using Address for address;
    using Strings for uint256;

    // Token name
    string private _name;

    // Token symbol
    string private _symbol;

    // Mapping from token ID to owner address
    mapping(uint256 => address) private _owners;

    // Mapping owner address to token count
    mapping(address => uint256) private _balances;

    // Mapping from token ID to approved address
    mapping(uint256 => address) private _tokenApprovals;

    // Mapping from owner to operator approvals
    mapping(address => mapping(address => bool)) private _operatorApprovals;

    /**
     * @dev Initializes the contract by setting a `name` and a `symbol` to the token collection.
     */
    constructor(string memory name_, string memory symbol_) {
        _name = name_;
        _symbol = symbol_;
    }

    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override(ERC165, IERC165) returns (bool) {
        return
            interfaceId == type(IERC721).interfaceId ||
            interfaceId == type(IERC721Metadata).interfaceId ||
            super.supportsInterface(interfaceId);
    }

    /**
     * @dev See {IERC721-balanceOf}.
     */
    function balanceOf(address owner) public view virtual override returns (uint256) {
        require(owner != address(0), "ERC721: address zero is not a valid owner");
        return _balances[owner];
    }

    /**
     * @dev See {IERC721-ownerOf}.
     */
    function ownerOf(uint256 tokenId) public view virtual override returns (address) {
        address owner = _ownerOf(tokenId);
        require(owner != address(0), "ERC721: invalid token ID");
        return owner;
    }

    /**
     * @dev See {IERC721Metadata-name}.
     */
    function name() public view virtual override returns (string memory) {
        return _name;
    }

    /**
     * @dev See {IERC721Metadata-symbol}.
     */
    function symbol() public view virtual override returns (string memory) {
        return _symbol;
    }

    /**
     * @dev See {IERC721Metadata-tokenURI}.
     */
    function tokenURI(uint256 tokenId) public view virtual override returns (string memory) {
        _requireMinted(tokenId);

        string memory baseURI = _baseURI();
        return bytes(baseURI).length > 0 ? string(abi.encodePacked(baseURI, tokenId.toString())) : "";
    }

    /**
     * @dev Base URI for computing {tokenURI}. If set, the resulting URI for each
     * token will be the concatenation of the `baseURI` and the `tokenId`. Empty
     * by default, can be overridden in child contracts.
     */
    function _baseURI() internal view virtual returns (string memory) {
        return "";
    }

    /**
     * @dev See {IERC721-approve}.
     */
    function approve(address to, uint256 tokenId) public virtual override {
        address owner = ERC721.ownerOf(tokenId);
        require(to != owner, "ERC721: approval to current owner");

        require(
            _msgSender() == owner || isApprovedForAll(owner, _msgSender()),
            "ERC721: approve caller is not token owner or approved for all"
        );

        _approve(to, tokenId);
    }

    /**
     * @dev See {IERC721-getApproved}.
     */
    function getApproved(uint256 tokenId) public view virtual override returns (address) {
        _requireMinted(tokenId);

        return _tokenApprovals[tokenId];
    }

    /**
     * @dev See {IERC721-setApprovalForAll}.
     */
    function setApprovalForAll(address operator, bool approved) public virtual override {
        _setApprovalForAll(_msgSender(), operator, approved);
    }

    /**
     * @dev See {IERC721-isApprovedForAll}.
     */
    function isApprovedForAll(address owner, address operator) public view virtual override returns (bool) {
        return _operatorApprovals[owner][operator];
    }

    /**
     * @dev See {IERC721-transferFrom}.
     */
    function transferFrom(
        address from,
        address to,
        uint256 tokenId
    ) public virtual override {
        //solhint-disable-next-line max-line-length
        require(_isApprovedOrOwner(_msgSender(), tokenId), "ERC721: caller is not token owner or approved");

        _transfer(from, to, tokenId);
    }

    /**
     * @dev See {IERC721-safeTransferFrom}.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId
    ) public virtual override {
        safeTransferFrom(from, to, tokenId, "");
    }

    /**
     * @dev See {IERC721-safeTransferFrom}.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId,
        bytes memory data
    ) public virtual override {
        require(_isApprovedOrOwner(_msgSender(), tokenId), "ERC721: caller is not token owner or approved");
        _safeTransfer(from, to, tokenId, data);
    }

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`, checking first that contract recipients
     * are aware of the ERC721 protocol to prevent tokens from being forever locked.
     *
     * `data` is additional data, it has no specified format and it is sent in call to `to`.
     *
     * This internal function is equivalent to {safeTransferFrom}, and can be used to e.g.
     * implement alternative mechanisms to perform token transfer, such as signature-based.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function _safeTransfer(
        address from,
        address to,
        uint256 tokenId,
        bytes memory data
    ) internal virtual {
        _transfer(from, to, tokenId);
        require(_checkOnERC721Received(from, to, tokenId, data), "ERC721: transfer to non ERC721Receiver implementer");
    }

    /**
     * @dev Returns the owner of the `tokenId`. Does NOT revert if token doesn't exist
     */
    function _ownerOf(uint256 tokenId) internal view virtual returns (address) {
        return _owners[tokenId];
    }

    /**
     * @dev Returns whether `tokenId` exists.
     *
     * Tokens can be managed by their owner or approved accounts via {approve} or {setApprovalForAll}.
     *
     * Tokens start existing when they are minted (`_mint`),
     * and stop existing when they are burned (`_burn`).
     */
    function _exists(uint256 tokenId) internal view virtual returns (bool) {
        return _ownerOf(tokenId) != address(0);
    }

    /**
     * @dev Returns whether `spender` is allowed to manage `tokenId`.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function _isApprovedOrOwner(address spender, uint256 tokenId) internal view virtual returns (bool) {
        address owner = ERC721.ownerOf(tokenId);
        return (spender == owner || isApprovedForAll(owner, spender) || getApproved(tokenId) == spender);
    }

    /**
     * @dev Safely mints `tokenId` and transfers it to `to`.
     *
     * Requirements:
     *
     * - `tokenId` must not exist.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function _safeMint(address to, uint256 tokenId) internal virtual {
        _safeMint(to, tokenId, "");
    }

    /**
     * @dev Same as {xref-ERC721-_safeMint-address-uint256-}[`_safeMint`], with an additional `data` parameter which is
     * forwarded in {IERC721Receiver-onERC721Received} to contract recipients.
     */
    function _safeMint(
        address to,
        uint256 tokenId,
        bytes memory data
    ) internal virtual {
        _mint(to, tokenId);
        require(
            _checkOnERC721Received(address(0), to, tokenId, data),
            "ERC721: transfer to non ERC721Receiver implementer"
        );
    }

    /**
     * @dev Mints `tokenId` and transfers it to `to`.
     *
     * WARNING: Usage of this method is discouraged, use {_safeMint} whenever possible
     *
     * Requirements:
     *
     * - `tokenId` must not exist.
     * - `to` cannot be the zero address.
     *
     * Emits a {Transfer} event.
     */
    function _mint(address to, uint256 tokenId) internal virtual {
        require(to != address(0), "ERC721: mint to the zero address");
        require(!_exists(tokenId), "ERC721: token already minted");

        _beforeTokenTransfer(address(0), to, tokenId, 1);

        // Check that tokenId was not minted by `_beforeTokenTransfer` hook
        require(!_exists(tokenId), "ERC721: token already minted");

        unchecked {
            // Will not overflow unless all 2**256 token ids are minted to the same owner.
            // Given that tokens are minted one by one, it is impossible in practice that
            // this ever happens. Might change if we allow batch minting.
            // The ERC fails to describe this case.
            _balances[to] += 1;
        }

        _owners[tokenId] = to;

        emit Transfer(address(0), to, tokenId);

        _afterTokenTransfer(address(0), to, tokenId, 1);
    }

    /**
     * @dev Destroys `tokenId`.
     * The approval is cleared when the token is burned.
     * This is an internal function that does not check if the sender is authorized to operate on the token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     *
     * Emits a {Transfer} event.
     */
    function _burn(uint256 tokenId) internal virtual {
        address owner = ERC721.ownerOf(tokenId);

        _beforeTokenTransfer(owner, address(0), tokenId, 1);

        // Update ownership in case tokenId was transferred by `_beforeTokenTransfer` hook
        owner = ERC721.ownerOf(tokenId);

        // Clear approvals
        delete _tokenApprovals[tokenId];

        unchecked {
            // Cannot overflow, as that would require more tokens to be burned/transferred
            // out than the owner initially received through minting and transferring in.
            _balances[owner] -= 1;
        }
        delete _owners[tokenId];

        emit Transfer(owner, address(0), tokenId);

        _afterTokenTransfer(owner, address(0), tokenId, 1);
    }

    /**
     * @dev Transfers `tokenId` from `from` to `to`.
     *  As opposed to {transferFrom}, this imposes no restrictions on msg.sender.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     * - `tokenId` token must be owned by `from`.
     *
     * Emits a {Transfer} event.
     */
    function _transfer(
        address from,
        address to,
        uint256 tokenId
    ) internal virtual {
        require(ERC721.ownerOf(tokenId) == from, "ERC721: transfer from incorrect owner");
        require(to != address(0), "ERC721: transfer to the zero address");

        _beforeTokenTransfer(from, to, tokenId, 1);

        // Check that tokenId was not transferred by `_beforeTokenTransfer` hook
        require(ERC721.ownerOf(tokenId) == from, "ERC721: transfer from incorrect owner");

        // Clear approvals from the previous owner
        delete _tokenApprovals[tokenId];

        unchecked {
            // `_balances[from]` cannot overflow for the same reason as described in `_burn`:
            // `from`'s balance is the number of token held, which is at least one before the current
            // transfer.
            // `_balances[to]` could overflow in the conditions described in `_mint`. That would require
            // all 2**256 token ids to be minted, which in practice is impossible.
            _balances[from] -= 1;
            _balances[to] += 1;
        }
        _owners[tokenId] = to;

        emit Transfer(from, to, tokenId);

        _afterTokenTransfer(from, to, tokenId, 1);
    }

    /**
     * @dev Approve `to` to operate on `tokenId`
     *
     * Emits an {Approval} event.
     */
    function _approve(address to, uint256 tokenId) internal virtual {
        _tokenApprovals[tokenId] = to;
        emit Approval(ERC721.ownerOf(tokenId), to, tokenId);
    }

    /**
     * @dev Approve `operator` to operate on all of `owner` tokens
     *
     * Emits an {ApprovalForAll} event.
     */
    function _setApprovalForAll(
        address owner,
        address operator,
        bool approved
    ) internal virtual {
        require(owner != operator, "ERC721: approve to caller");
        _operatorApprovals[owner][operator] = approved;
        emit ApprovalForAll(owner, operator, approved);
    }

    /**
     * @dev Reverts if the `tokenId` has not been minted yet.
     */
    function _requireMinted(uint256 tokenId) internal view virtual {
        require(_exists(tokenId), "ERC721: invalid token ID");
    }

    /**
     * @dev Internal function to invoke {IERC721Receiver-onERC721Received} on a target address.
     * The call is not executed if the target address is not a contract.
     *
     * @param from address representing the previous owner of the given token ID
     * @param to target address that will receive the tokens
     * @param tokenId uint256 ID of the token to be transferred
     * @param data bytes optional data to send along with the call
     * @return bool whether the call correctly returned the expected magic value
     */
    function _checkOnERC721Received(
        address from,
        address to,
        uint256 tokenId,
        bytes memory data
    ) private returns (bool) {
        if (to.isContract()) {
            try IERC721Receiver(to).onERC721Received(_msgSender(), from, tokenId, data) returns (bytes4 retval) {
                return retval == IERC721Receiver.onERC721Received.selector;
            } catch (bytes memory reason) {
                if (reason.length == 0) {
                    revert("ERC721: transfer to non ERC721Receiver implementer");
                } else {
                    /// @solidity memory-safe-assembly
                    assembly {
                        revert(add(32, reason), mload(reason))
                    }
                }
            }
        } else {
            return true;
        }
    }

    /**
     * @dev Hook that is called before any token transfer. This includes minting and burning. If {ERC721Consecutive} is
     * used, the hook may be called as part of a consecutive (batch) mint, as indicated by `batchSize` greater than 1.
     *
     * Calling conditions:
     *
     * - When `from` and `to` are both non-zero, ``from``'s tokens will be transferred to `to`.
     * - When `from` is zero, the tokens will be minted for `to`.
     * - When `to` is zero, ``from``'s tokens will be burned.
     * - `from` and `to` are never both zero.
     * - `batchSize` is non-zero.
     *
     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
     */
    function _beforeTokenTransfer(
        address from,
        address to,
        uint256, /* firstTokenId */
        uint256 batchSize
    ) internal virtual {
        if (batchSize > 1) {
            if (from != address(0)) {
                _balances[from] -= batchSize;
            }
            if (to != address(0)) {
                _balances[to] += batchSize;
            }
        }
    }

    /**
     * @dev Hook that is called after any token transfer. This includes minting and burning. If {ERC721Consecutive} is
     * used, the hook may be called as part of a consecutive (batch) mint, as indicated by `batchSize` greater than 1.
     *
     * Calling conditions:
     *
     * - When `from` and `to` are both non-zero, ``from``'s tokens were transferred to `to`.
     * - When `from` is zero, the tokens were minted for `to`.
     * - When `to` is zero, ``from``'s tokens were burned.
     * - `from` and `to` are never both zero.
     * - `batchSize` is non-zero.
     *
     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
     */
    function _afterTokenTransfer(
        address from,
        address to,
        uint256 firstTokenId,
        uint256 batchSize
    ) internal virtual {}
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (token/ERC721/extensions/ERC721Burnable.sol)

pragma solidity ^0.8.0;

import "../ERC721.sol";
import "../../../utils/Context.sol";

/**
 * @title ERC721 Burnable Token
 * @dev ERC721 Token that can be burned (destroyed).
 */
abstract contract ERC721Burnable is Context, ERC721 {
    /**
     * @dev Burns `tokenId`. See {ERC721-_burn}.
     *
     * Requirements:
     *
     * - The caller must own `tokenId` or be an approved operator.
     */
    function burn(uint256 tokenId) public virtual {
        //solhint-disable-next-line max-line-length
        require(_isApprovedOrOwner(_msgSender(), tokenId), "ERC721: caller is not token owner or approved");
        _burn(tokenId);
    }
}

// SPDX-License-Identifier: MIT

pragma solidity 0.8.21;

// Included to allow setting of ENS reverse register for contract:
interface IENSReverseRegistrar {
  function setName(string memory name) external returns (bytes32);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.7.0) (token/ERC1155/IERC1155.sol)

pragma solidity ^0.8.0;

import "../../utils/introspection/IERC165.sol";

/**
 * @dev Required interface of an ERC1155 compliant contract, as defined in the
 * https://eips.ethereum.org/EIPS/eip-1155[EIP].
 *
 * _Available since v3.1._
 */
interface IERC1155 is IERC165 {
    /**
     * @dev Emitted when `value` tokens of token type `id` are transferred from `from` to `to` by `operator`.
     */
    event TransferSingle(address indexed operator, address indexed from, address indexed to, uint256 id, uint256 value);

    /**
     * @dev Equivalent to multiple {TransferSingle} events, where `operator`, `from` and `to` are the same for all
     * transfers.
     */
    event TransferBatch(
        address indexed operator,
        address indexed from,
        address indexed to,
        uint256[] ids,
        uint256[] values
    );

    /**
     * @dev Emitted when `account` grants or revokes permission to `operator` to transfer their tokens, according to
     * `approved`.
     */
    event ApprovalForAll(address indexed account, address indexed operator, bool approved);

    /**
     * @dev Emitted when the URI for token type `id` changes to `value`, if it is a non-programmatic URI.
     *
     * If an {URI} event was emitted for `id`, the standard
     * https://eips.ethereum.org/EIPS/eip-1155#metadata-extensions[guarantees] that `value` will equal the value
     * returned by {IERC1155MetadataURI-uri}.
     */
    event URI(string value, uint256 indexed id);

    /**
     * @dev Returns the amount of tokens of token type `id` owned by `account`.
     *
     * Requirements:
     *
     * - `account` cannot be the zero address.
     */
    function balanceOf(address account, uint256 id) external view returns (uint256);

    /**
     * @dev xref:ROOT:erc1155.adoc#batch-operations[Batched] version of {balanceOf}.
     *
     * Requirements:
     *
     * - `accounts` and `ids` must have the same length.
     */
    function balanceOfBatch(address[] calldata accounts, uint256[] calldata ids)
        external
        view
        returns (uint256[] memory);

    /**
     * @dev Grants or revokes permission to `operator` to transfer the caller's tokens, according to `approved`,
     *
     * Emits an {ApprovalForAll} event.
     *
     * Requirements:
     *
     * - `operator` cannot be the caller.
     */
    function setApprovalForAll(address operator, bool approved) external;

    /**
     * @dev Returns true if `operator` is approved to transfer ``account``'s tokens.
     *
     * See {setApprovalForAll}.
     */
    function isApprovedForAll(address account, address operator) external view returns (bool);

    /**
     * @dev Transfers `amount` tokens of token type `id` from `from` to `to`.
     *
     * Emits a {TransferSingle} event.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     * - If the caller is not `from`, it must have been approved to spend ``from``'s tokens via {setApprovalForAll}.
     * - `from` must have a balance of tokens of type `id` of at least `amount`.
     * - If `to` refers to a smart contract, it must implement {IERC1155Receiver-onERC1155Received} and return the
     * acceptance magic value.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 id,
        uint256 amount,
        bytes calldata data
    ) external;

    /**
     * @dev xref:ROOT:erc1155.adoc#batch-operations[Batched] version of {safeTransferFrom}.
     *
     * Emits a {TransferBatch} event.
     *
     * Requirements:
     *
     * - `ids` and `amounts` must have the same length.
     * - If `to` refers to a smart contract, it must implement {IERC1155Receiver-onERC1155BatchReceived} and return the
     * acceptance magic value.
     */
    function safeBatchTransferFrom(
        address from,
        address to,
        uint256[] calldata ids,
        uint256[] calldata amounts,
        bytes calldata data
    ) external;
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/introspection/IERC165.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[EIP].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[EIP section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.6.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `from` to `to` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(
        address from,
        address to,
        uint256 amount
    ) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.7.0) (token/ERC721/IERC721.sol)

pragma solidity ^0.8.0;

import "../../utils/introspection/IERC165.sol";

/**
 * @dev Required interface of an ERC721 compliant contract.
 */
interface IERC721 is IERC165 {
    /**
     * @dev Emitted when `tokenId` token is transferred from `from` to `to`.
     */
    event Transfer(address indexed from, address indexed to, uint256 indexed tokenId);

    /**
     * @dev Emitted when `owner` enables `approved` to manage the `tokenId` token.
     */
    event Approval(address indexed owner, address indexed approved, uint256 indexed tokenId);

    /**
     * @dev Emitted when `owner` enables or disables (`approved`) `operator` to manage all of its assets.
     */
    event ApprovalForAll(address indexed owner, address indexed operator, bool approved);

    /**
     * @dev Returns the number of tokens in ``owner``'s account.
     */
    function balanceOf(address owner) external view returns (uint256 balance);

    /**
     * @dev Returns the owner of the `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function ownerOf(uint256 tokenId) external view returns (address owner);

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId,
        bytes calldata data
    ) external;

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`, checking first that contract recipients
     * are aware of the ERC721 protocol to prevent tokens from being forever locked.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must have been allowed to move this token by either {approve} or {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId
    ) external;

    /**
     * @dev Transfers `tokenId` token from `from` to `to`.
     *
     * WARNING: Usage of this method is discouraged, use {safeTransferFrom} whenever possible.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(
        address from,
        address to,
        uint256 tokenId
    ) external;

    /**
     * @dev Gives permission to `to` to transfer `tokenId` token to another account.
     * The approval is cleared when the token is transferred.
     *
     * Only a single account can be approved at a time, so approving the zero address clears previous approvals.
     *
     * Requirements:
     *
     * - The caller must own the token or be an approved operator.
     * - `tokenId` must exist.
     *
     * Emits an {Approval} event.
     */
    function approve(address to, uint256 tokenId) external;

    /**
     * @dev Approve or remove `operator` as an operator for the caller.
     * Operators can call {transferFrom} or {safeTransferFrom} for any token owned by the caller.
     *
     * Requirements:
     *
     * - The `operator` cannot be the caller.
     *
     * Emits an {ApprovalForAll} event.
     */
    function setApprovalForAll(address operator, bool _approved) external;

    /**
     * @dev Returns the account approved for `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function getApproved(uint256 tokenId) external view returns (address operator);

    /**
     * @dev Returns if the `operator` is allowed to manage all of the assets of `owner`.
     *
     * See {setApprovalForAll}
     */
    function isApprovedForAll(address owner, address operator) external view returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (token/ERC721/extensions/IERC721Metadata.sol)

pragma solidity ^0.8.0;

import "../IERC721.sol";

/**
 * @title ERC-721 Non-Fungible Token Standard, optional metadata extension
 * @dev See https://eips.ethereum.org/EIPS/eip-721
 */
interface IERC721Metadata is IERC721 {
    /**
     * @dev Returns the token collection name.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the token collection symbol.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the Uniform Resource Identifier (URI) for `tokenId` token.
     */
    function tokenURI(uint256 tokenId) external view returns (string memory);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.6.0) (token/ERC721/IERC721Receiver.sol)

pragma solidity ^0.8.0;

/**
 * @title ERC721 token receiver interface
 * @dev Interface for any contract that wants to support safeTransfers
 * from ERC721 asset contracts.
 */
interface IERC721Receiver {
    /**
     * @dev Whenever an {IERC721} `tokenId` token is transferred to this contract via {IERC721-safeTransferFrom}
     * by `operator` from `from`, this function is called.
     *
     * It must return its Solidity selector to confirm the token transfer.
     * If any other value is returned or the interface is not implemented by the recipient, the transfer will be reverted.
     *
     * The selector can be obtained in Solidity with `IERC721Receiver.onERC721Received.selector`.
     */
    function onERC721Received(
        address operator,
        address from,
        uint256 tokenId,
        bytes calldata data
    ) external returns (bytes4);
}

// SPDX-License-Identifier: MIT

/**
 *
 * @title NiftyMoves.sol. Convenient and gas efficient protocol for sending multiple
 * ERC721s from multiple contracts to multiple recipients, or the burn address.
 *
 * v4.0.0
 *
 * @author niftymoves https://niftymoves.io/
 * @author omnus      https://omn.us/
 *
 */

pragma solidity 0.8.21;

interface INiftyMoves {
  // Struct object that represents a single transfer request.
  // This has one 'to' address with 1 to n collections and 1 to n
  // tokens / quantities within each collection:
  struct Transfer {
    address toAddress;
    address[] contractAddresses;
    uint256[][] tokenIDs;
  }

  // Struct for discount parameters:
  struct DiscountParameters {
    address contractOrPayee;
    bytes12 referralID;
    uint256 tokenID1155;
    uint256 minimumBalance;
    uint256 discountBasisPoints;
    uint256 referrerBasisPoints;
  }

  // Struct for trusted provider bonuses
  struct TrustedProviderBonuses {
    address collection;
    uint256 transferCount;
  }

  event TransferFeeUpdated(uint256 newEthFee);
  event TreasuryUpdated(address newTreasury);
  event WETHAddressUpdated(address newWETH);
  event DiscountRootUpdated(bytes32 newDiscountRoot);
  event ENSReverseRegistrarUpdated(address newENSReverseRegistrar);
  event ENSNameSet(string name, bytes32 reverseRecordHash);

  /**
   *
   * @dev enableService: enable niftymoves (onlyOwner)
   *
   */
  function enableService() external;

  /**
   *
   * @dev disableService: disable niftymoves (onlyOwner)
   *
   */
  function disableService() external;

  /**
   *
   * @dev setENSReverseRegistrar: set the ENS register address (onlyOwner)
   *
   * @param ensRegistrar_: ENS Reverse Registrar address
   *
   */
  function setENSReverseRegistrar(address ensRegistrar_) external;

  /**
   *
   * @dev setENSName: used to set reverse record so interactions with this contract
   * are easy to identify (onlyOwner)
   *
   * @param ensName_: string ENS name
   *
   */
  function setENSName(string memory ensName_) external;

  /**
   *
   * @dev setTransferFee: set a fee per transfer (onlyOwner)
   *
   * @param transferFee_: the new fee
   *
   */
  function setTransferFee(uint88 transferFee_) external;

  /**
   *
   * @dev setWETH: set the WETH address for this chain (onlyOwner)
   *
   * @param wethAddress_: the new WETH address
   *
   */
  function setWETH(address wethAddress_) external;

  /**
   *
   * @dev setDiscountRoot: set the discount merkle root (onlyOwner)
   *
   * @param discountRoot_: the new root
   *
   */
  function setDiscountRoot(bytes32 discountRoot_) external;

  /**
   *
   * @dev setTreasury: set a new treasury address (onlyOwner)
   *
   * @param treasury_: the new treasury address
   *
   */
  function setTreasury(address treasury_) external;

  /**
   *
   * @dev withdrawETH: withdraw to the treasury address (onlyOwner)
   *
   * @param amount_: amount to withdraw
   *
   */
  function withdrawETH(uint256 amount_) external;

  /**
   *
   * @dev withdrawERC721: Retrieve ERC721s, likely only the ENS associated
   * with this contract (onlyOwner)
   *
   * @param erc721Address_: The token contract for the withdrawal
   * @param tokenIDs_: the list of tokenIDs for the withdrawal
   *
   */
  function withdrawERC721(
    address erc721Address_,
    uint256[] memory tokenIDs_
  ) external;

  /**
   *
   * @dev niftyMove: perform multiple ERC-721 transfers in a single transaction
   *
   * niftyMove is an overloaded function providing the following implementations:
   * 1) Move WITHOUT a discount or referral and WITHOUT trusted provider bonus(es)
   * 2) Move WITH a discount or referral and WITHOUT trusted provider bonus(es)
   * 3) Move WITH a discount or referral and WITH trusted provider bonus(es)
   *
   * Overloading in this way allows us to avoid IF statements in the code, keeping
   * gas costs to a minimum. It does so at the cost of reduced code reuse.
   *
   * This instance of the overloaded method is for the following:
   *
   *    Discount or Referral      **WITHOUT**
   *    Trusted provider bonus    **WITHOUT**
   *
   * @param transfers_: struct object containing an array of transfers
   * @param transferCount_: count of transfers
   * @param standardTransferGas_: gas cost of standard transfer
   *
   */
  function niftyMove(
    Transfer[] calldata transfers_,
    uint256 transferCount_,
    uint256 standardTransferGas_
  ) external payable;

  /**
   *
   * @dev niftyMove: perform multiple ERC-721 transfers in a single transaction
   *
   * niftyMove is an overloaded function providing the following implementations:
   * 1) Move WITHOUT a discount or referral and WITHOUT trusted provider bonus(es)
   * 2) Move WITH a discount or referral and WITHOUT trusted provider bonus(es)
   * 3) Move WITH a discount or referral and WITH trusted provider bonus(es)
   *
   * Overloading in this way allows us to avoid IF statements in the code, keeping
   * gas costs to a minimum. It does so at the cost of reduced code reuse.
   *
   * This instance of the overloaded method is for the following:
   *
   *    Discount or Referral      ** WITH  **
   *    Trusted provider bonus    **WITHOUT**
   *
   * @param transfers_: struct object containing an array of transfers
   * @param transferCount_: count of transfers
   * @param standardTransferGas_: gas cost of standard transfer
   * @param gasLimit_: gas limit for ETH transfers
   * @param discountDetails_: details of the discount being claimed
   * @param proof_: proof for validating discount / referral details
   *
   */
  function niftyMove(
    Transfer[] calldata transfers_,
    uint256 transferCount_,
    uint256 standardTransferGas_,
    uint256 gasLimit_,
    DiscountParameters calldata discountDetails_,
    bytes32[] calldata proof_
  ) external payable;

  /**
   *
   * @dev niftyMove: perform multiple ERC-721 transfers in a single transaction
   *
   * niftyMove is an overloaded function providing the following implementations:
   * 1) Move WITHOUT a discount or referral and WITHOUT trusted provider bonus(es)
   * 2) Move WITH a discount or referral and WITHOUT trusted provider bonus(es)
   * 3) Move WITH a discount or referral and WITH trusted provider bonus(es)
   *
   * Overloading in this way allows us to avoid IF statements in the code, keeping
   * gas costs to a minimum. It does so at the cost of reduced code reuse.
   *
   * This instance of the overloaded method is for the following:
   *
   *    Discount or Referral      ** WITH  **
   *    Trusted provider bonus    ** WITH  **
   *
   * @param transfers_: struct object containing an array of transfers
   * @param transferCount_: count of transfers
   * @param standardTransferGas_: gas cost of standard transfer
   * @param gasLimit_: gas limit for ETH transfers
   * @param discountDetails_: details of the discount being claimed
   * @param proof_: proof for validating discount / referral details
   * @param trustedProviderCollectionCount_: Number of trusted provider collections
   *
   */
  function niftyMove(
    Transfer[] calldata transfers_,
    uint256 transferCount_,
    uint256 standardTransferGas_,
    uint256 gasLimit_,
    DiscountParameters calldata discountDetails_,
    bytes32[] calldata proof_,
    uint256 trustedProviderCollectionCount_
  ) external payable;

  /**
   *
   * @dev niftyBurn: function to perform multiple burns
   *
   * niftyBurn is an overloaded function providing the following implementations:
   * 1) Move WITHOUT a discount or referral and WITHOUT trusted provider bonus(es)
   * 2) Move WITH a discount or referral and WITHOUT trusted provider bonus(es)
   * 3) Move WITH a discount or referral and WITH trusted provider bonus(es)
   *
   * Overloading in this way allows us to avoid IF statements in the code, keeping
   * gas costs to a minimum. It does so at the cost of reduced code reuse.
   *
   * This instance of the overloaded method is for the following:
   *
   *    Discount or Referral      ** WITHOUT**
   *    Trusted provider bonus    ** WITHOUT**
   *
   * @param transfers_: struct object containing an array of burns
   * @param transferCount_: count of burns
   * @param standardTransferGas_: gas cost of standard burns
   *
   */
  function niftyBurn(
    Transfer[] calldata transfers_,
    uint256 transferCount_,
    uint256 standardTransferGas_
  ) external payable;

  /**
   *
   * @dev niftyBurn: function to perform multiple burns
   *
   * niftyBurn is an overloaded function providing the following implementations:
   * 1) Move WITHOUT a discount or referral and WITHOUT trusted provider bonus(es)
   * 2) Move WITH a discount or referral and WITHOUT trusted provider bonus(es)
   * 3) Move WITH a discount or referral and WITH trusted provider bonus(es)
   *
   * Overloading in this way allows us to avoid IF statements in the code, keeping
   * gas costs to a minimum. It does so at the cost of reduced code reuse.
   *
   * This instance of the overloaded method is for the following:
   *
   *    Discount or Referral      ** WITH  **
   *    Trusted provider bonus    ** WITHOUT**
   *
   * @param transfers_: struct object containing an array of burns
   * @param transferCount_: count of burns
   * @param standardTransferGas_: gas cost of standard burns
   * @param gasLimit_: gas limit for ETH transfers
   * @param discountDetails_: details of the discount being claimed
   * @param proof_: proof for validating discount / referral details
   *
   */
  function niftyBurn(
    Transfer[] calldata transfers_,
    uint256 transferCount_,
    uint256 standardTransferGas_,
    uint256 gasLimit_,
    DiscountParameters calldata discountDetails_,
    bytes32[] calldata proof_
  ) external payable;

  /**
   *
   * @dev niftyBurn: function to perform multiple burns
   *
   * niftyBurn is an overloaded function providing the following implementations:
   * 1) Move WITHOUT a discount or referral and WITHOUT trusted provider bonus(es)
   * 2) Move WITH a discount or referral and WITHOUT trusted provider bonus(es)
   * 3) Move WITH a discount or referral and WITH trusted provider bonus(es)
   *
   * Overloading in this way allows us to avoid IF statements in the code, keeping
   * gas costs to a minimum. It does so at the cost of reduced code reuse.
   *
   * This instance of the overloaded method is for the following:
   *
   *    Discount or Referral      ** WITH  **
   *    Trusted provider bonus    ** WITH  **
   *
   * @param transfers_: struct object containing an array of burns
   * @param transferCount_: count of burns
   * @param standardTransferGas_: gas cost of standard burns
   * @param gasLimit_: gas limit for ETH transfers
   * @param discountDetails_: details of the discount being claimed
   * @param proof_: proof for validating discount / referral details
   * @param trustedProviderCollectionCount_: Number of trusted provider collections
   *
   */
  function niftyBurn(
    Transfer[] calldata transfers_,
    uint256 transferCount_,
    uint256 standardTransferGas_,
    uint256 gasLimit_,
    DiscountParameters calldata discountDetails_,
    bytes32[] calldata proof_,
    uint256 trustedProviderCollectionCount_
  ) external payable;

  /**
   *
   * @dev rootIsValid: check the passed details against the root
   *
   * @param proof_: the proof used to check passed details
   * @param discountDetails_: struct object for the claimed discount
   *
   * @return valid_ :  if this set of data is valid (or not)
   *
   */
  function rootIsValid(
    bytes32[] calldata proof_,
    DiscountParameters calldata discountDetails_
  ) external view returns (bool valid_);
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.21;

import {IERC20} from "@openzeppelin/contracts/token/ERC20/IERC20.sol";

interface IWETH is IERC20 {
  function deposit() external payable;

  function withdraw(uint256 wad) external;
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (utils/cryptography/MerkleProof.sol)

pragma solidity ^0.8.0;

/**
 * @dev These functions deal with verification of Merkle Tree proofs.
 *
 * The tree and the proofs can be generated using our
 * https://github.com/OpenZeppelin/merkle-tree[JavaScript library].
 * You will find a quickstart guide in the readme.
 *
 * WARNING: You should avoid using leaf values that are 64 bytes long prior to
 * hashing, or use a hash function other than keccak256 for hashing leaves.
 * This is because the concatenation of a sorted pair of internal nodes in
 * the merkle tree could be reinterpreted as a leaf value.
 * OpenZeppelin's JavaScript library generates merkle trees that are safe
 * against this attack out of the box.
 */
library MerkleProof {
    /**
     * @dev Returns true if a `leaf` can be proved to be a part of a Merkle tree
     * defined by `root`. For this, a `proof` must be provided, containing
     * sibling hashes on the branch from the leaf to the root of the tree. Each
     * pair of leaves and each pair of pre-images are assumed to be sorted.
     */
    function verify(
        bytes32[] memory proof,
        bytes32 root,
        bytes32 leaf
    ) internal pure returns (bool) {
        return processProof(proof, leaf) == root;
    }

    /**
     * @dev Calldata version of {verify}
     *
     * _Available since v4.7._
     */
    function verifyCalldata(
        bytes32[] calldata proof,
        bytes32 root,
        bytes32 leaf
    ) internal pure returns (bool) {
        return processProofCalldata(proof, leaf) == root;
    }

    /**
     * @dev Returns the rebuilt hash obtained by traversing a Merkle tree up
     * from `leaf` using `proof`. A `proof` is valid if and only if the rebuilt
     * hash matches the root of the tree. When processing the proof, the pairs
     * of leafs & pre-images are assumed to be sorted.
     *
     * _Available since v4.4._
     */
    function processProof(bytes32[] memory proof, bytes32 leaf) internal pure returns (bytes32) {
        bytes32 computedHash = leaf;
        for (uint256 i = 0; i < proof.length; i++) {
            computedHash = _hashPair(computedHash, proof[i]);
        }
        return computedHash;
    }

    /**
     * @dev Calldata version of {processProof}
     *
     * _Available since v4.7._
     */
    function processProofCalldata(bytes32[] calldata proof, bytes32 leaf) internal pure returns (bytes32) {
        bytes32 computedHash = leaf;
        for (uint256 i = 0; i < proof.length; i++) {
            computedHash = _hashPair(computedHash, proof[i]);
        }
        return computedHash;
    }

    /**
     * @dev Returns true if the `leaves` can be simultaneously proven to be a part of a merkle tree defined by
     * `root`, according to `proof` and `proofFlags` as described in {processMultiProof}.
     *
     * CAUTION: Not all merkle trees admit multiproofs. See {processMultiProof} for details.
     *
     * _Available since v4.7._
     */
    function multiProofVerify(
        bytes32[] memory proof,
        bool[] memory proofFlags,
        bytes32 root,
        bytes32[] memory leaves
    ) internal pure returns (bool) {
        return processMultiProof(proof, proofFlags, leaves) == root;
    }

    /**
     * @dev Calldata version of {multiProofVerify}
     *
     * CAUTION: Not all merkle trees admit multiproofs. See {processMultiProof} for details.
     *
     * _Available since v4.7._
     */
    function multiProofVerifyCalldata(
        bytes32[] calldata proof,
        bool[] calldata proofFlags,
        bytes32 root,
        bytes32[] memory leaves
    ) internal pure returns (bool) {
        return processMultiProofCalldata(proof, proofFlags, leaves) == root;
    }

    /**
     * @dev Returns the root of a tree reconstructed from `leaves` and sibling nodes in `proof`. The reconstruction
     * proceeds by incrementally reconstructing all inner nodes by combining a leaf/inner node with either another
     * leaf/inner node or a proof sibling node, depending on whether each `proofFlags` item is true or false
     * respectively.
     *
     * CAUTION: Not all merkle trees admit multiproofs. To use multiproofs, it is sufficient to ensure that: 1) the tree
     * is complete (but not necessarily perfect), 2) the leaves to be proven are in the opposite order they are in the
     * tree (i.e., as seen from right to left starting at the deepest layer and continuing at the next layer).
     *
     * _Available since v4.7._
     */
    function processMultiProof(
        bytes32[] memory proof,
        bool[] memory proofFlags,
        bytes32[] memory leaves
    ) internal pure returns (bytes32 merkleRoot) {
        // This function rebuild the root hash by traversing the tree up from the leaves. The root is rebuilt by
        // consuming and producing values on a queue. The queue starts with the `leaves` array, then goes onto the
        // `hashes` array. At the end of the process, the last hash in the `hashes` array should contain the root of
        // the merkle tree.
        uint256 leavesLen = leaves.length;
        uint256 totalHashes = proofFlags.length;

        // Check proof validity.
        require(leavesLen + proof.length - 1 == totalHashes, "MerkleProof: invalid multiproof");

        // The xxxPos values are "pointers" to the next value to consume in each array. All accesses are done using
        // `xxx[xxxPos++]`, which return the current value and increment the pointer, thus mimicking a queue's "pop".
        bytes32[] memory hashes = new bytes32[](totalHashes);
        uint256 leafPos = 0;
        uint256 hashPos = 0;
        uint256 proofPos = 0;
        // At each step, we compute the next hash using two values:
        // - a value from the "main queue". If not all leaves have been consumed, we get the next leaf, otherwise we
        //   get the next hash.
        // - depending on the flag, either another value for the "main queue" (merging branches) or an element from the
        //   `proof` array.
        for (uint256 i = 0; i < totalHashes; i++) {
            bytes32 a = leafPos < leavesLen ? leaves[leafPos++] : hashes[hashPos++];
            bytes32 b = proofFlags[i] ? leafPos < leavesLen ? leaves[leafPos++] : hashes[hashPos++] : proof[proofPos++];
            hashes[i] = _hashPair(a, b);
        }

        if (totalHashes > 0) {
            return hashes[totalHashes - 1];
        } else if (leavesLen > 0) {
            return leaves[0];
        } else {
            return proof[0];
        }
    }

    /**
     * @dev Calldata version of {processMultiProof}.
     *
     * CAUTION: Not all merkle trees admit multiproofs. See {processMultiProof} for details.
     *
     * _Available since v4.7._
     */
    function processMultiProofCalldata(
        bytes32[] calldata proof,
        bool[] calldata proofFlags,
        bytes32[] memory leaves
    ) internal pure returns (bytes32 merkleRoot) {
        // This function rebuild the root hash by traversing the tree up from the leaves. The root is rebuilt by
        // consuming and producing values on a queue. The queue starts with the `leaves` array, then goes onto the
        // `hashes` array. At the end of the process, the last hash in the `hashes` array should contain the root of
        // the merkle tree.
        uint256 leavesLen = leaves.length;
        uint256 totalHashes = proofFlags.length;

        // Check proof validity.
        require(leavesLen + proof.length - 1 == totalHashes, "MerkleProof: invalid multiproof");

        // The xxxPos values are "pointers" to the next value to consume in each array. All accesses are done using
        // `xxx[xxxPos++]`, which return the current value and increment the pointer, thus mimicking a queue's "pop".
        bytes32[] memory hashes = new bytes32[](totalHashes);
        uint256 leafPos = 0;
        uint256 hashPos = 0;
        uint256 proofPos = 0;
        // At each step, we compute the next hash using two values:
        // - a value from the "main queue". If not all leaves have been consumed, we get the next leaf, otherwise we
        //   get the next hash.
        // - depending on the flag, either another value for the "main queue" (merging branches) or an element from the
        //   `proof` array.
        for (uint256 i = 0; i < totalHashes; i++) {
            bytes32 a = leafPos < leavesLen ? leaves[leafPos++] : hashes[hashPos++];
            bytes32 b = proofFlags[i] ? leafPos < leavesLen ? leaves[leafPos++] : hashes[hashPos++] : proof[proofPos++];
            hashes[i] = _hashPair(a, b);
        }

        if (totalHashes > 0) {
            return hashes[totalHashes - 1];
        } else if (leavesLen > 0) {
            return leaves[0];
        } else {
            return proof[0];
        }
    }

    function _hashPair(bytes32 a, bytes32 b) private pure returns (bytes32) {
        return a < b ? _efficientHash(a, b) : _efficientHash(b, a);
    }

    function _efficientHash(bytes32 a, bytes32 b) private pure returns (bytes32 value) {
        /// @solidity memory-safe-assembly
        assembly {
            mstore(0x00, a)
            mstore(0x20, b)
            value := keccak256(0x00, 0x40)
        }
    }
}

// SPDX-License-Identifier: BUSL-1.1

/**
 *
 * @title NiftyMoves.sol. Convenient and gas efficient protocol for sending multiple
 * ERC721s from multiple contracts to multiple recipients, or the burn address.
 *
 * v4.0.0
 *
 * @author niftymoves https://niftymoves.io/
 * @author omnus      https://omn.us/
 *
 */

pragma solidity 0.8.21;

import {IENSReverseRegistrar} from "./ENS/IENSReverseRegistrar.sol";
import {IERC1155} from "@openzeppelin/contracts/token/ERC1155/IERC1155.sol";
import {IERC20} from "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import {IERC721, ERC721Burnable} from "@openzeppelin/contracts/token/ERC721/extensions/ERC721Burnable.sol";
import {IERC721Receiver} from "@openzeppelin/contracts/token/ERC721/IERC721Receiver.sol";
import {INiftyMoves} from "./INiftyMoves.sol";
import {IWETH} from "./WETH/IWETH.sol";
import {MerkleProof} from "@openzeppelin/contracts/utils/cryptography/MerkleProof.sol";
import {Ownable} from "@openzeppelin/contracts/access/Ownable.sol";
import {SafeERC20} from "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";

contract NiftyMoves is INiftyMoves, IERC721Receiver, Ownable {
  using SafeERC20 for IERC20;

  uint256 private constant DENOMINATOR_BASIS_POINTS = 10000;
  uint256 private constant BONUS_RATE_IN_BASIS_POINTS = 5000;

  // ETH fee for transfers, if any:
  uint88 public transferFee;

  // Boolean to control service availability:
  bool public enabled = true;

  // WETH:
  IWETH public wethContract;

  // Treasury to receive any ETH fees, if any:
  address public treasury;

  // Address of the ENS reverse registrar to allow assignment of an ENS
  // name to this contract:
  IENSReverseRegistrar public ensReverseRegistrar;

  // The merkleroot for referralls / discounts
  bytes32 public discountRoot;

  // Version codename:
  string public version = "Dugong";

  /**
   *
   * @dev constructor
   *
   */
  constructor() {
    // Initialise the treasury and owner to the deployer:
    treasury = tx.origin;
    _transferOwnership(tx.origin);
  }

  /**
   * @dev whenEnabled: Modifier to make a function callable only when the contract is enabled.
   *
   * Requirements:
   *
   * - The contract must be enabled.
   */
  modifier whenEnabled() {
    require(enabled, "niftymoves: not currently enabled");
    _;
  }

  /**
   *
   * @dev enableService: enable niftymoves (onlyOwner)
   *
   */
  function enableService() external onlyOwner {
    enabled = true;
  }

  /**
   *
   * @dev disableService: disable niftymoves (onlyOwner)
   *
   */
  function disableService() external onlyOwner {
    enabled = false;
  }

  /**
   *
   * @dev setENSReverseRegistrar: set the ENS register address (onlyOwner)
   *
   * @param ensRegistrar_: ENS Reverse Registrar address
   *
   */
  function setENSReverseRegistrar(address ensRegistrar_) external onlyOwner {
    ensReverseRegistrar = IENSReverseRegistrar(ensRegistrar_);
    emit ENSReverseRegistrarUpdated(ensRegistrar_);
  }

  /**
   *
   * @dev setENSName: used to set reverse record so interactions with this contract
   * are easy to identify (onlyOwner)
   *
   * @param ensName_: string ENS name
   *
   */
  function setENSName(string memory ensName_) external onlyOwner {
    bytes32 reverseRecordHash = ensReverseRegistrar.setName(ensName_);
    emit ENSNameSet(ensName_, reverseRecordHash);
  }

  /**
   *
   * @dev setTransferFee: set a fee per transfer (onlyOwner)
   *
   * @param transferFee_: the new fee
   *
   */
  function setTransferFee(uint88 transferFee_) external onlyOwner {
    transferFee = transferFee_;
    emit TransferFeeUpdated(transferFee_);
  }

  /**
   *
   * @dev setWETH: set the WETH address for this chain (onlyOwner)
   *
   * @param wethAddress_: the new WETH address
   *
   */
  function setWETH(address wethAddress_) external onlyOwner {
    wethContract = IWETH(wethAddress_);
    emit WETHAddressUpdated(wethAddress_);
  }

  /**
   *
   * @dev setDiscountRoot: set the discount merkle root (onlyOwner)
   *
   * @param discountRoot_: the new root
   *
   */
  function setDiscountRoot(bytes32 discountRoot_) external onlyOwner {
    discountRoot = discountRoot_;
    emit DiscountRootUpdated(discountRoot_);
  }

  /**
   *
   * @dev setTreasury: set a new treasury address (onlyOwner)
   *
   * @param treasury_: the new treasury address
   *
   */
  function setTreasury(address treasury_) external onlyOwner {
    require(treasury_ != address(0), "niftymoves: cannot set to zero address");
    treasury = treasury_;
    emit TreasuryUpdated(treasury_);
  }

  /**
   *
   * @dev withdrawETH: withdraw to the treasury address (onlyOwner)
   *
   * @param amount_: amount to withdraw
   *
   */
  function withdrawETH(uint256 amount_) external onlyOwner {
    (bool success, ) = treasury.call{value: amount_}("");
    require(success, "niftymoves: fransfer failed");
  }

  /**
   *
   * @dev withdrawERC721: Retrieve ERC721s, likely only the ENS associated
   * with this contract (onlyOwner)
   *
   * @param erc721Address_: The token contract for the withdrawal
   * @param tokenIDs_: the list of tokenIDs for the withdrawal
   *
   */
  function withdrawERC721(
    address erc721Address_,
    uint256[] memory tokenIDs_
  ) external onlyOwner {
    for (uint256 i = 0; i < tokenIDs_.length; ) {
      IERC721(erc721Address_).transferFrom(
        address(this),
        owner(),
        tokenIDs_[i]
      );
      unchecked {
        ++i;
      }
    }
  }

  /**
   *
   * @dev niftyMove: perform multiple ERC-721 transfers in a single transaction
   *
   * niftyMove is an overloaded function providing the following implementations:
   * 1) Move WITHOUT a discount or referral and WITHOUT trusted provider bonus(es)
   * 2) Move WITH a discount or referral and WITHOUT trusted provider bonus(es)
   * 3) Move WITH a discount or referral and WITH trusted provider bonus(es)
   *
   * Overloading in this way allows us to avoid IF statements in the code, keeping
   * gas costs to a minimum. It does so at the cost of reduced code reuse.
   *
   * This instance of the overloaded method is for the following:
   *
   *    Discount or Referral      **WITHOUT**
   *    Trusted provider bonus    **WITHOUT**
   *
   * @param transfers_: struct object containing an array of transfers
   * @param transferCount_: count of transfers
   * @param standardTransferGas_: gas cost of standard transfer
   *
   */
  function niftyMove(
    Transfer[] calldata transfers_,
    uint256 transferCount_,
    uint256 standardTransferGas_
  ) external payable whenEnabled {
    require(
      msg.value == transferFee * transferCount_,
      "niftymoves: incorrect payment"
    );

    // Perform transfers:
    uint256 transferCount = _performMoves(
      _msgSender(),
      transfers_,
      standardTransferGas_
    );

    // Validate transfer count received:
    require(
      (transferCount_ == transferCount),
      "niftymoves: transfer count mismatch"
    );
  }

  /**
   *
   * @dev niftyMove: perform multiple ERC-721 transfers in a single transaction
   *
   * niftyMove is an overloaded function providing the following implementations:
   * 1) Move WITHOUT a discount or referral and WITHOUT trusted provider bonus(es)
   * 2) Move WITH a discount or referral and WITHOUT trusted provider bonus(es)
   * 3) Move WITH a discount or referral and WITH trusted provider bonus(es)
   *
   * Overloading in this way allows us to avoid IF statements in the code, keeping
   * gas costs to a minimum. It does so at the cost of reduced code reuse.
   *
   * This instance of the overloaded method is for the following:
   *
   *    Discount or Referral      ** WITH  **
   *    Trusted provider bonus    **WITHOUT**
   *
   * @param transfers_: struct object containing an array of transfers
   * @param transferCount_: count of transfers
   * @param standardTransferGas_: gas cost of standard transfer
   * @param gasLimit_: gas limit for ETH transfers
   * @param discountDetails_: details of the discount being claimed
   * @param proof_: proof for validating discount / referral details
   *
   */
  function niftyMove(
    Transfer[] calldata transfers_,
    uint256 transferCount_,
    uint256 standardTransferGas_,
    uint256 gasLimit_,
    DiscountParameters calldata discountDetails_,
    bytes32[] calldata proof_
  ) external payable whenEnabled {
    // Perform fee processing:
    _processFees(
      msg.value,
      transferCount_,
      discountDetails_,
      gasLimit_,
      proof_
    );

    // Perform transfers:
    uint256 transferCount = _performMoves(
      _msgSender(),
      transfers_,
      standardTransferGas_
    );

    // Validate transfer count received:
    require(
      (transferCount_ == transferCount),
      "niftymoves: transfer count mismatch"
    );
  }

  /**
   *
   * @dev niftyMove: perform multiple ERC-721 transfers in a single transaction
   *
   * niftyMove is an overloaded function providing the following implementations:
   * 1) Move WITHOUT a discount or referral and WITHOUT trusted provider bonus(es)
   * 2) Move WITH a discount or referral and WITHOUT trusted provider bonus(es)
   * 3) Move WITH a discount or referral and WITH trusted provider bonus(es)
   *
   * Overloading in this way allows us to avoid IF statements in the code, keeping
   * gas costs to a minimum. It does so at the cost of reduced code reuse.
   *
   * This instance of the overloaded method is for the following:
   *
   *    Discount or Referral      ** WITH  **
   *    Trusted provider bonus    ** WITH  **
   *
   * @param transfers_: struct object containing an array of transfers
   * @param transferCount_: count of transfers
   * @param standardTransferGas_: gas cost of standard transfer
   * @param gasLimit_: gas limit for ETH transfers
   * @param discountDetails_: details of the discount being claimed
   * @param proof_: proof for validating discount / referral details
   * @param trustedProviderCollectionCount_: Number of trusted provider collections
   *
   */
  function niftyMove(
    Transfer[] calldata transfers_,
    uint256 transferCount_,
    uint256 standardTransferGas_,
    uint256 gasLimit_,
    DiscountParameters calldata discountDetails_,
    bytes32[] calldata proof_,
    uint256 trustedProviderCollectionCount_
  ) external payable whenEnabled {
    // Perform fee processing:
    uint256 referrerPayment = _processFees(
      msg.value,
      transferCount_,
      discountDetails_,
      gasLimit_,
      proof_
    );

    // Perform transfers:
    (
      uint256 transferCount,
      TrustedProviderBonuses[] memory bonuses
    ) = _performMovesAsTrustedProvider(
        _msgSender(),
        transfers_,
        standardTransferGas_,
        trustedProviderCollectionCount_
      );

    // Validate transfer count received:
    require(
      (transferCount_ == transferCount),
      "niftymoves: transfer count mismatch"
    );

    // Handle trusted provider bonuses, if any:
    if (bonuses.length > 0) {
      _remitBonuses(
        bonuses,
        (((msg.value - referrerPayment) / transferCount_) *
          BONUS_RATE_IN_BASIS_POINTS) / DENOMINATOR_BASIS_POINTS,
        gasLimit_
      );
    }
  }

  /**
   *
   * @dev niftyBurn: function to perform multiple burns
   *
   * niftyBurn is an overloaded function providing the following implementations:
   * 1) Move WITHOUT a discount or referral and WITHOUT trusted provider bonus(es)
   * 2) Move WITH a discount or referral and WITHOUT trusted provider bonus(es)
   * 3) Move WITH a discount or referral and WITH trusted provider bonus(es)
   *
   * Overloading in this way allows us to avoid IF statements in the code, keeping
   * gas costs to a minimum. It does so at the cost of reduced code reuse.
   *
   * This instance of the overloaded method is for the following:
   *
   *    Discount or Referral      ** WITHOUT**
   *    Trusted provider bonus    ** WITHOUT**
   *
   * @param transfers_: struct object containing an array of burns
   * @param transferCount_: count of burns
   * @param standardTransferGas_: gas cost of standard burns
   *
   */
  function niftyBurn(
    Transfer[] calldata transfers_,
    uint256 transferCount_,
    uint256 standardTransferGas_
  ) external payable whenEnabled {
    require(
      msg.value == transferFee * transferCount_,
      "niftymoves: incorrect payment"
    );

    // Perform burns:
    uint256 transferCount = _performBurns(
      _msgSender(),
      transfers_,
      standardTransferGas_
    );

    // Validate transfer count received:
    require(
      (transferCount_ == transferCount),
      "niftymoves: transfer count mismatch"
    );
  }

  /**
   *
   * @dev niftyBurn: function to perform multiple burns
   *
   * niftyBurn is an overloaded function providing the following implementations:
   * 1) Move WITHOUT a discount or referral and WITHOUT trusted provider bonus(es)
   * 2) Move WITH a discount or referral and WITHOUT trusted provider bonus(es)
   * 3) Move WITH a discount or referral and WITH trusted provider bonus(es)
   *
   * Overloading in this way allows us to avoid IF statements in the code, keeping
   * gas costs to a minimum. It does so at the cost of reduced code reuse.
   *
   * This instance of the overloaded method is for the following:
   *
   *    Discount or Referral      ** WITH  **
   *    Trusted provider bonus    ** WITHOUT**
   *
   * @param transfers_: struct object containing an array of burns
   * @param transferCount_: count of burns
   * @param standardTransferGas_: gas cost of standard burns
   * @param gasLimit_: gas limit for ETH transfers
   * @param discountDetails_: details of the discount being claimed
   * @param proof_: proof for validating discount / referral details
   *
   */
  function niftyBurn(
    Transfer[] calldata transfers_,
    uint256 transferCount_,
    uint256 standardTransferGas_,
    uint256 gasLimit_,
    DiscountParameters calldata discountDetails_,
    bytes32[] calldata proof_
  ) external payable whenEnabled {
    // Perform fee processing:
    _processFees(
      msg.value,
      transferCount_,
      discountDetails_,
      gasLimit_,
      proof_
    );

    // Perform burns:
    uint256 transferCount = _performBurns(
      _msgSender(),
      transfers_,
      standardTransferGas_
    );

    // Validate transfer count received:
    require(
      (transferCount_ == transferCount),
      "niftymoves: transfer count mismatch"
    );
  }

  /**
   *
   * @dev niftyBurn: function to perform multiple burns
   *
   * niftyBurn is an overloaded function providing the following implementations:
   * 1) Move WITHOUT a discount or referral and WITHOUT trusted provider bonus(es)
   * 2) Move WITH a discount or referral and WITHOUT trusted provider bonus(es)
   * 3) Move WITH a discount or referral and WITH trusted provider bonus(es)
   *
   * Overloading in this way allows us to avoid IF statements in the code, keeping
   * gas costs to a minimum. It does so at the cost of reduced code reuse.
   *
   * This instance of the overloaded method is for the following:
   *
   *    Discount or Referral      ** WITH  **
   *    Trusted provider bonus    ** WITH  **
   *
   * @param transfers_: struct object containing an array of burns
   * @param transferCount_: count of burns
   * @param standardTransferGas_: gas cost of standard burns
   * @param gasLimit_: gas limit for ETH transfers
   * @param discountDetails_: details of the discount being claimed
   * @param proof_: proof for validating discount / referral details
   * @param trustedProviderCollectionCount_: Number of trusted provider collections
   *
   */
  function niftyBurn(
    Transfer[] calldata transfers_,
    uint256 transferCount_,
    uint256 standardTransferGas_,
    uint256 gasLimit_,
    DiscountParameters calldata discountDetails_,
    bytes32[] calldata proof_,
    uint256 trustedProviderCollectionCount_
  ) external payable whenEnabled {
    // Perform fee processing:
    uint256 referrerPayment = _processFees(
      msg.value,
      transferCount_,
      discountDetails_,
      gasLimit_,
      proof_
    );

    // Perform burns:
    (
      uint256 transferCount,
      TrustedProviderBonuses[] memory bonuses
    ) = _performBurnsAsTrustedProvider(
        _msgSender(),
        transfers_,
        standardTransferGas_,
        trustedProviderCollectionCount_
      );

    // Validate transfer count received:
    require(
      (transferCount_ == transferCount),
      "niftymoves: transfer count mismatch"
    );

    // Handle trusted provider bonuses, if any:
    if (bonuses.length > 0) {
      _remitBonuses(
        bonuses,
        (((msg.value - referrerPayment) / transferCount_) *
          BONUS_RATE_IN_BASIS_POINTS) / DENOMINATOR_BASIS_POINTS,
        gasLimit_
      );
    }
  }

  /**
   *
   * @dev _remitBonuses: send bonus payments to collections that have added
   * niftymoves as a trusted provider.
   *
   */
  function _remitBonuses(
    TrustedProviderBonuses[] memory bonuses_,
    uint256 bonusFeePerTokenTransfered_,
    uint256 gasLimit_
  ) internal returns (bool) {
    uint256 payment;
    bool success;
    for (uint256 i = 0; i < bonuses_.length; ) {
      payment = bonusFeePerTokenTransfered_ * bonuses_[i].transferCount;

      if (payment > 0) {
        // If gas limit is zero or greater than gas left, use the remaining gas.
        uint256 gas = (gasLimit_ == 0 || gasLimit_ > gasleft())
          ? gasleft()
          : gasLimit_;

        (success, ) = bonuses_[i].collection.call{value: payment, gas: gas}("");
      }

      unchecked {
        i++;
      }
    }
    return (success);
  }

  /**
   *
   * @dev _isTrustedProvider: form a random address for checking trusted provider implementation
   *
   * @return isTrustedProvider_ : this is / isn't a trusted provider
   *
   */
  function _isTrustedProvider(
    address contract_
  ) internal view returns (bool isTrustedProvider_) {
    return (
      IERC721(contract_).isApprovedForAll(
        address(uint160(uint256(keccak256(abi.encodePacked(block.timestamp))))),
        address(this)
      )
    );
  }

  /**
   *
   * @dev _performMoves: move items on-chain.
   *
   * @param sender_: the calling address for this transaction
   * @param transfers_: the struct object containing the transfers
   *
   * @return transferCount_ : a count of the number of transfer transactions
   *
   */
  function _performMoves(
    address sender_,
    Transfer[] calldata transfers_,
    uint256
  ) internal returns (uint256 transferCount_) {
    // Iterate through the list of transfer objects. There is one transfer
    // object per 'to' address:
    for (uint256 transfer = 0; transfer < transfers_.length; ) {
      // Check that the addresses and tokenId lists for this transfer match length:
      require(
        transfers_[transfer].contractAddresses.length ==
          transfers_[transfer].tokenIDs.length,
        "niftymoves: length mismatch, contracts and tokens lists"
      );

      // Iterate through the list of collections for this "to" address:
      for (
        uint256 collection = 0;
        collection < transfers_[transfer].contractAddresses.length;

      ) {
        uint256 item;
        for (
          item = 0;
          item < transfers_[transfer].tokenIDs[collection].length;

        ) {
          _efficient721Transfer(
            sender_,
            transfers_[transfer].toAddress,
            transfers_[transfer].contractAddresses[collection],
            transfers_[transfer].tokenIDs[collection][item]
          );
          unchecked {
            item++;
          }
        }
        unchecked {
          transferCount_ += item;
          collection++;
        }
      }
      unchecked {
        transfer++;
      }
    }

    return (transferCount_);
  }

  /**
   *
   * @dev _performMovesAsTrustedProvider: move items on-chain.
   *
   * @param sender_: the calling address for this transaction
   * @param transfers_: the struct object containing the transfers
   * @param trustedProviderCollectionCount_: A count of collections in this
   * niftymove IF the UI has identified that one or more collections has
   * niftymoves as a trusted provider, and therefore qualifies for the bonus.
   *
   * @return transferCount_ : a count of the number of transfer transactions
   * @return bonuses_ : an array of bonus data structs
   *
   */
  function _performMovesAsTrustedProvider(
    address sender_,
    Transfer[] calldata transfers_,
    uint256,
    uint256 trustedProviderCollectionCount_
  )
    internal
    returns (uint256 transferCount_, TrustedProviderBonuses[] memory bonuses_)
  {
    bonuses_ = new TrustedProviderBonuses[](trustedProviderCollectionCount_);
    uint256 bonusCount;

    // Iterate through the list of transfer objects. There is one transfer
    // object per 'to' address:
    for (uint256 transfer = 0; transfer < transfers_.length; ) {
      // Check that the addresses and tokenId lists for this transfer match length:
      require(
        transfers_[transfer].contractAddresses.length ==
          transfers_[transfer].tokenIDs.length,
        "niftymoves: length mismatch, contracts and tokens lists"
      );

      // Iterate through the list of collections for this "to" address:
      for (
        uint256 collection = 0;
        collection < transfers_[transfer].contractAddresses.length;

      ) {
        uint256 item;
        for (
          item = 0;
          item < transfers_[transfer].tokenIDs[collection].length;

        ) {
          _efficient721Transfer(
            sender_,
            transfers_[transfer].toAddress,
            transfers_[transfer].contractAddresses[collection],
            transfers_[transfer].tokenIDs[collection][item]
          );
          unchecked {
            item++;
          }
        }
        unchecked {
          // See if we have a collection wide discount through niftymoves
          // being included as a trusted service provider:
          if (
            trustedProviderCollectionCount_ != 0 &&
            _isTrustedProvider(
              transfers_[transfer].contractAddresses[collection]
            )
          ) {
            // Collection has loaded niftymoves as a trusted provider. Record bonuses for distribution:
            bonuses_[bonusCount] = TrustedProviderBonuses(
              transfers_[transfer].contractAddresses[collection],
              item
            );
            bonusCount++;
          }
          transferCount_ += item;
          collection++;
        }
      }
      unchecked {
        transfer++;
      }
    }

    if (bonusCount != 0) {
      // Trim the list if is has more entries than we needed:
      if (trustedProviderCollectionCount_ > bonusCount) {
        assembly {
          let decrease := sub(trustedProviderCollectionCount_, bonusCount)
          mstore(bonuses_, sub(mload(bonuses_), decrease))
        }
      }
    }

    return (transferCount_, bonuses_);
  }

  /**
   *
   * @dev _efficient721Transfer: transfer items
   *
   * @param from_: the calling address for this transaction
   * @param to_: the address to which items are being transferred
   * @param contract_: the contract for the items being transferred
   * @param tokenId_: the tokenId being transferred
   *
   */
  function _efficient721Transfer(
    address from_,
    address to_,
    address contract_,
    uint256 tokenId_
  ) internal {
    bool success;

    assembly {
      let transferFromData := add(0x20, mload(0x40))
      // 0x23b872dd is the selector of {transferFrom}.
      mstore(
        transferFromData,
        0x23b872dd00000000000000000000000000000000000000000000000000000000
      )

      mstore(add(transferFromData, 0x04), from_)
      mstore(add(transferFromData, 0x24), to_)
      mstore(add(transferFromData, 0x44), tokenId_)

      success := call(gas(), contract_, 0, transferFromData, 0x64, 0, 0)

      // This has failed. Failures are not bubbled up the call stack (for example in the case of
      // the caller not being the owner of the token). We could pass back a custom error saying
      // the transfer has failed as follows. We won't (see below), but code provided here in
      // comments for anyone wishing to see the approach.
      // 0x90b8ec18 is the selector of {TransferFailed}.
      // if iszero(success) {
      //   mstore(
      //     0x00,
      //     0x1c43b97600000000000000000000000000000000000000000000000000000000
      //   )
      //   // Store the tokenContract address at the beginning of the error data
      //   mstore(0x04, contract_)
      //   // Store the tokenId immediately after the tokenContract address
      //   mstore(0x24, tokenId_)
      //   revert(0x00, 0x44)
      // }
    }
    if (!success) {
      // Contract call to return reason up call stack. This will cost a bit more gas
      // than handling the error in assembly and returning an error (e.g. TransferFailed)
      // directly from this contract. But that would remove all detail from the returned error
      // message, making it far harder for the end user to understand the reason for the
      // failure. Note in all cases the app should apply pre-call validation to avoid such
      // errors costing *any* gas.
      IERC721(contract_).transferFrom(from_, to_, tokenId_);
    }
  }

  /**
   *
   * @dev _performBurns: burn items on-chain.
   *
   * @param sender_: the calling address for this transaction
   * @param transfers_: the struct object containing the transfers
   *
   * @return transferCount_ : a count of the number of transfer transactions
   *
   */
  function _performBurns(
    address sender_,
    Transfer[] calldata transfers_,
    uint256
  ) internal returns (uint256 transferCount_) {
    require(
      transfers_.length == 1,
      "niftymoves: can only burn in a single transfer"
    );

    require(
      (transfers_[0].contractAddresses.length == transfers_[0].tokenIDs.length),
      "niftymoves: length mismatch, contracts and tokens lists"
    );

    for (
      uint256 collection = 0;
      collection < transfers_[0].contractAddresses.length;

    ) {
      uint256 item;

      // Collection is burnable. We burn by calling burn:
      for (item = 0; item < transfers_[0].tokenIDs[collection].length; ) {
        _efficient721Burn(
          sender_,
          transfers_[0].toAddress,
          transfers_[0].contractAddresses[collection],
          transfers_[0].tokenIDs[collection][item]
        );
        unchecked {
          item++;
        }
      }

      unchecked {
        transferCount_ += item;
        collection++;
      }
    }

    return (transferCount_);
  }

  /**
   *
   * @dev _performBurnsAsTrustedProvider: burn items on-chain.
   *
   * @param sender_: the calling address for this transaction
   * @param transfers_: the struct object containing the transfers
   * @param trustedProviderCollectionCount_: A count of collections in this
   * niftymove IF the UI has identified that one or more collections has
   * niftymoves as a trusted provider, and therefore qualifies for the bonus.
   *
   * @return transferCount_ : a count of the number of transfer transactions
   * @return bonuses_ : an array of bonus data structs
   *
   */
  function _performBurnsAsTrustedProvider(
    address sender_,
    Transfer[] calldata transfers_,
    uint256,
    uint256 trustedProviderCollectionCount_
  )
    internal
    returns (uint256 transferCount_, TrustedProviderBonuses[] memory bonuses_)
  {
    require(
      transfers_.length == 1,
      "niftymoves: can only burn in a single transfer"
    );

    require(
      (transfers_[0].contractAddresses.length == transfers_[0].tokenIDs.length),
      "niftymoves: length mismatch, contracts and tokens lists"
    );

    bonuses_ = new TrustedProviderBonuses[](trustedProviderCollectionCount_);
    uint256 bonusCount;

    for (
      uint256 collection = 0;
      collection < transfers_[0].contractAddresses.length;

    ) {
      uint256 item;

      // Collection is burnable. We burn by calling burn:
      for (item = 0; item < transfers_[0].tokenIDs[collection].length; ) {
        _efficient721Burn(
          sender_,
          transfers_[0].toAddress,
          transfers_[0].contractAddresses[collection],
          transfers_[0].tokenIDs[collection][item]
        );
        unchecked {
          item++;
        }
      }

      unchecked {
        // See if we have a collection wide discount through niftymoves
        // being included as a trusted service provider:
        if (
          trustedProviderCollectionCount_ != 0 &&
          _isTrustedProvider(transfers_[0].contractAddresses[collection])
        ) {
          // Collection has loaded niftymoves as a trusted provider. Record bonuses for distribution:
          bonuses_[bonusCount] = TrustedProviderBonuses(
            transfers_[0].contractAddresses[collection],
            item
          );
          bonusCount++;
        }
        transferCount_ += item;
        collection++;
      }
    }

    if (bonusCount != 0) {
      // Trim the list if is has more entries than we needed:
      if (trustedProviderCollectionCount_ > bonusCount) {
        assembly {
          let decrease := sub(trustedProviderCollectionCount_, bonusCount)
          mstore(bonuses_, sub(mload(bonuses_), decrease))
        }
      }
    }

    return (transferCount_, bonuses_);
  }

  /**
   *
   * @dev _efficient721Burn: burn items to the zero address
   *
   * @param from_: the calling address for this transaction
   * @param to_: the address to which items are being transferred
   * @param contract_: the contract for the items being transferred
   * @param tokenId_: the tokenId being transferred
   *
   */
  function _efficient721Burn(
    address from_,
    address to_,
    address contract_,
    uint256 tokenId_
  ) internal {
    // Check burning to address(0):
    require(to_ == address(0), "niftymoves: can only burn to zero address");

    // Check ownership:
    require(
      IERC721(contract_).ownerOf(tokenId_) == from_,
      "niftymoves: burn call from non owner"
    );

    // Perform burn:
    bool success;
    assembly {
      let burnData := add(0x20, mload(0x40))
      mstore(
        burnData,
        0x42966c6800000000000000000000000000000000000000000000000000000000
      )
      mstore(add(burnData, 0x04), tokenId_)
      success := call(gas(), contract_, 0, burnData, 0x24, 0, 0)
      // This has failed. Failures are not bubbled up the call stack (for example in the case of
      // the caller not being the owner of the token). We could pass back a custom error saying
      // the burn has failed as follows. We won't (see below), but code provided here in
      // comments for anyone wishing to see the approach.
      // 0x016f84a1 is the selector of {BurnFailed}.
      // if iszero(success) {
      //   mstore(
      //     0x00,
      //     0x016f84a100000000000000000000000000000000000000000000000000000000
      //   )
      //   // Store the tokenContract address at the beginning of the error data
      //   mstore(0x04, contract_)
      //   // Store the tokenId immediately after the tokenContract address
      //   mstore(0x24, tokenId_)
      //   revert(0x00, 0x44)
      // }
    }

    if (!success) {
      // Contract call to return reason up call stack. This will cost a bit more gas
      // than handling the error in assembly and returning an error (e.g. BurnFailed)
      // directly from this contract. But that would remove all detail from the returned error
      // message, making it far harder for the end user to understand the reason for the
      // failure. Note in all cases the app should apply pre-call validation to avoid such
      // errors costing *any* gas.
      ERC721Burnable(contract_).burn(tokenId_);
    }
  }

  /**
   *
   * @dev _processFees: process fees (if any)
   *
   * @param value_: the ETH sent with this call
   * @param transferCount_: the number of transfers made
   * @param discountDetails_: details of the discount being claimed
   * @param gasLimit_: The gas limit, if any, on referrer payments
   * @param proof_: proof for discount checks
   *
   */
  function _processFees(
    uint256 value_,
    uint256 transferCount_,
    DiscountParameters calldata discountDetails_,
    uint256 gasLimit_,
    bytes32[] calldata proof_
  ) internal returns (uint256 referrerPayment_) {
    // Calculate the base fee required:
    uint256 baseFee = transferFee * transferCount_;
    uint256 feeToPay;

    // See if we have a referral ID or a discount to apply based on holding.
    // In both cases the contractOrPayee will be non-zero:
    if (discountDetails_.contractOrPayee == address(0)) {
      // If we are here there is no discount to be applied.
      feeToPay = baseFee;
      referrerPayment_ = 0;
    } else {
      (feeToPay, referrerPayment_) = _processDiscountOrReferral(
        baseFee,
        discountDetails_,
        gasLimit_,
        proof_
      );
    }
    require(value_ == feeToPay, "niftymoves: incorrect payment");

    return (referrerPayment_);
  }

  /**
   *
   * @dev _processDiscountOrReferral: process details for either a referral or a discount
   *
   * @param baseFee_: the ETH required for this call before discounts
   * @param discountDetails_: details of the discount being claimed
   * @param gasLimit_: The gas limit, if any, on referrer payments
   * @param proof_: The merkle proof
   *
   * @return feePaid_ : the total fee to pay
   * @return referrerPayment_ : any referrer payment for the transaction
   *
   */
  function _processDiscountOrReferral(
    uint256 baseFee_,
    DiscountParameters calldata discountDetails_,
    uint256 gasLimit_,
    bytes32[] calldata proof_
  ) internal returns (uint256 feePaid_, uint256 referrerPayment_) {
    // Validate the provided details against the root:
    require(
      rootIsValid(proof_, discountDetails_),
      "niftymoves: invalid discount details for root"
    );

    // Check for a referral ID:
    if (discountDetails_.referralID != bytes12(0)) {
      // We have a referralID. Perform referral processing:
      (feePaid_, referrerPayment_) = _processReferral(
        baseFee_,
        discountDetails_,
        gasLimit_
      );
    } else {
      // If we reach here we must be processing a discount based on holding:
      (feePaid_) = _processDiscount(baseFee_, discountDetails_);
    }
  }

  /**
   *
   * @dev rootIsValid: check the passed details against the root
   *
   * @param proof_: the proof used to check passed details
   * @param discountDetails_: struct object for the claimed discount
   *
   * @return valid_ :  if this set of data is valid (or not)
   *
   */
  function rootIsValid(
    bytes32[] calldata proof_,
    DiscountParameters calldata discountDetails_
  ) public view returns (bool valid_) {
    bytes32 leaf = keccak256(
      abi.encodePacked(
        discountDetails_.contractOrPayee,
        discountDetails_.referralID,
        discountDetails_.tokenID1155,
        discountDetails_.minimumBalance,
        discountDetails_.discountBasisPoints,
        discountDetails_.referrerBasisPoints
      )
    );

    return (MerkleProof.verify(proof_, discountRoot, leaf));
  }

  /**
   *
   * @dev _processReferral: process fees associated with a referral
   *
   * @param baseFee_: the ETH required for this call before discounts
   * @param discountDetails_: details of the discount being claimed
   * @param gasLimit_: The gas limit, if any, on referrer payments
   *
   * @return feePaid_ : the total fee to pay
   * @return referrerPayment_ : any referrer payment for the transaction
   *
   */
  function _processReferral(
    uint256 baseFee_,
    DiscountParameters calldata discountDetails_,
    uint256 gasLimit_
  ) internal returns (uint256 feePaid_, uint256 referrerPayment_) {
    // Calculate the discount:
    (feePaid_) = _calculateDiscount(
      baseFee_,
      discountDetails_.discountBasisPoints
    );

    // Calculate the referral payment as a percentage of the discounted payment:
    referrerPayment_ = ((feePaid_ * discountDetails_.referrerBasisPoints) /
      DENOMINATOR_BASIS_POINTS);

    if (referrerPayment_ > 0) {
      // If gas limit is zero or greater than gas left, use the remaining gas.
      uint256 gas = (gasLimit_ == 0 || gasLimit_ > gasleft())
        ? gasleft()
        : gasLimit_;

      (bool success, ) = discountDetails_.contractOrPayee.call{
        value: referrerPayment_,
        gas: gas
      }("");
      // If the ETH transfer fails, wrap the ETH and try send it as WETH.
      if (!success) {
        wethContract.deposit{value: referrerPayment_}();
        IERC20(address(wethContract)).safeTransfer(
          discountDetails_.contractOrPayee,
          referrerPayment_
        );
      }
    }

    return (feePaid_, referrerPayment_);
  }

  /**
   *
   * @dev _processDiscount: process fees associated with a holding discount
   *
   * @param baseFee_: the ETH required for this call before discounts
   * @param discountDetails_: details of the discount being claimed
   *
   * @return feePaid_ : the total fee to pay
   *
   */
  function _processDiscount(
    uint256 baseFee_,
    DiscountParameters calldata discountDetails_
  ) internal view returns (uint256 feePaid_) {
    // Check they hold the required balance:
    require(
      _hasSufficientBalance(
        discountDetails_.contractOrPayee,
        discountDetails_.tokenID1155,
        discountDetails_.minimumBalance
      ),
      "niftymoves: insufficient holding for discount"
    );

    // Calculate the discount:
    feePaid_ = _calculateDiscount(
      baseFee_,
      discountDetails_.discountBasisPoints
    );

    return (feePaid_);
  }

  /**
   *
   * @dev _calculateDiscount: calculate the discount and therefore fee required
   *
   * @param baseFee_: the ETH required for this call before discounts
   * @param discountBasisPoints_: basis points of the discount
   *
   * @return feePaid_ : the total fee to pay
   *
   */
  function _calculateDiscount(
    uint256 baseFee_,
    uint256 discountBasisPoints_
  ) internal pure returns (uint256 feePaid_) {
    // Calculate the fee required given the discount:
    feePaid_ = (baseFee_ -
      ((baseFee_ * discountBasisPoints_) / DENOMINATOR_BASIS_POINTS));

    return (feePaid_);
  }

  /**
   *
   * @dev _hasSufficientBalance: check the caller holds a sufficient balance for the discount
   *
   * @param contractAddress_: the contract on which to check the holder's balance
   * @param tokenID1155_: this is populated if we need to check an 1155 balance
   * @param minimumBalance_: the minimum balance requirement for this discount
   *
   * @return hasBalance_ : if the holder has sufficient balance (or not)
   *
   */
  function _hasSufficientBalance(
    address contractAddress_,
    uint256 tokenID1155_,
    uint256 minimumBalance_
  ) internal view returns (bool hasBalance_) {
    if (tokenID1155_ != 0) {
      // Perform 1155 balance check
      return _balanceCheck1155(contractAddress_, tokenID1155_, minimumBalance_);
    } else {
      // Perform ERC721 / 20 / 777 check
      return (IERC721(contractAddress_).balanceOf(_msgSender()) >=
        minimumBalance_);
    }
  }

  /**
   *
   * @dev _balanceCheck1155: check the caller holds a sufficient balance for the discount
   *
   * @param contractAddress_: the contract on which to check the holder's balance
   * @param tokenID1155_: this is populated if we need to check an 1155 balance
   * @param minimumBalance_: the minimum balance requirement for this discount
   *
   * @return hasBalance_ : if the holder has sufficient balance (or not)
   *
   */
  function _balanceCheck1155(
    address contractAddress_,
    uint256 tokenID1155_,
    uint256 minimumBalance_
  ) internal view returns (bool hasBalance_) {
    // Perform 1155 check:
    uint256 tokenIDToCheck;
    if (tokenID1155_ == type(uint256).max) {
      tokenIDToCheck = 0;
    } else {
      tokenIDToCheck = tokenID1155_;
    }
    return (IERC1155(contractAddress_).balanceOf(
      _msgSender(),
      tokenIDToCheck
    ) >= minimumBalance_);
  }

  /**
   *
   * @dev onERC721Received: allow transfer from owner (for the ENS token).
   *
   * @param from_: used to check this is only from the contract owner
   *
   */
  function onERC721Received(
    address,
    address from_,
    uint256,
    bytes memory
  ) external view override returns (bytes4) {
    if (from_ == owner()) {
      return this.onERC721Received.selector;
    } else {
      return ("");
    }
  }

  /**
   *
   * @dev Revert unexpected ETH
   *
   */
  receive() external payable {
    require(
      _msgSender() == owner(),
      "niftymoves: only owner can fund contract"
    );
  }

  /**
   *
   * @dev Revert unexpected function calls
   *
   */
  fallback() external payable {
    revert();
  }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.7.0) (access/Ownable.sol)

pragma solidity ^0.8.0;

import "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _transferOwnership(_msgSender());
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions anymore. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby removing any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.7.0) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.0;

import "../IERC20.sol";
import "../extensions/draft-IERC20Permit.sol";
import "../../../utils/Address.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using Address for address;

    function safeTransfer(
        IERC20 token,
        address to,
        uint256 value
    ) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transfer.selector, to, value));
    }

    function safeTransferFrom(
        IERC20 token,
        address from,
        address to,
        uint256 value
    ) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transferFrom.selector, from, to, value));
    }

    /**
     * @dev Deprecated. This function has issues similar to the ones found in
     * {IERC20-approve}, and its usage is discouraged.
     *
     * Whenever possible, use {safeIncreaseAllowance} and
     * {safeDecreaseAllowance} instead.
     */
    function safeApprove(
        IERC20 token,
        address spender,
        uint256 value
    ) internal {
        // safeApprove should only be called when setting an initial allowance,
        // or when resetting it to zero. To increase and decrease it, use
        // 'safeIncreaseAllowance' and 'safeDecreaseAllowance'
        require(
            (value == 0) || (token.allowance(address(this), spender) == 0),
            "SafeERC20: approve from non-zero to non-zero allowance"
        );
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, value));
    }

    function safeIncreaseAllowance(
        IERC20 token,
        address spender,
        uint256 value
    ) internal {
        uint256 newAllowance = token.allowance(address(this), spender) + value;
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, newAllowance));
    }

    function safeDecreaseAllowance(
        IERC20 token,
        address spender,
        uint256 value
    ) internal {
        unchecked {
            uint256 oldAllowance = token.allowance(address(this), spender);
            require(oldAllowance >= value, "SafeERC20: decreased allowance below zero");
            uint256 newAllowance = oldAllowance - value;
            _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, newAllowance));
        }
    }

    function safePermit(
        IERC20Permit token,
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) internal {
        uint256 nonceBefore = token.nonces(owner);
        token.permit(owner, spender, value, deadline, v, r, s);
        uint256 nonceAfter = token.nonces(owner);
        require(nonceAfter == nonceBefore + 1, "SafeERC20: permit did not succeed");
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We use {Address.functionCall} to perform this call, which verifies that
        // the target address contains contract code and also asserts for success in the low-level call.

        bytes memory returndata = address(token).functionCall(data, "SafeERC20: low-level call failed");
        if (returndata.length > 0) {
            // Return data is optional
            require(abi.decode(returndata, (bool)), "SafeERC20: ERC20 operation did not succeed");
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.7.0) (utils/Strings.sol)

pragma solidity ^0.8.0;

/**
 * @dev String operations.
 */
library Strings {
    bytes16 private constant _HEX_SYMBOLS = "0123456789abcdef";
    uint8 private constant _ADDRESS_LENGTH = 20;

    /**
     * @dev Converts a `uint256` to its ASCII `string` decimal representation.
     */
    function toString(uint256 value) internal pure returns (string memory) {
        // Inspired by OraclizeAPI's implementation - MIT licence
        // https://github.com/oraclize/ethereum-api/blob/b42146b063c7d6ee1358846c198246239e9360e8/oraclizeAPI_0.4.25.sol

        if (value == 0) {
            return "0";
        }
        uint256 temp = value;
        uint256 digits;
        while (temp != 0) {
            digits++;
            temp /= 10;
        }
        bytes memory buffer = new bytes(digits);
        while (value != 0) {
            digits -= 1;
            buffer[digits] = bytes1(uint8(48 + uint256(value % 10)));
            value /= 10;
        }
        return string(buffer);
    }

    /**
     * @dev Converts a `uint256` to its ASCII `string` hexadecimal representation.
     */
    function toHexString(uint256 value) internal pure returns (string memory) {
        if (value == 0) {
            return "0x00";
        }
        uint256 temp = value;
        uint256 length = 0;
        while (temp != 0) {
            length++;
            temp >>= 8;
        }
        return toHexString(value, length);
    }

    /**
     * @dev Converts a `uint256` to its ASCII `string` hexadecimal representation with fixed length.
     */
    function toHexString(uint256 value, uint256 length) internal pure returns (string memory) {
        bytes memory buffer = new bytes(2 * length + 2);
        buffer[0] = "0";
        buffer[1] = "x";
        for (uint256 i = 2 * length + 1; i > 1; --i) {
            buffer[i] = _HEX_SYMBOLS[value & 0xf];
            value >>= 4;
        }
        require(value == 0, "Strings: hex length insufficient");
        return string(buffer);
    }

    /**
     * @dev Converts an `address` with fixed length of 20 bytes to its not checksummed ASCII `string` hexadecimal representation.
     */
    function toHexString(address addr) internal pure returns (string memory) {
        return toHexString(uint256(uint160(addr)), _ADDRESS_LENGTH);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (token/ERC20/extensions/draft-IERC20Permit.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 Permit extension allowing approvals to be made via signatures, as defined in
 * https://eips.ethereum.org/EIPS/eip-2612[EIP-2612].
 *
 * Adds the {permit} method, which can be used to change an account's ERC20 allowance (see {IERC20-allowance}) by
 * presenting a message signed by the account. By not relying on {IERC20-approve}, the token holder account doesn't
 * need to send a transaction, and thus is not required to hold Ether at all.
 */
interface IERC20Permit {
    /**
     * @dev Sets `value` as the allowance of `spender` over ``owner``'s tokens,
     * given ``owner``'s signed approval.
     *
     * IMPORTANT: The same issues {IERC20-approve} has related to transaction
     * ordering also apply here.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `deadline` must be a timestamp in the future.
     * - `v`, `r` and `s` must be a valid `secp256k1` signature from `owner`
     * over the EIP712-formatted function arguments.
     * - the signature must use ``owner``'s current nonce (see {nonces}).
     *
     * For more information on the signature format, see the
     * https://eips.ethereum.org/EIPS/eip-2612#specification[relevant EIP
     * section].
     */
    function permit(
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external;

    /**
     * @dev Returns the current nonce for `owner`. This value must be
     * included whenever a signature is generated for {permit}.
     *
     * Every successful call to {permit} increases ``owner``'s nonce by one. This
     * prevents a signature from being used multiple times.
     */
    function nonces(address owner) external view returns (uint256);

    /**
     * @dev Returns the domain separator used in the encoding of the signature for {permit}, as defined by {EIP712}.
     */
    // solhint-disable-next-line func-name-mixedcase
    function DOMAIN_SEPARATOR() external view returns (bytes32);
}

{
  "compilationTarget": {
    "contracts/NIFTYMOVES/contracts/NiftyMoves.sol": "NiftyMoves"
  },
  "evmVersion": "shanghai",
  "libraries": {},
  "metadata": {
    "bytecodeHash": "ipfs"
  },
  "optimizer": {
    "enabled": true,
    "runs": 200
  },
  "remappings": []
}